Author Topic: TI-58C calculator (Read 3736 times)

Richard Frost · « **on:** January 31, 2019, 11:43:26 pm »

Code: QB64: [Select]

_TITLE "TI-58C by rfrost@mail.com"
 
DEFINT A-Z
DECLARE SUB DrawCalc ()
DECLARE SUB Init ()
DECLARE SUB Keyboard ()
DECLARE SUB Learn ()
DECLARE SUB MemOps ()
DECLARE SUB Mouse ()
DECLARE SUB NoPend ()
DECLARE SUB NumDisp ()
DECLARE SUB PlotNum (Text$)
DECLARE SUB ProcessEquals ()
DECLARE SUB ProcessKey ()
DECLARE SUB ProcessTrig ()
DECLARE SUB ColorSet ()
DECLARE SUB ShowText (x, y, Text$, kolor)
DECLARE SUB WriteProg ()
 
COMMON SHARED true, false, ddp
COMMON SHARED black, white, yellow, redi, redd
COMMON SHARED i$, lft, rgt, mkey$
COMMON SHARED Num#, expo, dp&
COMMON SHARED OperationPending, op$, MemOp$, Running, Prog
COMMON SHARED LearnFlag, ProgPos
COMMON SHARED y#, treg#, ShiftFlag, InvFlag, AngMode$, IsError
COMMON SHARED pi#, ator#
COMMON SHARED GetNum, GetNum$
COMMON SHARED psize, msize
COMMON SHARED minx, miny, maxx, maxy
COMMON SHARED up, down, left, right
COMMON SHARED noise
 
psize = 99: msize = 99
DIM SHARED MemReg#(msize), ProgStep(psize), pat(255, 13), garr(999)
DIM SHARED k$(100), kn(100), bx1(50), by1(50), bx2(50), by2(50)
Init
DO: _LIMIT 10
    Mouse
    Keyboard
    ProcessKey
    IF Running AND Prog = 5 THEN Num# = Num# + 1: NumDisp
LOOP
   
card:
DATA "DOW, DAYS BETWEEN DATES",ML-20
DATA (MMDD.YYYY),"","","",""
DATA DATE1,DATE2,#Days,D>DOW,""
 
'      key  key color keycode keycode
Keys:
DATA "A","A'",0,11,16
DATA "B","B'",0,12,17
DATA "C","C'",0,13,18
DATA "D","D'",0,14,19
DATA "E","E'",0,15,20
 
DATA "2nd","",6,0,0
DATA "INV","",0,22,0
DATA "lnx","log",0,23,28
DATA "CE","CP",0,24,29
DATA "CLR","",6,25,0
 
DATA "LRN","Pgm",0,31,36
DATA "xt","PR",0,32,37
DATA "xý","sin",0,33,38
DATA "ûx","cos",0,34,39
DATA "1/x","tan",0,35,30
 
DATA "SST","Ins",0,41,45
DATA "STO","CMs",0,42,46
DATA "RCL","Exc",0,43,47
DATA "SUM","Prd",0,44,48
DATA "yx","Ind",0,45,49
 
DATA "BST","Del",0,51,55
DATA "EE","Eng",0,52,56
DATA "(","Fix",0,52,57
DATA ")","Int",0,53,58
DATA "ö","³x³",6,54,59
 
DATA "GTO","Pause",0,61,66
DATA "7","x=t",15,7,67
DATA "8","Nop",15,8,68
DATA "9","Op",15,9,69
DATA "x","Deg",6,65,70
 
DATA "SBR","Lbl",0,71,76
DATA "4","xòt",15,4,77
DATA "5","ä+",15,5,78
DATA "6","x",15,6,79
DATA "-","Rad",6,75,80
 
DATA "RST","St flg",0,81,86
DATA "1","If flg",15,1,87
DATA "2","D.MS",15,2,88
DATA "3","ã",15,3,89
DATA "+","Grad",6,85,90
 
