FlipIt v1.0 - Light Out puzzle game

[Dav]

This is a simple "Lights out" puzzle game.  I don't really like this kind of game, but just wanted to make something.  It's nothing special, but does show one way of breaking the screen into a clickable grid of buttons.

- Dav

Code: QB64: [Select]

1. '==========
2. 'FLIPIT.BAS v1.0
3. '==========
4. 'Like the lights out color flip puzzle.
5. 'Try to make all squares the same by flipping them.
6. 'When you select a square, its color will flip, and
7. 'its neighboring squares will also flip colors.
8. 'Coded by Dav for QB64, SEP/2018
9.  
10.  
11. 'define button grid deminsions
12. DIM SHARED grid: grid = 8 '           size of grid is 8x8
13. DIM SHARED size: size = 65 '          size of buttons is 65x65
14. DIM SHARED btns: btns = grid * grid ' number of buttons on grid
15.  
16. 'define button data
17. DIM SHARED bv(btns) '              data for button
18. DIM SHARED bx(btns), by(btns) '    top x/y cords of buttons
19. DIM SHARED bx2(btns), by2(btns) '  bottom x/y cords of buttons
20.  
21. 'set screen based on grid & size
22. SCREEN _NEWIMAGE(size * grid, size * grid, 32)
23.  
24. 'set button values
25. bc = 1 'counter
26. FOR row = 1 TO grid
27.     FOR col = 1 TO grid
28.         x = (row * size): y = (col * size)
29.         bx(bc) = x - size: bx2(bc) = x ' generate x/y values
30.         by(bc) = y - size: by2(bc) = y
31.         bv(bc) = 0 'set to 0, button off
32.         bc = bc + 1
33.     NEXT
34. NEXT
35.  
36. bv(INT(btns / 2)) = 1 'set one random button ON
37.  
38. updateboard
39.  
40. '==== MAIN GAME LOOP
41.  
42. DO
43.  
44.     _LIMIT 60 'to save CPU cycles - the program even starts faster on my XP virtual machine
45.     WHILE _MOUSEINPUT: WEND 'reads mouse input in a loop to prevent lagging
46.  
47.     IF _MOUSEBUTTON(1) THEN
48.         mx = _MOUSEX: my = _MOUSEY
49.  
50.         'handle button pressed
51.         FOR t = 1 TO btns
52.             IF mx >= bx(t) AND mx <= bx2(t) AND my >= by(t) AND my <= by2(t) THEN
53.                 'change the clicked button
54.                 IF bv(t) = 0 THEN bv(t) = 1 ELSE bv(t) = 0
55.                 setbv "U", t 'now change 1 up above t
56.                 setbv "D", t 'now change 1 down t
57.                 setbv "L", t 'now change the left
58.                 setbv "R", t 'now change the right
59.                 updateboard
60.             END IF
61.         NEXT
62.  
63.         'wait until mouse button up to continue
64.         WHILE _MOUSEBUTTON(1) <> 0: n = _MOUSEINPUT: WEND
65.  
66.     END IF
67.  
68. LOOP
69.  
70. END
71.  
72. '==============================================
73.  
74. SUB updateboard ()
75.     _DISPLAY: CLS
76.     FOR b = 1 TO btns
77.         IF bv(b) = 0 THEN
78.             LINE (bx(b), by(b))-(bx2(b), by2(b)), _RGB(55, 55, 55), BF
79.             LINE (bx(b), by(b))-(bx2(b), by2(b)), _RGB(88, 88, 88), B
80.         ELSE
81.             LINE (bx(b), by(b))-(bx2(b), by2(b)), _RGB(88, 88, 88), BF
82.             LINE (bx(b), by(b))-(bx2(b), by2(b)), _RGB(55, 55, 55), B
83.         END IF
84.     NEXT
85.     _AUTODISPLAY
86. END SUB
87.  
88. '==============================================
89.  
90. SUB setbv (way$, b)
91.     'sets new button values.
92.  
93.     IF way$ = "U" THEN
94.         FOR j = 1 TO btns STEP grid
95.             IF b = j THEN EXIT SUB
96.         NEXT
97.         IF bv(b - 1) = 0 THEN bv(b - 1) = 1 ELSE bv(b - 1) = 0
98.     END IF
99.  
100.     IF way$ = "D" THEN
101.         FOR j = grid TO btns STEP grid
102.             IF b = j THEN EXIT SUB
103.         NEXT
104.         IF bv(b + 1) = 0 THEN bv(b + 1) = 1 ELSE bv(b + 1) = 0
105.     END IF
106.  
107.     IF way$ = "L" THEN
108.         FOR j = 1 TO grid
109.             IF b = j THEN EXIT SUB
110.         NEXT j
111.         IF bv(b - grid) = 0 THEN bv(b - grid) = 1 ELSE bv(b - grid) = 0
112.     END IF
113.  
114.     IF way$ = "R" THEN
115.         FOR j = btns - grid + 1 TO btns
116.             IF b = j THEN EXIT SUB
117.         NEXT j
118.         IF bv(b + grid) = 0 THEN bv(b + grid) = 1 ELSE bv(b + grid) = 0
119.     END IF
120.  
121. END SUB
122.  

[FellippeHeitor]

Nice sample, Dav. Two suggestions:

Code: QB64: [Select]

1. '==== MAIN GAME LOOP
2.  
3. DO
4.     _LIMIT 60 'to save CPU cycles - the program even starts faster on my XP virtual machine
5.     WHILE _MOUSEINPUT: WEND 'reads mouse input in a loop to prevent lagging
6.     IF _MOUSEBUTTON(1) THEN

The two new lines above made a world of a difference in my experience.

I did write one similar to this, but I ended up giving it a slightly different spin. Here's the code if you want to check it out: https://github.com/FellippeHeitor/LightsOn (Download here)

[Zeppelin]

This seems like a port of a MacOS terminal game '5x5'.
If you want to try that:
1. Get a Mac.
2. Open terminal
3. Type in 'emacs'
4. Press escape
5. Press x
6. Type 5x5 into the input field at the bottom.

Is this you game you based this off of Dav?

Zeppelin

[Dav]

Thanks, Fillippe! That works well.  I had tried _LIMIT 60 before, but it lagged horribly the way I was getting the mouse input so I removed it.  The way you put them together works very well and I will adopt that method.  Your game looks great!

Zeppelin: I think it is the same type game, originally called 5x5 according to the wikipedia. I first ran across it as called lights out, on a pc.

I have edited the code with Fillippes suggestions, and also added _DISPLAY/_AUTODISPLAY in the updateboard SUB to reduce any screen flickering.

- Dav

[bplus]

Thanks Dav, I've not seen that game before. Really like these puzzle games!

Fellippe, wow! nice attention to details, sound, light bulb images, help at start...

[FellippeHeitor]

@Dav: glad to hear it works well with the changes there too.

@bplus: thanks a lot!