User Customized Input

[SMcNeill]

We see a lot of people post little games around here.  We also see a lot of other people post things like "Can you change it so that I can use XXX key for (whatever), rather than what you have set?"

Here's the very simplest set of code I can think of to allow someone to set custom controls for a game:

Code: QB64: [Select]

1. PRINT "Press the key you want to move UP   :";
2. Up = SetKey: PRINT Up
3. PRINT "Press the key you want to move LEFT :";
4. Left = SetKey: PRINT Left
5. PRINT "Press the key you want to move DOWN :";
6. Down = SetKey: PRINT Down
7. PRINT "Press the key you want to move RIGHT:";
8. Right = SetKey: PRINT Right
9. _DELAY 1
10.  
11. HeroX = 20: HeroY = 20
12. _CONTROLCHR OFF
13. DO
14.     CLS
15.     LOCATE HeroY, HeroX: PRINT CHR$(1);
16.     K = _KEYHIT
17.     SELECT CASE K
18.         CASE Up: HeroY = HeroY - 1 - (HeroY <= 1)
19.         CASE Left: HeroX = HeroX - 1 - (HeroX <= 1)
20.         CASE Down: HeroY = HeroY + 1 + (HeroY >= 25)
21.         CASE Right: HeroX = HeroX + 1 + (HeroX >= 80)
22.     END SELECT
23.     _LIMIT 30
24.     _DISPLAY
25. LOOP
26.  
27.  
28. FUNCTION SetKey
29.     STATIC KeysInUse(1 TO 100) AS LONG
30.     DO
31.         SetKey = _KEYHIT
32.         FOR i = 1 TO 100
33.             IF KeysInUse(i) = SetKey THEN SetKey = 0 'Can't define the same key twice.
34.             IF KeysInUse(i) = 0 THEN EXIT FOR
35.         NEXT
36.         IF i < 101 THEN KeysInUse(i) = SetKey
37.         _LIMIT 30
38.     LOOP UNTIL SetKey > 0
39. END FUNCTION
40.  
41.  

It really can be that simple of a process.  :)

[STxAxTIC]

I like this. Some games, namely Portal 2 and Rage to name a few, ask you to "look up" right off the bat, so whatever your natural reflex is, that's "up" for now on, and so on. This is right in that spirit.

[SMcNeill]

And here's a version which looks more like what my game has going for it:

Code: QB64: [Select]

