platform.bas - an attempted QB64 clone of Mr Jump S

[FellippeHeitor]

Here's the current state of my clone of Mr Jump S. No difference in gameplay, as I've simply restructured the code so it's prettier and easier to follow.

Ah, but now you can now jump with the mouse button (click on the game screen).

ESC resets the random level.

This is taken directly from the latest commit c6521ab.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST false = 0, true = NOT false
4.  
5. SCREEN _NEWIMAGE(800, 450, 32)
6.  
7. TYPE newLevel
8.     landColor AS _UNSIGNED LONG
9.     grassColor AS _UNSIGNED LONG
10.     waterColor AS _UNSIGNED LONG
11.     symbolSpacingX AS LONG
12.     symbolSpacingY AS LONG
13. END TYPE
14.  
15. TYPE newObject
16.     id AS LONG
17.     x AS SINGLE
18.     xv AS SINGLE
19.     y AS SINGLE
20.     yv AS SINGLE
21.     w AS LONG
22.     h AS LONG
23.     img AS LONG
24.     imgPointer AS _BYTE
25.     color AS _UNSIGNED LONG
26.     standing AS _BYTE
27.     alive AS _BYTE
28. END TYPE
29.  
30. CONST idPlatform = 1
31. CONST idGoal = 2
32. CONST idAirJump = 3
33. CONST idInfiniteJumps = 4
34. CONST idSpike = 5
35. CONST idCloud = 6
36. CONST idScene = 7
37. CONST idSky = 8
38. CONST idWater = 9
39.  
40. DIM SHARED thisLevel AS LONG
41. DIM SHARED arenaWidth AS LONG, i AS LONG
42. DIM SHARED x AS SINGLE, y AS SINGLE
43. DIM SHARED totalObjects AS LONG
44. DIM SHARED drowned AS _BYTE
45. DIM SHARED restartRequested AS _BYTE
46. DIM SHARED levelData AS newLevel
47. DIM SHARED platformDecoration AS STRING
48. DIM SHARED obj(100) AS newObject
49. DIM SHARED hero AS LONG
50. DIM SHARED goal AS LONG
51. DIM SHARED camera AS SINGLE
52. DIM SHARED gravity AS SINGLE
53. DIM SHARED goalGlyph AS STRING, airJumpGlyph AS STRING
54. DIM SHARED airJumps AS LONG
55.  
56. RANDOMIZE TIMER
57.  
58. goalGlyph = "C" + STR$(_RGB32(255, 255, 255)) + "e10f10g10 h8e8f6g6 h4 e4f2g1"
59. airJumpGlyph = "C" + STR$(_RGB32(255, 255, 255)) + "e10f10g10h10"
60. gravity = .8
61. thisLevel = 1
62.  
63. Restart:
64. setLevel thisLevel
65.  
66. DO
67.     processInput
68.     doPhysics
69.     adjustCamera
70.     drawObjects
71.     IF restartRequested THEN restartRequested = false: GOTO Restart
72.     IF NOT drowned THEN drawHero
73.  
74.     _DISPLAY
75.     _LIMIT 60
76. LOOP
77.  
78. SUB addWater
79.     DIM this AS LONG
80.     this = newObject
81.     obj(this).id = idWater
82.     obj(this).img = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
83.     _DEST obj(this).img
84.     LINE (0, _HEIGHT - _HEIGHT / 4)-STEP(_WIDTH, _HEIGHT / 4), darken(levelData.waterColor, 55), BF
85.     LINE (0, _HEIGHT - _HEIGHT / 4)-STEP(_WIDTH, _HEIGHT / 7), darken(levelData.waterColor, 70), BF
86.     LINE (0, _HEIGHT - _HEIGHT / 4)-STEP(_WIDTH, _HEIGHT / 9), darken(levelData.waterColor, 85), BF
87.     LINE (0, _HEIGHT - _HEIGHT / 4)-STEP(_WIDTH, _HEIGHT / 11), levelData.waterColor, BF
88.     _DEST 0
89. END SUB
90.  
91. SUB drawObjects
92.     FOR i = 1 TO totalObjects
93.         SELECT CASE obj(i).id
94.             CASE idPlatform
95.                 _PUTIMAGE (obj(i).x + camera, obj(i).y), obj(i).img
96.             CASE idGoal
97.                 DRAW "bm" + STR$(obj(goal).x + camera) + "," + STR$(obj(goal).y + obj(goal).h / 2)
98.                 DRAW goalGlyph
99.             CASE idAirJump
100.                 DRAW "bm" + STR$(obj(i).x + camera) + "," + STR$(obj(i).y + obj(i).h / 2)
101.                 DRAW airJumpGlyph
102.             CASE idCloud
103.                 obj(i).x = obj(i).x - obj(i).xv
104.                 IF obj(i).x + obj(i).w < 0 THEN obj(i).x = arenaWidth
105.                 LINE (obj(i).x + camera / 2.5, obj(i).y)-STEP(obj(i).w, obj(i).h), _RGBA32(255, 255, 255, 30), BF
106.             CASE idScene
107.                 _PUTIMAGE (obj(i).x + camera / obj(i).xv, obj(i).y), obj(i).img
108.             CASE idSky
109.                 LINE (0, 0)-(_WIDTH, _HEIGHT), obj(i).color, BF
110.             CASE idWater
111.                 _PUTIMAGE , obj(i).img
112.         END SELECT
113.     NEXT
114. END SUB
115.  
116. SUB processInput
117.     DIM button AS _BYTE
118.  
119.     IF _KEYHIT = 27 THEN
120.         obj(hero).alive = true
121.         obj(hero).yv = 0
122.         restartRequested = true
123.         EXIT SUB
124.     END IF
125.  
126.     IF obj(hero).alive = false THEN EXIT SUB
127.     IF obj(hero).x + obj(hero).w < arenaWidth + _WIDTH THEN obj(hero).x = obj(hero).x + 5
128.  
129.     'IF _KEYDOWN(19712) THEN 'character goes left, screen goes right
130.     '    obj(hero).x = obj(hero).x + 5
131.     'END IF
132.  
133.     'IF _KEYDOWN(19200) THEN 'character goes right, screen goes left
134.     '    obj(hero).x = obj(hero).x - 5
135.     'END IF
136.  
137.     STATIC lastJump!, jumpKeyDown AS _BYTE
138.     CONST jumpFactor = 3
139.  
140.     WHILE _MOUSEINPUT: WEND
141.     button = _MOUSEBUTTON(1) OR _KEYDOWN(32)
142.  
143.     IF button THEN '18432
144.         IF jumpKeyDown = false AND (obj(hero).standing = true OR airJumps > 0) THEN
145.             IF airJumps > 0 THEN airJumps = airJumps - 1
146.             jumpKeyDown = true
147.             obj(hero).standing = false
148.             lastJump! = 0
149.             obj(hero).yv = obj(hero).yv - gravity * jumpFactor
150.         ELSE
151.             lastJump! = lastJump! + 1
152.             IF lastJump! < 7 THEN
153.                 obj(hero).yv = obj(hero).yv - gravity * jumpFactor
154.             END IF
155.         END IF
156.     ELSE
157.         jumpKeyDown = false
158.     END IF
159. END SUB
160.  
161. SUB adjustCamera
162.     camera = _WIDTH / 4 - obj(hero).x
163.     IF camera > 0 THEN camera = 0
164.     IF camera < -arenaWidth THEN camera = -arenaWidth
165. END SUB
166.  
167. SUB drawHero
168.     LINE (obj(hero).x + camera, obj(hero).y)-STEP(obj(hero).w, obj(hero).h), obj(hero).color, BF
169. END SUB
170.  
171. SUB doPhysics
172.     DIM this AS newObject
173.     DIM j AS LONG, shadowCast AS _BYTE
174.  
175.     IF NOT obj(hero).alive THEN
176.         _PRINTSTRING (0, 0), "Dead"
177.         _PRINTSTRING (0, 20), STR$((obj(hero).x / arenaWidth) * 100) + "%"
178.         EXIT SUB
179.     END IF
180.  
181.     CONST gravityCap = 15
182.  
183.     obj(hero).standing = false
184.     drowned = false
185.     IF obj(hero).y + obj(hero).yv + gravity > _HEIGHT - _HEIGHT / 4 + _HEIGHT / 22 THEN drowned = true: obj(hero).alive = false: EXIT SUB
186.  
187.     FOR j = 1 TO totalObjects
188.         IF obj(j).id = idPlatform THEN
189.             IF obj(hero).x + obj(hero).w > obj(j).x AND obj(hero).x < obj(j).x + obj(j).w THEN
190.                 shadowCast = true
191.                 LINE ((obj(hero).x - 3) + camera, obj(j).y + 5)-STEP(obj(hero).w + 6, 2), _RGBA32(0, 0, 0, 30), BF
192.  
193.                 IF obj(hero).y + obj(hero).yv + gravity < obj(j).y - (obj(hero).h - 5) THEN
194.                     EXIT FOR
195.                 ELSEIF obj(hero).y + obj(hero).yv + gravity <= obj(j).y - (obj(hero).h - 20) THEN
196.                     obj(hero).standing = true
197.                     obj(hero).y = obj(j).y - (obj(hero).h - 5)
198.                     EXIT FOR
199.                 ELSEIF obj(hero).y >= obj(j).y - (obj(hero).h - 20) THEN
200.                     obj(hero).alive = false
201.                     EXIT FOR
202.                 END IF
203.             END IF
204.         END IF
205.     NEXT
206.  
207.     IF NOT obj(hero).standing THEN
208.         obj(hero).yv = obj(hero).yv + gravity
209.         IF obj(hero).yv > gravityCap THEN obj(hero).yv = gravityCap
210.         obj(hero).y = obj(hero).y + obj(hero).yv
211.         obj(hero).color = _RGB32(255, 255, 255)
212.     ELSE
213.         _PRINTSTRING (0, 0), "Standing"
214.         obj(hero).yv = 0
215.         obj(hero).color = _RGB32(200, 200, 200)
216.     END IF
217.  
218.     IF hit(obj(hero), obj(goal)) THEN _AUTODISPLAY: _PRINTSTRING (_WIDTH / 2 - _PRINTWIDTH("Level complete!") / 2, _HEIGHT / 2 - _FONTHEIGHT / 2), "Level complete!": obj(hero).alive = false: SLEEP
219.  
220.     IF shadowCast = false THEN LINE ((obj(hero).x - 3) + camera, _HEIGHT - _HEIGHT / 4 + _HEIGHT / 22)-STEP(obj(hero).w + 6, 2), _RGBA32(0, 0, 0, 30), BF
221. END SUB
222.  
223. FUNCTION hit%% (obj1 AS newObject, obj2 AS newObject)
224.     hit%% = obj1.x + obj1.w > obj2.x AND obj1.x <= obj2.x + obj2.w AND obj1.y + obj1.h > obj2.y AND obj1.y < obj2.y + obj2.h
225. END FUNCTION
226.  
227. FUNCTION darken~& (WhichColor~&, ByHowMuch%)
228.     darken~& = _RGB32(_RED32(WhichColor~&) * (ByHowMuch% / 100), _GREEN32(WhichColor~&) * (ByHowMuch% / 100), _BLUE32(WhichColor~&) * (ByHowMuch% / 100))
229. END FUNCTION
230.  
231.  
232. SUB setLevel (level AS LONG)
233.     'the order of creation of objects is also the draw order
234.  
235.     DIM totalPlatforms AS LONG
236.     DIM this AS LONG, firstPlatform AS LONG
237.  
238.     resetObjects
239.     SELECT CASE level
240.         CASE 1
241.             arenaWidth = 3200
242.             totalPlatforms = 30
243.             levelData.landColor = _RGB32(194, 127, 67)
244.             levelData.waterColor = _RGB32(33, 166, 188)
245.             levelData.grassColor = _RGB32(83, 161, 72)
246.  
247.             this = newObject
248.             obj(this).id = idSky
249.             obj(this).color = _RGB32(67, 200, 205)
250.  
251.             addScene level
252.  
253.             addWater
254.  
255.             addClouds 5
256.  
257.             platformDecoration = "c" + STR$(_RGB32(166, 111, 67)) + " bd5 e10r1g10r1e10r1g10r1e10r1g10r1e10r1g10"
258.             levelData.symbolSpacingX = 11
259.             levelData.symbolSpacingY = 11
260.             FOR i = 1 TO totalPlatforms
261.                 this = newObject
262.                 obj(this).id = idPlatform
263.                 obj(this).w = RND * 200 + 50
264.                 obj(this).w = obj(this).w - (obj(this).w MOD 20)
265.                 IF i = 1 THEN
266.                     firstPlatform = this
267.                     obj(this).h = 200
268.                     obj(this).x = RND * (arenaWidth / totalPlatforms)
269.                 ELSE
270.                     obj(this).h = RND * 50 + 50
271.                     obj(this).x = obj(this - 1).x + obj(this - 1).w + (RND * (arenaWidth / (totalPlatforms * 1.5)))
272.                 END IF
273.                 obj(this).y = (_HEIGHT - _HEIGHT / 4 + (_HEIGHT / 20)) - obj(this).h
274.                 drawPlatform obj(this)
275.             NEXT
276.  
277.             goal = newObject
278.             obj(goal).id = idGoal
279.             obj(goal).x = arenaWidth
280.             obj(goal).y = _HEIGHT / 2
281.             obj(goal).h = 20
282.             obj(goal).w = 20
283.  
284.             hero = newObject
285.             obj(hero).x = obj(firstPlatform).x
286.             obj(hero).y = obj(firstPlatform).y - 25
287.             obj(hero).w = 15
288.             obj(hero).h = 30
289.             obj(hero).alive = true
290.             obj(hero).standing = true
291.     END SELECT
292. END SUB
293.  
294. FUNCTION newObject&
295.     totalObjects = totalObjects + 1
296.     IF totalObjects > UBOUND(obj) THEN
297.         REDIM _PRESERVE obj(totalObjects + 99) AS newObject
298.     END IF
299.     newObject& = totalObjects
300. END FUNCTION
301.  
302. SUB resetObjects
303.     DIM emptyObject AS newObject
304.     FOR i = 1 TO UBOUND(obj)
305.         IF obj(i).img < -1 AND obj(i).imgPointer = false THEN _FREEIMAGE obj(i).img
306.         obj(i) = emptyObject
307.     NEXT
308.     totalObjects = 0
309. END SUB
310.  
311. SUB drawPlatform (this AS newObject)
312.     this.img = _NEWIMAGE(this.w, this.h, 32)
313.     _DEST this.img
314.     LINE (0, 10)-STEP(this.w - 1, this.h - 1), levelData.landColor, BF
315.     FOR x = -10 TO this.w STEP levelData.symbolSpacingX
316.         FOR y = 15 TO this.h + 10 STEP levelData.symbolSpacingY
317.             PSET (x, y), levelData.landColor
318.             DRAW platformDecoration
319.         NEXT
320.     NEXT
321.     LINE (0, 0)-STEP(this.w - 1, 20), levelData.grassColor, BF
322.     LINE (0, 0)-STEP(this.w - 1, 10), _RGBA32(255, 255, 255, 30), BF
323.     LINE (0, 10)-STEP(5, this.h), _RGBA32(255, 255, 255, 30), BF
324.     LINE (this.w - 6, 10)-STEP(5, this.h), _RGBA32(0, 0, 0, 30), BF
325.  
326.     LINE (0, 5)-(5, 0), _RGB32(255, 0, 255)
327.     PAINT (0, 0), _RGB32(255, 0, 255), _RGB32(255, 0, 255)
328.     LINE (_WIDTH - 1, 5)-(_WIDTH - 6, 0), _RGB32(255, 0, 255)
329.     PAINT (_WIDTH - 1, 0), _RGB32(255, 0, 255), _RGB32(255, 0, 255)
330.     LINE (0, this.h - 4)-STEP(this.w, 3), _RGB32(255, 0, 255), BF
331.     _CLEARCOLOR _RGB32(255, 0, 255)
332.     LINE (0, this.h - 5)-STEP(this.w - 1, 5), _RGBA32(0, 0, 0, 30), BF
333.     _DEST 0
334. END SUB
335.  
336. SUB addClouds (max AS LONG)
337.     DIM this AS LONG
338.  
339.     FOR i = 1 TO max
340.         this = newObject
341.         obj(this).id = idCloud
342.         obj(this).x = RND * arenaWidth
343.         obj(this).y = RND * (_HEIGHT / 2)
344.         obj(this).h = 30
345.         obj(this).w = arenaWidth / max
346.         obj(this).xv = RND
347.     NEXT
348. END SUB
349.  
350. SUB addScene (level AS LONG)
351.     DIM this AS LONG, firstItem AS LONG
352.  
353.     SELECT CASE level
354.         CASE 1
355.             'green mountains, 2 layers
356.  
357.             'farther range
358.             FOR i = 1 TO 20
359.                 this = newObject
360.                 IF i = 1 THEN
361.                     firstItem = this
362.                     obj(this).img = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
363.                     _DEST obj(this).img
364.                     LINE (0, _HEIGHT - 1)-(_WIDTH / 2, 0), _RGB32(100, 150, 122)
365.                     LINE -(_WIDTH - 1, _HEIGHT - 1), _RGB32(100, 150, 122)
366.                     LINE -(0, _HEIGHT - 1), _RGB32(100, 150, 122)
367.                     PAINT (_WIDTH / 2, _HEIGHT / 2), _RGB32(100, 150, 122), _RGB32(100, 150, 122)
368.                     _DEST 0
369.                 ELSE
370.                     obj(this).img = obj(firstItem).img
371.                     obj(this).imgPointer = true
372.                 END IF
373.  
374.                 obj(this).id = idScene
375.                 obj(this).x = RND * arenaWidth
376.                 obj(this).y = RND * (_HEIGHT / 2)
377.                 obj(this).xv = 2.5
378.             NEXT
379.  
380.             'closer range
381.             FOR i = 1 TO 20
382.                 this = newObject
383.                 IF i = 1 THEN
384.                     firstItem = this
385.                     obj(this).img = _NEWIMAGE(_WIDTH, _HEIGHT, 32)
386.                     _DEST obj(this).img
387.                     LINE (0, _HEIGHT - 1)-(_WIDTH / 2, 0), _RGB32(78, 111, 67)
388.                     LINE -(_WIDTH - 1, _HEIGHT - 1), _RGB32(78, 111, 67)
389.                     LINE -(0, _HEIGHT - 1), _RGB32(78, 111, 67)
390.                     PAINT (_WIDTH / 2, _HEIGHT / 2), _RGB32(78, 111, 67), _RGB32(78, 111, 67)
391.                     _DEST 0
392.                 ELSE
393.                     obj(this).img = obj(firstItem).img
394.                     obj(this).imgPointer = true
395.                 END IF
396.  
397.                 obj(this).id = idScene
398.                 obj(this).x = RND * arenaWidth
399.                 obj(this).y = RND * (_HEIGHT / 2)
400.                 obj(this).xv = 2
401.             NEXT
402.     END SELECT
403. END SUB
404.  

[Pete]

Cool! Did you code that? It reminds me of Nintendo Mario.

Pete [:)] Maybe now some time to enable smilies?

[keybone]

Definately had fun playing that one for a few minutes. :-)

[Pete]

See? Keybone wants smilies, too!

[keybone]

See? Keybone wants smilies, too!

irc habits. :D

[Pete]

666