Simple Joystick Detection and Interaction

[SMcNeill]

A small little demo to help highlight how one would work with the joystick in QB64:

Code: QB64: [Select]

1. D = _DEVICES 'Find the number of devices on someone's system
2. '1 is the keyboard
3. '2 is the mouse
4. '3 is the joystick
5. 'unless someone has a strange setup with multiple mice/keyboards/ect...
6. 'In that case, you can use _DEVICE$(i) to look for "KEYBOARD", "MOUSE", "JOYSTICK", if necessary.
7. 'I've never actually found it necessary, but I figure it's worth mentioning, just in case...
8.  
9.  
10. DIM Button(_LASTBUTTON(3)) ' number of buttons on the joystick
11. DIM Axis(_LASTAXIS(3)) 'number of axis on the joystick
12.  
13. DO
14.  
15.  
16.     DO
17.  
18.         'This following little segment of code gets the joystick status for us
19.         'The reason this is inside a DO...LOOP structure as I've created it,
20.         'is so that my joystick's axis won't generate any form of lag for
21.         'my program as I scroll them around to generate positive/negative values.
22.  
23.         IF _DEVICEINPUT = 3 THEN 'this says we only care about joystick input values
24.             FOR i = 1 TO _LASTBUTTON(3) 'this is a loop to check all the buttons
25.                 IF _BUTTONCHANGE(i) THEN Button(i) = NOT Button(i) 'and this changes my button array to indicate if a button is up or down currently.
26.             NEXT
27.             FOR i = 1 TO _LASTAXIS(3) 'this loop checks all my axis
28.                 'I like to give a little "jiggle" resistance to my controls, as I have an old joystick
29.                 'which is prone to always give minute values and never really center on true 0.
30.                 'A value of 1 means my axis is pushed fully in one direction.
31.                 'A value greater than 0.1 means it's been partially pushed in a direction (such as at a 45 degree diagional angle).
32.                 'A value of less than 0.1 means we count it as being centered. (As if it was 0.)
33.                 IF ABS(_AXIS(i)) <= 1 AND ABS(_AXIS(i)) >= .1 THEN Axis(i) = _AXIS(i) ELSE Axis(i) = 0
34.             NEXT
35.         ELSE EXIT DO
36.         END IF
37.     LOOP
38.  
39.     'And below here is just the simple display routine which displays our values.
40.     'If this was for a game, I'd choose something like Axis(1) = -1 for a left arrow style input,
41.     'Axis(1) = 1 for a right arrow style input, rather than just using _KEYHIT or INKEY$.
42.  
43.  
44.     CLS
45.     FOR i = 1 TO _LASTBUTTON(3) 'A loop for each button
46.         PRINT "BUTTON "; i; ": "; Button(i) 'display their status to the screen
47.     NEXT
48.     FOR i = 1 TO _LASTAXIS(3) 'A loop for each axis
49.         PRINT "Axis "; i; ": "; Axis(i) 'display their status to the screen
50.     NEXT
51.  
52.     _LIMIT 30
53. LOOP UNTIL _KEYHIT = 27 'ESCAPE to quit
54.  
55. SYSTEM 'And that's all it is to it!

[Pete]

Yes, that's what I was getting at in Terry's asteroids thread. I would think every gamer here would want to add something like this. I mean imagine if Atari came out with a keyboard plugin with just the wasdx and the Enter key on it. Who the hell would pay extra for that control option?

Pete

[johnno56]

