Antialiasing using Gauss or Average filters

[RhoSigma]

This is a mini-version of my BinClock screen blanker. I made it to replace the old windows sidebar.exe based Clock, which is not available on Win10 anymore.

However, I mainly post it here to showcase how to achive antialiasing in QB64 programs by using Gauss or Average blurring filters.

Note you also need my Libraries Collection for this (see signature) and if you're not on Windows, then you may have to change the LOCALAPPDATA environment folder, which is used to save the current clock window position.

You may change the month abbreviations in lines 77-79 and assemble the date format (d$) in line 144 for your country if you want to.

Feel free to play with different filters in line 166 (see QB64Library\IMG-Support\docs\imageprocess.bm\ApplyFilter.html for available filters), the magnifying glass may help you to inspect the effects in detail.

Code: QB64: [Select]

1. '+---------------+---------------------------------------------------+
2. '| ###### ###### |     .--. .         .-.                            |
3. '| ##  ## ##   # |     |   )|        (   ) o                         |
4. '| ##  ##  ##    |     |--' |--. .-.  `-.  .  .-...--.--. .-.        |
5. '| ######   ##   |     |  \ |  |(   )(   ) | (   ||  |  |(   )       |
6. '| ##      ##    |     '   `'  `-`-'  `-'-' `-`-`|'  '  `-`-'`-      |
7. '| ##     ##   # |                            ._.'                   |
8. '| ##     ###### |  Sources & Documents placed in the Public Domain. |
9. '+---------------+---------------------------------------------------+
10. '|                                                                   |
11. '| === NewClock.bas ===                                              |
12. '|                                                                   |
13. '| == A simple binary (BCD) clock inspired by the alien countdown    |
14. '| == from the movie "Mission to Mars".                              |
15. '| == For easy reading it also have digital and analog displays.     |
16. '|                                                                   |
17. '+-------------------------------------------------------------------+
18. '| Done by RhoSigma, R.Heyder, provided AS IS, use at your own risk. |
19. '| Find me in the QB64 Forum or mail to support&rhosigma-cw.net for  |
20. '| any questions or suggestions. Thanx for your interest in my work. |
21. '+-------------------------------------------------------------------+
22.  
23. 'get my local appdata folder
24. lad$ = ENVIRON$("LOCALAPPDATA")
25. IF lad$ <> "" THEN
26.     IF RIGHT$(lad$, 1) <> "\" THEN lad$ = lad$ + "\"
27. END IF
28. IF NOT _DIREXISTS(lad$ + "RhoSigma") THEN MKDIR lad$ + "RhoSigma"
29. lad$ = lad$ + "RhoSigma\"
30.  
31. 'get old window position
32. cfg$ = lad$ + "NewClock.bin"
33. IF _FILEEXISTS(cfg$) THEN
34.     OPEN "B", #1, cfg$
35.     GET #1, , lft%
36.     GET #1, , top%
37.     CLOSE #1
38. ELSE
39.     lft% = -1: top% = -1
40. END IF
41.  
42. 'setup screen
43. DIM SHARED scr&, tru&, col&
44. scr& = _NEWIMAGE(300, 180, 32)
45. SCREEN scr&
46. tru& = _NEWIMAGE(300, 180, 32)
47. col& = _NEWIMAGE(300, 180, 256)
48. _SOURCE col&: _DEST col&
49. _DELAY 0.2
50. IF lft% < 0 OR top% < 0 THEN
51.     _SCREENMOVE _MIDDLE
52. ELSE
53.     _SCREENMOVE lft%, top%
54. END IF
55. scrFont& = _LOADFONT("C:\Windows\Fonts\timesbd.ttf", 30)
56. _FONT scrFont&
57.  
58. '3D space origin is on these screen coordinates
59. DIM SHARED cx%: cx% = 8
60. DIM SHARED cy%: cy% = 110
61.  
62. 'init BCD discs
63. TYPE Disc
64.     x AS INTEGER
65.     y AS INTEGER
66.     z AS INTEGER
67.     r AS INTEGER
68.     a AS INTEGER
69. END TYPE
70. DIM SHARED Discs(23) AS Disc
71. InitDiscs
72. DIM SHARED curState&: curState& = 0
73. DIM SHARED newState&: newState& = 0
74.  
75. 'init month names
76. DIM SHARED month$(12)
77. month$(1) = "Jan": month$(2) = "Feb": month$(3) = "Mar": month$(4) = "Apr"
78. month$(5) = "May": month$(6) = "Jun": month$(7) = "Jul": month$(8) = "Aug"
79. month$(9) = "Sep": month$(10) = "Oct": month$(11) = "Nov": month$(12) = "Dec"
80.  
81. 'draw hour/minute/seconds separators
82. Line3D 52, 0, 0, 52, 210, 0, 2
83. Line3D 52, 0, 0, 52, 0, -30, 2
84. Line3D 128, 0, 0, 128, 210, 0, 2
85. Line3D 128, 0, 0, 128, 0, -30, 2
86.  
87. 'mark binary factors
88. COLOR 6
89. _PRINTSTRING (8, 5), "8": Line3D -20, 180, 0, -70, 180, 0, 6
90. _PRINTSTRING (8, 30), "4": Line3D -20, 130, 0, -45, 130, 0, 6
91. _PRINTSTRING (280, 55), "2": Line3D 200, 80, 0, 225, 80, 0, 6
92. _PRINTSTRING (280, 80), "1": Line3D 200, 30, 0, 250, 30, 0, 6
93.  
94. 'main loop
95. _SCREENSHOW
96. _TITLE "Uhrzeit/Datum"
97. _DISPLAY
98. DO
99.     _LIMIT 1
100.     FlipDiscs
101.     IF _SCREENX <> -32000 AND _SCREENY <> -32000 THEN 'minimized?
102.         IF _SCREENX <> lft% OR _SCREENY <> top% THEN 'position changed?
103.             lft% = _SCREENX: top% = _SCREENY
104.             OPEN "B", #1, cfg$
105.             PUT #1, , lft%
106.             PUT #1, , top%
107.             CLOSE #1
108.         END IF
109.     END IF
110. LOOP UNTIL _EXIT
111. _AUTODISPLAY
112.  
113. 'cleanup
114. _FONT 16
115. _FREEFONT scrFont&
116. SYSTEM
117.  
118. 'run the clock
119. SUB FlipDiscs
120. t$ = TIME$
121. newState& = (VAL(MID$(t$, 1, 1)) * (2 ^ 20)) + (VAL(MID$(t$, 2, 1)) * (2 ^ 16)) +_
122.             (VAL(MID$(t$, 4, 1)) * (2 ^ 12)) + (VAL(MID$(t$, 5, 1)) * (2 ^ 8)) +_
123.             (VAL(MID$(t$, 7, 1)) * (2 ^ 4)) + (VAL(MID$(t$, 8, 1)) * (2 ^ 0))
124. diff& = curState& XOR newState&
125. curState& = newState&
126. FOR rot% = 6 TO 90 STEP 6
127.     FOR n% = 0 TO 23
128.         IF (n% MOD 4) = 0 THEN AxisSegments Discs(n%).x
129.         IF diff& AND (2 ^ n%) THEN
130.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a, 0
131.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a + 6, 15
132.             Discs(n%).a = Discs(n%).a + 6
133.             IF Discs(n%).a = 180 THEN Discs(n%).a = 0
134.         ELSE
135.             Circle3D Discs(n%).x, Discs(n%).y, Discs(n%).z, Discs(n%).r, Discs(n%).a, 15
136.         END IF
137.     NEXT n%
138.     IF rot% = 54 THEN
139.         'digital clock
140.         COLOR 9
141.         _PRINTSTRING (14, 117), MID$(t$, 1, 2)
142.         _PRINTSTRING (84, 117), MID$(t$, 4, 2)
143.         _PRINTSTRING (157, 117), MID$(t$, 7, 2)
144.         d$ = MID$(DATE$, 4, 2) + ". " + month$(VAL(LEFT$(DATE$, 2))) + " " + RIGHT$(DATE$, 4)
145.         _PRINTSTRING (98 - (_PRINTWIDTH(d$) / 2), 145), d$
146.         'analog clock
147.         LINE (242 - 34, 142 - 34)-(242 + 34, 142 + 34), 0, BF
148.         CIRCLE (242, 142), 34, 14
149.         CIRCLE (242, 142), 32, 6: t# = TIMER
150.         x% = PolToCartX%((360 / 43200 * t#) - 90, 22)
151.         y% = PolToCartY%((360 / 43200 * t#) - 90, 22)
152.         LINE (242, 142)-(x% + 242, y% + 142), 14
153.         x% = PolToCartX%((360 / 3600 * t#) - 90, 26)
154.         y% = PolToCartY%((360 / 3600 * t#) - 90, 26)
155.         LINE (242, 142)-(x% + 242, y% + 142), 10
156.         x% = PolToCartX%((360 / 60 * t#) - 90, 28)
157.         y% = PolToCartY%((360 / 60 * t#) - 90, 28)
158.         LINE (242, 142)-(x% + 242, y% + 142), 12
159.         x% = PolToCartX%((360 / 60 * t#) + 90, 7)
160.         y% = PolToCartY%((360 / 60 * t#) + 90, 7)
161.         LINE (242, 142)-(x% + 242, y% + 142), 12
162.         CIRCLE (242, 142), 1, 12
163.         CIRCLE (242, 142), 2, 12
164.     END IF
165.     _PUTIMAGE , col&, tru&
166.     gau& = ApplyFilter&(tru&, "Gauss8", 0, 0, -1, -1, -1, -1, -1)
167.     _PUTIMAGE , gau&, scr&
168.     _FREEIMAGE gau&
169.     _DISPLAY
170. NEXT rot%
171. END SUB
172.  
173. 'setup start values for all discs
174. SUB InitDiscs
175. n% = 0
176. FOR i% = 180 TO 150 STEP -30
177.     FOR j% = 30 TO 180 STEP 50
178.         Discs(n%).x = i%
179.         Discs(n%).y = j%
180.         Discs(n%).z = 0
181.         Discs(n%).r = 10
182.         Discs(n%).a = 0
183.         n% = n% + 1
184.     NEXT j%
185. NEXT i%
186. FOR i% = 105 TO 75 STEP -30
187.     FOR j% = 30 TO 180 STEP 50
188.         Discs(n%).x = i%
189.         Discs(n%).y = j%
190.         Discs(n%).z = 0
191.         Discs(n%).r = 10
192.         Discs(n%).a = 0
193.         n% = n% + 1
194.     NEXT j%
195. NEXT i%
196. FOR i% = 30 TO 0 STEP -30
197.     FOR j% = 30 TO 180 STEP 50
198.         Discs(n%).x = i%
199.         Discs(n%).y = j%
200.         Discs(n%).z = 0
201.         Discs(n%).r = 10
202.         Discs(n%).a = 0
203.         n% = n% + 1
204.     NEXT j%
205. NEXT i%
206. END SUB
207.  
208. 'draw rotation axis segments between discs
209. SUB AxisSegments (x%)
210. Line3D x%, 0, 0, x%, 20, 0, 12
211. Line3D x%, 40, 0, x%, 70, 0, 12
212. Line3D x%, 90, 0, x%, 120, 0, 12
213. Line3D x%, 140, 0, x%, 170, 0, 12
214. Line3D x%, 190, 0, x%, 210, 0, 12
215. END SUB
216.  
217. SUB Line3D (x1%, y1%, z1%, x2%, y2%, z2%, col%)
218. 'x1%/y1%/z1% = start, x2%/y2%/z2% = end, col% = color pen
219. x1# = (x1% + (y1% * 0.5)): z1# = (z1% + (y1% * 0.5))
220. x2# = (x2% + (y2% * 0.5)): z2# = (z2% + (y2% * 0.5))
221. LINE (x1# + cx%, -z1# + cy%)-(x2# + cx%, -z2# + cy%), col%
222. END SUB
223.  
224. SUB Circle3D (x%, y%, z%, r%, ba%, col%)
225. 'x%/y%/z% = center, r% = radius, ba% = B-Axis angle, col% = color pen
226. mx# = (x% + (y% * 0.5)): mz# = (z% + (y% * 0.5))
227. zx# = r% * COS(ba% * 0.017453292519943)
228. zz# = r% * SIN(ba% * 0.017453292519943)
229. FOR cir% = 0 TO 359 STEP 5
230.     x# = zx# * COS(cir% * 0.017453292519943)
231.     y# = r% * SIN(cir% * 0.017453292519943)
232.     z# = zz# * COS(cir% * 0.017453292519943)
233.     x# = (x# + (y# * 0.5)): z# = (z# + (y# * 0.5))
234.     PSET (x# + mx# + cx%, -z# + -mz# + cy%), col%
235. NEXT cir%
236. END SUB
237.  
238. '$INCLUDE: 'QB64Library\IMG-Support\converthelper.bm'
239. '$INCLUDE: 'QB64Library\IMG-Support\imageprocess.bm'
240.  
241.