Complete Input Popup Menu

[SMcNeill]

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(640, 480, 32)
2. $COLOR:32
3. RANDOMIZE TIMER
4.  
5. FOR i = 1 TO 100
6.     'LINE (RND * 640, RND * 640)-(RND * 640, RND * 640), &HFF000000 + RND * &HFFFFFF, BF
7. NEXT
8.  
9.  
10.  
11. choice = PopUpMenu("New|Start|Run|Quit", 100, 100, 16, 2, _RGB32(255, 255, 0), _RGB32(255, 128, 255))
12. CLS , SkyBlue
13. PRINT "You chose choice #"; choice
14.  
15. f = _LOADFONT("courbd.ttf", 72, "monospace")
16.  
17. choice = PopUpMenu("Cheese|Beef|Soda|Frog", 150, 150, f, 5, Silver, Purple)
18.  
19. PRINT choice
20. PRINT
21. PRINT "And this time you chose choice #"; choice
22.  
23.  
24. FUNCTION PopUpMenu (choice$, left, top, font, framesize, framecolor, fontcolor)
25.     D = _DEST
26.     fh = _FONTHEIGHT(font)
27.     tempimage = _NEWIMAGE(1000, 1000, 32)
28.     _DEST tempimage
29.     _FONT font
30.  
31.     DO
32.         count = count + 1
33.         REDIM _PRESERVE temp(count) AS STRING
34.         l = INSTR(choice$, "|")
35.  
36.         IF l THEN
37.             temp(count) = LEFT$(choice$, l - 1)
38.             choice$ = MID$(choice$, l + 1)
39.         ELSE
40.             temp(count) = choice$
41.         END IF
42.         IF _PRINTWIDTH(temp(count)) > pw THEN pw = _PRINTWIDTH(temp(count))
43.  
44.         PRINT count, temp(count)
45.     LOOP UNTIL l = 0
46.     _FREEIMAGE tempimage
47.  
48.     iw = pw + framesize * 2
49.     ih = fh * count + (framesize) * (count + 2) - 1
50.  
51.     tempimage = _NEWIMAGE(iw, ih, 32)
52.     _DEST tempimage: _FONT font
53.     FOR i = 0 TO framesize - 1: LINE (i, i)-(iw - i, ih - i), framecolor, B: NEXT
54.  
55.     COLOR fontcolor, 0
56.     FOR i = 1 TO UBOUND(temp)
57.         Center fh * (i - 1) + framesize * (i + 1), temp(i), tempimage
58.     NEXT
59.     Highlight = BoxImage(iw - framesize + 2, fh + framesize * 2, framesize, 0, fontcolor)
60.     _DEST Highlight: CLS , 0
61.     FOR i = 0 TO framesize - 1: LINE (i, i)-(iw - i - framesize * 2, fh + framesize - i), fontcolor, B: NEXT
62.     _DEST D
63.  
64.     BG = _NEWIMAGE(_WIDTH(D), _HEIGHT(D), 32)
65.     _PUTIMAGE , D, BG
66.     PopUpMenu = 1
67.     B = _BLEND(D)
68.  
69.     oldmouse = -1
70.     DO
71.         _DONTBLEND D
72.         _PUTIMAGE , BG, D 'Restore our original background
73.         _BLEND D
74.         _PUTIMAGE (left, top), tempimage, D 'Put our options on the screen
75.         _PUTIMAGE (left + framesize, top + (fh + framesize) * (PopUpMenu - 1) + framesize), Highlight, D 'put our highlight onto the screen
76.         k = _KEYHIT
77.         SELECT CASE k
78.             CASE 20480: PopUpMenu = (PopUpMenu + 1) 'down
79.             CASE 18432: PopUpMenu = (PopUpMenu - 1) 'up
80.             CASE 13, 32: EXIT DO 'space or enter to select
81.         END SELECT
82.  
83.         scroll = 0
84.         WHILE _MOUSEINPUT
85.             scroll = scroll + _MOUSEWHEEL
86.         WEND
87.         PopUpMenu = (PopUpMenu + SGN(scroll)) 'up/down from scrolling the mousewheel
88.         IF _MOUSEX >= left AND _MOUSEX <= left + iw THEN 'we're in the right spot of the screen for mouse input
89.             IF _MOUSEY > top + framesize AND _MOUSEY < top + ih THEN
90.                 y = (_MOUSEY - top - framesize) \ (fh + framesize * 2)
91.                 PopUpMenu = y + 1
92.                 IF _MOUSEBUTTON(1) AND NOT oldmouse THEN EXIT DO
93.             END IF
94.         END IF
95.         IF _MOUSEBUTTON(1) AND NOT oldmouse THEN EXIT DO
96.         'Note:  If you only want the mouse to work inside the box, and not be counted as a viable click, then
97.         'remark out the command above
98.         oldmouse = _MOUSEBUTTON(1): scroll = 0
99.  
100.  
101.         FOR i = 1 TO 3 'We have up/down movement on the joystick
102.             IF ABS(STICK(1, i) - 127) > 10 THEN PopUpMenu = PopUpMenu + SGN(STICK(1, i) - 127): _DELAY .25
103.         NEXT
104.         IF STRIG(1) AND STRIG(0) THEN EXIT DO 'Joystick button 1 was pressed.
105.         IF PopUpMenu > count THEN PopUpMenu = 1
106.         IF PopUpMenu < 1 THEN PopUpMenu = count
107.  
108.         _LIMIT 10
109.         _DISPLAY
110.     LOOP
111.  
112.     _FREEIMAGE tempimage 'free the menu text
113.     _FREEIMAGE Highlight 'free the highlight box
114.     _DONTBLEND D
115.     _PUTIMAGE , BG, D 'Restore our original background
116.     _FREEIMAGE BG 'free the background copy
117.     _DEST D
118.     IF B = 0 THEN _DONTBLEND D
119.     _DISPLAY
120. END FUNCTION
121.  
122.  
123.  
124. SUB Center (FromTop, what$, where)
125.     D = _DEST: pw = _PRINTWIDTH(what$): sw = _WIDTH(where) 'print width and screen width
126.     IF pw > sw THEN Explode "Center, with pw > sw"
127.     _DEST where: _PRINTSTRING ((sw - pw) \ 2, FromTop), what$: _DEST D
128. END SUB
129.  
130. SUB CenterImage (FromTop, what, where)
131.     pw = _WIDTH(what): sw = _WIDTH(where) 'print width and screen width
132.     IF pw > sw THEN Explode "CenterImage, with pw > sw"
133.     _PUTIMAGE ((sw - pw) \ 2, FromTop), what, where
134. END SUB
135.  
136. SUB Explode (where$)
137.     CLS: _AUTODISPLAY
138.     PRINT "YOU F'ED UP!!  THERE'S A GLITCH IN THE CODE SOMEWHERE!"
139.     FOR i = 1 TO 10: PRINT "FIX IT! ": BEEP: _DELAY .5: NEXT
140.     PRINT: PRINT: PRINT "THE GLITCH IS IN: "; where$
141.     END
142. END SUB
143.  
144. FUNCTION BoxImage (wide, tall, thick, BGcolor, FrameColor)
145.     D = _DEST
146.     BoxImage = _NEWIMAGE(wide, tall, 32)
147.     _DEST BoxImage
148.     CLS , BGcolor
149.     FOR i = 0 TO thick - 1
150.         LINE (i, i)-STEP(wide - i * 2, tall - i * 2), FrameColor, B
151.     NEXT
152.     _DEST D
153. END FUNCTION

