Scrolling LED Sign

[TerryRitchie]

I've been going through all my code snippets to organize them. I ran across this one and thought others might like it. It's a very simple method for creating a scrolling sign of any size.

Code: QB64: [Select]

1. '********************************
2. '*                              *
3. '* LED Maker  by  Terry Ritchie *
4. '*                              *
5. '********************************
6.  
7. CONST ROUND = 0, SQUARE = 1
8.  
9. TYPE LED
10.     Screen AS LONG ' the LED screen to show on screen
11.     Image AS LONG '  the LED image to work on in the background
12.     Mask AS LONG '   the LED mask to place over the LED image
13. END TYPE
14.  
15. DIM LED AS LED
16. DIM News$
17. DIM Mpos%
18.  
19. News$ = "                Breaking News!                QB64.org is awesome! "
20.  
21. MAKELED 128, 16, 10, ROUND '                                                   create LED screen
22. SCREEN LED.Screen '                                                            set LED screen as view screen
23. _TITLE "LED Scrolling Sign" '                                                  give screen a title
24. Mpos% = 0 '                                                                    reset message position pointer
25. DO
26.     _LIMIT 5 '                                                                 5 frames per second
27.     _DEST LED.Image '                                                          set small image as destination
28.     COLOR _RGB32(255, 255, 0) '                                                set text color to yellow
29.     Mpos% = Mpos% + 1 '                                                        increment message pointer
30.     IF Mpos% > LEN(News$) THEN Mpos% = 1 '                                     reset pointer at end of message
31.     LOCATE 1, 1 '                                                              position cursor
32.     PRINT MID$(News$, Mpos%, 16); '                                            display portion of message
33.     _DEST 0 '                                                                  set LED screen back to destination
34.     _PUTIMAGE , LED.Image '                                                    stretch the small image across screen
35.     _PUTIMAGE , LED.Mask '                                                     place LED mask over image
36.     _DISPLAY '                                                                 viola', the screen looks pixelized
37. LOOP UNTIL INKEY$ <> ""
38.  
39. '----------------------------------------------------------------------------------------------------------------------
40. '                                                                                                               MAKELED
41. SUB MAKELED (w%, h%, psize%, pshape%)
42.  
43. SHARED LED AS LED '  need access to LED screen properties
44.  
45. DIM OriginalDest& '  calling routine destination
46. DIM LEDPixel& '      temporary image to hold single LED pixel
47.  
48. OriginalDest& = _DEST '                                                        remember calling routine destination
49. LED.Screen = _NEWIMAGE(w% * psize%, h% * psize%, 32) '                         create LED screen image holder
50. LED.Image = _NEWIMAGE(w%, h%, 32) '                                            create LED work image
51. LED.Mask = _COPYIMAGE(LED.Screen) '                                            create LED matrix image mask
52. LEDPixel& = _NEWIMAGE(psize%, psize%, 32) '                                    create LED pixel
53. _DEST LEDPixel& '                                                              set LED pixel as destination image
54. CLS '                                                                          remove 0,0,0 alpha transparency
55. LINE (0, 0)-(psize% - 1, psize% - 1), _RGB32(10, 10, 10), BF '                 set background color
56. SELECT CASE pshape% '                                                          which pixel shape should be created?
57.     CASE ROUND '                                                               round pixels
58.         CIRCLE (psize% \ 2, psize% \ 2), psize% \ 2 - 1, _RGB32(0, 0, 2) '     create round pixel in center of image
59.         PAINT (psize% \ 2, psize% \ 2), _RGB32(0, 0, 1), _RGB32(0, 0, 2) '     fill the pixel in
60.     CASE SQUARE '                                                              square pixels
61.         LINE (1, 1)-(psize% - 1, psize% - 1), _RGB32(0, 0, 2), B '            create square pixel in center of image
62.         LINE (2, 2)-(psize% - 2, psize% - 2), _RGB32(0, 0, 1), BF
63. END SELECT
64. _DEST LED.Mask '                                                               set LED mask as destination image
65. CLS '                                                                          remove 0,0,0 alpha transparency
66. FOR x% = 0 TO w% * psize% - 1 STEP psize% '                                    cycle through horizontal pixel positions
67.     FOR y% = 0 TO h% * psize% - 1 STEP psize% '                                cycle through vertical pixel positions
68.         _PUTIMAGE (x%, y%), LEDPixel& '                                        place a pixel image
69.     NEXT y%
70. NEXT x%
71. FOR x% = 0 TO w% * psize% - 1 STEP psize% * 8 '                                cycle every 8 horizontal pixels
72.     LINE (x%, 0)-(x%, h% * psize% - 1), _RGB32(0, 0, 0) '                      draw a divider line
73. NEXT x%
74. FOR y% = 0 TO h% * psize% - 1 STEP psize% * 8 '                                cycle every 8 vertical pixels
75.     LINE (0, y%)-(w% * psize% - 1, y%), _RGB32(0, 0, 0) '                      draw a divider line
76. NEXT y%
77. _SETALPHA 0, _RGB32(0, 0, 1) '                                                 set transparency color of mask
78. _SETALPHA 63, _RGB32(0, 0, 2)
79. _DEST OriginalDest& '                                                          return to calling routine destination
80. _FREEIMAGE LEDPixel& '                                                         removel pixel image from memory
81.  
82. END SUB
83.  
84. '----------------------------------------------------------------------------------------------------------------------
85.  

[johnno56]

This bring back memories! Cool...

[Petr]

Hi [banned user],

Your code work not, because PIXEL type is not defined.

[bplus]

Hi Petr,

Just comment it out and lower limit from 60 to say 4, otherwise it zips by! ;)