Let's PLAY(0) Wheel of Fortune...

[Pete]

Code: QB64: [Select]

1. DIM SHARED overlay
2. _SCREENMOVE _MIDDLE
3.  
4. Screen0 = _NEWIMAGE(80, 25, 0)
5. SCREEN Screen0
6.  
7. COLOR 8, 0
8. FOR i = 1 TO 25
9.     LOCATE i, 1: PRINT STRING$(80, 176);
10. NEXT
11.  
12. font = _LOADFONT("lucon.ttf", 60, "monospace")
13. IF font <= 0 THEN font = 16
14.  
15. overlay = _NEWIMAGE(_WIDTH * _FONTWIDTH, _HEIGHT * _FONTHEIGHT, 32)
16. _DEST overlay
17. _FONT font
18. COLOR _RGB(255, 102, 0), 0
19.  
20. b = 73
21.  
22. FOR i = 0 TO 7
23.     IF i <> 4 THEN LINE (25 + i * b + 18, 55)-(76 + i * b + 18, 125 - 10), _RGB(255, 255, 255), B , 255
24. NEXT
25.  
26. FOR i = 1 TO 5
27.     LINE (25 + i * b + 54, 175)-(76 + i * b + 54, 245 - 10), _RGB(255, 255, 255), B , 255
28. NEXT
29.  
30. Overlay_Hardware = _COPYIMAGE(overlay, 33)
31. _PUTIMAGE (0, 0), Overlay_Hardware
32. _DISPLAY
33.  
34. _DELAY 2
35.  
36. FOR i = 1 TO 8
37.     READ z$, q, w
38.     t$(i) = z$: q(i) = q: w(i) = w
39. NEXT
40.  
41. FOR i = 1 TO 8
42.     FOR j = 1 TO 8
43.         IF i <> j THEN
44.             IF q(i) < q(j) THEN SWAP t$(i), t$(j): SWAP q(i), q(j): SWAP w(i), w(j)
45.         END IF
46.     NEXT
47. NEXT
48.  
49. FOR h = 1 TO 8
50.     IF w(h) < 10 THEN
51.         t$ = t$(h)
52.         x = 2.5 + (w(h) - 1) * 2: y = 2
53.         PSL y, x, t$
54.     ELSE
55.         t$ = t$(h)
56.         x = 3.5 + (w(h) - 9) * 2: y = 4
57.         PSL y, x, t$
58.     END IF
59.     IF h <> 2 THEN _DELAY 3
60. NEXT
61.  
62. _FONT 16
63. y = 20: x = 23
64. COLOR _RGB(255, 255, 255)
65. t$ = "I'd like to solve the puzzle, please!"
66. PSL y, x, t$
67. _DELAY 3
68.  
69. _FREEFONT font
70.  
71. _DEST 0
72.  
73. _DEST overlay
74. CLS
75.  
76. COLOR _RGB(255, 102, 0), 0
77.  
78. x = 0: y = 0: t$ = ""
79. font = _LOADFONT("lucon.ttf", 60, "monospace")
80. IF font <= 0 THEN font = 16
81. _FONT font
82.  
83. a$ = CHR$(76) + CHR$(101) + CHR$(116) + "'" + CHR$(115) + CHR$(32) + CHR$(71) + CHR$(111) + CHR$(32) + CHR$(66) + CHR$(114) + CHR$(97) + CHR$(110) + CHR$(100) + CHR$(111) + CHR$(110) + "!"
84. m$ = "MBn29L3n24L3n33L3n29L4"
85.  
86. DO
87.     IF seed% = 0 THEN PLAY m$
88.     y = 150: x = 8 + x + LEN(t$) * 36
89.     t$ = MID$(a$ + " ", seed%, INSTR(seed%, a$ + " ", " ") - seed% + 1)
90.     _PRINTSTRING (x, y), RTRIM$(t$)
91.     Overlay_Hardware = _COPYIMAGE(overlay, 33)
92.     _PUTIMAGE (0, 0), Overlay_Hardware
93.     _DISPLAY
94.     IF seed% < LEN(a$) THEN
95.         seed% = INSTR(seed%, a$ + " ", " ") + 1
96.         _DELAY .66
97.     ELSE
98.         _DELAY .66: CLS: _DISPLAY: seed% = 0: x = 0: _DELAY 1.33
99.     END IF
100. LOOP UNTIL LEN(INKEY$)
101. _FONT 16
102. _FREEFONT font
103. _FREEIMAGE overlay
104.  
105. _DEST 0
106. _DELAY .66
107.  
108. SYSTEM
109.  
110. DATA C,8,3
111. DATA K,4,4
112. DATA B,7,10
113. DATA J,5,6
114. DATA F,1,1
115. DATA E,2,8
116. DATA N,6,14
117. DATA E,3,13
118.  
119. SUB PSL (y, x, t$)
120.     _PRINTSTRING ((x - 1) * _FONTWIDTH, (y - 1) * _FONTHEIGHT), t$
121.     overlay_hardware = _COPYIMAGE(overlay, 33)
122.     _PUTIMAGE (0, 0), overlay_hardware
123.     _DISPLAY
124. END SUB

Well, on a serious "note," It's a shame QB64 was not able to get the PLAY(0) function implemented. PLAY(0) was a QB / QuickBASIC function that tracked the number notes (up to 36) in the buffer if the MB handle was used to tell PLAY to play the notes in the background. You could use it to figure out where you were in a music loop, or when the last note ended. Very useful.

So my question is probably to @SpriggsySpriggs

Is there a Windows API method to track the sound buffer, or at least to tell us when sound playing sound / music in the background has completed? 

Pete

[Pete]

Ah, it's a version incompatibility issue. It runs correctly in 2.0, but in 1.3, it misplaces and overlaps the letters, as you described. Apparently _FONTWIDTH and _FONTHEIGHT are not processed the same in the older versions.

Try this, if you'd like to see the real puzzle...

Change this one line in the PSL() sub...

_PRINTSTRING ((x - 1) * _FONTWIDTH, (y - 1) * _FONTHEIGHT), t$

to...

_PRINTSTRING ((x - 1) * 36, (y - 1) * 60), t$

That should do it.

BTW: What's the version of QB64 you are currently running? $COLOR:32 is another one that won't run in 1.3, but I believe does in 1.4.

Pete