DATA "R/S","",0,91,0
DATA "0","Dsz",15,0,96
DATA ".","Adv",15,93,97
DATA "+/-","Prt",15,94,98
DATA "=","Lst",6,95,99
 
DATA "RTN","",0,92,0
 
Logo:
DATA ...XXX...X......
DATA ...XXXX.........
DATA ...XXXX..X.XXXXX
DATA ...XXXX..X.XXXXX
DATA ...XX....X....XX
DATA ...XX....X....XX
DATA XXXXXXX..X..XXXX
DATA XXXXXXX..X..XXXX
DATA .XXXXXX..X..XXX.
DATA ..XXXXX..X..X...
DATA ....XXX..X..X...
DATA ......X.....X...
DATA .......XXXXX....
DATA ........XXXX....
DATA .........XX.....
DATA "end"
 
Prog:
DATA 76,Lbl
DATA 15,E
DATA 85,+
DATA 1,1
DATA 66,Pause
DATA 81,RST
DATA 0,"end"
 
SUB ColorSet
    black = 0
    redi = 1
    redd = 2
    yellow = 6
    white = 10
    FOR i = 1 TO 15
        IF i = yellow THEN
            PALETTE i, 65536 * 20 + 256 * 30 + 40 ' yellow
        ELSEIF i = redi THEN
            PALETTE i, 65536 * 15 + 256 * 15 + 63 ' red intense
        ELSEIF i = redd THEN
            PALETTE i, 65536 * 5 + 256 * 5 + 13 ' red dim
        ELSEIF i = white THEN
            PALETTE i, 65536 * 35 + 256 * 35 + 35 ' white
        END IF
    NEXT i
END SUB
 
SUB DrawCalc
    CLS
    ColorSet
    LINE (177, 4)-(461, 475), white, B ' full machine
    LINE (183, 30)-(456, 88), white, B ' number window
    LINE (183, 88)-(456, 136), white, B ' card window
    LINE (183, 104)-(456, 104), yellow ' card window
    LINE (183, 119)-(456, 119), yellow ' card window
 
    LINE (183, 136)-(456, 470), yellow, B ' button window
    LINE (185, 138)-(454, 468), yellow, B ' button window
    PAINT (184, 140), yellow, yellow
 
    RESTORE Logo
    bx = 190: x = bx
    by = 10: y = by
    DO
        READ pat$
        IF pat$ = "end" THEN EXIT DO
        FOR t = 1 TO LEN(pat$)
            IF MID$(pat$, t, 1) = "X" THEN PSET (x, y), white
            x = x + 1
        NEXT t
        x = bx: y = y + 1
    LOOP
 
    ShowText 225, 32, "Texas Instruments", black
 
    IF LearnFlag THEN
        mkey$ = "xxx"
        Learn
    ELSE
        NumDisp
    END IF
 
    RESTORE card
    READ Card1$: ShowText 206, 110, Card1$, -1
    READ Card2$: ShowText 426, 110, Card2$, -1
    FOR row = 1 TO 2
        FOR col = 1 TO 5
            READ Text$
            IF Text$ = "D>DOW" THEN MID$(Text$, 2, 1) = CHR$(26)
            x = (col - 1) * 54 + 208
            y = (row - 1) * 16 + 140
            z = 31
            IF (Card2$ = "ML-20") AND (col = 1) THEN
                LINE (x + z, 119)-(x + z, 136), yellow
            ELSEIF col < 5 THEN
                LINE (x + z, 104)-(x + z, 136), yellow
            END IF
            ShowText x, y - 14, Text$, -1
        NEXT col
    NEXT row
 
    RESTORE Keys
    kn = 0
    FOR row = 1 TO 9
        FOR col = 1 TO 5
            kn = kn + 1
            READ k$(kn), k$(kn + 50), kolor, kn(kn), kn(kn + 50)
            IF kolor = 6 THEN kolor = yellow
            IF kolor = 15 THEN kolor = white
            IF k$(kn + 50) = "PR" THEN k$(kn + 50) = "P" + CHR$(26) + "R"
            x = (col - 1) * 54 + 208
            y = (row - 1) * 34 + 180
            ShowText x, y - 15, k$(kn + 50), -1
            IF kolor = 0 THEN
                LINE (x - 13, y - 21)-(x + 21, y - 7), white, B
            ELSE
                LINE (x - 13, y - 21)-(x + 21, y - 7), kolor, BF
            END IF
            bx1(kn) = x - 13: bx2(kn) = x + 21
            by1(kn) = y - 21: by2(kn) = y - 7
            ShowText x, y, k$(kn), kolor
        NEXT col
    NEXT row
    kn = kn + 1
    READ k$(kn), k$(kn + 50), kolor, kn(kn), kn(kn + 50)
    ShowText 311, 471, "TI Programmable 58C", -1
