Some Phantasy Star Progess, Opening Sequence.

[Cobalt]

⚠️ Here is some work that I have been doing toward my Phantasy Star I clone. ⚠️

⚠️⚠️A little Caution though, some the audio is quite loud at times.⚠️⚠️

Only option that really does anything is Start, Though some of Continue does exist(you can delete the dummy save slots) it doesn't make a difference anywhere.

Controls:
Up and Down arrows
Enter key.

⚠️⚠️⚠️⚠️Don't forget to download the MFI file!⚠️⚠️⚠️⚠️

Code: QB64: [Select]

1. TYPE ControllerKeys
2.  KBCon_Up AS LONG
3.  KBCon_Down AS LONG
4.  KBCon_Left AS LONG
5.  KBCon_Right AS LONG
6.  KBCon_Select AS LONG
7.  KBCon_Start AS LONG
8.  KBCon_A_Button AS LONG
9.  KBCon_B_Button AS LONG
10.  
11.  Control_Pad AS _BYTE 'which Gamepad\Joystick Device Is player Using?
12.  BAD_Pad AS _BYTE 'option for Buttons As Directions
13.  Joy_Up AS _BYTE 'axis for up
14.  Joy_Up_Val AS _BYTE 'axis value for up
15.  Joy_Down AS _BYTE 'axis for down
16.  Joy_Down_Val AS _BYTE 'axis value for down
17.  Joy_Left AS _BYTE 'axis for left
18.  Joy_Left_Val AS _BYTE 'axis value for left
19.  Joy_Right AS _BYTE 'axis for right
20.  Joy_Right_Val AS _BYTE 'axis value for right
21.  Joy_Select AS _BYTE
22.  Joy_Start AS _BYTE
23.  Joy_A_Button AS _BYTE
24.  Joy_B_Button AS _BYTE
25.  Joy_Button_Up AS _BYTE 'for people whos controllers give BUTTON states for direction keys
26.  Joy_Button_Down AS _BYTE 'or just want to use buttons for the direction keys.
27.  Joy_Button_Left AS _BYTE '""""
28.  Joy_Button_Right AS _BYTE 'however this fails to work so may not be implemented.
29. END TYPE
30. TYPE Game_Data
31.  SavedGames AS _BYTE
32. END TYPE
33.  
34. CONST Default_Key_Right = 19712, Default_Key_Left = 19200, Default_Key_Up = 18432, Default_Key_Down = 20480
35. CONST Default_A_Button = 13, Default_B_Button = 32, Default_Start_Button = 65, Default_Select_Button = 66
36. CONST ESC_Key = 27, ESC = 99
37. CONST TRUE = -1, FALSE = NOT TRUE
38. CONST New_Game = 101, Loaded_Game = 102
39. CONST DOWN = 0, LEFT = 1, UP = 2, RIGHT = 3, SELECT_BUTTON = 4, START_BUTTON = 5, BUTTON_B = 6, BUTTON_A = 7
40.  
41. DIM SHARED Line$(1200), Temp&
42. DIM SHARED G AS Game_Data, SavedNames(5) AS STRING * 5, C AS ControllerKeys
43. DIM SHARED Layer(64) AS LONG, SFX(64) AS LONG
44. '------dummy data-------
45. C.KBCon_Up = Default_Key_Up
46. C.KBCon_Down = Default_Key_Down
47. C.KBCon_Left = Default_Key_Left
48. C.KBCon_Right = Default_Key_Right
49. C.KBCon_Select = Default_Select_Button
50. C.KBCon_Start = Default_Start_Button
51. C.KBCon_A_Button = Default_A_Button
52. C.KBCon_B_Button = Default_B_Button
53. SavedNames(1) = "ALIS"
54. SavedNames(2) = "FELLI"
55. SavedNames(3) = "STEVE"
56. SavedNames(4) = "BPLUS"
57. SavedNames(5) = "DAVID"
58. G.SavedGames = 5
59. '-----------------------
60. MFI_Loader "PS_Opening_Demo.MFI"
61. 'Layer(33) = _LOADIMAGE("GFX\SMS_Console_SM.bmp", 32)
62. 'Layer(34) = _LOADIMAGE("GFX\SMS_Console_Overlay.bmp", 32)
63. 'Layer(35) = _LOADIMAGE("GFX\SMS_Console_Overlay2.bmp", 32)
64. 'Layer(36) = _LOADIMAGE("GFX\CartridgeInserted.bmp", 32)
65. 'Layer(37) = _LOADIMAGE("GFX\Controller_Plug.bmp", 32)
66. 'Layer(38) = _LOADIMAGE("GFX\Controller.bmp", 32)
67. 'Layer(39) = _LOADIMAGE("GFX\PowerButton_ON.bmp", 32)
68. 'Layer(40) = _LOADIMAGE("GFX\PowerLED_ON.bmp", 32)
69. 'Layer(41) = _LOADIMAGE("GFX\FingerPressPower.bmp", 32)
70. 'Layer(42) = _LOADIMAGE("GFX\SMS_BIOS_UP.bmp", 32)
71. 'Layer(43) = _LOADIMAGE("GFX\MainMenuScreen.bmp", 32)
72. 'Layer(44) = _LOADIMAGE("GFX\BackGroundsMaster.bmp", 32)
73. 'Layer(45) = _LOADIMAGE("GFX\CutScenes_NPC_Sprites.bmp", 32)
74. 'Layer(46) = _LOADIMAGE("GFX\StarSkyLoop.bmp", 32)
75. 'Layer(47) = _LOADIMAGE("GFX\FontMasterLinear.bmp", 32)
76. 'SFX(0) = _SNDOPEN("Audio\MasterSystem_StartUp.ogg")
77. 'SFX(1) = _SNDOPEN("Audio\InsertCart_SLOW.ogg")
78. 'SFX(2) = _SNDOPEN("Audio\Power_Button.ogg")
79. 'SFX(3) = _SNDOPEN("Audio\MainMenuLoop.ogg")
80. 'SFX(4) = _SNDOPEN("Audio\IntroLoop.ogg")
81. '
82. 'OPEN "dialog_dump.txt" FOR BINARY AS #1
83. 'DO
84. ' LINE INPUT #1, Line$(i%)
85. ' Line$(i%) = RTRIM$(LTRIM$(Line$(i%)))
86. ' i% = i% + 1
87. 'LOOP UNTIL EOF(1)
88. 'CLOSE #1
89.  
90. SCREEN _NEWIMAGE(640, 480, 32): CLS: RANDOMIZE TIMER
91. Temp& = _NEWIMAGE(640, 480, 32)
92. Layer(32) = _NEWIMAGE(640, 480, 32)
93. _CLEARCOLOR _RGB32(0), Layer(37)
94. _CLEARCOLOR _RGB32(0), Layer(36)
95. _CLEARCOLOR _RGB32(0), Layer(41)
96. _CLEARCOLOR _RGB32(0), Layer(34)
97. _CLEARCOLOR _RGB32(0), Layer(35)
98. _CLEARCOLOR _RGB32(0), Layer(38)
99.  
100. Elaborate_Loading
101. Startup_Menu
102. New_Game_Sequence
103.  
104.  
105. SUB TimedPrint (X%, Y%, Txt$, LPS%)
106.  Speed! = (100 / LPS%) / 100
107.  FOR i%% = 1 TO LEN(Txt$)
108.   IF MID$(Txt$, i%%, 1) = CHR$(34) THEN By%% = 8 ELSE By%% = 0
109.   _PUTIMAGE (X% + i%% * 16, Y% - By%%)-STEP(15, 15), Layer(47), _DISPLAY, (1 + (10 * (ASC(MID$(Txt$, i%%, 1)) - 32)), 1)-STEP(7, 7)
110.   _DELAY Speed!
111.  NEXT i%%
112. END SUB
113.  
114. SUB KeyPressWait
115.  _KEYCLEAR
116.  DO: LOOP UNTIL INKEY$ <> ""
117. END SUB
118.  
119. SUB ClearTextRegion
120.  LINE (144, 320)-(464, 464), _RGB32(0), BF
121. END SUB
122.  
123. SUB PS_Print (X%, Y%, TxT$)
124.  L% = LEN(TxT$)
125.  FOR i%% = 1 TO L%
126.   _PUTIMAGE (X% + i%% * 16, Y%)-STEP(15, 15), Layer(47), _DISPLAY, (1 + (10 * (ASC(MID$(TxT$, i%%, 1)) - 32)), 1)-STEP(7, 7)
127.  NEXT
128. END SUB
129.  
130. SUB Create_Dialog_Box (X%, Y%, H%, W%)
131.  Top$ = "a"
132.  Bot$ = "g"
133.  FOR i%% = 1 TO W%
134.   Top$ = Top$ + "b"
135.   Bot$ = Bot$ + "h"
136.  NEXT i%%
137.  Top$ = Top$ + "c"
138.  Bot$ = Bot$ + "i"
139.  sid$ = "d" + SPACE$(W%) + "f"
140.  ' PS_Print 144, 336, "abbbbbbbbbbbbbbbbbbc"
141.  ' PS_Print 144, 352, "d                  f"
142.  ' PS_Print 144, 368, "d                  f"
143.  ' PS_Print 144, 384, "d                  f"
144.  ' PS_Print 144, 400, "d                  f"
145.  ' PS_Print 144, 416, "ghhhhhhhhhhhhhhhhhhi"
146.  PS_Print X% * 16, Y% * 16, Top$
147.  FOR i%% = 1 TO H%
148.   PS_Print X% * 16, (Y% + i%%) * 16, sid$
149.  NEXT i%%
150.  PS_Print X% * 16, (Y% + i%%) * 16, Bot$
151. END SUB
152.  
153. SUB StarScroll
154.  DO
155.   _PUTIMAGE (64, 48)-STEP(511, 383), Layer(46), _DISPLAY, (0, gx%)-STEP(255, 191)
156.   _LIMIT 60
157.   gx% = gx% + 1
158.  LOOP UNTIL gx% = 256
159. END SUB
160.  
161. SUB Fade_Out (L&)
162.  FOR n! = 1 TO 0.00 STEP -0.05
163.   i2& = _COPYIMAGE(L&)
164.   DarkenImage i2&, n!
165.   _PUTIMAGE (0, 0), i2&
166.   _FREEIMAGE i2&
167.   _DELAY .03
168.  NEXT
169. END SUB
170.  
171. SUB Fade_In (L&)
172.  FOR n! = 0.01 TO 1 STEP 0.05
173.   i2& = _COPYIMAGE(L&)
174.   DarkenImage i2&, n!
175.   _PUTIMAGE (0, 0), i2&
176.   _FREEIMAGE i2&
177.   _DELAY .03
178.  NEXT
179. END SUB
180.  
181. SUB DarkenImage (Image AS LONG, Value_From_0_To_1 AS SINGLE)
182.  IF Value_From_0_To_1 <= 0 OR Value_From_0_To_1 >= 1 OR _PIXELSIZE(Image) <> 4 THEN EXIT SUB
183.  DIM Buffer AS _MEM: Buffer = _MEMIMAGE(Image) 'Get a memory reference to our image
184.  DIM Frac_Value AS LONG: Frac_Value = Value_From_0_To_1 * 65536 'Used to avoid slow floating point calculations
185.  DIM O AS _OFFSET, O_Last AS _OFFSET
186.  O = Buffer.OFFSET 'We start at this offset
187.  O_Last = Buffer.OFFSET + _WIDTH(Image) * _HEIGHT(Image) * 4 'We stop when we get to this offset
188.  'use on error free code ONLY!
189.  $CHECKING:OFF
190.  DO
191.   _MEMPUT Buffer, O, _MEMGET(Buffer, O, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
192.   _MEMPUT Buffer, O + 1, _MEMGET(Buffer, O + 1, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
193.   _MEMPUT Buffer, O + 2, _MEMGET(Buffer, O + 2, _UNSIGNED _BYTE) * Frac_Value \ 65536 AS _UNSIGNED _BYTE
194.   O = O + 4
195.  LOOP UNTIL O = O_Last
196.  'turn checking back on when done!
197.  $CHECKING:ON
198.  _MEMFREE Buffer
199. END SUB
200.  
201. SUB ClearLayer (L&)
202.  old& = _DEST
203.  _DEST L&
204.  CLS
205.  _DEST old&
206. END SUB
207.  
208. SUB Startup_Menu
209.  _SNDLOOP SFX(3)
210.  _PUTIMAGE (64, 48)-STEP(512, 383), Layer(43), Temp& 'place start menu into temp to fade in
211.  Fade_In Temp&
212.  _PUTIMAGE (64, 48)-STEP(512, 383), Layer(43), _DISPLAY
213.  DO
214.   Inputs%% = Get_Input
215.   SELECT CASE Inputs%%
216.    CASE UP
217.     TimedPrint 192, 304 + (32 * Opt%%), " ", 100
218.     Opt%% = Opt%% - 1
219.     IF Opt%% = -1 THEN Opt%% = 0
220.     DO: Inputs%% = Get_Input: LOOP UNTIL Inputs%% = TRUE
221.    CASE DOWN
222.     TimedPrint 192, 304 + (32 * Opt%%), " ", 100
223.     Opt%% = Opt%% + 1
224.     IF Opt%% = 3 THEN Opt%% = 2
225.     DO: Inputs%% = Get_Input: LOOP UNTIL Inputs%% = TRUE
226.    CASE BUTTON_A
227.     SELECT CASE Opt%%
228.      CASE 0
229.       ExitFlag%% = TRUE
230.       Result%% = New_Game
231.      CASE 1
232.       IF G.SavedGames THEN Result%% = Continue ELSE ExitFlag%% = TRUE: Result%% = New_Game
233.       IF Result%% = TRUE THEN
234.        ExitFlag%% = TRUE: Result%% = Loaded_Game
235.       ELSE
236.        _PUTIMAGE (64, 48)-STEP(512, 383), Layer(43), Temp& 'place start menu into temp to fade in
237.        Fade_In Temp&
238.        _PUTIMAGE (64, 48)-STEP(512, 383), Layer(43), _DISPLAY
239.       END IF
240.      CASE 2
241.       Run_Options
242.     END SELECT
243.    CASE ESC
244.     END
245.   END SELECT
246.   IF blinkon%% THEN TimedPrint 192, 304 + (32 * Opt%%), "j", 100 ELSE TimedPrint 192, 304 + (32 * Opt%%), " ", 100
247.   blink%% = blink%% + 1
248.   IF blink%% = 8 AND blinkon%% = 0 THEN blinkon%% = -1: blink%% = 0
249.   IF blink%% = 8 AND blinkon%% = -1 THEN blinkon%% = 0: blink%% = 0
250.   _LIMIT 60
251.  LOOP UNTIL ExitFlag%%
252. END SUB
253.  
254. FUNCTION Continue%%
255.  Fade_Out _DISPLAY
256.  Create_Dialog_Box 9, 21, 4, 18
257.  TimedPrint 16 * 10, 16 * 23, "CONTINUE GAME- YES", 100
258.  TimedPrint 16 * 10, 16 * 25, "DELETE   GAME- NO ", 100
259.  Result%% = Yes_No_Box(24, 16)
260.  SELECT CASE Result%%
261.   CASE 0
262.    Load_Game
263.    Result%% = TRUE
264.   CASE 1
265.    Delete_Game
266.    Result%% = FALSE
267.  END SELECT
268.  Continue%% = Result%%
269. END FUNCTION
270.  
271. SUB Run_Options
272. END SUB
273.  
274. FUNCTION Yes_No_Box%% (X%, Y%)
275.  Result%% = TRUE
276.  Create_Dialog_Box X%, Y%, 3, 3
277.  TimedPrint 16 * (X% + 1), 16 * (Y% + 1), "YES", 100
278.  TimedPrint 16 * (X% + 1), 16 * (Y% + 3), "NO", 100
279.  DO
280.   IF _KEYDOWN(Default_Key_Down) OR _KEYDOWN(Default_Key_Up) THEN
281.    IF NOT KeyStop%% THEN
282.     IF Opt%% THEN Opt%% = 0 ELSE Opt%% = 1
283.     KeyStop%% = TRUE
284.    END IF
285.   ELSE
286.    KeyStop%% = FALSE
287.   END IF
288.   SELECT CASE Opt%%
289.    CASE 0
290.     IF Blinkon%% THEN PS_Print 16 * (X%), 16 * (Y% + 1), "k" ELSE PS_Print 16 * (X%), 16 * (Y% + 1), "d"
291.     PS_Print 16 * X%, 16 * (Y% + 3), "d"
292.    CASE 1
293.     PS_Print 16 * X%, 16 * (Y% + 1), "d"
294.     IF Blinkon%% THEN PS_Print 16 * X%, 16 * (Y% + 3), "k" ELSE PS_Print 16 * X%, 16 * (Y% + 3), "d"
295.   END SELECT
296.   _LIMIT 60
297.   blink%% = blink%% + 1
298.   IF blink%% = 10 THEN Blinkon%% = NOT Blinkon%%: blink%% = 0
299.   LOCATE 1, 1: PRINT Opt%%
300.   IF _KEYDOWN(Default_A_Button) THEN Result%% = Opt%%: ExitFlag%% = TRUE
301.  LOOP UNTIL ExitFlag%%
302.  Yes_No_Box = Result%%
303. END FUNCTION
304.  
305. SUB Load_Game
306.  CLS
307.  Create_Dialog_Box 9, 21, 4, 18
308.  TimedPrint 16 * 10, 16 * 23, "CONTINUE A GAME.", 100
309.  TimedPrint 16 * 10, 16 * 25, "SELECT A NUMBER. ", 100
310.  Result%% = Select_Game
311. END SUB
312.  
313. SUB Delete_Game
314.  Create_Dialog_Box 9, 21, 4, 18
315.  TimedPrint 16 * 10, 16 * 23, "WILL DELETE A", 100
316.  TimedPrint 16 * 10, 16 * 25, "SAVED GAME O.K.? ", 100
317.  Result%% = Yes_No_Box(24, 16)
318.  SELECT CASE Result%%
319.   CASE 0
320.    CLS
321.    Create_Dialog_Box 9, 21, 4, 18
322.    TimedPrint 16 * 10, 16 * 23, "DELETE A GAME", 100
323.    TimedPrint 16 * 10, 16 * 25, "SELECT A NUMBER. ", 100
324.    Result%% = Select_Game
325.  END SELECT
326. END SUB
327.  
328. FUNCTION Select_Game
329.  Create_Dialog_Box 26, 1, 10, 7
330.  TimedPrint 16 * 27, 16 * 3, "1", 100
331.  TimedPrint 16 * 27, 16 * 5, "2 ", 100
332.  TimedPrint 16 * 27, 16 * 7, "3", 100
333.  TimedPrint 16 * 27, 16 * 9, "4 ", 100
334.  TimedPrint 16 * 27, 16 * 11, "5", 100
335.  FOR i%% = 1 TO 5
336.   TimedPrint 16 * 29, 16 * (1 + i%% * 2), SavedNames(i%%), 100
337.  NEXT i%%
338.  Tmp& = _COPYIMAGE(_DISPLAY)
339.  Opt%% = 1
340.  DO
341.   Inputs%% = Get_Input
342.   SELECT CASE Inputs%%
343.    CASE UP
344.     Opt%% = Opt%% - 1
345.     IF Opt%% = 0 THEN Opt%% = 1
346.     DO: Inputs%% = Get_Input: LOOP UNTIL Inputs%% = TRUE
347.    CASE DOWN
348.     Opt%% = Opt%% + 1
349.     IF Opt%% = 6 THEN Opt%% = 5
350.     DO: Inputs%% = Get_Input: LOOP UNTIL Inputs%% = TRUE
351.    CASE BUTTON_A
352.     IF LTRIM$(SavedNames(Opt%%)) <> "" THEN
353.      SavedNames(Opt%%) = ""
354.      G.SavedGames = G.SavedGames - 1
355.      ExitFlag%% = TRUE
356.     ELSE
357.      Opt%% = 1
358.     END IF
359.   END SELECT
360.   _PUTIMAGE , Tmp&, _DISPLAY
361.   IF Blinkon%% THEN PS_Print 16 * (26), 16 * (1 + Opt%% * 2), "k"
362.   _PRINTSTRING (0, 0), STR$(Opt%%)
363.   _LIMIT 60
364.   blink%% = blink%% + 1
365.   IF blink%% = 10 THEN Blinkon%% = NOT Blinkon%%: blink%% = 0
366.  LOOP UNTIL ExitFlag%%
367.  _FREEIMAGE Tmp&
368. END FUNCTION
369.  
370.  
371. FUNCTION Get_Input%% ()
372.  Result%% = TRUE '-1 for no input
373.  ' SELECT CASE G.ControlType
374.  '  CASE TRUE 'Keyboard input
375.  IF _KEYDOWN(ESC_Key) THEN Result%% = ESC
376.  IF _KEYDOWN(C.KBCon_Up) THEN Result%% = UP
377.  IF _KEYDOWN(C.KBCon_Down) THEN Result%% = DOWN
378.  IF _KEYDOWN(C.KBCon_Left) THEN Result%% = LEFT
379.  IF _KEYDOWN(C.KBCon_Right) THEN Result%% = RIGHT
380.  IF _KEYDOWN(C.KBCon_Select) THEN Result%% = SELECT_BUTTON: DO: LOOP WHILE _KEYDOWN(C.KBCon_Select)
381.  IF _KEYDOWN(C.KBCon_Start) THEN Result%% = START_BUTTON: DO: LOOP WHILE _KEYDOWN(C.KBCon_Start)
382.  IF _KEYDOWN(C.KBCon_A_Button) THEN Result%% = BUTTON_A: DO: LOOP WHILE _KEYDOWN(C.KBCon_A_Button)
383.  IF _KEYDOWN(C.KBCon_B_Button) THEN Result%% = BUTTON_B: DO: LOOP WHILE _KEYDOWN(C.KBCon_B_Button)
384.  
385.  '  CASE FALSE 'joystick input
386.  ' IF C.Control_Pad THEN
387.  '  IF NOT G.Flag THEN DO: LOOP WHILE _DEVICEINPUT(C.Control_Pad)
388.  '  IF NOT C.BAD_Pad THEN
389.  '   nul%% = AxisPower(CJR%%, CJL%%, CJU%%, CJD%%) 'read directional axis values
390.  ' IF CJU%% THEN Result%% = UP
391.  ' IF CJD%% THEN Result%% = DOWN
392.  ' IF CJL%% THEN Result%% = LEFT
393.  ' IF CJR%% THEN Result%% = RIGHT
394.  '  ELSE
395.  '   IF _BUTTON(C.Joy_Button_Up) THEN Result%% = UP ': Joy_Lock_Button (C.Joy_Button_Up)
396.  '   IF _BUTTON(C.Joy_Button_Down) THEN Result%% = DOWN ': Joy_Lock_Button (C.Joy_Button_Down)
397.  ' IF _BUTTON(C.Joy_Button_Left) THEN Result%% = LEFT ': Joy_Lock_Button (C.Joy_Button_Left)
398.  ' IF _BUTTON(C.Joy_Button_Right) THEN Result%% = RIGHT ': Joy_Lock_Button (C.Joy_Button_Right)
399.  '  END IF
400.  '  IF _BUTTON(C.Joy_Select) THEN Result%% = SELECT_BUTTON: Joy_Lock_Button (C.Joy_Select)
401.  '  IF _BUTTON(C.Joy_Start) THEN Result%% = START_BUTTON: Joy_Lock_Button (C.Joy_Start)
402.  '  IF _BUTTON(C.Joy_A_Button) THEN Result%% = BUTTON_A: Joy_Lock_Button (C.Joy_A_Button)
403.  '  IF _BUTTON(C.Joy_B_Button) THEN Result%% = BUTTON_B: Joy_Lock_Button (C.Joy_B_Button)
404.  ' END IF
405.  ' END SELECT
406.  Get_Input = Result%%
407. END FUNCTION
408.  
409. SUB New_Game_Sequence
410.  Fade_Out _DISPLAY
411.  Fade_SFX_Out SFX(3)
412.  ClearLayer Temp&
413.  _PUTIMAGE (64, 48)-STEP(511, 383), Layer(46), Temp&, (0, 0)-STEP(255, 191)
414.  Fade_In Temp&
415.  _SNDLOOP SFX(4)
416.  StarScroll
417.  _DELAY 1
418.  Fade_Out _DISPLAY
419.  ClearLayer Temp&
420.  _PUTIMAGE (64, 48)-STEP(511, 383), Layer(44), Temp&, (0, 0)-STEP(255, 191)
421.  Fade_In Temp&
422.  _PUTIMAGE (64, 48)-STEP(511, 383), Layer(44), _DISPLAY, (0, 0)-STEP(255, 191)
423.  Create_Dialog_Box 6, 5, 3, 18
424.  TimedPrint 16 * 7, 16 * 6, "SPACE CENTURY 324,", 20
425.  TimedPrint 16 * 7, 16 * 8, "CAMINEET ON PALMA", 20
426.  _DELAY 1.5
427.  ClearLayer Temp&
428.  _PUTIMAGE (64, 48)-STEP(511, 319), Layer(45), Temp&, (0, 0)-STEP(255, 159)
429.  _PUTIMAGE (160, 96)-STEP(319, 191), Layer(45), Temp&, (0, 160)-STEP(159, 95)
430.  Fade_In Temp&
431.  FOR i%% = 0 TO 3
432.   TimedPrint 144, 320 + 30 * i%%, Line$(1083 + i%%), 24
433.  NEXT i%%
434.  KeyPressWait
435.  Fade_Out _DISPLAY
436.  _PUTIMAGE (160, 96)-STEP(319, 191), Layer(45), Temp&, (161, 257)-STEP(159, 95)
437.  Fade_In Temp&
438.  FOR i%% = 0 TO 1
439.   TimedPrint 144, 320 + 30 * i%%, Line$(1087 + i%%), 24
440.  NEXT i%%
441.  KeyPressWait
442.  Fade_Out _DISPLAY
443.  _PUTIMAGE (160, 96)-STEP(319, 191), Layer(45), Temp&, (0, 257)-STEP(159, 95)
444.  Fade_In Temp&
445.  FOR i%% = 0 TO 3
446.   TimedPrint 144, 320 + 30 * i%%, Line$(1089 + i%%), 24
447.  NEXT i%%
448.  KeyPressWait
449.  ClearTextRegion
450.  FOR i%% = 0 TO 3
451.   TimedPrint 144, 320 + 30 * i%%, Line$(1093 + i%%), 24
452.  NEXT i%%
453.  KeyPressWait
454.  ClearTextRegion
455.  FOR i%% = 0 TO 3
456.   TimedPrint 144, 320 + 30 * i%%, Line$(1097 + i%%), 24
457.  NEXT i%%
458.  KeyPressWait
459.  ClearTextRegion
460.  FOR i%% = 0 TO 3
461.   TimedPrint 144, 320 + 30 * i%%, Line$(1101 + i%%), 24
462.  NEXT i%%
463.  KeyPressWait
464.  Fade_Out _DISPLAY
465.  _PUTIMAGE (160, 96)-STEP(319, 191), Layer(45), Temp&, (161, 160)-STEP(159, 95)
466.  Fade_In Temp&
467.  FOR i%% = 0 TO 3
468.   TimedPrint 144, 320 + 30 * i%%, Line$(1105 + i%%), 24
469.  NEXT i%%
470.  KeyPressWait
471.  ClearTextRegion
472.  TimedPrint 144, 320, Line$(1105 + i%%), 24
473.  KeyPressWait
474.  Fade_Out _DISPLAY
475.  Fade_SFX_Out SFX(4)
476. END SUB
477.  
478. SUB Elaborate_Loading
479.  _PUTIMAGE (0, 0), Layer(33), Layer(32)
480.  _PUTIMAGE (80, 300), Layer(38), Layer(32)
481.  Fade_In Layer(32)
482.  'insert Cart
483.  FOR i% = 256 TO 0 STEP -1
484.   _PUTIMAGE (0, 0), Layer(32), Temp&
485.   _PUTIMAGE (356, 16 - i%), Layer(36), Temp&
486.   _PUTIMAGE (318, 68), Layer(34), Temp&
487.   _PUTIMAGE , Temp&, _DISPLAY
488.   IF i% = 50 THEN _SNDPLAY SFX(1)
489.   _LIMIT 120
490.  NEXT i%
491.  _PUTIMAGE , _DISPLAY, Layer(32)
492.  'insert Controller
493.  FOR i% = 256 TO 0 STEP -1
494.   _PUTIMAGE (0, 0), Layer(32), Temp&
495.   _PUTIMAGE (0 - i%, 194 + i%), Layer(37), Temp&
496.   _PUTIMAGE (215, 189), Layer(35), Temp&
497.   _PUTIMAGE , Temp&, _DISPLAY
498.   _LIMIT 90
499.  NEXT i%
500.  _PUTIMAGE , _DISPLAY, Layer(32)
501.  'Press Power Button
502.  FOR i% = 128 TO 0 STEP -1
503.   _PUTIMAGE (0, 0), Layer(32), Temp&
504.   _PUTIMAGE (-184 - i%, 160 + i%), Layer(41), Temp&
505.  
506.   IF i% = 15 THEN _SNDPLAY SFX(2)
507.   _PUTIMAGE , Temp&, _DISPLAY
508.   _DELAY .008
509.  NEXT i%
510.  'Depress button
511.  _PUTIMAGE (31, 139), Layer(39), Layer(32)
512.  _PUTIMAGE (356, 139), Layer(40), Layer(32)
513.  
514.  FOR i% = 0 TO 128
515.   _PUTIMAGE (0, 0), Layer(32), Temp&
516.   _PUTIMAGE (-184 - i%, 160 + i%), Layer(41), Temp&
517.   _PUTIMAGE , Temp&, _DISPLAY
518.   _DELAY .008
519.  NEXT i%
520.  _DELAY .5
521.  Fade_Out _DISPLAY
522.  _SNDPLAY SFX(0)
523.  _PUTIMAGE , Layer(42), Temp&
524.  Fade_In Temp&
525.  DO: LOOP WHILE _SNDPLAYING(SFX(0))
526.  Fade_Out _DISPLAY
527. END SUB
528.  
529. SUB Fade_SFX_Out (Snd&)
530.  FOR i%% = 100 TO 0 STEP -1
531.   _SNDVOL Snd&, (i%% / 100)
532.   _LIMIT 100
533.  NEXT i%%
534.  _SNDSTOP Snd&
535. END SUB
536.  
537. SUB MFI_Loader (FN$)
538.  DIM Size(128) AS LONG, FOffset(128) AS LONG
539.  OPEN FN$ FOR BINARY AS #1
540.  GET #1, , c~%% 'retrieve number of files
541.  FOR I~%% = 1 TO c~%%
542.   GET #1, , FOffset(I~%%)
543.   GET #1, , Size(I~%%)
544.   FOffset&(I~%%) = FOffset&(I~%%) + 1
545.  NEXT I~%%
546.  FOR i%% = 1 TO 15
547.   Layer(32 + i%%) = LoadGFX(FOffset(i%%), Size(i%%))
548.  NEXT i%%
549.  FOR i%% = 0 TO 4
550.   SFX(i%%) = LoadSFX(FOffset(16 + i%%), Size(16 + i%%))
551.  NEXT i%%
552.  LoadData FOffset(21), Size(21)
553.  F1 = FREEFILE
554.  OPEN "temp.dat" FOR BINARY AS #F1
555.  DO
556.   LINE INPUT #F1, Line$(i%)
557.   i% = i% + 1
558.  LOOP UNTIL EOF(F1)
559.  CLOSE #F1
560.  
561.  CLOSE #1
562.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
563. END SUB
564.  
565. SUB LoadData (Foff&, Size&)
566.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
567.  OPEN "temp.dat" FOR BINARY AS #3
568.  dat$ = SPACE$(Size&)
569.  GET #1, Foff&, dat$
570.  PUT #3, , dat$
571.  CLOSE #3
572. END SUB
573.  
574. REM '$include:'MFI_Loader2.bi'
575.  
576. FUNCTION LoadGFX& (Foff&, Size&)
577.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
578.  OPEN "temp.dat" FOR BINARY AS #3
579.  dat$ = SPACE$(Size&)
580.  GET #1, Foff&, dat$
581.  PUT #3, , dat$
582.  CLOSE #3
583.  LoadGFX& = _LOADIMAGE("temp.dat", 32)
584. END FUNCTION
585.  
586. FUNCTION LoadFFX& (Foff&, Size&, Fize%%)
587.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
588.  OPEN "temp.dat" FOR BINARY AS #3
589.  dat$ = SPACE$(Size&)
590.  GET #1, Foff&, dat$
591.  PUT #3, , dat$
592.  CLOSE #3
593.  LoadFFX& = _LOADFONT("temp.dat", Fize%%, "monospace")
594. END FUNCTION
595.  
596. FUNCTION LoadSFX& (Foff&, Size&)
597.  IF _FILEEXISTS("temp.dat") THEN KILL "temp.dat"
598.  OPEN "temp.dat" FOR BINARY AS #3
599.  dat$ = SPACE$(Size&)
600.  GET #1, Foff&, dat$
601.  PUT #3, , dat$
602.  CLOSE #3
603.  LoadSFX& = _SNDOPEN("temp.dat")
604. END FUNCTION
605.  

[johnno56]

I am not a fan of this type of game nor have I played this game before.... But this is very well made. I do not know how it compares with the original, but what you have done so far, is quite impressive... Well done!

[SMcNeill]

Might want to drop a limit in the keypress wait routine to keep cpu usage low:


SUB KeyPressWait
 _KEYCLEAR
 DO
    _LIMIT 30
 LOOP UNTIL INKEY$ <> ""
END SUB

[FellippeHeitor]

Finally got around to running this, @Cobalt. Great job recreating the intro!

[Ashish]

Its amazing... The first animation looks like 3D.. I like it.. Its look very professional