NEON PEN

[SierraKen]

LOL that's awesome B+! I love the dimming effect, it can be used on neon signs. :)

[Ashish]

@TempodiBasic
There is a simpler way to draw circle in OpenGL

Code: QB64: [Select]

1. _TITLE "Learning OpenGL" 'giving title to your window
2. SCREEN _NEWIMAGE(600, 600, 32) 'creating a window of 600x600
3.  
4. 'This is our main loop
5. DO
6.     _LIMIT 40 'Adding this will prevent high cpu usage.
7. LOOP
8.  
9. SUB _GL ()
10.     'Here we'll put our OpenGL commands!
11.  
12.     _glViewport 0, 0, _WIDTH, _HEIGHT 'here _WIDTH() and _HEIGHT() gives the width and height of our window.
13.     '_glClearColor 1, .5, 0, 1
14.     _glClear _GL_COLOR_BUFFER_BIT
15.  
16.  
17.     _glColor3f 1, 1, 1
18.  
19.     r = .5
20.     _glBegin _GL_TRIANGLE_FAN
21.     FOR i = 0 TO _PI(2) STEP .05
22.         _glVertex2f COS(i) * r, SIN(i) * r
23.     NEXT
24.     _glEnd
25.  
26.     _glFlush
27. END SUB
28.  

For explanation, see GL_TRIANGLE_FAN section here - https://ashishkingdom.github.io/OpenGL-Tutorials/2d-shapes/

[Ashish]

@bplus gives us new IDEA! :D

Here is the dimming effect in GL

Code: QB64: [Select]

1. _TITLE "NEON PEN"
2. SCREEN _NEWIMAGE(800, 600, 32)
3.  
4. TYPE vec2
5.     x AS SINGLE
6.     y AS SINGLE
7. END TYPE
8.  
9. REDIM SHARED vert(1024) AS vec2, max_v_index
10. DIM SHARED rFactor!, gFactor!, bFactor!
11. rFactor! = 0.5: gFactor! = 1: bFactor! = 0.5
12. DO
13.     CLS
14.     PRINT "VRAM Usage : "; vram; "KB"
15.     PRINT "Vertices Used : "; max_v_index; "/"; UBOUND(vert)
16.     vram = (UBOUND(vert) * 4) / 1024
17.     WHILE _MOUSEINPUT: WEND
18.     IF _MOUSEBUTTON(1) THEN
19.         mx = _MOUSEX: my = _MOUSEY
20.         px = mx: py = my
21.         WHILE _MOUSEBUTTON(1) AND max_v_index < UBOUND(vert)
22.             WHILE _MOUSEINPUT: WEND
23.             mx = _MOUSEX: my = _MOUSEY
24.             IF ABS(px - mx) >= ABS(py - my) THEN
25.                 IF mx >= px THEN s = 1 ELSE s = -1
26.                 FOR i = px TO mx STEP s
27.                     vert(max_v_index).x = i
28.                     vert(max_v_index).y = map(i, px, mx, py, my)
29.                     max_v_index = max_v_index + 1
30.                     IF max_v_index > INT(UBOUND(vert) * 0.8) THEN REDIM _PRESERVE vert(max_v_index * 2) AS vec2
31.                 NEXT
32.             ELSE
33.                 IF my >= py THEN s = 1 ELSE s = -1
34.                 FOR i = py TO my STEP s
35.                     vert(max_v_index).x = map(i, py, my, px, mx)
36.                     vert(max_v_index).y = i
37.                     max_v_index = max_v_index + 1
38.                     IF max_v_index > INT(UBOUND(vert) * 0.8) THEN REDIM _PRESERVE vert(max_v_index * 2) AS vec2
39.                 NEXT
40.  
41.             END IF
42.             px = mx: py = my
43.             _LIMIT 30
44.         WEND
45.     END IF
46.  
47.     _LIMIT 60
48. LOOP
49.  
50. SUB _GL ()
51.     STATIC glInit, clock
52.     clock = clock + 0.03
53.     IF glInit = 0 THEN
54.         glInit = 1
55.  
56.     END IF
57.     _glViewport 0, 0, _WIDTH, _HEIGHT
58.     'set the gl screen so that it can work normal screen coordinates
59.     _glTranslatef -1, 1, 0
60.     _glScalef 1 / 400, -1 / 300, 1
61.  
62.     _glEnable _GL_BLEND
63.  
64.     _glBlendFunc _GL_SRC_ALPHA, _GL_ONE
65.     _glEnableClientState _GL_VERTEX_ARRAY
66.     _glVertexPointer 2, _GL_FLOAT, 0, _OFFSET(vert())
67.     FOR j = 1 TO 15
68.         _glColor4f rFactor!, gFactor!, bFactor!, 0.009 + 0.03 * ABS(SIN(clock))
69.         _glPointSize j
70.         _glDrawArrays _GL_POINTS, 10, max_v_index
71.     NEXT
72.     _glFlush
73. END SUB
74.  
75. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
76.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
77. END FUNCTION
78.  
79.  

[TempodiBasic]

@Ashish
Hi thanks for suggestion but I must say you that I have already a good master for Opengl
and I have travelled already his lessons to this Website https://ashishkingdom.github.io/OpenGL-Tutorials/
Now I need to use Opengl and  to pass again in the OpenGl travel to learn and memorize better.
Ripetita iuvant.

PS:
is your that website, master of OpenGl? 
;-)

[SierraKen]