END SUB
 
SUB Init
    CLS
    true = -1
    false = 0
 
    noise = true
    pi# = ATN(1) * 4
    ator# = ATN(1) / 45
    AngMode$ = "D"
 
    s& = VARSEG(pat(0, 0))
    o& = VARPTR(pat(0, 0))
    DEF SEG = s&
    BLOAD "font.dat", o&
 
    SCREEN 12 ' 640*480*16
    minx = 196: maxx = 444
    miny = 161: maxy = 444
    msx = 334: msy = 234
    DrawCalc
 
    psize = 99
    OPEN "prog.txt" FOR APPEND AS #1
    CLOSE #1
    GetProg:
    OPEN "prog.txt" FOR INPUT AS #1
    IF EOF(1) THEN
        CLOSE #1
        RESTORE Prog
        DO
            READ ProgStep, Prog$
            IF Prog$ = "end" THEN EXIT DO
            ProgStep(ProgPos) = ProgStep
            ProgPos = ProgPos + 1
        LOOP
        WriteProg
        GOTO GetProg
    ELSE
        ProgPos = 0
        WHILE NOT (EOF(1))
            INPUT #1, pstep$
            IF LEFT$(pstep$, 1) = "M" THEN
                INPUT #1, MemReg$, memval$
                MemReg#(VAL(MemReg$)) = VAL(memval$)
            ELSE
                INPUT #1, pcode$, palph$
                ProgStep(ProgPos) = VAL(pcode$)
                ProgPos = ProgPos + 1
            END IF
        WEND
    END IF
    CLOSE #1
    ProgPos = 0
    dp& = 1
    up = 72: down = 80: left = 75: right = 77
END SUB
 
SUB Keyboard
    IF mkey$ > "" THEN
        i$ = mkey$
        IF i$ = "CLR" THEN i$ = "c"
        mkey$ = ""
        IF noise THEN SOUND 3000, 1
    ELSE
        i$ = INKEY$
        IF i$ = "s" THEN noise = noise XOR 1
        IF noise AND LEN(i$) THEN SOUND 3000, 1
    END IF
END SUB
 
SUB Learn
    IF mkey$ = "Del" THEN
        FOR t = ProgPos TO psize - 1
            ProgStep(t) = ProgStep(t + 1)
        NEXT t
        ProgStep(psize) = 0
        mkey$ = ""
    END IF
 
    IF mkey$ = "Ins" THEN
        FOR t = psize TO ProgPos + 1 STEP -1
            ProgStep(t) = ProgStep(t - 1)
        NEXT t
        ProgStep(ProgPos) = 0
        mkey$ = ""
    END IF
 
    IF mkey$ > "" THEN
        FOR t = 1 TO 100
            IF mkey$ = k$(t) THEN
                ProgStep(ProgPos) = kn(t)
                ProgPos = ProgPos + 1
                IF ProgPos > psize THEN
                    ProgPos = psize
                    LearnFlag = false
                END IF
                EXIT FOR
            END IF
        NEXT t
    END IF
 
    Text$ = SPACE$(7) + RIGHT$("00" + LTRIM$(STR$(ProgPos)), 3) + " "
    Text$ = Text$ + RIGHT$("00" + LTRIM$(STR$(ProgStep(ProgPos))), 2)
    IF mkey$ > "" THEN PlotNum Text$
    mkey$ = ""