1. TYPE Control_Type
2.     Label AS STRING
3.     Value AS LONG
4.     JoyStick AS LONG
5. END TYPE
6. DIM SHARED Control(10) AS Control_Type
7. Control(0).Label = "UP": Control(0).Value = 18432: Control(0).JoyStick = 1210000
8. Control(1).Label = "DOWN": Control(1).Value = 20480: Control(1).JoyStick = 1220000
9. Control(2).Label = "LEFT": Control(2).Value = 19200: Control(2).JoyStick = 1120000
10. Control(3).Label = "RIGHT": Control(3).Value = 19712: Control(3).JoyStick = 1110000
11. Control(4).Label = "SELECT": Control(4).Value = 8: Control(4).JoyStick = 1000000
12. Control(5).Label = "TAB": Control(5).Value = 9: Control(5).JoyStick = 1000001
13. Control(6).Label = "ENTER": Control(6).Value = 13: Control(6).JoyStick = 1000002
14. Control(7).Label = "CANCEL": Control(7).Value = 27: Control(7).JoyStick = 1000003
15.  
16. SCREEN _NEWIMAGE(800, 600, 32) 'An initial screen for testing
17. $COLOR:32
18. Settings
19.  
20. SCREEN _NEWIMAGE(640, 480, 32) 'And a second screen, so we can see that we scale to fit any environment properly
21. Settings
22.  
23.  
24.  
25.  
26.  
27. SUB Settings
28.     DIM BGC AS _UNSIGNED LONG, f AS LONG, BT AS LONG, D AS LONG, tempimage AS LONG
29.     DIM ScaleX AS _FLOAT, ScaleY AS _FLOAT, cx AS _FLOAT
30.     DIM BackUp(10) AS Control_Type
31.     FOR i = 0 TO 10: BackUp(i) = Control(i): NEXT
32.  
33.     Dev = _DEVICES
34.     WHILE _DEVICEINPUT(3): WEND
35.     LB = _LASTBUTTON(3): LA = _LASTAXIS(3)
36.  
37.  
38.     f = _LOADFONT("courbd.ttf", 48, "monospace")
39.     BGC = SkyBlue 'Background color
40.     BT = _LOADIMAGE("marble.jpg", 32) ' Button Tile
41.     D = _DEST
42.     PCOPY D, 1
43.  
44.     tempimage = _NEWIMAGE(1280, 720, 32)
45.     ScaleX = 1280 / _WIDTH(D): ScaleY = 720 / _HEIGHT(D)
46.     Button = BoxImage(300, 50, 5, BT, Ivory)
47.     Frame = BoxImage(300, 50, 5, 0, Red)
48.  
49.     _DEST tempimage
50.     COLOR Black, 0
51.     CLS , BGC
52.     _FONT f
53.     CenterLabel 200, 10, 300, 50, "Keyboard"
54.     CenterLabel 600, 10, 300, 50, "JoyStick"
55.     FOR i = 0 TO 10
56.         _PRINTSTRING (190 - _PRINTWIDTH(Control(i).Label), 60 * i + 71), Control(i).Label
57.         _PUTIMAGE (200, 60 * i + 70), Button
58.         CenterLabel 200, 60 * i + 71, 300, 50, GetKeyName(Control(i).Value)
59.         _PUTIMAGE (600, 60 * i + 70), Button
60.         CenterLabel 600, 60 * i + 71, 300, 50, GetKeyName(Control(i).JoyStick)
61.     NEXT
62.  
63.     Accept = BoxImage(200, 200, 5, Green, Ivory)
64.     Cancel = BoxImage(200, 200, 5, Red, Ivory)
65.     _PUTIMAGE (1000, 100), Accept, tempimage
66.     _PUTIMAGE (1000, 400), Cancel, tempimage
67.     CenterLabel 1000, 100, 200, 200, "OK"
68.     CenterLabel 1000, 400, 200, 200, "Cancel"
69.  
70.     replace = -1: j = -1: OM = -1
71.     DO
72.         _PUTIMAGE , tempimage, D
73.         k = _KEYHIT
74.         WHILE _DEVICEINPUT(3): WEND
75.         WHILE _MOUSEINPUT: WEND
76.         MB = _MOUSEBUTTON(1)
77.         IF MB AND NOT OM THEN
78.             MX = _MOUSEX * ScaleX: MY = _MOUSEY * ScaleY
79.             IF MX >= 1000 AND MX <= 1200 THEN
80.                 SELECT CASE MY
81.                     CASE 100 TO 300 'Accept
82.                         EXIT DO
83.                     CASE 400 TO 600 'Cancel
84.                         FOR i = 0 TO 10: Control(i) = BackUp(i): NEXT
85.                         EXIT DO
86.                 END SELECT
87.             END IF
88.         END IF
89.         OM = MB
90.  
91.  
92.         IF k = 0 THEN
93.             FOR i = 1 TO LB
94.                 IF _BUTTON(i) THEN k = 999999 + i: EXIT FOR
95.             NEXT
96.             IF k = 0 THEN
97.                 FOR i = 1 TO LA
98.                     IF ABS(_AXIS(i)) > 0.25 THEN
99.                         k = 1000000 + i * 100000
100.                         IF _AXIS(i) > 0 THEN k = k + 10000 ELSE k = k + 20000
101.                     END IF
102.                 NEXT
103.             END IF
104.         END IF
105.  
106.         IF k > 0 AND k < 1000000 THEN
107.             IF replace = -1 THEN
108.                 FOR i = 0 TO 10
109.                     IF Control(i).Value = k THEN
110.                         replace = i
111.                         _PUTIMAGE (200, 60 * i + 70), Button, tempimage
112.                         _PUTIMAGE (200, 60 * i + 70), Frame, tempimage
113.                         EXIT FOR
114.                     END IF
115.                 NEXT
116.             ELSE
117.                 FOR i = 0 TO 10
118.                     IF Control(i).Value = k THEN EXIT FOR
119.                 NEXT
120.                 IF i > 10 THEN
121.                     Control(replace).Value = k
122.                     _PUTIMAGE (200, 60 * replace + 70), Button, tempimage
123.                     CenterLabel 200, 60 * replace + 71, 300, 50, GetKeyName(k)
124.                     replace = -1
125.                 END IF
126.             END IF
127.         ELSEIF k > 999999 THEN
128.             IF j = -1 THEN
129.                 FOR i = 0 TO 10
130.                     IF Control(i).JoyStick = k THEN
131.                         j = i
132.                         _PUTIMAGE (600, 60 * i + 70), Button, tempimage
133.                         _PUTIMAGE (600, 60 * i + 70), Frame, tempimage
134.                         EXIT FOR
135.                     END IF
136.                 NEXT
137.             ELSEIF j >= 0 AND j <= 10 THEN
138.                 FOR i = 0 TO 10
139.                     IF Control(i).JoyStick = k THEN EXIT FOR
140.                 NEXT
141.                 IF i > 10 THEN
142.                     Control(j).JoyStick = k
143.                     _PUTIMAGE (600, 60 * j + 70), Button, tempimage
144.                     CenterLabel 600, 60 * j + 71, 300, 50, GetKeyName(k)
145.                     j = -1
146.                     _DELAY .25
147.                 END IF
148.             END IF
149.         END IF
150.         _LIMIT 30
151.         _DISPLAY
152.     LOOP
153.     PCOPY 1, D
154.     _DEST D
155.     _FREEIMAGE tempimage
156.     _FREEIMAGE Accept
157.     _FREEIMAGE Cancel
158.     _FREEIMAGE Button
159.     _FREEIMAGE Frame
160. END SUB
161.  
162. FUNCTION BoxImage (wide&, tall&, thick&, BGcolor&&, FrameColor&&)
163.     D = _DEST
164.     BoxImage = _NEWIMAGE(wide&, tall&, 32)
165.     _DEST BoxImage
166.     IF BGcolor&& = -1 THEN BGcolor&& = 0
167.     IF BGcolor&& < 0 THEN
168.         _PUTIMAGE , BGcolor&&
169.     ELSE
170.         CLS , BGcolor&&
171.     END IF
172.     FOR i& = 0 TO thick& - 1
173.         LINE (i&, i&)-STEP(wide& - i& * 2, tall& - i& * 2), FrameColor&&, B
174.     NEXT
175.     _DEST D
176. END SUB
177.  
178. SUB CenterLabel (left&, top&, wide&, tall&, text$)
179.     pw = _PRINTWIDTH(text$): fw = _FONTHEIGHT
180.     bx = (wide& - pw) \ 2: by = (tall& - fw) \ 2
181.     _PRINTSTRING (left& + bx, top& + by), text$
182. END SUB
183.  
184.  
185. FUNCTION GetKeyName$ (code)
186.     SELECT CASE code
187.         CASE 8: GetKeyName$ = "BKSP"
188.         CASE 9: GetKeyName$ = "TAB"
189.         CASE 13: GetKeyName$ = "ENTER"
190.         CASE 27: GetKeyName$ = "ESC"
191.         CASE 32: GetKeyName$ = "SPACE"
192.         CASE 33 TO 255: GetKeyName$ = CHR$(code)
193.         CASE 15104: GetKeyName$ = "F1"
194.         CASE 15360: GetKeyName$ = "F2"
195.         CASE 15616: GetKeyName$ = "F3"
196.         CASE 15872: GetKeyName$ = "F4"
197.         CASE 16128: GetKeyName$ = "F5"
198.         CASE 16384: GetKeyName$ = "F6"
199.         CASE 16640: GetKeyName$ = "F7"
200.         CASE 16896: GetKeyName$ = "F8"
201.         CASE 17152: GetKeyName$ = "F9"
202.         CASE 17408: GetKeyName$ = "F10"
203.         CASE 34048: GetKeyName$ = "F11"
204.         CASE 34304: GetKeyName$ = "F12"
205.         CASE 18432: GetKeyName$ = ""
206.         CASE 19200: GetKeyName$ = ""
207.         CASE 19712: GetKeyName$ = ""
208.         CASE 20480: GetKeyName$ = ""
209.  
210.         CASE 18176: GetKeyName$ = "HOME"
211.         CASE 18688: GetKeyName$ = "PG UP"
212.         CASE 20224: GetKeyName$ = "END"
213.         CASE 20736: GetKeyName$ = "PG DOWN"
214.         CASE 20992: GetKeyName$ = "INS"
215.         CASE 21248: GetKeyName$ = "DEL"
216.  
217.         CASE 100019: GetKeyName$ = "PAUSE"
218.         CASE 100300: GetKeyName$ = "NUM LOCK"
219.         CASE 100301: GetKeyName$ = "CAPS LOCK"
220.         CASE 100302: GetKeyName$ = "SCROLL LOCK"
221.         CASE 100303: GetKeyName$ = "R SHIFT"
222.         CASE 100304: GetKeyName$ = "L SHIFT"
223.         CASE 100305: GetKeyName$ = "R CTRL"
224.         CASE 100306: GetKeyName$ = "L CTRL"
225.         CASE 100307: GetKeyName$ = "R ALT"
226.         CASE 100308: GetKeyName$ = "L ALT"
227.         CASE 100309: GetKeyName$ = "L APPLE"
228.         CASE 100310: GetKeyName$ = "R APPLE"
229.         CASE 100311: GetKeyName$ = "R WIN"
230.         CASE 100312: GetKeyName$ = "L WIN"
231.         CASE 100316: GetKeyName$ = "SYSTEM"
232.         CASE 100319: GetKeyName$ = "MENU"
233.         CASE 1000000 TO 1000100
234.             GetKeyName$ = "JB #" + _TRIM$(STR$(code - 999999))
235.         CASE 1110000: GetKeyName$ = "AX 1+"
236.         CASE 1120000: GetKeyName$ = "AX 1-"
237.         CASE 1210000: GetKeyName$ = "AX 2+"
238.         CASE 1220000: GetKeyName$ = "AX 2-"
239.         CASE 1310000: GetKeyName$ = "AX 3+"
240.         CASE 1320000: GetKeyName$ = "AX 3-"
241.         CASE 1410000: GetKeyName$ = "AX 4+"
242.         CASE 1420000: GetKeyName$ = "AX 4-"
243.         CASE 1510000: GetKeyName$ = "AX 5+"
244.         CASE 1520000: GetKeyName$ = "AX 5-"
245.         CASE 1610000: GetKeyName$ = "AX 6+"
246.         CASE 1620000: GetKeyName$ = "AX 6-"
247.         CASE 1710000: GetKeyName$ = "AX 7+"
248.         CASE 1720000: GetKeyName$ = "AX 7-"
249.  
250.     END SELECT
251. END FUNCTION