Intro Video for my KingsBounty game.

[Cobalt]

 Finished the intro for my King's Bounty clone and since it seems a lot of people can't get audio working in QB64 I thought I'd capture it to a video, so its posted on youtube for everybody to check out. 

Let me Know: A-if the link works, B-what you think of how the Intro 'flows'

Here is the code,

Code: QB64: [Select]

1. 'Kings Bounty 64, Logo Screen Intro
2. '2019, Feb 25, 18:10 EST
3. '2019, Feb 26, 00:32 EST Ver 1.1a
4. 'UniKorn ProDucKions- Cobalt
5. 'YouTube Preview-  [youtube]https://youtu.be/NJ6gJVpzGN8[/youtube]
6. 'audio: "Dark Star" by Atom Music Audio
7.  
8. SCREEN _NEWIMAGE(640, 480, 32)
9. CONST TRUE = -1, FALSE = NOT TRUE
10. DIM SHARED Layer(24) AS LONG
11. DIM SHARED RES_Size(64) AS LONG, RES_FOffset&(64)
12. '-------------Logo Intro Screen needs------------
13. CONST LARGE = 1, SMALL = 2, START_SCREENS = 2, TEMP_1 = 3, TEMP_2 = 4
14. DIM SHARED Trigger(10) AS _BYTE, IntroBGM&
15. '------------------------------------------------
16. RES_Loader
17.  
18. Layer(0) = _DISPLAY
19. Layer(1) = _NEWIMAGE(640, 480, 32) 'mix layer
20. Layer(START_SCREENS) = LoadGFX&(RES_FOffset&(1), RES_Size(1)) '_LOADIMAGE("startscreens.bmp", 32) 'sheet layer
21. Layer(TEMP_1) = _NEWIMAGE(640, 480, 32) 'fade in\out layer
22. Layer(TEMP_2) = _NEWIMAGE(640, 480, 32) 'NWC screen fade
23. _CLEARCOLOR _RGB32(0, 0, 0), Layer(START_SCREENS)
24. IntroBGM& = LoadSFX&(RES_FOffset&(2), RES_Size(2)) '_SNDOPEN("LogoScreen002a.ogg")
25. FOR i%% = 0 TO 10
26.  Trigger(i%%) = FALSE
27. NEXT i%%
28. _SCREENMOVE 64, 32
29. _TITLE "Kings Bounty 64- Logo Intro"
30. IF IntroBGM& THEN _SNDPLAY IntroBGM&
31.  
32. Run_Logo_Intro
33.  
34. Fade_In_Character_Screen
35. END
36.  
37.  
38. SUB Run_Logo_Intro
39.  DO
40.   Tick! = INT(_SNDGETPOS(IntroBGM&) * 1000) / 1000
41.   IF Tick! >= .22 AND Trigger(0) = FALSE THEN Fade_In_UKP_Logo: Trigger(0) = TRUE
42.   IF Tick! >= 6.14 AND Trigger(1) = FALSE THEN Fade_Out_UKP_Logo: Trigger(1) = TRUE
43.   IF Tick! >= 10.65 AND Trigger(2) = FALSE THEN Fade_In_EA_Logo: Trigger(2) = TRUE
44.   IF Tick! >= 16.46 AND Trigger(3) = FALSE THEN Fade_Out_EA_Logo: Trigger(3) = TRUE
45.   IF Tick! >= 20.88 AND Trigger(4) = FALSE THEN Fade_In_NWC_Planet: Trigger(4) = TRUE
46.   IF Tick! >= 26.81 AND Trigger(5) = FALSE THEN Drop_NWC_Sword: _PUTIMAGE , Layer(0), Layer(TEMP_1): Trigger(5) = TRUE
47.   IF Tick! >= 28.83 AND Trigger(6) = FALSE THEN Raise_NWC_Logo: _PUTIMAGE , Layer(0), Layer(TEMP_1): Trigger(6) = TRUE
48.   IF Tick! >= 32.1 AND Trigger(7) = FALSE THEN
49.    IF NOT In_Sparkle%% THEN
50.     IF INT(RND * 100) + 1 >= 91 THEN
51.      x% = INT(RND * 560) + 28
52.      y% = INT(RND * 48) + 208
53.      IF INT(RND * 100) + 1 >= 51 THEN s% = LARGE ELSE s% = SMALL
54.      In_Sparkle%% = 5
55.     END IF
56.    END IF
57.    _PUTIMAGE , Layer(TEMP_1), Layer(1)
58.    IF In_Sparkle%% THEN
59.     Sparkle x%, y%, s%
60.     In_Sparkle%% = In_Sparkle%% - 1
61.    END IF
62.    _PUTIMAGE , Layer(1), Layer(0)
63.    IF In_Sparkle%% THEN _DELAY .1 ELSE _DELAY .025
64.   END IF
65.  
66.   IF Tick! > 40.1 AND Trigger(8) = FALSE THEN
67.    Trigger(7) = TRUE: Trigger(8) = TRUE
68.    _PUTIMAGE , Layer(0), Layer(TEMP_2): ClearLayer 3
69.    Fade_Out_NWC_Logo
70.   END IF
71.  
72.   IF Tick! > 41.0 AND Trigger(9) = FALSE THEN Fade_In_KB_Title: Trigger(9) = TRUE
73.   IF Tick! > 64.5 AND Trigger(10) = FALSE THEN Fade_Out_KB_Title: Trigger(10) = TRUE
74.   _DELAY .001
75.   LOCATE 1, 1: PRINT Tick!
76.   IF INKEY$ = CHR$(27) THEN _SNDSTOP IntroBGM&
77.  LOOP WHILE _SNDPLAYING(IntroBGM&)
78. END SUB
79.  
80. SUB Fade_In_Character_Screen
81.  FOR i%% = 0 TO 63 STEP 2
82.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (0, 448)-STEP(319, 223)
83.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
84.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
85.   _PUTIMAGE , Layer(1), Layer(0)
86.   _DELAY .025
87.  NEXT i%%
88. END SUB
89.  
90. SUB Sparkle (X%, Y%, S%)
91.  STATIC Sparkle_Frame%%, Count_up%%
92.  'large sparkle
93.  IF S% = LARGE THEN
94.   _PUTIMAGE (X%, Y%), Layer(START_SCREENS), Layer(1), (136 - Sparkle_Frame%% * 26, 420)-STEP(26, 26)
95.  ELSEIF S% = SMALL THEN
96.   _PUTIMAGE (X%, Y%), Layer(START_SCREENS), Layer(1), (194 - Sparkle_Frame%% * 15, 433)-STEP(14, 14)
97.  END IF
98.  IF NOT Count_up%% THEN Sparkle_Frame%% = Sparkle_Frame%% + 1 ELSE Sparkle_Frame%% = Sparkle_Frame%% - 1
99.  IF Sparkle_Frame%% = 2 THEN Count_up%% = TRUE
100.  IF Sparkle_Frame%% = 0 THEN Count_up%% = FALSE
101. END SUB
102.  
103. SUB Fade_In_UKP_Logo
104.  FOR i%% = 0 TO 63 STEP 2
105.   _PUTIMAGE (0, 0), Layer(START_SCREENS), Layer(1), (0, 672)-STEP(639, 479)
106.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
107.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
108.   _PUTIMAGE , Layer(1), Layer(0)
109.   _DELAY .025
110.  NEXT i%%
111. END SUB
112.  
113. SUB Fade_Out_UKP_Logo
114.  FOR i%% = 63 TO 0 STEP -3
115.   _PUTIMAGE (0, 0), Layer(START_SCREENS), Layer(1), (0, 672)-STEP(639, 479)
116.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
117.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
118.   _PUTIMAGE , Layer(1), Layer(0)
119.   _DELAY .05
120.  NEXT i%%
121. END SUB
122.  
123. SUB Fade_In_EA_Logo
124.  FOR i%% = 0 TO 63 STEP 1
125.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (0, 0)-STEP(319, 223)
126.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
127.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
128.   _PUTIMAGE , Layer(1), Layer(0)
129.   _DELAY .015
130.  NEXT i%%
131. END SUB
132.  
133. SUB Fade_Out_EA_Logo
134.  FOR i%% = 63 TO 0 STEP -3
135.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (0, 0)-STEP(319, 223)
136.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
137.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
138.   _PUTIMAGE , Layer(1), Layer(0)
139.   _DELAY .05
140.  NEXT i%%
141. END SUB
142.  
143. SUB Fade_In_NWC_Planet
144.  FOR i%% = 0 TO 63 STEP 1
145.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (320, 0)-STEP(319, 223)
146.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
147.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
148.   _PUTIMAGE , Layer(1), Layer(0)
149.   _DELAY .025
150.  NEXT i%%
151. END SUB
152.  
153. SUB Drop_NWC_Sword
154.  _SETALPHA 255, , Layer(TEMP_1)
155.  FOR i%% = 0 TO 54 STEP 1
156.   _PUTIMAGE (376 - Xo%, -400 + Yo%)-STEP(141, 395), Layer(START_SCREENS), Layer(1), (0, 250)-STEP(70, 197)
157.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (320, 0)-STEP(319, 223)
158.   _PUTIMAGE , Layer(1), Layer(0)
159.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
160.   _DELAY .004
161.   Xo% = Xo% + 2
162.   Yo% = Yo% + 8
163.  NEXT i%%
164. END SUB
165.  
166. SUB Raise_NWC_Logo
167.  FOR i%% = 0 TO 66 STEP 1
168.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
169.   _PUTIMAGE (31, 580 - Yo%)-STEP(260, 102), Layer(START_SCREENS), Layer(1), (104, 250)-STEP(130, 51)
170.   _PUTIMAGE (294, 614 - Yo%)-STEP(321, 53), Layer(START_SCREENS), Layer(1), (104, 302)-STEP(161, 27)
171.   _PUTIMAGE , Layer(1), Layer(0)
172.   Yo% = Yo% + 6
173.   _DELAY .04
174.  NEXT i%%
175. END SUB
176.  
177. SUB Fade_Out_NWC_Logo
178.  FOR i%% = 63 TO 0 STEP -3
179.   _PUTIMAGE , Layer(TEMP_2), Layer(1)
180.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
181.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
182.   _PUTIMAGE , Layer(1), Layer(0)
183.   _DELAY .001
184.  NEXT i%%
185. END SUB
186.  
187. SUB Fade_In_KB_Title
188.  FOR i%% = 0 TO 63 STEP 1
189.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (320, 224)-STEP(319, 223)
190.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
191.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
192.   _PUTIMAGE , Layer(1), Layer(0)
193.   _DELAY .06
194.  NEXT i%%
195. END SUB
196.  
197. SUB Fade_Out_KB_Title
198.  FOR i%% = 63 TO 0 STEP -1
199.   _PUTIMAGE (0, 16)-STEP(639, 447), Layer(START_SCREENS), Layer(1), (320, 224)-STEP(319, 223)
200.   _SETALPHA 255 - i%% * 4, , Layer(TEMP_1)
201.   _PUTIMAGE , Layer(TEMP_1), Layer(1)
202.   _PUTIMAGE , Layer(1), Layer(0)
203.   _DELAY .05
204.  NEXT i%%
205. END SUB
206.  
207. SUB ClearLayer (id%%)
208.  old& = _DEST
209.  _DEST Layer(id%%)
210.  CLS
211.  _DEST old&
212. END SUB
213.  
214. SUB RES_Loader
215.  '-------------layer loader-----------------------
216.  OPEN "Intro.RES" FOR BINARY AS #1
217.  GET #1, , c~%% 'number of records
218.  FOR w% = 1 TO c~%%
219.   GET #1, , RES_FOffset&(w%)
220.   GET #1, , RES_Size(w%)
221.   RES_FOffset&(w%) = RES_FOffset&(w%) + 1
222.  NEXT
223.  '------------------------------------------------
224. END SUB
225.  
226. FUNCTION LoadGFX& (Foff&, Size&)
227.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
228.  OPEN "temp.dat" FOR BINARY AS #3
229.  dat$ = SPACE$(Size&)
230.  GET #1, Foff&, dat$
231.  PUT #3, , dat$
232.  CLOSE #3
233.  LoadGFX& = _LOADIMAGE("temp.dat", 32)
234. END FUNCTION
235.  
236. FUNCTION LoadSFX& (Foff&, Size&)
237.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
238.  OPEN "temp.dat" FOR BINARY AS #3
239.  dat$ = SPACE$(Size&)
240.  GET #1, Foff&, dat$
241.  PUT #3, , dat$
242.  CLOSE #3
243.  LoadSFX& = _SNDOPEN("temp.dat")
244. END FUNCTION

Without the resource file it won't run so be sure to download it too, but you can see how I fade in and out, also how I tried to get the timing to work. odd thing is timing still shifts a little bit from machine to machine even though its based off the time of the audio file playing which shouldn't change from machine to machine.

[Pete]

Nice! Good luck with bringing the project to life. I featured your into here: https://www.tapatalk.com/groups/qbasic/viewtopic.php?f=648955&t=39446

Pete

[Cobalt]

Thanks Pete.

[Petr]

I wrote my clear conclusion under the video. I like it very much.