Today I found _GL_LINE_STRIP so I turned your Neon Pen into making lines. It's not the same neon-look as you had before, but it's just something to learn. I also upped the vert DIM by a lot more. I found out that CLS or even a giant black box using LINE doesn't clear the screen for some reason. I'm still learning this stuff. I had to change your SUB to use the new _GL_LINE_STRIP, I'll post all of the code below. I should probably say too that I'm sure there's a much easier way to make this lines program without using OpenGL and without Dimming the memory. Or at least something very similar. This is just an OpenGL example is all. First click once on the screen, then click again to make your first line. Every line after that is connected to the end of your older line.
But first I want to say that people can also change the width of your Neon Pen (not this lines example below) to make wider lines or drawings by just changing the SUB's line For j=1 to 15 to something like For j=1 to 25.

 

Code: QB64: [Select]

1. _TITLE "Neon Lines"
2. SCREEN _NEWIMAGE(800, 600, 32)
3.  
4. TYPE vec2
5.     x AS SINGLE
6.     y AS SINGLE
7. END TYPE
8.  
9. REDIM SHARED vert(200024) AS vec2, max_v_index
10. DIM SHARED rFactor!, gFactor!, bFactor!
11. rFactor! = 0.5: gFactor! = 2.5: bFactor! = 0.5
12. DO
13.     'CLS
14.     LOCATE 1, 1: PRINT "VRAM Usage : "; vram; "KB"
15.     LOCATE 2, 1: PRINT "Vertices Used : "; max_v_index; "/"; UBOUND(vert)
16.     vram = (UBOUND(vert) * 4) / 1024
17.     a$ = INKEY$
18.     IF a$ = CHR$(27) THEN END
19.  
20.     WHILE _MOUSEINPUT: WEND
21.     m = _MOUSEBUTTON(1)
22.     IF m = -1 THEN
23.         t = t + 1
24.         px = mx: py = my
25.         mx = _MOUSEX: my = _MOUSEY
26.         IF t < 2 THEN GOTO notthistime:
27.         'px = mx: py = my
28.         WHILE m = -1 AND max_v_index < UBOUND(vert)
29.             WHILE _MOUSEINPUT: WEND
30.             mx = _MOUSEX: my = _MOUSEY
31.             IF ABS(px - mx) >= ABS(py - my) THEN
32.                 IF mx >= px THEN s = 1 ELSE s = -1
33.                 FOR i = px TO mx STEP s
34.                     vert(max_v_index).x = i
35.                     vert(max_v_index).y = map(i, px, mx, py, my)
36.                     max_v_index = max_v_index + 1
37.                     'IF max_v_index > UBOUND(vert) THEN REDIM _PRESERVE vert(max_v_index * 2) AS vec2
38.                 NEXT
39.             ELSE
40.                 IF my >= py THEN s = 1 ELSE s = -1
41.                 FOR i = py TO my STEP s
42.                     vert(max_v_index).x = map(i, py, my, px, mx)
43.                     vert(max_v_index).y = i
44.                     max_v_index = max_v_index + 1
45.                     'IF max_v_index > UBOUND(vert) THEN REDIM _PRESERVE vert(max_v_index * 2) AS vec2
46.                 NEXT
47.             END IF
48.             'px = mx: py = my
49.             notthistime:
50.             m = 0
51.         WEND
52.     END IF
53.     _LIMIT 200
54. LOOP
55.  
56. 'This sub was changed from points to lines.
57. SUB _GL ()
58.     STATIC glInit
59.     IF glInit = 0 THEN
60.         glInit = 1
61.  
62.     END IF
63.     _glViewport 0, 0, _WIDTH, _HEIGHT
64.     'set the gl screen so that it can work normal screen coordinates
65.     _glTranslatef -1, 1, 0
66.     _glScalef 1 / 400, -1 / 300, 1
67.  
68.     _glEnable _GL_BLEND
69.     _glBlendFunc _GL_SRC_ALPHA, _GL_ONE
70.     _glEnableClientState _GL_VERTEX_ARRAY
71.     _glVertexPointer 2, _GL_FLOAT, 0, _OFFSET(vert())
72.     FOR j = 1 TO 30
73.         'For j=1 to 15
74.         '_glColor4f rFactor!, gFactor!, bFactor!, 0.015
75.         _glColor4f rFactor!, gFactor!, bFactor!, 0.06
76.         _glPointSize j
77.         '_glDrawArrays _GL_POINTS, 10, max_v_index
78.         _glLineWidth 10
79.         _glDrawArrays _GL_LINE_STRIP, 0, max_v_index
80.     NEXT
81.     _glFlush
82. END SUB
83.  
84. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
85.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
86. END FUNCTION
87.  

[SierraKen]

Here's what your Neon Pen looks like with the wider length I mentioned in my last post. Oh I also had to add more to the Dim for the vert's on this too.

[TempodiBasic]

@SierraKen
Hi I'm seeing that you like it!

if you want clear screen in Opengl you must 1. set the color of clearing (say Black _rgb32(0,0,0,255)) with _glclearcolor and after 2 use _glclear what (generally _gl_color_buffer_bit)
as here

Code: QB64: [Select]

1.     _GLCLEARCOLOR 1, .5, 0, 1
2.     _GLCLEAR _GL_COLOR_BUFFER_BIT

the 4th parameter is Alpha channel, so if you want to see as background normal graphic (that made by LINE and erased by CLS) you can use a lower value at the place of 1 (0-1  in Opengl 0-255 in standard graphic).

But all these are info taken from my Opengl master  here https://ashishkingdom.github.io/OpenGL-Tutorials/.

If you want to learn how to mix normal graphic and Opengl graphic you can see the demo posted by Steve here:  https://www.qb64.org/forum/index.php?topic=3254.msg125353#msg125353
but I warning you it is just a little advanced. ;-)

[SierraKen]

Thanks TempodiBasic, but I don't know much more OpenGL I'm going to do. I rarely stay with anything I jump in the middle of. But thanks for the info.