SUB thickLine

[FellippeHeitor]

This can be used to draw a line with a specified lineWidth%:

Code: QB64: [Select]

1. SUB thickLine (x1!, y1!, x2!, y2!, lineWidth%)
2.     DIM angle%, distance%, halfThickness%
3.     angle% = INT(_R2D(_ATAN2(y2! - y1!, x2! - x1!)))
4.     distance% = _HYPOT((x2! - x1!), (y2! - y1!))
5.     halfThickness% = lineWidth% / 2
6.     IF halfThickness% < 1 THEN halfThickness% = 1
7.     IF halfThickness% = 1 THEN
8.         DRAW "bm" + STR$(x1!) + "," + STR$(y1!) + " TA" + STR$(-angle%) + " R" + STR$(distance%)
9.     ELSE
10.         DRAW "bm" + STR$(x1!) + "," + STR$(y1!) + " TA" + STR$(-angle%) + "U" + STR$(halfThickness%) + " R" + STR$(distance%) + "D" + STR$(halfThickness% * 2) + " L" + STR$(distance%) + "U" + STR$(halfThickness%) + " B R" + STR$(distance% / 2) + "P" + STR$(_DEFAULTCOLOR) + "," + STR$(_DEFAULTCOLOR)
11.     END IF
12. END SUB

Sample code using the method:

Code: QB64: [Select]

1. CONST false = 0, true = NOT false
2.  
3. DIM x1, y1, x2, y2
4. DIM mouseDown AS _BYTE
5. DIM totalDots AS INTEGER
6. DIM thickness AS INTEGER
7.  
8. thickness = 10
9.  
10. SCREEN _NEWIMAGE(800, 600, 32)
11.  
12. DO
13.     WHILE _MOUSEINPUT: thickness = thickness + _MOUSEWHEEL: WEND
14.  
15.     IF thickness < 1 THEN thickness = 1
16.  
17.     IF _MOUSEBUTTON(1) THEN
18.         IF NOT mouseDown THEN
19.             mouseDown = true
20.             totalDots = totalDots + 1
21.             IF totalDots > 2 THEN totalDots = 1
22.             SELECT CASE totalDots
23.                 CASE 1
24.                     x1 = _MOUSEX
25.                     y1 = _MOUSEY
26.                 CASE 2
27.                     x2 = _MOUSEX
28.                     y2 = _MOUSEY
29.             END SELECT
30.         END IF
31.     ELSE
32.         mouseDown = false
33.     END IF
34.  
35.     CLS
36.     PRINT "Click to set the initial line coordinate,"
37.     PRINT "click again to set the final line coordinate."
38.     PRINT "Use the mousewheel to make the line thicker/thinner."
39.     PRINT "Current thickness:"; thickness
40.  
41.     IF totalDots = 1 THEN
42.         PSET (x1, y1)
43.     ELSE
44.         thickLine x1, y1, x2, y2, thickness
45.     END IF
46.     _DISPLAY
47.     _LIMIT 30
48. LOOP
49.  
50. SUB thickLine (x1!, y1!, x2!, y2!, lineWidth%)
51.     DIM angle%, distance%, halfThickness%
52.     angle% = INT(_R2D(_ATAN2(y2! - y1!, x2! - x1!)))
53.     distance% = _HYPOT((x2! - x1!), (y2! - y1!))
54.     halfThickness% = lineWidth% / 2
55.     IF halfThickness% < 1 THEN halfThickness% = 1
56.     IF halfThickness% = 1 THEN
57.         DRAW "bm" + STR$(x1!) + "," + STR$(y1!) + " TA" + STR$(-angle%) + " R" + STR$(distance%)
58.     ELSE
59.         DRAW "bm" + STR$(x1!) + "," + STR$(y1!) + " TA" + STR$(-angle%) + "U" + STR$(halfThickness%) + " R" + STR$(distance%) + "D" + STR$(halfThickness% * 2) + " L" + STR$(distance%) + "U" + STR$(halfThickness%) + " B R" + STR$(distance% / 2) + "P" + STR$(_DEFAULTCOLOR) + "," + STR$(_DEFAULTCOLOR)
60.     END IF
61. END SUB

[FellippeHeitor]

Same idea, different method. This version of the SUB uses _MAPTRIANGLE to achieve similar results. You can replace this in the sample above and it'll work as expected:

Code: QB64: [Select]

1. SUB thickLine (x1 AS SINGLE, y1 AS SINGLE, x2 AS SINGLE, y2 AS SINGLE, lineWeight%)
2.     DIM a AS SINGLE, x0 AS SINGLE, y0 AS SINGLE
3.     DIM prevDest AS LONG, prevColor AS _UNSIGNED LONG
4.     STATIC colorSample AS LONG
5.  
6.     IF colorSample = 0 THEN
7.         colorSample = _NEWIMAGE(1, 1, 32)
8.     END IF
9.  
10.     prevDest = _DEST
11.     prevColor = _DEFAULTCOLOR
12.     _DEST colorSample
13.     PSET (0, 0), prevColor
14.     _DEST prevDest
15.  
16.     a = _ATAN2(y2 - y1, x2 - x1)
17.     a = a + _PI / 2
18.     x0 = 0.5 * lineWeight% * COS(a)
19.     y0 = 0.5 * lineWeight% * SIN(a)
20.  
21.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), colorSample TO(x1 - x0, y1 - y0)-(x1 + x0, y1 + y0)-(x2 + x0, y2 + y0), , _SMOOTH
22.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), colorSample TO(x1 - x0, y1 - y0)-(x2 + x0, y2 + y0)-(x2 - x0, y2 - y0), , _SMOOTH
23. END SUB

This is the same method Ashish and I used for p5js.bas

[Pete]

How about underlined letters? SmallBASIC for Android has that, oooh and italics! I can't recall if this was ever added to QB64 or not. I  recall making something close to this for a graphics GUI that had http hypertext I wanted underlined. Hmmm, maybe I need to go dig that one up.

Atari BASIC actually had a very easy way to customize the 8x8 pixel grid of each ASCII character, so you could make your own underline characters very easily, although italics would be a lot more work involved.

Pete :)

PS The mouse wheel was a nice effect!

[FellippeHeitor]

PS The mouse wheel was a nice effect!

Thanks, Pete!