Practicing Coding Game

[eddy498]

thanks lol. if i want to be able to do my own games i want to be able to do them from scratch not just getting pictures and working with them. ill dissect this code for a bit if i come up with any questions ill post it up again :)

[bplus]

A simpler tree:

Code: QB64: [Select]

1. _TITLE "Basic Tree from branch"
2. RANDOMIZE TIMER
3. SCREEN _NEWIMAGE(800, 600, 32)
4. _SCREENMOVE 300, 20
5. COLOR _RGB32(0, 255, 0)
6.  
7. 'just test call to sub
8. '       x,   y,  270, .2*height, 1  start a tree with 270 degrees to point up, and about 1/5 the height you want to grow the tree
9. branch 400, 500, 270, 100, 1
10. PRINT "press any to see the forest..."
11. SLEEP
12.  
13. horizon = .35 * _HEIGHT
14. FOR i = 0 TO horizon
15.     LINE (0, i)-(_WIDTH, i), _RGB(0, 0, .25 * i + 100)
16. NEXT
17. FOR i = horizon TO _HEIGHT
18.     LINE (0, i)-(_WIDTH, i), _RGB(0, 255 - .25 * i - 50, 0)
19. NEXT
20. FOR i = 1 TO 250
21.     y = randWeight(horizon, _HEIGHT, 3)
22.     branch _WIDTH * RND, y, 270, .04 * y, 1
23. NEXT
24.  
25. SUB branch (x, y, angD, lngth, lev)
26.     x2 = x + COS(_D2R(angD)) * lngth
27.     y2 = y + SIN(_D2R(angD)) * lngth
28.     LINE (x, y)-(x2, y2), _RGB32(RND * 100, RND * 170 + 80, RND * 50)
29.     IF lev > 6 OR lngth < 2 THEN EXIT SUB
30.     l = lev + 1
31.     branch x2, y2, angD + 10 + 30 * RND, .7 * lngth + .2 * RND * lngth, l
32.     branch x2, y2, angD - 10 - 30 * RND, .7 * lngth + .2 * RND * lngth, l
33.     IF RND < .65 THEN branch x2, y2, angD + 20 * RND - 10, .7 * lngth + .2 * RND * lngth, l
34. END SUB
35.  
36. FUNCTION randWeight (manyValue, fewValue, power)
37.     randWeight = manyValue + RND ^ power * (fewValue - manyValue)
38. END FUNCTION
39.