A .exe file pops up in the qb64 directory when running a code

[STxAxTIC]

I understand what you are asking for, but as Fellippe pointed out, this is not like QB45. When you ask to QB64 to run the code, it *must* generate the exe. The code does not run somewhere "within" the qb64 environment. It's for this reason that certain things aren't included in the modern IDE - such as the F8 key for stepping. That kind of thing is completely undefined here.

tldr: the exe is always created, it's a law

[mrhuman]

@STxAxTIC
Yeah auto deleting is bad.
I thing I lost a video because of windows 10's storage sense thing.

Reply to latest comment
So QB64 is sorta like visual studio? And what I am asking is like I am asking it to not make an exe to test the software

[STxAxTIC]

Define "test the software". If any part of that statement means "run" the code, you need the entire exe. Basically how you see it work now is the only way it can work. QB64 is not "like" any other product, really.

[mrhuman]

Ok then
Thanks!
To @STxAxTIC
I am marking your reply as the answer
Signing out

[SMcNeill]

Write a little program to check your folders for you, run QB64, and then do clean up, if necessary...

Like this one:

Code: QB64: [Select]

1. _TITLE "QB64 Auto-cleanup"
2. $SCREENHIDE
3. DECLARE CUSTOMTYPE LIBRARY ".\direntry"
4.     FUNCTION load_dir& (s AS STRING)
5.     FUNCTION has_next_entry& ()
6.     SUB close_dir ()
7.     SUB get_next_entry (s AS STRING, flags AS LONG, file_size AS LONG)
8. END DECLARE
9.  
10. REDIM Dir(0) AS STRING, File(0) AS STRING
11. REDIM Dir2(0) AS STRING, File2(0) AS STRING
12.  
13. GetFileList _CWD$, Dir(), File()
14.  
15. SHELL "QB64.EXE"
16. _SCREENSHOW
17.  
18. GetFileList _CWD$, Dir2(), File2()
19.  
20. FOR i = 1 TO UBOUND(dir2)
21.     flag = 0 'not found
22.     FOR j = 1 TO UBOUND(dir)
23.         IF Dir2(i) = Dir(j) THEN flag = -1: EXIT FOR
24.     NEXT
25.     IF flag = 0 THEN PRINT Dir2(i); " is a new directory."
26. NEXT
27. FOR i = 1 TO UBOUND(File2)
28.     flag = 0 'not found
29.     FOR j = 1 TO UBOUND(File)
30.         IF File2(i) = File(j) THEN flag = -1: EXIT FOR
31.     NEXT
32.     IF flag = 0 THEN PRINT File2(i); " is a new file."
33. NEXT
34.  
35. SUB GetFileList (SearchDirectory AS STRING, DirList() AS STRING, FileList() AS STRING)
36.     CONST IS_DIR = 1
37.     CONST IS_FILE = 2
38.     DIM flags AS LONG, file_size AS LONG
39.  
40.     REDIM _PRESERVE DirList(100), FileList(100)
41.     DirCount = 0: FileCount = 0
42.  
43.     IF load_dir(SearchDirectory) THEN
44.         DO
45.             length = has_next_entry
46.             IF length > -1 THEN
47.                 nam$ = SPACE$(length)
48.                 get_next_entry nam$, flags, file_size
49.                 IF flags AND IS_DIR THEN
50.                     DirCount = DirCount + 1
51.                     IF DirCount > UBOUND(DirList) THEN REDIM _PRESERVE DirList(UBOUND(DirList) + 100)
52.                     DirList(DirCount) = nam$
53.                 ELSEIF flags AND IS_FILE THEN
54.                     FileCount = FileCount + 1
55.                     IF FileCount > UBOUND(filelist) THEN REDIM _PRESERVE FileList(UBOUND(filelist) + 100)
56.                     FileList(FileCount) = nam$
57.                 END IF
58.             END IF
59.         LOOP UNTIL length = -1
60.         close_dir
61.     ELSE
62.     END IF
63.     REDIM _PRESERVE DirList(DirCount)
64.     REDIM _PRESERVE FileList(FileCount)
65. END SUB
66.  

Run it, it stores a list of all files and directories in the folder where QB64 is.
The it starts up QB64.
When QB64 ends, it unhides itself and then prints you a list of all the new folders or directories that have appeared in the QB64 folder.

Now, I'm not doing anything with those files or folders, as I don't believe in messing with other folks drives, but all you'd have to do is now KILL them out of existence, if you so desired...

[luke]

It is not practical to have QB64 delete the executable made when you press F5, because the IDE doesn't know when the program has finished executing.