an ASCII emulated light moving on the screen SUB vs GOSUB version

[TempodiBasic]

Hi guys

thanks to all you to read this post...
I have tried to emulate an ASCII screen in 32bit  to create a light moving with arrows...

here is

Code: QB64: [Select]

1. DIM SHARED A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG
2. DIM SHARED r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER
3. DIM row AS INTEGER, col AS INTEGER
4. DIM min AS INTEGER, max AS INTEGER, up AS INTEGER, down AS INTEGER
5.  
6. Setup
7. CalculateRows
8.  
9. col = 1
10. row = 10
11. min = 1
12. max = 44
13. up = 1
14. down = 23
15.  
16. DO
17.     IF _KEYDOWN(19200) THEN
18.         LOCATE 27, 1: COLOR whites(1): PRINT "Left"
19.         IF col > min THEN col = col - 1
20.     END IF
21.     IF _KEYDOWN(19712) THEN
22.         LOCATE 27, 1: COLOR whites(1): PRINT "Right"
23.         IF col < max THEN col = col + 1
24.     END IF
25.     IF _KEYDOWN(18432) THEN
26.         LOCATE 27, 1: COLOR whites(1): PRINT "Up"
27.         IF row > up THEN row = row - 1
28.     END IF
29.     IF _KEYDOWN(20480) THEN
30.         LOCATE 27, 1: COLOR whites(1): PRINT "Down"
31.         IF row < down THEN row = row + 1
32.     END IF
33.  
34.     MoveLight row, col, 10, 1, 1
35.     LOCATE 26, 1: COLOR _RGB(255, 255, 55), Black: PRINT " press arrows to move light, space to quit ";
36.     _LIMIT 15
37.     CLS
38. LOOP UNTIL _KEYDOWN(32) = -1
39. END
40.  
41. SUB MoveLight (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
42.     outputs row, col, min, max, -steps
43.     outputs row, min + col, max, min, steps
44.     outputs row + 1, col, min, max, -steps
45.     outputs row + 1, min + col, max, min, steps
46.     outputs row + 2, col, min, max, -steps
47.     outputs row + 2, min + col, max, min, steps
48. END SUB
49.  
50. SUB outputs (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
51.     LOCATE row, col
52.     FOR r = min TO max STEP steps
53.         COLOR Black, whites(r): PRINT "0";
54.     NEXT
55. END SUB
56.  
57. SUB Setup
58.     A = _NEWIMAGE(500, 500, 32)
59.     IF A THEN SCREEN A ELSE PRINT "Error create SCREEN"
60.     Black = _RGB(0, 0, 0)
61.     whites(1) = _RGB(255, 255, 255)
62.     r = 255
63.     b = 255
64.     g = 255
65.     counter = 1
66.     FOR counter = 1 TO 10
67.         r = r - INT(255 / 10)
68.         b = b - INT(255 / 10)
69.         g = g - INT(255 / 10)
70.         whites(counter) = _RGB(r, g, b)
71.     NEXT counter
72. END SUB
73.  
74. SUB CalculateRows
75.     LOCATE 1, 1: COLOR _RGB(0, 127, 127)
76.     FOR x = 1 TO 80 STEP 1
77.         IF x > -1 THEN PRINT LTRIM$(STR$(x MOD 10));
78.     NEXT x
79.     SLEEP 3
80. END SUB
81.  
82.  

and here is the same code  modded to using GOSUB at the place of SUBs

Code: QB64: [Select]

1. DIM A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG
2. DIM r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER
3. DIM row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER
4. DIM row1 AS INTEGER, col1 AS INTEGER
5. DIM Smin AS INTEGER, Smax AS INTEGER, Sup AS INTEGER, Sdown AS INTEGER
6.  
7. GOSUB Setup
8.  
9. GOSUB CalculateRows
10.  
11. col = 1
12. row = 10
13. Smin = 1
14. Smax = 44
15. Sup = 1
16. Sdown = 23
17. col1 = 0
18. row1 = 0
19. steps = 0
20. DO
21.     IF _KEYDOWN(19200) THEN
22.         LOCATE 27, 1: COLOR whites(1): PRINT "Left"
23.         IF col > Smin THEN col = col - 1
24.     END IF
25.     IF _KEYDOWN(19712) THEN
26.         LOCATE 27, 1: COLOR whites(1): PRINT "Right"
27.         IF col < Smax THEN col = col + 1
28.     END IF
29.     IF _KEYDOWN(18432) THEN
30.         LOCATE 27, 1: COLOR whites(1): PRINT "Up"
31.         IF row > Sup THEN row = row - 1
32.     END IF
33.     IF _KEYDOWN(20480) THEN
34.         LOCATE 27, 1: COLOR whites(1): PRINT "Down"
35.         IF row < Sdown THEN row = row + 1
36.     END IF
37.     min = 10
38.     max = 1
39.     steps = 1
40.     GOSUB MoveLight
41.     LOCATE 26, 1: COLOR _RGB(255, 255, 55), Black: PRINT " press arrows to move light, space to quit ";
42.     _LIMIT 15
43.     CLS
44. LOOP UNTIL _KEYDOWN(32) = -1
45. END
46.  
47.  
48.  
49. MoveLight:
50.  
51. col1 = col
52. steps = -steps
53. row1 = row
54. GOSUB outputs
55. row1 = row1 + 1
56. GOSUB outputs
57. row1 = row1 + 1
58. GOSUB outputs
59.  
60. SWAP min, max
61. steps = -steps
62. col1 = col1 + 10
63. row1 = row
64. GOSUB outputs
65. row1 = row1 + 1
66. GOSUB outputs
67. row1 = row1 + 1
68. GOSUB outputs
69. RETURN
70.  
71. outputs:
72. LOCATE row1, col1
73. FOR r = min TO max STEP steps
74.     COLOR Black, whites(r): PRINT "0";
75. NEXT r
76. RETURN
77.  
78. Setup:
79. A = _NEWIMAGE(500, 500, 32)
80. IF A THEN SCREEN A ELSE PRINT "Error create SCREEN"
81. Black = _RGB(0, 0, 0)
82. whites(1) = _RGB(255, 255, 255)
83. r = 255
84. b = 255
85. g = 255
86. counter = 1
87. FOR counter = 1 TO 10
88.     r = r - INT(255 / 10)
89.     b = b - INT(255 / 10)
90.     g = g - INT(255 / 10)
91.     whites(counter) = _RGB(r, g, b)
92. NEXT counter
93. RETURN
94.  
95. CalculateRows:
96. LOCATE 1, 1: COLOR _RGB(0, 127, 127)
97. FOR x = 1 TO 80 STEP 1
98.     IF x > -1 THEN PRINT LTRIM$(STR$(x MOD 10));
99. NEXT x
100. SLEEP 3
101. RETURN
102.  

thanks for feedback

Here attached files for who doesn't like to select-copy-paste from codeboxes.

[TempodiBasic]

Sorry I have missed the background that is here:

Code: QB64: [Select]

1. DIM SHARED A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG, Black2 AS LONG
2. DIM SHARED r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER
3. DIM row AS INTEGER, col AS INTEGER
4. DIM min AS INTEGER, max AS INTEGER, up AS INTEGER, down AS INTEGER
5.  
6. Setup
7. 'CalculateRows
8. '30 rows and 62 columns
9. col = 1
10. row = 10
11. min = 1
12. max = 44
13. up = 1
14. down = 23
15.  
16. DO
17.     IF _KEYDOWN(19200) THEN
18.         LOCATE 27, 1: COLOR whites(1): PRINT "Left    "
19.         IF col > min THEN col = col - 1
20.     END IF
21.     IF _KEYDOWN(19712) THEN
22.         LOCATE 27, 1: COLOR whites(1): PRINT "Right    "
23.         IF col < max THEN col = col + 1
24.     END IF
25.     IF _KEYDOWN(18432) THEN
26.         LOCATE 27, 1: COLOR whites(1): PRINT "Up       "
27.         IF row > up THEN row = row - 1
28.     END IF
29.     IF _KEYDOWN(20480) THEN
30.         LOCATE 27, 1: COLOR whites(1): PRINT "Down     "
31.         IF row < down THEN row = row + 1
32.     END IF
33.     Arena
34.     MoveLight row, col, 10, 1, 1
35.     LOCATE 26, 1: COLOR _RGB(255, 255, 55), Black: PRINT " press arrows to move light, space to quit ";
36.     _LIMIT 12
37.     CLS
38. LOOP UNTIL _KEYDOWN(32) = -1
39. END
40.  
41. SUB Arena
42.     LOCATE 1, 1
43.     COLOR Black2, Black
44.     FOR x = 1 TO 25 STEP 1
45.         PRINT STRING$(62, "0");
46.     NEXT x
47. END SUB
48.  
49. SUB MoveLight (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
50.     outputs row, col, min, max, -steps
51.     outputs row, min + col, max, min, steps
52.     outputs row + 1, col, min, max, -steps
53.     outputs row + 1, min + col, max, min, steps
54.     outputs row + 2, col, min, max, -steps
55.     outputs row + 2, min + col, max, min, steps
56. END SUB
57.  
58. SUB outputs (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
59.     LOCATE row, col
60.     FOR r = min TO max STEP steps
61.         COLOR Black, whites(r): PRINT "0";
62.     NEXT
63. END SUB
64.  
65.  
66. SUB Setup
67.     A = _NEWIMAGE(500, 500, 32)
68.     IF A THEN SCREEN A ELSE PRINT "Error create SCREEN"
69.     Black = _RGB(0, 0, 0)
70.     Black2 = _RGB(0, 0, 15)
71.     whites(1) = _RGB(255, 255, 255)
72.     r = 255
73.     b = 255
74.     g = 255
75.     counter = 1
76.     FOR counter = 1 TO 10
77.         r = r - INT(255 / 10)
78.         b = b - INT(255 / 10)
79.         g = g - INT(255 / 10)
80.         whites(counter) = _RGB(r, g, b)
81.     NEXT counter
82. END SUB
83.  
84. SUB CalculateRows
85.     LOCATE 1, 1: COLOR _RGB(0, 127, 127)
86.     FOR x = 1 TO 80 STEP 1
87.         IF x > -1 THEN PRINT LTRIM$(STR$(x MOD 10));
88.     NEXT x
89.     PRINT
90.     FOR x = 1 TO 30 STEP 1
91.         IF x > -1 THEN PRINT LTRIM$(STR$(x MOD 10))
92.     NEXT x
93.  
94.     SLEEP
95. END SUB
96.  

now you can see a rectangular light on the background

[Jack002]

Neat effect. This should work well in a game.

[Raptor88]

Hi guys

thanks to all you to read this post...
I have tried to emulate an ASCII screen in 32bit  to create a light moving with arrows...

here is

Code: QB64: [Select]

1. DIM SHARED A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG
2. DIM SHARED r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER
3. DIM row AS INTEGER, col AS INTEGER
4. DIM min AS INTEGER, max AS INTEGER, up AS INTEGER, down AS INTEGER
5.  
6. Setup
7. CalculateRows
8.  
9. col = 1
10. row = 10
11. min = 1
12. max = 44
13. up = 1
14. down = 23
15.  
16. DO
17.     IF _KEYDOWN(19200) THEN
18.         LOCATE 27, 1: COLOR whites(1): PRINT "Left"
19.         IF col > min THEN col = col - 1
20.     END IF
21.     IF _KEYDOWN(19712) THEN
22.         LOCATE 27, 1: COLOR whites(1): PRINT "Right"
23.         IF col < max THEN col = col + 1
24.     END IF
25.     IF _KEYDOWN(18432) THEN
26.         LOCATE 27, 1: COLOR whites(1): PRINT "Up"
27.         IF row > up THEN row = row - 1
28.     END IF
29.     IF _KEYDOWN(20480) THEN
30.         LOCATE 27, 1: COLOR whites(1): PRINT "Down"
31.         IF row < down THEN row = row + 1
32.     END IF
33.  
34.     MoveLight row, col, 10, 1, 1
35.     LOCATE 26, 1: COLOR _RGB(255, 255, 55), Black: PRINT " press arrows to move light, space to quit ";
36.     _LIMIT 15
37.     CLS
38. LOOP UNTIL _KEYDOWN(32) = -1
39. END
40.  
41. SUB MoveLight (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
42.     outputs row, col, min, max, -steps
43.     outputs row, min + col, max, min, steps
44.     outputs row + 1, col, min, max, -steps
45.     outputs row + 1, min + col, max, min, steps
46.     outputs row + 2, col, min, max, -steps
47.     outputs row + 2, min + col, max, min, steps
48. END SUB
49.  
50. SUB outputs (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)
51.     LOCATE row, col
52.     FOR r = min TO max STEP steps
53.         COLOR Black, whites(r): PRINT "0";
54.     NEXT
55. END SUB
56.  
57. SUB Setup
58.     A = _NEWIMAGE(500, 500, 32)
59.     IF A THEN SCREEN A ELSE PRINT "Error create SCREEN"
60.     Black = _RGB(0, 0, 0)
61.     whites(1) = _RGB(255, 255, 255)
62.     r = 255
63.     b = 255
64.     g = 255
65.     counter = 1
66.     FOR counter = 1 TO 10
67.         r = r - INT(255 / 10)
68.         b = b - INT(255 / 10)
69.         g = g - INT(255 / 10)
70.         whites(counter) = _RGB(r, g, b)
71.     NEXT counter
72. END SUB
73.  
74. SUB CalculateRows
75.     LOCATE 1, 1: COLOR _RGB(0, 127, 127)
76.     FOR x = 1 TO 80 STEP 1
77.         IF x > -1 THEN PRINT LTRIM$(STR$(x MOD 10));
78.     NEXT x
79.     SLEEP 3
80. END SUB
81.  
82.  

Hi Tempodi,

I just started using QB64.  Regarding your SUB version, how about using this as the first line in the code:
DEFINT A-Z

I believe that would automatically define all variables as integers unless otherwise DIM'ed as longs.

Then the line:
SUB MoveLight (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)

could be simplified as:
SUB MoveLight (row, col, min, max, steps)

It would also negate the need for the lines:
DIM row AS INTEGER, col AS INTEGER
DIM min AS INTEGER, max AS INTEGER, up AS INTEGER, down AS INTEGER
and just use:
col = 1
row = 10
min = 1
max = 44
up = 1
down = 23

I'm new to QB64 so I'm not sure if doing the above has any cons when most variables are integers.
PS:  I'm learning from your code as a clean example of how to use SUBS.

[SMcNeill]

I just started using QB64.  Regarding your SUB version, how about using this as the first line in the code:
DEFINT A-Z

I believe that would automatically define all variables as integers unless otherwise DIM'ed as longs.

Then the line:
SUB MoveLight (row AS INTEGER, col AS INTEGER, min AS INTEGER, max AS INTEGER, steps AS INTEGER)

could be simplified as:
SUB MoveLight (row, col, min, max, steps)

Personally, I prefer to make SUBs with the variables explicitly defined, such as in the original.

The reason?

I prefer modular coding techniques and want to make my subs and functions as simple as possible to move from one program to another.

Let’s say I have a program like this:

DEFINT A-Z
..... stuff
SUB Whatever (x, y)
.....more stuff
END SUB

Now, x and y are integers and everything runs just fine...

BUT....

What if I want to reuse that sub in other code that starts with _DEFINE A-Z AS _FLOAT?  Will it still function and work as intended?  Will it generate rounding errors over time?  Can I now get edge-case exceptions where 3.2 + 4.4 = 7.6, which might round to 8??

By explicitly defining SUB Whatever (x AS INTEGER, y AS INTEGER), it can be ripped out and reused in another program, with fewer concerns and issues.

[Raptor88]

Personally, I prefer to make SUBs with the variables explicitly defined, such as in the original.

The reason?

I prefer modular coding techniques and want to make my subs and functions as simple as possible to move from one program to another.

Let’s say I have a program like this:

DEFINT A-Z
..... stuff
SUB Whatever (x, y)
.....more stuff
END SUB

Now, x and y are integers and everything runs just fine...

BUT....

What if I want to reuse that sub in other code that starts with _DEFINE A-Z AS _FLOAT?  Will it still function and work as intended?  Will it generate rounding errors over time?  Can I now get edge-case exceptions where 3.2 + 4.4 = 7.6, which might round to 8??

By explicitly defining SUB Whatever (x AS INTEGER, y AS INTEGER), it can be ripped out and reused in another program, with fewer concerns and issues.

Explicitly defining SUB variables for reuse of SUBs in another program is something I had not thought of.  Thanks for this info.
Raptor88

[TempodiBasic]

Hi Raptor88

thanks to take a look at my code

about why I don't use a global definition of the type of the variables at the begin of the code....

1. the first reason is that has explained with supreme clearness Steve, the reusability of the code if you use the SUBs and Functions. I started this habit in writing code in the time of when I was coding in Qbasic,   in which I realized that more times I had had coded for the same functions (mouse implementation by ASM and Call Absolute, ASCII windowing in MSDOS etc). Moreover in QB you can make an your own library that you could compile using a command line option on loading QB, today in QB64 you can use your personal library splitting your code in declaration part (that you $include: at the start of the program) and in code part (that you $include: at the end of the program).

2. the second reason is that also if you use DEFINT or DEFSTR or someother definition,  you must DIM SHARED or COMMON variables

DIM SHARED A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG
DIM SHARED r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER

3. the third reason is that I am following some instructions to write clear code to be readable also after much time and avoid bugs. These instructions are born for coding clear C but they works fine also for Basic. The concepts behind are writing names (constants, variables, labels, subs and functions) that tell you what do that code, chunk the work in miniworks to assemble in sequence, initialize variables to default values before to use them and to avoid garbage in RAM, release the resources that are not more used (opened files, images loaded, sound loaded, arrays and variables dynamic).
 
Thanks to read

[Raptor88]

Hi Tempodi,

Thanks for taking the time to explain.  All makes sense. 

Am learning as I go,
Raptor88

[bplus]

2. the second reason is that also if you use DEFINT or DEFSTR or someother definition,  you must DIM SHARED or COMMON variables
Quote
DIM SHARED A AS LONG, whites(1 TO 50) AS LONG, Black AS LONG
DIM SHARED r AS INTEGER, g AS INTEGER, b AS INTEGER, counter AS INTEGER

I confess, I don't understand "you must" ? You don't even have to DIM other types if you use suffixes, so why "must" they also be SHARED or COMMON?

It is probably good form to use OPTION _EXPLICIT which forces DIM for everything. C coders would approve, I think. :)

[TempodiBasic]

Hi Bplus
sorry for my bad communication
about

2. the second reason is that also if you use DEFINT or DEFSTR or someother definition,  you must DIM SHARED or COMMON variables

I'm trying to say that also if I use DEFINT (or another definition type of data) when I need Global variables I must declare them also if the type has been declare before with the command of type definition...
for example

DEFINT A-C   '<--- this force all variables typed and that their name starts with A or B or C to be integer
DIM SHARED Account [AS INTEGER]  '<--- to create this integer variable as global (DIM SHARED) I must declare there variable  [ You are not allowed to view this attachment ]