The demo above should showcase what this little snippet is all about -- it pops up a menu on the screen and asks the user to respond to it.  Keyboard, mouse, and joystick all should be valid methods to interact with the menu and have it do what you expect it to.   Works with all fonts -- monospaced and not -- and restores your background when it closes itself.

[bplus]

I am trying to decide if I like this better than Right Click pop-ups, they seem more refined.

What would you (or anyone) say advantage for this menu system is?

@SMcNeill I am watching the Keyboard Library thread for Samples Gallery, Informatics probably, do you plan to add this to that library? Not completely unrelated for input tools that go nice with Extended Input.

[SMcNeill]

Advantage for me, is just ease of menu integration.  If you see the splash screen demo for the game I’ve been working on you’ll see this for the title screen options.  It’s all self contained, builds itself, updates itself, and works with mouse, scroll wheel, joystick, and keyboard interactions.  It maintains and restores background, so it can be used as a pop-up selection tool, with no worries of screen corruption.  Just toss this into a mouse routine to check for Right Clicks, and this can pop-up just like those can — only offering more options with interactions, fonts, and such.  ;)

[bplus]

Ah good! Thanks. Do you plan to include it with Keyboard Library with Extended Input?

[SMcNeill]

I can, if you want.  There’s also a pop-up text box, message box, and input box which I’ll be sharing soon, for those who might be interested.  In the end, it’ll probably be nice to wrap them all up in a library together, but for discussion/examples, I find it easier to keep them independent to avoid any confusion anywhere.  :)

[bplus]

I can, if you want.  There’s also a pop-up text box, message box, and input box which I’ll be sharing soon, for those who might be interested.  In the end, it’ll probably be nice to wrap them all up in a library together, but for discussion/examples, I find it easier to keep them independent to avoid any confusion anywhere.  :)

Well you should do it how you want, sorry to interrupt, I was just thinking if all the parts were integrated and work well with each other ie your use of keyhit numbers working with the other parts or if you had a mouse or device routine working with all the other parts. I've discovered the need for one mouse/device handler (probably including keyboard) to cover all the box controls in a screen up at the same time.