Need ideas for more API usage....

[SpriggsySpriggs]

Fellas, I need more ideas for API usage. Whether it be WinAPI or REST/HTTP/HTTPS. Just some ideas. I'm getting restless waiting at home for call backs for jobs I've been applying to so I'm keeping myself occupied by absorbing myself into QB64. Give me some ideas, bros.

[bplus]

For moving copying deleting... files something to do them in groups selected out of various folders and placed into a shopping cart then at checkout time do the function. I think moving files or copying for backup into one folder is what I have in mind. For instance I'd like to backup all QB64 folders without the exe's to save a ton of room.

[SpriggsySpriggs]

So I could basically just build an array with the files that you are wanting to move and then move them to the specified directory? And I guess for the backup thing it would be like a scheduled task? I'll look into this.

[SpriggsySpriggs]

@bplus Here is something I did just now....

Code: QB64: [Select]

1. DIM cart(5) AS STRING
2. cart(1) = _DIR$("desktop") + "QB64 x64\GetComputerName.bas"
3. cart(2) = _DIR$("desktop") + "QB64 x64\timediff.bas"
4. cart(3) = _DIR$("desktop") + "QB64 x64\qrtag api.bas"
5. cart(4) = _DIR$("desktop") + "QB64 x64\Genderize API.bas"
6. cart(5) = _DIR$("desktop") + "QB64 x64\rewind.png.MEM"
7.  
8. DIM dest AS STRING
9. dest = _DIR$("desktop")
10.  
11. a = RunTransaction(cart(), dest, 2)
12.  
13. FUNCTION RunTransaction (filecart() AS STRING, dest AS STRING, mode AS INTEGER) 'dest is optional, only used for Copy and Move
14.     DIM x AS INTEGER
15.     DIM a AS INTEGER
16.     IF RIGHT$(dest, 1) <> "\" THEN
17.         dest = dest + "\"
18.     END IF
19.     SELECT CASE mode
20.         CASE 1 'Recycle
21.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
22.                 IF filecart(x) <> "" THEN
23.                     a = Recycle(filecart(x))
24.                 END IF
25.             NEXT
26.         CASE 2 'Copy
27.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
28.                 IF filecart(x) <> "" THEN
29.                     a = Copy(filecart(x), dest + StripDirectory(filecart(x)))
30.                 END IF
31.             NEXT
32.         CASE 3 'Move
33.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
34.                 IF filecart(x) <> "" THEN
35.                     a = Move(filecart(x), dest + StripDirectory(filecart(x)))
36.                 END IF
37.             NEXT
38.     END SELECT
39. END FUNCTION
40.  
41. FUNCTION StripDirectory$ (OFile$)
42.     DO
43.         OFile$ = RIGHT$(OFile$, LEN(OFile$) - INSTR(OFile$, "\"))
44.     LOOP WHILE INSTR(OFile$, "\")
45.     StripDirectory$ = OFile$
46. END FUNCTION

[bplus]

hmm... maybe not enough of a challenge.

I realized I could write the backup thing with QB64, I'm pretty sure, specially after we were doing trees of our files.

I would like to write a QB64 program, compile it and run it in shell from same program that wrote the program.
I don't know if API can help with that? What do you think?

[SpriggsySpriggs]

@bplus
Here are screenshots from a tweak I made to the transaction thing. It can be used for your backup idea.

  [ You are not allowed to view this attachment ]    [ You are not allowed to view this attachment ]    [ You are not allowed to view this attachment ]  

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3.  
4. 'To - From, From - To Flags
5. CONST FO_MOVE = &H1
6. CONST FO_COPY = &H2
7. CONST FO_DELETE = &H3
8. CONST FO_RENAME = &H4
9.  
10. 'File Op Flags
11. CONST FOF_MULTIDESTFILES = &H1
12. CONST FOF_CONFIRMMOUSE = &H2
13. CONST FOF_SILENT = &H4
14. CONST FOF_RENAMEONCOLLISION = &H8
15. CONST FOF_NOCONFIRMATION = &H10
16. CONST FOF_WANTMAPPINGHANDLE = &H20
17. CONST FOF_ALLOWUNDO = &H40
18. CONST FOF_FILESONLY = &H80
19. CONST FOF_SIMPLEPROGRESS = &H100
20. CONST FOF_NOCONFIRMMKDIR = &H200
21. CONST FOF_NOERRORUI = &H400
22. CONST FOF_NOCOPYSECURITYATTRIBS = &H800
23. CONST FOF_NORECURSION = &H1000
24. CONST FOF_NO_CONNECTED_ELEMENTS = &H2000
25. CONST FOF_WANTNUKEWARNING = &H4000
26. CONST FOF_NORECURSEREPARSE = &H8000
27. CONST FOF_NO_UI = FOF_SILENT
28.  
29. 'Return Values
30. CONST DE_SAMEFILE = &H71
31. CONST DE_MANYSRC1DEST = &H72
32. CONST DE_DIFFDIR = &H73
33. CONST DE_ROOTDIR = &H74
34. CONST DE_OPCANCELLED = &H75
35. CONST DE_DESTSUBTREE = &H76
36. CONST DE_ACCESSDENIEDSRC = &H78
37. CONST DE_PATHTOODEEP = &H79
38. CONST DE_MANYDEST = &H7A
39. CONST DE_INVALIDFILES = &H7C
40. CONST DE_DESTSAMETREE = &H7D
41. CONST DE_FLDDESTISFILE = &H7E
42. CONST DE_FILEDESTISFLD = &H80
43. CONST DE_FILENAMETOOLONG = &H81
44. CONST DE_DEST_IS_CDROM = &H82
45. CONST DE_DEST_IS_DVD = &H83
46. CONST DE_DEST_IS_CDRECORD = &H84
47. CONST DE_FILE_TOO_LARGE = &H85
48. CONST DE_SRC_IS_CDROM = &H86
49. CONST DE_SRC_IS_DVD = &H87
50. CONST DE_SRC_IS_CDRECORD = &H88
51. CONST DE_ERROR_MAX = &HB7
52. CONST UNKNOWN = &H402
53. CONST ERRORONDEST = &H10000
54. CONST DE_ROOTDIR_ERRORONDEST = &H10074
55.  
56. TYPE SHFILEOPSTRUCTA
57.     hwnd AS _OFFSET
58.     $IF 64BIT THEN
59.         wfunc AS _UNSIGNED _INTEGER64 'To - From, From - To Flags
60.     $ELSE
61.     wfunc AS _UNSIGNED LONG
62.     $END IF
63.     pFrom AS _OFFSET
64.     pTo AS _OFFSET
65.     fFlags AS LONG
66.     fAnyOperationsAborted AS _BYTE
67.     hNameMappings AS _OFFSET
68.     lpszProgressTitle AS _OFFSET
69. END TYPE
70.  
71. TYPE SHQUERYRBINFO
72.     $IF 64BIT THEN
73.         cbsize AS _INTEGER64
74.         i64Size AS _INTEGER64
75.         i64NumItems AS _INTEGER64
76.     $ELSE
77.     cbsize AS LONG
78.     i64Size AS _INTEGER64
79.     i64NumItems AS _INTEGER64
80.     $END IF
81. END TYPE
82.  
83. DECLARE DYNAMIC LIBRARY "Shell32"
84.     FUNCTION FileOperation% ALIAS SHFileOperationA (lpFileOp AS SHFILEOPSTRUCTA)
85.     FUNCTION EmptyRecycleBin% ALIAS SHEmptyRecycleBinA (BYVAL hwnd AS LONG, BYVAL pszRootPath AS _OFFSET, BYVAL dwFlags AS LONG)
86.     FUNCTION QueryRecycleBin~& ALIAS SHQueryRecycleBinA (pszRootPath AS STRING, pSHQueryRBInfo AS SHQUERYRBINFO)
87. END DECLARE
88.  
89. 'Test code
90. 'IF _FILEEXISTS(_DIR$("desktop") + "this is a test.txt") = 0 THEN
91. '    OPEN _DIR$("desktop") + "this is a test.txt" FOR OUTPUT AS #1
92. '    CLOSE #1
93. 'END IF
94. 'PRINT Copy(_DIR$("desktop") + "this is a test.txt", _DIR$("desktop") + "this is a test as well.txt")
95. '_DELAY 2
96. 'PRINT Rename(_DIR$("desktop") + "this is a test as well.txt", _DIR$("desktop") + "this is a test also.txt")
97. '_DELAY 2
98. 'PRINT Recycle(_DIR$("desktop") + "this is a test also.txt")
99. '_DELAY 2
100. 'PRINT GetRecycleInfo
101. '_DELAY 2
102. 'PRINT EmptyBin
103. 'SLEEP
104.  
105. 'DIM cart(5) AS STRING
106. 'cart(1) = _DIR$("desktop") + "QB64 x64\GetComputerName.bas"
107. 'cart(2) = _DIR$("desktop") + "QB64 x64\timediff.bas"
108. 'cart(3) = _DIR$("desktop") + "QB64 x64\qrtag api.bas"
109. 'cart(4) = _DIR$("desktop") + "QB64 x64\Genderize API.bas"
110. 'cart(5) = _DIR$("desktop") + "QB64 x64\rewind.png.MEM"
111.  
112. 'DIM dest AS STRING
113. 'dest = _DIR$("desktop")
114.  
115. 'a = RunTransaction(cart(), dest, 2)
116.  
117. 'bplus backup test code
118. SHELL _HIDE "PowerShell Get-ChildItem '" + _STARTDIR$ + "' -exclude *.exe | where {! $_.PSIsContainer} | foreach {$_.Name} | Out-File dirslist.txt -Encoding ASCII" 'Replace _STARTDIR$ with whatever directory contains the files
119. '                                                                                                                                                                    used -exclude *.exe since you said you didn't want EXEs to be copied
120. OPEN "dirslist.txt" FOR BINARY AS #1
121.  
122. DO
123.     IF NOT EOF(1) THEN
124.         x = x + 1
125.         REDIM _PRESERVE filelist(x) AS STRING
126.         LINE INPUT #1, filelist(x)
127.         filelist(x) = _STARTDIR$ + "\" + filelist(x)
128.     END IF
129. LOOP UNTIL EOF(1)
130. CLOSE #1
131. DIM dest AS STRING
132. dest = _DIR$("desktop") + "Test Folder"
133. a = RunTransaction(filelist(), dest, 2)
134.  
135. FUNCTION GetRecycleInfo$
136.     DIM RecycleInfo AS SHQUERYRBINFO
137.     DIM path AS STRING
138.     DIM a~&
139.     path = "" + CHR$(0)
140.     RecycleInfo.cbsize = LEN(RecycleInfo)
141.     a~& = QueryRecycleBin(path, RecycleInfo)
142.     GetRecycleInfo = _TRIM$(STR$(RecycleInfo.i64Size)) + " bytes, " + _TRIM$(STR$(RecycleInfo.i64NumItems)) + " items"
143. END FUNCTION
144.  
145. FUNCTION Recycle% (file AS STRING)
146.     DIM lpFileOp AS SHFILEOPSTRUCTA
147.     DIM doublenull AS STRING
148.     doublenull = CHR$(0) + CHR$(0)
149.     file = file + doublenull
150.     lpFileOp.hwnd = _WINDOWHANDLE
151.     lpFileOp.wfunc = FO_DELETE
152.     lpFileOp.pFrom = _OFFSET(file)
153.     lpFileOp.fFlags = FOF_ALLOWUNDO + FOF_WANTNUKEWARNING
154.     Recycle = FileOperation(lpFileOp)
155. END FUNCTION
156.  
157. FUNCTION Copy% (file AS STRING, dest AS STRING)
158.     DIM lpFileOp AS SHFILEOPSTRUCTA
159.     DIM doublenull AS STRING
160.     doublenull = CHR$(0) + CHR$(0)
161.     file = file + doublenull
162.     dest = dest + doublenull
163.     lpFileOp.hwnd = _WINDOWHANDLE
164.     lpFileOp.wfunc = FO_COPY
165.     lpFileOp.pFrom = _OFFSET(file)
166.     lpFileOp.pTo = _OFFSET(dest)
167.     lpFileOp.fFlags = FOF_ALLOWUNDO
168.     Copy = FileOperation(lpFileOp)
169. END FUNCTION
170.  
171. FUNCTION Move% (file AS STRING, dest AS STRING)
172.     DIM lpFileOp AS SHFILEOPSTRUCTA
173.     DIM doublenull AS STRING
174.     doublenull = CHR$(0) + CHR$(0)
175.     file = file + doublenull
176.     dest = dest + doublenull
177.     lpFileOp.hwnd = _WINDOWHANDLE
178.     lpFileOp.wfunc = FO_MOVE
179.     lpFileOp.pFrom = _OFFSET(file)
180.     lpFileOp.pTo = _OFFSET(dest)
181.     lpFileOp.fFlags = FOF_ALLOWUNDO
182.     Move = FileOperation(lpFileOp)
183. END FUNCTION
184.  
185. FUNCTION Rename% (file AS STRING, newname AS STRING)
186.     DIM lpFileOp AS SHFILEOPSTRUCTA
187.     DIM doublenull AS STRING
188.     doublenull = CHR$(0) + CHR$(0)
189.     file = file + doublenull
190.     newname = newname + doublenull
191.     lpFileOp.hwnd = _WINDOWHANDLE
192.     lpFileOp.wfunc = FO_RENAME
193.     lpFileOp.pFrom = _OFFSET(file)
194.     lpFileOp.pTo = _OFFSET(newname)
195.     lpFileOp.fFlags = FOF_ALLOWUNDO
196.     Rename = FileOperation(lpFileOp)
197. END FUNCTION
198.  
199. FUNCTION EmptyBin%
200.     DIM drive AS STRING
201.     drive = ""
202.     EmptyBin = EmptyRecycleBin(0, _OFFSET(drive), 0)
203. END FUNCTION
204.  
205. FUNCTION RunTransaction (filecart() AS STRING, dest AS STRING, mode AS INTEGER) 'dest is optional, only used for Copy and Move
206.     DIM x AS INTEGER
207.     DIM a AS INTEGER
208.     IF RIGHT$(dest, 1) <> "\" THEN
209.         dest = dest + "\"
210.     END IF
211.     SELECT CASE mode
212.         CASE 1 'Recycle
213.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
214.                 IF filecart(x) <> "" THEN
215.                     a = Recycle(filecart(x))
216.                     PRINT "Recycling item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
217.                 END IF
218.             NEXT
219.         CASE 2 'Copy
220.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
221.                 IF filecart(x) <> "" THEN
222.                     a = Copy(filecart(x), dest + StripDirectory(filecart(x)))
223.                     PRINT "Copying item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
224.                 END IF
225.             NEXT
226.         CASE 3 'Move
227.             FOR x = LBOUND(filecart) TO UBOUND(filecart)
228.                 IF filecart(x) <> "" THEN
229.                     a = Move(filecart(x), dest + StripDirectory(filecart(x)))
230.                     PRINT "Moving item "; x; " of "; UBOUND(filecart); " ("; filecart(x); ")"
231.                 END IF
232.             NEXT
233.     END SELECT
234. END FUNCTION
235.  
236. FUNCTION StripDirectory$ (OFile$)
237.     DO
238.         OFile$ = RIGHT$(OFile$, LEN(OFile$) - INSTR(OFile$, "\"))
239.     LOOP WHILE INSTR(OFile$, "\")
240.     StripDirectory$ = OFile$
241. END FUNCTION

[SpriggsySpriggs]

I would like to write a QB64 program, compile it and run it in shell from same program that wrote the program.
I don't know if API can help with that? What do you think?

I suppose you could do this by making a console program, having it write a BAS source for a console program using PRINT commands,  then SHELLing to QB64 to compile the program then SHELL the program inside the first console program which will run the new one in the same window.