END SUB
 
SUB MemOps
    MemReg = VAL(GetNum$)
    SELECT CASE MemOp$
        CASE IS = "STO"
            MemReg#(MemReg) = Num#
        CASE IS = "RCL"
            Num# = MemReg#(MemReg)
        CASE IS = "SUM"
            MemReg#(MemReg) = MemReg#(MemReg) + Num#
        CASE IS = "Exc"
            SWAP MemReg#(MemReg), Num#
        CASE IS = "Prd"
            MemReg#(MemReg) = MemReg#(MemReg) * Num#
    END SELECT
    MemOp$ = ""
    NumDisp
    OperationPending = true
END SUB
 
SUB Mouse
    DO WHILE _MOUSEINPUT
        mx = _MOUSEX
        my = _MOUSEY
        lft = _MOUSEBUTTON(1)
        rgt = _MOUSEBUTTON(2)
    LOOP
    msx = mx: msy = my
 
    IF NOT (lft OR rgt) THEN EXIT SUB
 
    FOR t = 1 TO 50
        hitx = (mx > bx1(t)) AND (mx < bx2(t))
        hity = (my > by1(t)) AND (my < by2(t))
        IF hitx AND hity THEN
            GET (bx1(t), by1(t))-(bx2(t), by2(t)), garr()
            LINE (bx1(t), by1(t))-(bx2(t), by2(t)), 15, B
            IF lft OR rgt THEN mkey$ = k$(t - ShiftFlag * 50)
            ShiftFlag = 0
            _DELAY .2
            PUT (bx1(t), by1(t)), garr(), PSET
            EXIT FOR
        END IF
    NEXT t
 
    IF Running AND (mkey$ <> "R/S") THEN mkey$ = "": EXIT SUB
    IF mkey$ = "BST" THEN ProgPos = ProgPos - 1 - (ProgPos = 0): mkey$ = "xxx"
    IF mkey$ = "SST" THEN
        ProgPos = ProgPos + 1
        IF ProgPos > psize THEN
            ProgPos = psize
            mkey$ = "LRN"
        ELSE
            mkey$ = "xxx"
        END IF
    END IF
    IF mkey$ = "LRN" THEN LearnFlag = NOT (LearnFlag): mkey$ = " "
    IF LearnFlag THEN Learn: EXIT SUB
    IF mkey$ = "RST" THEN ProgPos = 0: mkey$ = ""
    IF mkey$ = "GTO" THEN GetNum = 3: mkey$ = ""
    IF mkey$ = "R/S" THEN Running = NOT (Running): OperationPending = true
    IF mkey$ = "E" THEN Prog = 5: Running = true
    IF mkey$ = "2nd" THEN ShiftFlag = true
    IF mkey$ = "INV" THEN InvFlag = true
    IF mkey$ = "log" THEN
        IF InvFlag THEN
            IsError = true
            InvFlag = false
        ELSE
            Num# = LOG(Num#) / LOG(10): NoPend
        END IF
    END IF
    IF mkey$ = "lnx" THEN
        IF InvFlag THEN
            IsError = true
            InvFlag = false
        ELSE
            Num# = LOG(Num#): NoPend
        END IF
    END IF
    IF mkey$ = "CE" THEN Num# = 0: ShiftFlag = false: InvFlag = false
    IF mkey$ = "xt" THEN SWAP treg#, Num#: NoPend
    IF mkey$ = "xý" THEN Num# = Num# * Num#: NoPend
    IF LEN(mkey$) = 3 THEN
        IF INSTR("STO RCL SUM Exc Prd", mkey$) > 0 THEN MemOp$ = mkey$: GetNum = 2
        IF INSTR("SIN COS TAN", UCASE$(mkey$)) > 0 THEN ProcessTrig
    END IF
    IF mkey$ = "ûx" THEN Num# = SQR(Num#): NoPend
    IF mkey$ = "1/x" THEN Num# = 1 / Num#: NoPend
    IF mkey$ = "Int" THEN Num# = FIX(Num#): NoPend
    IF mkey$ = "CMs" THEN
        FOR MemReg = 0 TO 99
            MemReg#(MemReg) = 0
        NEXT MemReg
    END IF
    IF mkey$ = "yx" THEN
        IF y# = 0 THEN
            y# = Num#
            op$ = "^"
            OperationPending = true
        END IF
    END IF
    IF mkey$ = "³x³" THEN Num# = ABS(Num#): NoPend
    IF mkey$ = "Deg" THEN AngMode$ = "D": NoPend
    IF mkey$ = "Rad" THEN AngMode$ = "R": NoPend
    IF mkey$ = "Grad" THEN AngMode$ = "Grad": NoPend
    IF mkey$ = "ã" THEN Num# = pi#: NoPend
    IF mkey$ = "+/-" THEN Num# = -(Num#): NoPend