Plugged in my old USB Logitech Extreme3D Pro joystick, after blowing off all the dust... lol, and your programme  detected all 12 buttons and 6 axis correctly... I wonder which QB64 game could make use of my old joystick? Any guesses? (I don't want to put it back in storage... unless...)

J

[madscijr]

I just gave this code a try and it worked!

Update: I figured out what was happening in my code, basically it was setting the axis and button count when the user pressed a button or moved a stick, so until that happened it had nothing to report.

Below is my updated test program to read upto 4 joysticks with 2 buttons and 3 axes each (you can increase or change by modifying the constants). Hope this helps someone.

One question though. 

In your code you check for device 3:

Code: QB64: [Select]

1.                 IF _DEVICEINPUT = 3 THEN ' this says we only care about joystick input values
2.             FOR i = 1 TO _LASTBUTTON(3) ' this is a loop to check all the buttons
3.  

and I modified it to read upto 8 devices (code below), but it seems my code isn't detecting the devices until a button is pressed or the stick is moved.

Can anyone explain would you would count how many controllers are connected without the player having to move or press a button?

Code: QB64: [Select]

1. ' ################################################################################################################################################################
2. ' Multi gamepad test
3.  
4. ' BASED ON CODE BY SMcNeill FROM:
5. ' Simple Joystick Detection and Interaction  (Read 316 times)
6. ' https://www.qb64.org/forum/index.php?topic=2160.msg129051#msg129051
7. ' ################################################################################################################################################################
8.  
9. ' =============================================================================
10. ' GLOBAL DECLARATIONS a$=string, i%=integer, L&=long, s!=single, d#=double
11.  
12. ' boolean constants
13. CONST FALSE = 0
14. CONST TRUE = NOT FALSE
15.  
16. ' =============================================================================
17. ' UDTs
18.  
19. ' UDT TO HOLD THE INFO FOR A PLAYER
20. TYPE PlayerType
21.     x AS INTEGER ' player x position
22.     y AS INTEGER ' player y position
23.         c AS INTEGER ' character to display on screen
24.         xOld AS INTEGER
25.         yOld AS INTEGER
26.         buttonCount AS INTEGER
27.         axisCount AS INTEGER
28. END TYPE ' PlayerType
29.  
30. ' =============================================================================
31. ' GLOBAL VARIABLES
32. DIM ProgramPath$
33. DIM ProgramName$
34.  
35. ' =============================================================================
36. ' INITIALIZE
37. ProgramName$ = MID$(COMMAND$(0), _INSTRREV(COMMAND$(0), "\") + 1)
38. ProgramPath$ = LEFT$(COMMAND$(0), _INSTRREV(COMMAND$(0), "\"))
39.  
40. 'DIM a$ ' string
41. 'DIM i% ' integer
42. 'DIM L& ' long integer
43. 'DIM s! ' single precision
44. 'DIM d# ' double precision
45. 'DIM bValue% ' boolean is an integer
46.  
47. ' =============================================================================
48. ' TRY THE MOUSE
49. main ProgramName$
50.  
51. ' =============================================================================
52. ' FINISH
53. SYSTEM ' return control to the operating system
54. PRINT ProgramName$ + " finished."
55. END
56.  
57. ' /////////////////////////////////////////////////////////////////////////////
58.  
59. SUB main (ProgName$)
60.         DIM RoutineName AS STRING :: RoutineName = "main"
61.         DIM in$
62.         DIM iDeviceCount AS INTEGER
63.        
64.         iDeviceCount = _DEVICES ' Find the number of devices on someone's system
65.        
66.         ' 1 is the keyboard
67.         ' 2 is the mouse
68.         ' 3 is the joystick
69.         ' unless someone has a strange setup with multiple mice/keyboards/ect...
70.         ' In that case, you can use _DEVICE$(i) to look for "KEYBOARD", "MOUSE", "JOYSTICK", if necessary.
71.         ' I've never actually found it necessary, but I figure it's worth mentioning, just in case...
72.        
73.         if iDeviceCount > 2 then
74.                 TestJoysticks
75.         else
76.                 PRINT "No joysticks found."
77.         end if
78.        
79.         INPUT "PRESS <ENTER> TO CONTINUE", in$
80. END SUB ' main
81.  
82. ' /////////////////////////////////////////////////////////////////////////////
83.  
84. SUB TestJoysticks()
85.         DIM RoutineName AS STRING :: RoutineName = "TestJoysticks"
86.        
87.         CONST cMaxPlayers = 8
88.         CONST cMaxButtons = 2
89.         CONST cMaxAxis = 2
90.        
91.         DIM in$
92.         DIM iDeviceCount AS INTEGER
93.         DIM iDevice AS INTEGER
94.        
95.         ' WE'RE PREPARED TO SUPPORT UPTO 8 JOYSTICKS, WITH UPTO 2 BUTTONS AND 2 AXES EACH
96.         ' (THIS IS FOR ATARI 2600 JOYSTICKS)
97.         DIM arrButton(8, 2) ' number of buttons on the joystick
98.         DIM arrAxis(8, 3) ' number of axis on the joystick
99.         'DIM Button(_LASTBUTTON(3) ) ' number of buttons on the joystick
100.         'DIM Axis(_LASTAXIS(3) ) ' number of axis on the joystick
101.        
102.         DIM arrPlayer(8) AS PlayerType ' holds info for each player
103.         DIM iNumPlayers AS INTEGER
104.         DIM iPlayerLoop AS INTEGER
105.         DIM iNextY AS INTEGER
106.         DIM iNextX AS INTEGER
107.         DIM iNextC AS INTEGER
108.         DIM iLoop AS INTEGER
109.        
110.         ' COUNT # OF JOYSTICKS
111.         iDeviceCount = _DEVICES ' Find the number of devices on someone's system
112.         IF iDeviceCount < 3 THEN
113.                 CLS
114.                 PRINT "NO JOYSTICKS FOUND, EXITING..."
115.                 INPUT "PRESS <ENTER>", in$
116.                 EXIT SUB
117.         END IF
118.        
119.         ' BASE # OF PLAYERS ON HOW MANY CONTROLLERS FOUND
120.         iNumPlayers = iDeviceCount - 2 ' TODO: find out the right way to count joysticks
121.         IF iNumPlayers > cMaxPlayers THEN
122.                 iNumPlayers = cMaxPlayers
123.         END IF
124.        
125.         ' INITIALIZE PLAYER COORDINATES AND SCREEN CHARACTERS
126.         iNextY = 1
127.         iNextX = -3
128.         iNextC = 64
129.         FOR iPlayerLoop = 1 to iNumPlayers
130.                 iNextX = iNextX + 4
131.                 IF iNextX > 80 THEN
132.                         iNextX = 1
133.                         iNextY = iNextY + 4
134.                 END IF
135.                 iNextC = iNextC + 1
136.                 arrPlayer(iPlayerLoop).x = iNextX
137.                 arrPlayer(iPlayerLoop).y = iNextY
138.                 arrPlayer(iPlayerLoop).c = iNextC
139.                 arrPlayer(iPlayerLoop).xOld = iNextX
140.                 arrPlayer(iPlayerLoop).yOld = iNextY
141.                 arrPlayer(iPlayerLoop).buttonCount = cMaxButtons
142.                 arrPlayer(iPlayerLoop).axisCount = cMaxAxis
143.         NEXT iPlayerLoop
144.        
145.         ' CLEAR THE SCREEN
146.         DO
147.                 FOR iPlayerLoop = 1 to iNumPlayers
148.                         iDevice = iPlayerLoop + 2
149.                        
150.                         WHILE _DEVICEINPUT(iDevice) ' clear and update the device buffer
151.                                 'IF _DEVICEINPUT = 3 THEN ' this says we only care about joystick input values
152.                                
153.                                 ' check all the buttons
154.                                 FOR iLoop = 1 TO _LASTBUTTON(iDevice)
155.                                         IF (iLoop > cMaxButtons) THEN
156.                                                 EXIT FOR
157.                                         END IF
158.                                         arrPlayer(iPlayerLoop).buttonCount = iLoop
159.                                        
160.                                         ' update button array to indicate if a button is up or down currently.
161.                                         IF _BUTTONCHANGE(iLoop) THEN
162.                                                 ' _BUTTON(number) returns -1 when a button is pressed and 0 when released.
163.                                                 'arrButton(iLoop) = NOT arrButton(iLoop)
164.                                                 arrButton(iPlayerLoop, iLoop) = _BUTTON(iLoop)
165.                                         END IF
166.                                 NEXT iLoop
167.                                
168.                                 FOR iLoop = 1 TO _LASTAXIS(iDevice) ' this loop checks all my axis
169.                                         IF (iLoop > cMaxAxis) THEN
170.                                                 EXIT FOR
171.                                         END IF
172.                                         arrPlayer(iPlayerLoop).axisCount = iLoop
173.                                        
174.                                         ' I like to give a little "jiggle" resistance to my controls, as I have an old joystick
175.                                         ' which is prone to always give minute values and never really center on true 0.
176.                                         ' A value of 1 means my axis is pushed fully in one direction.
177.                                         ' A value greater than 0.1 means it's been partially pushed in a direction (such as at a 45 degree diagional angle).
178.                                         ' A value of less than 0.1 means we count it as being centered. (As if it was 0.)
179.                                         IF ABS(_AXIS(iLoop)) <= 1 AND ABS(_AXIS(iLoop)) >= .1 THEN
180.                                                 arrAxis(iPlayerLoop, iLoop) = _AXIS(iLoop)
181.                                         ELSE
182.                                                 arrAxis(iPlayerLoop, iLoop) = 0
183.                                         END IF
184.                                 NEXT iLoop
185.                         WEND ' clear and update the device buffer
186.                        
187.                 NEXT iPlayerLoop
188.                
189.                 ' And below here is just the simple display routine which displays our values.
190.                 ' If this was for a game, I'd choose something like arrAxis(1) = -1 for a left arrow style input,
191.                 ' arrAxis(1) = 1 for a right arrow style input, rather than just using _KEYHIT or INKEY$.
192.                 CLS
193.                 FOR iPlayerLoop = 1 to iNumPlayers
194.                         FOR iLoop = 1 TO arrPlayer(iPlayerLoop).axisCount ' A loop for each axis
195.                                 ' display their status to the screen
196.                                 PRINT "Player " + cstr$(iPlayerLoop) + ",   Axis " + cstr$(iLoop) + " = " + cstr$(arrAxis(iPlayerLoop, iLoop) )
197.                         NEXT iLoop
198.                         FOR iLoop = 1 TO arrPlayer(iPlayerLoop).buttonCount ' A loop for each button
199.                                 ' display their status to the screen
200.                                 PRINT "Player " + cstr$(iPlayerLoop) + ", Button " + cstr$(iLoop) + " = " + cstr$(arrButton(iPlayerLoop, iLoop) )
201.                         NEXT iLoop
202.                 NEXT iPlayerLoop
203.                 PRINT "PRESS <ESC> TO EXIT"
204.                
205.                 _LIMIT 30
206.         LOOP UNTIL _KEYHIT = 27 ' ESCAPE to quit
207. END SUB ' TestJoysticks
208.  
209. ' ################################################################################################################################################################
210. ' BEGIN GENERAL ROUTINES
211. ' ################################################################################################################################################################
212.  
213. ' /////////////////////////////////////////////////////////////////////////////
214.  
215. FUNCTION cstr$ (myValue)
216.     'cstr$ = LTRIM$(RTRIM$(STR$(myValue)))
217.     cstr$ = _TRIM$(STR$(myValue))
218. END FUNCTION ' cstr$
219.  
220. FUNCTION cstrl$ (myValue AS LONG)
221.     cstrl$ = _TRIM$(STR$(myValue))
222. END FUNCTION ' cstrl$
223.  
224. ' ################################################################################################################################################################
225. ' END GENERAL ROUTINES
226. ' ################################################################################################################################################################
227.  

[SMcNeill]

I just gave this code a try and it worked!
One question though - I have 4 gamepads plugged into the system.
The code is checking for device 3:

Code: QB64: [Select]

1.                 IF _DEVICEINPUT = 3 THEN ' this says we only care about joystick input values
2.             FOR i = 1 TO _LASTBUTTON(3) ' this is a loop to check all the buttons
3.  

How would you count how many gamepads are detected, and read them all?

The first line tells you the number of devices plugged in.  (D = _DEVICES)

 
D= _DEVICES  'MUST be read in order for other 2 device functions to work!
PRINT "Number of input devices found ="; devices
FOR i = 1 TO D
  PRINT _DEVICE$(i)
  PRINT "Buttons:"; _LASTBUTTON(i); "Axis:"; _LASTAXIS(i); "Wheels:"; _LASTWHEEL(i)
NEXT

[madscijr]

Thanks for your reply. I updated my question but I see you replied before I clicked Save.

If you see my original question, it now has my multi joystick version of the test code.

There is one problem, which is it doesn't seem to detect a given controller until that joystick is moved or its button is pressed.

So my followup question is, is there a way to detect and count the controllers that are plugged in, without each player having to first move their joystick or press a button? It's not a deal breaker, but it would be nice to know how to do that if it is possible.

Thanks again!

[SMcNeill]

Thanks for your reply. I updated my question but I see you replied before I clicked Save.

If you see my original question, it now has my multi joystick version of the test code.

There is one problem, which is it doesn't seem to detect a given controller until that joystick is moved or its button is pressed.

So my followup question is, is there a way to detect and count the controllers that are plugged in, without each player having to first move their joystick or press a button? It's not a deal breaker, but it would be nice to know how to do that if it is possible.

Thanks again!

I've never had any problems detecting the joysticks before movement.  If there's four on your system, here's a quick question:  Do any of them have a SLEEP mode which they might be entering?  My system has an usb hub which sleeps with inactivity, so anything I plug into it takes a couple of seconds to "wake up" and become responsive.  I've also got a wireless bluetooth joystick which does the same thing -- it puts itself into sleep mode to save energy, and takes a couple of seconds to wake up when I first start using it.

If either of those things are going on, it could explain the lag in detection and interaction that you're encountering.

[madscijr]

I've never had any problems detecting the joysticks before movement.  If there's four on your system, here's a quick question:  Do any of them have a SLEEP mode which they might be entering?  My system has an usb hub which sleeps with inactivity, so anything I plug into it takes a couple of seconds to "wake up" and become responsive.  I've also got a wireless bluetooth joystick which does the same thing -- it puts itself into sleep mode to save energy, and takes a couple of seconds to wake up when I first start using it.

If either of those things are going on, it could explain the lag in detection and interaction that you're encountering.

Hmm, I don't know if it has a sleep mode, and even if it does, I think the hub and/or joystick adapter isn't going to be in sleep mode, because even when I move all 4 joysticks and immediately restart the joystick test code, the behavior is the same.

FYI here is the device:
Retro USB Adapter for Atari Joysticks and Paddles - 4 Port/Players
https://www.amazon.com/Retro-Adapter-Atari-Joysticks-Paddles/dp/B08LCTP9TQ

It must be some quirk in the logic of my test program. If you have 2 gamepads and could run my code and see if you get the same behavior, that might help.

It is definitely detecting the _presence_ of one or more controller from the very start, because if it's not plugged into the USB hub, it would output

"No joysticks found.
PRESS <ENTER> TO CONTINUE

and exit. It does that if I unplug the joystick adapter from the USB hub.

But with the controllers plugged in, it isn't doing that, the output is

PRESS <ESC> TO EXIT


and it waits for input. So it is seeing controllers.

The problem is, the program isn't showing data for a given controller until I move that particular joystick or press its button. If I move joystick 2, I'll see:


Player 2,   Axis 1 = 0
Player 2,   Axis 2 = 0
Player 2, Button 1 = 0
Player 2, Button 2 = 0
PRESS <ESC> TO EXIT


Then if I move joystick 1, I'll see:

Player 1,   Axis 1 = 0
Player 1,   Axis 2 = 0
Player 1, Button 1 = 0
Player 1, Button 2 = 0
Player 2,   Axis 1 = 0
Player 2,   Axis 2 = 0
Player 2, Button 1 = 0
Player 2, Button 2 = 0
PRESS <ESC> TO EXIT


Then if I move joystick 4, the output is:
Then if I move joystick 1, I'll see:

Player 1,   Axis 1 = 0
Player 1,   Axis 2 = 0
Player 1, Button 1 = 0
Player 1, Button 2 = 0
Player 2,   Axis 1 = 0
Player 2,   Axis 2 = 0
Player 2, Button 1 = 0
Player 2, Button 2 = 0
Player 4,   Axis 1 = 0
Player 4,   Axis 2 = 0
Player 4, Button 1 = 0
Player 4, Button 2 = 0
PRESS <ESC> TO EXIT


Finally, after moving joystick 3 we see the full output:

Player 1,   Axis 1 = 0
Player 1,   Axis 2 = 0
Player 1, Button 1 = 0
Player 1, Button 2 = 0
Player 2,   Axis 1 = 0
Player 2,   Axis 2 = 0
Player 2, Button 1 = 0
Player 2, Button 2 = 0
Player 3,   Axis 1 = 0
Player 3,   Axis 2 = 0
Player 3, Button 1 = 0
Player 3, Button 2 = 0
Player 4,   Axis 1 = 0
Player 4,   Axis 2 = 0
Player 4, Button 1 = 0
Player 4, Button 2 = 0
PRESS <ESC> TO EXIT


BTW, it is detecting and displaying the input correctly.
For example, if I press the fire button on joystick #2, the output for that changes from:

Player 2, Button 1 = 0

to

Player 2, Button 1 = -1


So I'm just not sure why it doesn't show all 4 controllers from the start. Why do I have to move a stick or press its button before the program displays its values?

Am I not "initializing" reading the joysticks correctly? Or is there is just some silly bug in my logic?

Thanks again...

[Pete]

I don't have usb joysticks or gamepad controls, so I can't look into this, but I do have a question about usage.

Will it also work as: WHILE _DEVICEINPUT(iDevice): WEND....you know, like WHILE _MOUSEINPUT: WEND, followed by mouse calls. The mouse wheel is the only one of those commands, which differs, and needs to be placed within that WHILE/WEND loop. How about the joystick stuff?

Pete

[madscijr]

Will it also work as: WHILE _DEVICEINPUT(iDevice): WEND....you know, like WHILE _MOUSEINPUT: WEND, followed by mouse calls. The mouse wheel is the only one of those commands, which differs, and needs to be placed within that WHILE/WEND loop. How about the joystick stuff?

That's a good question, I'm pretty new to QB64 and have no idea. Anyone??

Update: The WHILE/WEND does seem to work with joysticks the same way.
I'll post my code which is now working as expected.