END SUB
 
SUB NoPend
    mkey$ = "="
    InvFlag = false
    ShiftFlag = false
END SUB
 
SUB NumDisp
    expo = 0
    exp$ = SPACE$(3)
 
    IF Num# = INT(Num#) THEN
        Num$ = RIGHT$(SPACE$(10) + STR$(Num#), 10)
        ddp = 0
    ELSE
        Num$ = LTRIM$(STR$(Num#))
        IF LEFT$(Num$, 1) = "." THEN Num$ = "0" + Num$
        IF LEN(Num$) > 11 THEN Num$ = LEFT$(Num$, 11)
        WHILE LEN(Num$) < 11
            Num$ = " " + Num$
        WEND
        ddp = INSTR(Num$, ".")
        Num$ = LEFT$(Num$, ddp - 1) + RIGHT$(Num$, LEN(Num$) - ddp)
    END IF
    GOTO woof
 
    Num$ = LTRIM$(STR$(Num#))
    IF (Num# > 0) AND (Num# < .000000001#) THEN
        tnum# = Num#
        WHILE tnum# < 1
            tnum# = tnum# * 10
            expo = expo + 1
        WEND
        Num$ = RIGHT$(SPACE$(10) + STR$(tnum#), 10)
        IF expo > 0 THEN exp$ = "-" + RIGHT$("00" + LTRIM$(STR$(expo)), 2)
    ELSEIF Num# > 9999999999# THEN
        tnum# = Num#
        WHILE tnum# > 10
            tnum# = tnum# / 10
            expo = expo + 1
        WEND
        Num$ = RIGHT$(SPACE$(10) + STR$(tnum#), 10)
        IF expo > 0 THEN exp$ = " " + RIGHT$("00" + LTRIM$(STR$(expo)), 2)
    ELSE
        IF LEN(Num$) > 10 THEN
            Num$ = LEFT$(Num$, 10)
        ELSE
            Num$ = RIGHT$(SPACE$(10) + STR$(Num#), 10)
        END IF
    END IF
 
    woof:
    IF expo > 99 THEN IsError = true
    Text$ = Num$ + exp$
    Text$ = RIGHT$(SPACE$(13) + Text$, 13)
    IF IsError THEN Text$ = "         E   "
    PlotNum Text$
END SUB
 
SUB PlotNum (Text$)
    LINE (184, 31)-(455, 87), black, BF ' erase number window
    LINE (183, 30)-(456, 88), white, B ' number window
 
    FOR i = 1 TO LEN(Text$)
        a = ASC(MID$(Text$, i, 1))
        dx = 196 + i * 18
        dy = 48
        FOR byte = 1 TO 10
            LINE (dx, dy)-(dx + 7, dy), redi, , pat(a, byte) * 128
            dy = dy + 2
        NEXT byte
    NEXT i
 
    IF NOT (LearnFlag) AND (ddp > 0) THEN
        dx = 188 + ddp * 18
        dy = 65
        LINE (dx, dy)-(dx + 1, dy + 1), redi, BF
    END IF
END SUB
 
SUB ProcessEquals
    SELECT CASE op$
        CASE IS = "+"
            Num# = y# + Num#
        CASE IS = "-"
            Num# = y# - Num#
        CASE IS = "*"
            Num# = y# * Num#
        CASE IS = "x"
            Num# = y# * Num#
        CASE IS = "ö"
            Num# = y# / Num#
        CASE IS = "/"
            Num# = y# / Num#
        CASE IS = "^"
            Num# = y# ^ Num#
            y# = 0
    END SELECT
    op$ = ""
END SUB
 
SUB ProcessKey
    IF LEN(i$) = 0 THEN EXIT SUB
    IF i$ = CHR$(27) THEN WriteProg: SYSTEM
    IF LearnFlag THEN EXIT SUB
    IF INSTR(".0123456789", i$) > 0 THEN
        IF (GetNum > 0) AND (i$ <> ".") THEN
            GetNum$ = GetNum$ + i$
            IF LEN(GetNum$) = GetNum THEN
                GetNum = 0
                IF LEN(MemOp$) > 0 THEN
                    MemOps
                ELSE
                    NewPos = VAL(GetNum$)
                    IF NewPos <= psize THEN ProgPos = NewPos
                END IF
                GetNum$ = ""
            END IF
            EXIT SUB
        END IF
        IF OperationPending THEN
            Num# = 0
            dp& = 1
            OperationPending = false
        END IF
        IF i$ = "." THEN
            IF dp& = 1 THEN dp& = 10
        ELSE
            IF dp& > 1 THEN
                log10 = LOG(dp&) / LOG(10)
                IF log10 < 9 THEN
                    Num# = Num# + VAL(i$) / dp&
                    dp& = dp& * 10
                END IF
            ELSE
                IF Num# < 1000000000 THEN Num# = Num# * 10 + VAL(i$)
            END IF
        END IF
    END IF
 
    IF i$ = CHR$(8) THEN ' backspace
        IF dp& > 1 THEN
            tdp& = dp& \ 10
            tnum& = Num# * tdp&
            Num# = tnum& / tdp&
            dp& = dp& \ 10
        ELSE
            Num# = Num# \ 10
        END IF
    END IF
 
    IF i$ = "c" THEN ' clear
        IsError = false
        ShiftFlag = false
        InvFlag = false
        OperationPending = false
        MemOp$ = ""
        op$ = ""
        y# = 0
        Num# = 0
        dp& = 1
    END IF
 
    IF INSTR("öx+-/*", i$) > 0 THEN ' operation
        IF op$ <> "" THEN ProcessEquals
        op$ = i$
        y# = Num#
        OperationPending = true
    END IF
 
    IF i$ = CHR$(13) THEN i$ = "="
    IF i$ = "=" THEN
        ProcessEquals
        OperationPending = true
        y# = 0
    END IF
 
    NumDisp
END SUB
 
SUB ProcessTrig
    IF AngMode$ = "G" THEN IsError = true
    IF InvFlag THEN
        IF mkey$ = "sin" THEN IsError = true
        IF mkey$ = "cos" THEN IsError = true
        IF mkey$ = "tan" THEN Num# = ATN(Num#)
        InvFlag = false
    ELSE
        IF AngMode$ = "D" THEN Num# = Num# * ator#
        IF mkey$ = "sin" THEN Num# = SIN(Num#)
        IF mkey$ = "cos" THEN Num# = COS(Num#)
        IF mkey$ = "tan" THEN Num# = TAN(Num#)
    END IF
    mkey$ = "="
END SUB
 
SUB ShowText (x, y, Text$, kolor)
    Text$ = LTRIM$(RTRIM$(Text$))
    lt = LEN(Text$)
    xb = -16 - (lt = 1) * 16 - (lt = 2) * 12 - (lt = 3) * 7 - (lt = 4) * 4
    IF RIGHT$(Text$, 1) = "'" THEN xb = xb + 4
    yb = -8
    IF Text$ = "yx" THEN yb = -10
    IF Text$ = "." THEN yb = -12: xb = xb - 1
    FOR byte = 0 TO 13
        ty = yb + (y - 12) + byte + ((Text$ = "yx") AND (i = 2)) * 2
        FOR i = 1 TO LEN(Text$)
            tx = xb + x + (i - 1) * 8
            a = ASC(MID$(Text$, i, 1))
            IF kolor = -1 THEN
                co = yellow
            ELSEIF kolor = black THEN
                co = white
            ELSE
                co = black
            END IF
            LINE (tx, ty)-(tx + 7, ty), co, , pat(a, byte) * 128
        NEXT i
    NEXT byte
 
    IF (Text$ = "x") AND (kolor = -1) THEN ' x bar
        LINE (x + xb, y - 20)-(x + xb + 8, y - 20), yellow
    END IF
    IF Text$ = "ûx" THEN ' square root
        LINE (x + xb, y - 20)-(x + xb + 8, y - 20), black
        LINE (x + xb + 5, y - 19)-(x + xb + 15, y - 19), white
    END IF
    IF Text$ = "³x³" THEN ' abs
        LINE (x + xb, y - 20)-(x + xb + 25, y - 20), black
        LINE (x + xb, y - 19)-(x + xb + 25, y - 19), black
        LINE (x + xb, y - 7)-(x + xb + 25, y - 7), black
    END IF
END SUB
 
SUB WriteProg
    OPEN "prog.txt" FOR OUTPUT AS #1
    FOR t = 0 TO psize ' program
        pstep$ = RIGHT$("000" + LTRIM$(STR$(t)), 3)
        pcode$ = RIGHT$("00" + LTRIM$(STR$(ProgStep(t))), 2)
        palph$ = "0"
        FOR i = 0 TO 100
            IF kn(i) = ProgStep(t) THEN
                palph$ = k$(i)
                EXIT FOR
            END IF
        NEXT i
        IF LEN(palph$) = 0 THEN palph$ = "0"
        PRINT #1, pstep$; ","; pcode$; ","; palph$
    NEXT t
    FOR t = 0 TO msize ' memory
        pstep$ = "M"
        pcode$ = RIGHT$("00" + LTRIM$(STR$(t)), 2)
        palph$ = LTRIM$(STR$(MemReg#(t)))
        PRINT #1, pstep$; ","; pcode$; ","; palph$
    NEXT t
    CLOSE #1
END SUB
 
 

bplus · « **Reply #1 on:** February 01, 2019, 12:13:12 am »

Looks nice!

Richard Frost · « **Reply #2 on:** February 01, 2019, 02:20:25 am »

Found the code tag thing by chance, then scrolled down and saw it pointed out for me. Duh!

This code has undergone one update/replacement already - killed a font that was in DATA statements in favor of BLOADing it.
I'd like to use _PRINTSTRING, but I have to expand the font in the vertical direction for the number display.

bplus · « **Reply #3 on:** February 01, 2019, 09:44:17 am »

This might be good link to manual (not secure), unless Richard has better?
http://83.156.189.247/ti58c/download/doc/LRNen.pdf

Dang! can't save a program? Can you emulate a printout from calculator?

Following the first steps in programming manual above, looks like the keys aren't all working yet.

The program clear function doesn't seem to be, nor picking up 2nd and the PI in program. SST and BST look OK.

Nope, Lst not working either, eh?

This is cool and ambitious project of course it will take awhile to get right.

Richard Frost · « **Reply #4 on:** February 01, 2019, 04:13:42 pm »

True, I didn't take the simulation all the way to the end. The program that's in there, under label E, works.
The E for Error thing is wonky - getting some weird INF (infinity) display beyond 10^99 too.....

News:

Author Topic: TI-58C calculator (Read 3736 times)

Richard Frost

TI-58C calculator

bplus

Re: TI-58C calculator

Richard Frost

Re: TI-58C calculator

bplus

Re: TI-58C calculator

Richard Frost

Re: TI-58C calculator