« previous next »
Pages: 1 2 [3]   Go Down

Author Topic: Trying to imitate TIS-100  (Read 7328 times)

0 Members and 1 Guest are viewing this topic.

Offline Juan Tamarit

  • Newbie
  • Posts: 53
    • View Profile
Re: Trying to imitate TIS-100
« Reply #30 on: September 10, 2020, 11:16:10 pm »
OK, i keep doing some nice advances: SUB textProccesor() works fine to input the instructions, but im having some troubles realizing how can i achieve the SUB IDE(). I did a horrible IF statement filled with ORs (very noob aproach), but didn't work. Any suggestions about this point? I can't figure out the logic for this, even with separeted IF statements



Code: QB64: [Select]
  1. '----------------------------------------------------------------------------------------------------------Û   SETUP   Û----------------------------------------------------------------------------------------------------------
  3.  
  4. CONST ScreenWidth = 1024 '                       ¿           ÚÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
  5. CONST ScreenHeight = 768 '                       ³           ³  1y,1x     ³
  6. '                                                ³ video     ³  TEXT       ³
  7. SCREEN _NEWIMAGE(ScreenWidth, ScreenHeight, 32) '³           ³    SCREEN   ³
  8. _FULLSCREEN '                                    ³           ³   48y,128x ³
  9. _MOUSEHIDE '                                     Ù           ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
  10.  
  11. CONST WHITE = _RGB32(255, 255, 255) '            ¿
  12. CONST BLACK = _RGB32(0, 0, 0) '                  ³
  13. CONST MIDGRAY = _RGB32(127, 127, 127) '          ³
  14. CONST DARKGRAY = _RGB32(63, 63, 63) '            ³ colors
  15. CONST LIGHTGRAY = _RGB32(191, 191, 191) '        ³
  16. CONST RED = _RGB32(127, 0, 0) '                  ³
  17. CONST GREEN = _RGB32(0, 127, 0) '                ³
  18. CONST BLUE = _RGB32(0, 0, 127) '                 ³
  19. CONST YELLOW = _RGB32(255, 255, 0) '             Ù
  20.  
  21. '----------------------------------------------------------------------------------------------------------Û VARIABLES Û----------------------------------------------------------------------------------------------------------
  22.  
  23. DIM SHARED segmentState%(34) ' is segment NOMINAL(1) or ERROR(0)?   ¿
  24. DIM SHARED actualSegmentWorking% ' where are we?                    ³ SEGMENTS
  25. DIM SHARED segmentName$(34) ' names of the segments                 Ù
  26.  
  27. TYPE NODEv21 '                               ¿
  28.     y AS INTEGER '                           ³
  29.     x AS INTEGER '                           ³
  30.     acc AS INTEGER '                         ³
  31.     bak AS INTEGER '                         ³
  32.     mode AS STRING '                         ³
  33.     last AS STRING '                         ³ NODES
  34. END TYPE '                                   ³
  35. '                                            ³
  36. DIM SHARED nodeV21(34, 11) AS NODEv21 '      ³
  37. '          nodeV21(segment, node).type       ³
  38. '                                            ³
  39. DIM SHARED actualNodeWorking% ' where are we?³
  40. '                                            Ù
  41. DIM SHARED inst$(34, 11, 10) '               ¿
  42. '          inst$(segment, node, instruction) ³ INSTRUCTIONS
  43. DIM SHARED actualLineWorking% '              Ù
  44.  
  45. DIM SHARED IDEcomplains%
  46.  
  47. DIM SHARED menuHighlight% ' <----------------- MAIN MENU only
  48. DIM SHARED blink% ' <--------------------blinking CURSOR
  49. '---------------------------------------------------------------------------------------------------------Û PRE-PROGRAM Û----------------------------------------------------------------------------------------------------------
  50. FOR i% = 0 TO 33 '          ¿
  51.     segmentState%(i%) = 0 ' ³ SEGMENTS
  52. NEXT i% '                   Ù
  53. segmentState%(34) = -1 ' SANDBOX
  54.  
  55.  
  56. FOR i% = 0 TO 34 '                                  ¿
  57.     FOR j% = 0 TO 11 '                              ³
  58.         SELECT CASE j% '                            ³
  59.             CASE 0 TO 3: nodeV21(i%, j%).y = 4 '    ³
  60.             CASE 4 TO 7: nodeV21(i%, j%).y = 19 '   ³
  61.             CASE 8 TO 11: nodeV21(i%, j%).y = 34 '  ³
  62.         END SELECT '                                ³ NODES
  63.         SELECT CASE j% '                            ³ positions
  64.             CASE 0, 4, 8: nodeV21(i%, j%).x = 31 '  ³
  65.             CASE 1, 5, 9: nodeV21(i%, j%).x = 56 '  ³
  66.             CASE 2, 6, 10: nodeV21(i%, j%).x = 81 ' ³
  67.             CASE 3, 7, 11: nodeV21(i%, j%).x = 106 '³
  68.         END SELECT '                                ³
  69.     NEXT j% '                                       ³
  70. NEXT i% '                                           Ù
  71.  
  72. FOR i% = 0 TO 34 '                                 ¿
  73.     FOR j% = 0 TO 11 '                             ³
  74.         nodeV21(i%, j%).acc = 0 '                  ³
  75.         nodeV21(i%, j%).bak = 0 '                  ³ NODES
  76.         nodeV21(i%, j%).mode = "IDLE" '            ³ registers
  77.         nodeV21(i%, j%).last = "NONE" '            ³
  78.     NEXT j% '                                      ³
  79. NEXT i% '                                          Ù
  80.  
  81. FOR i% = 0 TO 34 ' setear las instrucciones a null ¿
  82.     FOR j% = 0 TO 11 '                             ³
  83.         FOR k% = 0 TO 10 '                         ³
  84.             inst$(i%, j%, k%) = "" '               ³ INSTRUCTIONS
  85.         NEXT k% '                                  ³
  86.     NEXT j% '                                      ³
  87. NEXT i% '                                          Ù
  88.  
  89. 'infect                                                                ¿
  90. 'CLS _AUTODISPLAY                                                      ³
  91. 'systemCheck                                                           ³
  92. '                                                                      ³
  93. segmentName$(0) = "SYSTEM CLOCK" '                                     ³
  94. segmentName$(1) = "MULTIPLEXER" '                                      ³ INITIALIZE (at least for testing)
  95. segmentName$(34) = "SANDBOX" '                                         ³
  96. '                                                                      ³
  97. menuHighlight% = 0 '            segment 1 is index 0 on the array      ³
  98. actualSegmentWorking% = -1 '    main menu is -1                        ³
  99. actualNodeWorking% = -1 '       on main menu no node is being operated Ù
  100. actualLineWorking% = -1
  101. IDEcomplains% = 0
  102.  
  103. '---------------------------------------------------------------------------------------------------------Û   PROGRAM   Û----------------------------------------------------------------------------------------------------------
  104. mainMenu
  105.  
  106. '---------------------------------------------------------------------------------------------------------Û SUBROUTINES Û----------------------------------------------------------------------------------------------------------
  107. SUB mainMenu () ' draws main menu and instructions on the bottom
  108.  
  109.     DIM KeyPress$
  110.  
  111.     DO
  112.         DO
  113.             _LIMIT 20
  114.             CLS
  115.             SELECT CASE actualSegmentWorking%
  116.                 CASE -2: drawSegments: UsureToLeave
  117.                 CASE -1: drawSegments
  118.                 CASE 0: inSegment_1
  119.                 CASE 1: inSegment_2
  120.                 CASE 34: sandBox
  121.  
  122.             END SELECT
  123.  
  124.             KeyPress$ = INKEY$
  125.             _DISPLAY
  126.         LOOP UNTIL KeyPress$ <> ""
  127.  
  128.         IF actualSegmentWorking% = -1 THEN '                                                                                      ¿
  129.             IF KeyPress$ = CHR$(0) + CHR$(77) AND menuHighlight% <> 34 THEN menuHighlight% = menuHighlight% + 1 '  ¿             ³
  130.             IF KeyPress$ = CHR$(0) + CHR$(75) AND menuHighlight% <> 0 THEN menuHighlight% = menuHighlight% - 1 '   ³ ARROWS for  ³ only works
  131.             IF KeyPress$ = CHR$(0) + CHR$(80) AND menuHighlight% < 28 THEN menuHighlight% = menuHighlight% + 7 '   ³ navigation  ³ in the
  132.             IF KeyPress$ = CHR$(0) + CHR$(72) AND menuHighlight% > 6 THEN menuHighlight% = menuHighlight% - 7 '    Ù             ³ main menu
  133.             IF KeyPress$ = CHR$(13) THEN actualSegmentWorking% = menuHighlight% '                              ENTER to select    ³
  134.         END IF '                                                                                                                  Ù
  135.  
  136.         IF KeyPress$ = CHR$(0) + CHR$(68) THEN actualSegmentWorking% = -2 ' F10 to ask for leaving
  137.  
  138.         IF KeyPress$ = "y" AND actualSegmentWorking% = -2 THEN SYSTEM '                     Y ¿ YES  ¿
  139.         IF KeyPress$ = CHR$(13) AND actualSegmentWorking% = -2 THEN SYSTEM '            ENTER Ù      ³ when asked
  140.         '                                                                                            ³ to leave
  141.         IF KeyPress$ = "n" AND actualSegmentWorking% = -2 THEN actualSegmentWorking% = -1 ' N ¿ NO   ³
  142.         IF KeyPress$ = CHR$(27) THEN actualSegmentWorking% = -1 '-------------------------ESC Ù      Ù
  143.     LOOP
  144.  
  146. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  147. SUB UsureToLeave ()
  148.  
  149.     COLOR WHITE
  150.     drawASCIIbox 20, 46, 34, 2, " Are you sure you wan't to leave? ", 3
  151.     LOCATE 22, 47
  152.     PRINT "        <";
  153.     COLOR YELLOW
  154.     PRINT "Y";
  155.     COLOR WHITE
  156.     PRINT ">es         <";
  157.     COLOR YELLOW
  158.     PRINT "N";
  159.     COLOR WHITE
  160.     PRINT ">o        ";
  161.  
  163. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  164. SUB displayInstructions
  165.  
  166.     DIM i%
  167.     DIM ii%
  168.  
  169.     FOR i% = 0 TO 11
  170.         FOR ii% = 0 TO 10
  171.             LOCATE nodeV21(actualSegmentWorking%, i%).y + ii% + 1, nodeV21(actualSegmentWorking%, i%).x + 1
  172.             PRINT inst$(actualSegmentWorking%, i%, ii%)
  173.         NEXT ii%
  174.     NEXT i%
  175.  
  177. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  178. SUB IDE () ' checks the instructions spelling and warns if incorrect
  179.  
  180.     DIM i%
  181.     DIM j%
  182.     DIM analyzing$
  183.     DIM opCode$
  184.     DIM subComplaint%
  185.  
  186.     FOR i% = 0 TO 11 ' for all the nodes
  187.         FOR j% = 0 TO 10 ' for all the instructions
  188.  
  189.             analyzing$ = _TRIM$(inst$(actualSegmentWorking%, i%, j%))
  190.  
  191.             IF LEN(analyzing$) THEN ' cases that are not null
  192.                 opCode$ = LEFT$(analyzing$, 3)
  193.                 IF NOT opCode$ = "NOP"_
  194.                 OR NOT opCode$ = "MOV"_
  195.                 OR NOT opCode$ = "SWP"_
  196.                 OR NOT opCode$ = "SAV"_
  197.                 OR NOT opCode$ = "ADD"_
  198.                 OR NOT opCode$ = "SUB"_
  199.                 OR NOT opCode$ = "NEG"_
  200.                 OR NOT opCode$ = "JMP"_
  201.                 OR NOT opCode$ = "JEZ"_
  202.                 OR NOT opCode$ = "JNZ"_
  203.                 OR NOT opCode$ = "JGZ"_
  204.                 OR NOT opCode$ = "JLZ"_
  205.                 OR NOT opCode$ = "JRO" THEN
  206.                     IDEcomplains% = -1
  207.                 ELSE
  208.                     IDEcomplains% = 0
  209.                 END IF
  210.  
  211.                 IF IDEcomplains% THEN
  212.                     COLOR RED
  213.                     drawASCIIbox 46, 2, 27, 1, "      INVALID  OPCODE", 2
  214.                     COLOR MIDGRAY
  215.                 END IF
  216.  
  217.             END IF
  218.         NEXT j%
  219.     NEXT i%
  220.  
  221.     '       - INSTRUCTION SET QUICK REFERENCE -
  222.     '
  223.     'NOP                       NO OPERATION
  224.     'MOV <DST>, <SRC>       MOVE <SRC> TO <DST>
  225.     'SWP                    SWAP ACC AND BAK
  226.     'SAV                    SAVE ACC TO BAK
  227.     'ADD <SRC>              ADD <SRC> TO ACC
  228.     'SUB <SRC>              SUBSTRACT <SRC> FROM ACC
  229.     'NEG                    NEGATE ACC
  230.     'JMP <LABEL>            JUMP TO <LABEL>
  231.     'JEZ <LABEL>            JUMP TO <LABEL> IF ACC = 0
  232.     'JNZ <LABEL>            JUMP TO <LABEL> IF ACC != 0
  233.     'JGZ <LABEL>            JUMP TO <LABEL> IF ACC > 0
  234.     'JLZ <LABEL>            JUMP TO <LABEL> IF ACC < 0
  235.     'JRO <SRC>              JUMP TO RELATIVE OFFSET <SRC>
  236.  
  237.  
  239. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  240. SUB sandBox () ' subroutines for each segment has the name as the user sees it (practical purposes)
  241.  
  242.     DIM keyPress$
  243.  
  244.     actualNodeWorking% = 0
  245.     actualLineWorking% = 0
  246.     DO
  247.         _LIMIT 20
  248.         CLS
  249.         drawInsideSegment 1, 1
  250.         COLOR MIDGRAY
  251.         displayInstructions
  252.         textProccesor keyPress$
  253.         IDE
  254.         keyPress$ = UCASE$(INKEY$)
  255.         _DISPLAY
  256.     LOOP UNTIL keyPress$ = CHR$(27)
  257.     actualSegmentWorking% = -1
  258.     actualNodeWorking% = -1
  259.     actualLineWorking% = -1
  260.  
  262.  
  263. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  264. SUB inSegment_1 () ' subroutines for each segment has the name as the user sees it (practical purposes)
  265.  
  266.     DIM keyPress$
  267.  
  268.     actualNodeWorking% = 0
  269.     actualLineWorking% = 0
  270.     DO
  271.         _LIMIT 20
  272.         CLS
  273.         drawInsideSegment 1, 1
  274.         COLOR MIDGRAY
  275.         displayInstructions
  276.         textProccesor keyPress$
  277.         keyPress$ = UCASE$(INKEY$)
  278.         _DISPLAY
  279.     LOOP UNTIL keyPress$ = CHR$(27)
  280.     actualSegmentWorking% = -1
  281.     actualNodeWorking% = -1
  282.     actualLineWorking% = -1
  283.  
  285.  
  286. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  287. SUB inSegment_2 () ' subroutines for each segment has the name as the user sees it (practical purposes)
  288.  
  289.     DIM keyPress$
  290.  
  291.     DO
  292.         _LIMIT 20
  293.         CLS
  294.         drawInsideSegment 2, 1
  295.         keyPress$ = INKEY$
  296.         _DISPLAY
  297.     LOOP UNTIL keyPress$ = CHR$(27)
  298.     actualSegmentWorking% = -1
  299.     actualNodeWorking% = -1
  301.  
  302. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  303. SUB drawInsideSegment (ins%, outs%) ' when you get inside a segment you see this (pass in the number of inputs and outputs)
  304.  
  305.     DIM nY%
  306.     DIM nX%
  307.     DIM i%
  308.     DIM ii%
  309.     DIM j%
  310.     DIM k%
  311.  
  312.     IF ins% > 3 THEN EXIT SUB '  ¿                Ú REM if only 1 output, you can have up to 3 inputs
  313.     IF outs% < 1 THEN EXIT SUB ' ³ check if logic ³ for  2 outputs only 1 input... video thing really,
  314.     IF outs% > 2 THEN EXIT SUB ' Ù                À ELSE overprinting
  315.  
  316.     COLOR MIDGRAY '                                                      ¿
  317.     LOCATE 2, 9 '                                                        ³ title and
  318.     PRINT "- SEGMENT "; LTRIM$(STR$(actualSegmentWorking% + 1)); " -"; ' ³ segment name
  319.     LOCATE 3, 9 '                                                        ³                  °°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  320.     'PRINT "- "; segmentName$(actualSegmentWorking%); " -" ' ------------Ù---------------- °  UNCOMMENT AFTER TESTINGS °
  321.     '                                                                                       °°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  322.     drawASCIIbox 4, 2, 25, 6, "", 2 'draw the instructions box
  323.  
  324.     FOR nY% = 4 TO 34 STEP 15 '      ¿
  325.         FOR nX% = 31 TO 106 STEP 25 '³ draw nodes at
  326.             drawNodeV21 nY%, nX% '   ³ corresponding
  327.         NEXT nX% '                   ³ position
  328.     NEXT nY% '                       Ù
  329.  
  330.     IF NOT actualSegmentWorking% = 34 THEN ' <------ NOT the SANDBOX
  331.  
  332.         IF ins% > 0 THEN '                                                ¿
  333.             ii% = 2 '                               ¿                     ³
  334.             FOR i% = 1 TO ins% '                    ³ print as many       ³
  335.                 LOCATE 13, ii% + 1 '                ³ ASCII boxes as      ³
  336.                 PRINT "IN."; CHR$(96 + i%); '       ³ inputs needed and   ³
  337.                 drawASCIIbox 14, ii%, 4, 25, "", 2 '³ a title "IN" +      ³
  338.                 ii% = ii% + 5 '                     ³ a, b, c, d...       ³
  339.             NEXT i% '                               Ù                     ³
  340.             '                                                             ³
  341.             IF ins% > 1 THEN '             ¿                              ³
  342.                 ii% = 7 '                  ³                              ³ INPUTS
  343.                 FOR i% = 1 TO ins% - 1 '   ³ correct                      ³ table
  344.                     LOCATE 14, ii% '       ³ corners                      ³
  345.                     PRINT CHR$(203); ' Ë   ³ if                           ³
  346.                     LOCATE 40, ii% '       ³ needed                       ³
  347.                     PRINT CHR$(202); ' Ê   ³                              ³
  348.                     ii% = ii% + 5 '        ³                              ³
  349.                 NEXT i% '                  ³                              ³
  350.             END IF '                       Ù                              ³
  351.         END IF '                                                          Ù
  352.  
  353.         LOCATE 13, 21 '                     ¿            ¿
  354.         PRINT "OUT.x"; '                    ³ rightmost  ³
  355.         drawASCIIbox 14, 23, 4, 25, "", 2 ' ³            ³
  356.         drawASCIIbox 14, 18, 4, 25, "", 2 ' Ù            ³
  357.         '                                                ³
  358.         LOCATE 14, 23 '      ¿                           ³
  359.         PRINT CHR$(203); ' Ë ³ corner correction         ³
  360.         LOCATE 40, 23 '      ³ for rightmost             ³
  361.         PRINT CHR$(202); ' Ê Ù                           ³
  362.         '                                                ³
  363.         IF outs% = 2 THEN ' only if asked for            ³
  364.             LOCATE 13, 11 ' ¿                            ³
  365.             PRINT "OUT.x"; '³ "OUT.y" overprinted        ³
  366.             LOCATE 13, 21 ' ³ rightmost "OUT.x"          ³ OUTPUTS
  367.             PRINT "OUT.y"; 'Ù                            ³ table
  368.             drawASCIIbox 14, 13, 4, 25, "", 2 '          ³
  369.             drawASCIIbox 14, 8, 4, 25, "", 2 '           ³
  370.             '                                            ³
  371.             LOCATE 14, 18 '      ¿                       ³
  372.             PRINT CHR$(203); ' Ë ³                       ³
  373.             LOCATE 14, 13 '      ³ corner                ³
  374.             PRINT CHR$(203); ' Ë ³ correction            ³
  375.             LOCATE 40, 18 '      ³ for                   ³
  376.             PRINT CHR$(202); ' Ê ³ both                  ³
  377.             LOCATE 40, 13 '      ³                       ³
  378.             PRINT CHR$(202); ' Ê Ù                       ³
  379.         END IF '                                         Ù
  380.  
  381.     ELSE '                                          ¿
  382.         drawASCIIbox 12, 4, 7, 1, "CONSOLE", 2 '    ³
  383.         drawASCIIbox 14, 4, 7, 23, "", 2 '          ³
  384.         drawASCIIbox 38, 4, 7, 1, ">", 2 '          ³
  385.         LOCATE 14, 4 '                              ³
  386.         PRINT CHR$(204); ' Ì                        ³
  387.         LOCATE 14, 12 '                             ³ SANDBOX
  388.         PRINT CHR$(185); ' ¹                        ³ CONSOLE
  389.         LOCATE 38, 4 '                              ³
  390.         PRINT CHR$(204); ' Ì                        ³
  391.         LOCATE 38, 12 '                             ³
  392.         PRINT CHR$(185); ' ¹                        ³
  393.     END IF '                                        Ù
  394.  
  395.     FOR k% = 9 TO 39 STEP 15 ' Y        ¿            ¿
  396.         FOR j% = 53 TO 103 STEP 25 ' X  ³            ³
  397.             LOCATE k%, j% '             ³            ³
  398.             PRINT CHR$(26); '          ³ left/right ³
  399.             LOCATE k% + 2, j% + 1 '     ³ PORTS      ³
  400.             PRINT CHR$(27); '          ³            ³
  401.         NEXT j% '                       ³            ³ PORTS
  402.     NEXT k% '                           Ù            ³ between
  403.     '                                                ³ NODES
  404.     FOR k% = 18 TO 33 STEP 15 ' Y       ¿            ³
  405.         FOR j% = 38 TO 113 STEP 25 '    ³            ³
  406.             LOCATE k%, j% '             ³ up/down    ³
  407.             PRINT CHR$(24); '          ³ PORTS      ³
  408.             LOCATE k% - 1, j% + 4 '     ³            ³
  409.             PRINT CHR$(25); '          ³            ³
  410.         NEXT j% '                       ³            ³
  411.     NEXT k% '                           Ù            Ù
  412.  
  413.     IF ins% > 0 THEN LOCATE 3, 62: PRINT "IN.a"; CHR$(25); '   ¿
  414.     IF ins% > 1 THEN LOCATE 3, 87: PRINT "IN.b"; CHR$(25); '   ³
  415.     IF ins% > 2 THEN LOCATE 3, 112: PRINT "IN.c"; CHR$(25); '  ³
  416.     '                                                          ³
  417.     IF actualSegmentWorking% = 34 THEN '         ¿             ³
  418.         LOCATE 3, 61: PRINT "CNS.a"; CHR$(25); ' ³ SANDBOX     ³
  419.     END IF '                                     Ù             ³ IN/OUT
  420.     '                                                          ³ ports
  421.     LOCATE 47, 87 '                                            ³
  422.     IF NOT actualSegmentWorking% = 34 THEN '                   ³
  423.         PRINT "OUT.x"; CHR$(25); '                             ³
  424.     ELSE '                                                     ³
  425.         PRINT "CNS.x"; CHR$(25); ' <---------SANDBOX           ³
  426.     END IF '                                                   ³
  427.     IF outs% > 1 THEN LOCATE 47, 62: PRINT "OUT.y"; CHR$(25); 'Ù
  428.  
  429.     drawASCIIbox 41, 4, 2, 1, (CHR$(16) + CHR$(16)), 1 '    ¿
  430.     drawASCIIbox 41, 14, 2, 1, (CHR$(124) + CHR$(16)), 1 '  ³
  431.     drawASCIIbox 41, 24, 2, 1, (CHR$(219) + CHR$(219)), 1 ' ³
  432.     LOCATE 44, 3 '                                          ³
  433.     PRINT "F5 Run"; '                                       ³
  434.     LOCATE 44, 12 '                                         ³ BUTTONS
  435.     PRINT "F6 Step"; '                                      ³
  436.     LOCATE 44, 22 '                                         ³
  437.     PRINT "F8 Stop"; '                                      ³
  438.     COLOR DARKGRAY '                                        ³
  439.     LOCATE 45, 9 '                                          ³
  440.     PRINT "ESC to go back"; '                               Ù
  441.  
  443. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  444. SUB textProccesor (key$)
  445.  
  446.     blink% = blink% - 16 '                                                                                                               ¿
  447.     IF blink% < 0 THEN blink% = 255 '                                                                                                    ³
  448.     COLOR _RGB32(blink%, blink%, blink%) '                                                                                               ³ CURSOR
  449.     LOCATE nodeV21(actualSegmentWorking%, actualNodeWorking%).y + actualLineWorking% + 1,_
  450.     nodeV21(actualSegmentWorking%, actualNodeWorking%).x + LEN(inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%)) + 1'³
  451.     PRINT CHR$(219) '                                                                                                                    Ù
  452.  
  453.     IF LEN(key$) THEN ' B+ avoided the null =)
  454.  
  455.         IF LEN(inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%)) < 13 THEN ' ¿ PRINTABLE
  456.             IF ASC(key$) > 31 AND ASC(key$) < 127 THEN '                                         ³ CHARACTERS
  457.                 inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%) =_
  458.                 inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%) + key$ '    ³ can't write more than
  459.             END IF '                                                                             ³ 13 characters
  460.         END IF '                                                                                 Ù
  461.  
  462.         IF ASC(key$) = 8 THEN '                                                                             ¿  BACKSPACE
  463.             inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%) =_
  464.             LEFT$(inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%),_
  465.             LEN(inst$(actualSegmentWorking%, actualNodeWorking%, actualLineWorking%)) - 1) '                ³
  466.         END IF '                                                                                            Ù
  467.  
  468.         IF ASC(key$) = 13 AND actualLineWorking% < 10 AND inst$(actualSegmentWorking%, actualNodeWorking%, 10) = "" THEN '¿
  469.             actualLineWorking% = actualLineWorking% + 1 '                                                                 ³ ENTER
  470.         END IF '                                                                                                          Ù
  471.  
  472.         IF ASC(key$) = 9 THEN '                               ¿
  473.             IF actualNodeWorking% < 11 THEN '                 ³
  474.                 actualNodeWorking% = actualNodeWorking% + 1 ' ³
  475.             ELSE '                                            ³ TAB
  476.                 actualNodeWorking% = 0 '                      ³
  477.             END IF '                                          ³
  478.             actualLineWorking% = 0 '                          ³
  479.         END IF '                                              Ù
  480.  
  481.     END IF ' B+ avoid null ; -) U2pro bro
  482.  
  483.     IF key$ = CHR$(0) + CHR$(72) AND actualLineWorking% > 0 THEN ' UP        ¿
  484.         actualLineWorking% = actualLineWorking% - 1 '                        ³
  485.     ELSEIF key$ = CHR$(0) + CHR$(80) AND actualLineWorking% < 10 THEN 'DOWN  ³ ARROWS
  486.         actualLineWorking% = actualLineWorking% + 1 '                        ³
  487.     END IF '                                                                 Ù
  488.  
  489.  
  491.  
  492. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  493. SUB infect () ' virus intro sketch... base under attack!
  494.  
  495.     DIM row%
  496.     DIM column%
  497.     DIM message1$
  498.     DIM message2$
  499.     DIM i%
  500.     DIM ii%
  501.     DIM loadingBar$
  502.  
  503.     row% = 20
  504.     column% = 52
  505.     message1$ = "I'm taking control..."
  506.     message2$ = "And you can't stop me"
  507.  
  508.     'sayHello
  509.     COLOR GREEN '                                    ¿ try to
  510.     PRINTslowly row% + 3, column% + 2, message1$, 1 '³ psychopatiate
  511.     PRINTslowly row% + 4, column% + 2, message2$, 1 'Ù the user
  512.     SLEEP 1
  513.  
  514.     'install
  515.     i% = 0
  516.     ii% = 0
  517.     loadingBar$ = CHR$(219)
  518.     DO
  519.         _LIMIT 500
  520.         i% = i% + 1
  521.         ii% = INT(i% / 100)
  522.  
  523.         COLOR MIDGRAY '                             ¿
  524.         LOCATE RND(1) * 47 + 1, RND(1) * 127 + 1 '  ³ random characthers on the back
  525.         PRINT CHR$(RND(1) * 222 + 32); '            Ù
  526.  
  527.         COLOR GREEN '    a virus is GREEN!       ¿
  528.         '                                         ³ draw box and
  529.         drawASCIIbox row%, column%, 23, 7, "", 2 '³ CLS inside it
  530.         '                                         ³ (don't erease back)
  531.         fakeCLS row% + 1, column% + 1, 22, 6 '    Ù
  532.  
  533.         IF ii% MOD 2 = 0 THEN '                   ¿
  534.             LOCATE row% + 1, column% + 2 '        ³ blink: title
  535.             PRINT "CV64 VIRUS V0.2  >:-["; '      ³ underline
  536.             LOCATE row% + 2, column% + 2 '        ³ message1$
  537.             PRINT STRING$(21, CHR$(223)); '       ³ and
  538.             '                                     ³ message2$
  539.             LOCATE row% + 3, column% + 2 '        ³
  540.             PRINT message1$; '                    ³
  541.             '                                     ³
  542.             LOCATE row% + 4, column% + 2 '        ³
  543.             PRINT message2$; '                    ³
  544.         END IF '                                  Ù
  545.  
  546.         LOCATE row% + 6, column% + 2 '                              ¿
  547.         IF ii% < 20 THEN PRINT "Overriding OS..."; '                ³
  548.         IF ii% < 40 AND ii% > 19 THEN PRINT "Accesing files..."; '  ³ loading messages
  549.         IF ii% < 60 AND ii% > 39 THEN PRINT "Infecting..."; '       ³
  550.         IF ii% < 80 AND ii% > 59 THEN PRINT "Replicating..."; '     ³
  551.         IF ii% < 100 AND ii% > 79 THEN PRINT "Ereasing nodes..."; ' ³
  552.         IF ii% = 100 THEN PRINT "Nodes killed "; '                 Ù
  553.  
  554.         ii$ = LTRIM$(STR$(ii%)) '                   ¿
  555.         LOCATE row% + 6, column% + 22 - LEN(ii$) '  ³ xx%
  556.         PRINT ii$ + "%"; '                          Ù
  557.  
  558.         IF i% MOD 500 = 0 THEN loadingBar$ = loadingBar$ + CHR$(219) ' ¿
  559.         LOCATE row% + 7, column% + 2 '                                 ³ loading bar
  560.         PRINT loadingBar$; '                                           Ù
  561.         _DISPLAY
  562.     LOOP UNTIL i% = 10000
  563.     SLEEP 2 '                                       infection complete XD
  564.  
  566.  
  567. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  568. SUB systemCheck () ' fake system check as excuse to go at main menu
  569.  
  570.     DIM i&
  571.  
  572.     COLOR LIGHTGRAY
  573.     PRINTslowly 2, 2, "Unexpected restart. Running system check...", 1
  574.     FOR i& = 0 TO 247483647 STEP 2048
  575.         _LIMIT 20000
  576.         LOCATE 4, 2
  577.         PRINT "CHECKSUM: ";: PRINT LTRIM$(STR$(i&));
  578.     NEXT i&
  579.     PRINT " OK"
  580.     PRINTslowly 6, 2, "Nodes have been corrupted...", 1
  581.     PRINTslowly 8, 2, "Reprogram them to recover access to OS...", 1
  582.     PRINTslowly 10, 2, "Please, don't shut down the equipment until reprogramming is over", 1
  583.     PRINTslowly 11, 2, "or all system data won't be able to recover...", 0
  584.     PRINTslowly 13, 2, "Starting debbuger", 1
  585.     SLEEP 2
  586.  
  588.  
  589. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  590. SUB drawSegments () ' draw the segment on the main menu
  591.  
  592.     DIM i%
  593.     DIM y%
  594.     DIM x%
  595.     DIM yy%
  596.     DIM xx%
  597.     DIM segmentNumber$
  598.  
  599.     i% = -1
  600.  
  601.     FOR y% = 3 TO 39 STEP 9
  602.         FOR x% = 4 TO 112 STEP 18
  603.  
  604.             i% = i% + 1 ' node index number, start -1 to make it 0 here for the array
  605.             '              we add another +1 later to make em look like start at 1
  606.             COLOR DARKGRAY '                                  ¿
  607.             FOR yy% = 2 TO 5 '                                ³
  608.                 FOR xx% = 1 TO 11 '                           ³ if node is broke
  609.                     LOCATE y% + yy%, x% + xx% '               ³ random characters
  610.                     IF NOT segmentState%(i%) THEN '           ³
  611.                         PRINT CHR$(RND(1) * 200 + 32); '      ³ if fixed by
  612.                     ELSE '                                    ³ user then
  613.                         PRINT LTRIM$(STR$(_ROUND(RND))); '    ³ plain 1's and 0's
  614.                     END IF '                                  ³
  615.                 NEXT xx% '                                    ³
  616.             NEXT yy% '                                        Ù
  617.  
  618.             IF i% > 8 THEN '                                  ¿ the shown number
  619.                 segmentNumber$ = LTRIM$(STR$(i% + 1)) '       ³ of the segment,
  620.             ELSE '                                            ³ avoiding the
  621.                 segmentNumber$ = " " + LTRIM$(STR$(i% + 1)) ' ³ spaces if
  622.             END IF '                                          Ù two digits
  623.  
  624.             IF menuHighlight% = i% THEN ' ¿
  625.                 COLOR WHITE '             ³ show WHITE if
  626.             ELSE '                        ³ selected, else
  627.                 COLOR MIDGRAY '           ³ is MIDGRAY
  628.             END IF '                      Ù
  629.  
  630.             drawASCIIbox y%, x%, 11, 5, " SEGMENT" + segmentNumber$, 1 ' draw the box
  631.  
  632.             LOCATE 40, 113: PRINT "  SANDBOX  "; ' <---------------SANDBOX CASE (overprinted over SEGMENT 35)
  633.  
  634.             LOCATE y% + 3, x% + 2 '     ¿
  635.             IF segmentState%(i%) THEN ' ³ accordingly to
  636.                 COLOR MIDGRAY, GREEN '  ³ segmentState%()
  637.                 PRINT "-NOMINAL-" '     ³ draw -NOMINAL-
  638.             ELSE '                      ³ or   - ERROR -
  639.                 COLOR BLACK, RED '      ³
  640.                 PRINT " -ERROR- " '     ³
  641.             END IF '                    Ù
  642.  
  643.             COLOR , BLACK '  don't conflictuate other stuff
  644.  
  645.         NEXT x%
  646.     NEXT y%
  647.  
  648.     drawMainInstructions
  649.  
  651.  
  652. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  653. SUB drawMainInstructions () ' draws a single blue line with some instruction on it at the bottom of the screen
  654.  
  655.     DIM ii%
  656.  
  657.     COLOR YELLOW, BLUE
  658.  
  659.     FOR ii% = 1 TO 127 '   ¿
  660.         LOCATE 48, ii% '   ³ blue background
  661.         PRINT " "; '       ³ line at bottom
  662.     NEXT ii% '             Ù
  663.  
  664.     LOCATE 48, 25 '             ¿
  665.     PRINT "F1 Help"; '          ³
  666.     LOCATE 48, 43 '             ³ options in
  667.     PRINT "ARROWS Navigate"; '  ³ the main menu
  668.     LOCATE 48, 71 '             ³
  669.     PRINT "ENTER Select"; '     ³
  670.     LOCATE 48, 92 '             ³
  671.     PRINT "F10 Save and Exit"; 'Ù
  672.  
  673.     COLOR , BLACK ' don't conflictuate with other things
  674.  
  676.  
  677. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  678. SUB drawNodeV21 (nodeY%, nodeX%)
  679.  
  680.     DIM i%
  681.  
  682.     FOR i% = 0 TO 11 '                                                                               ¿
  683.         COLOR DARKGRAY '                                                                             ³
  684.         LOCATE nodeV21(actualSegmentWorking%, i%).y + 2, nodeV21(actualSegmentWorking%, i%).x + 16 ' ³
  685.         PRINT nodeV21(actualSegmentWorking%, i%).acc; '                                              ³ show
  686.         LOCATE nodeV21(actualSegmentWorking%, i%).y + 5, nodeV21(actualSegmentWorking%, i%).x + 16 ' ³ information
  687.         PRINT nodeV21(actualSegmentWorking%, i%).bak; '                                              ³ of node
  688.         LOCATE nodeV21(actualSegmentWorking%, i%).y + 8, nodeV21(actualSegmentWorking%, i%).x + 16 ' ³ registers
  689.         PRINT nodeV21(actualSegmentWorking%, i%).mode; '                                             ³ (acc, bak,
  690.         LOCATE nodeV21(actualSegmentWorking%, i%).y + 11, nodeV21(actualSegmentWorking%, i%).x + 16 '³ mode, last)
  691.         PRINT nodeV21(actualSegmentWorking%, i%).last; '                                             ³
  692.     NEXT i% '                                                                                        Ù
  693.  
  694.     COLOR MIDGRAY
  695.  
  696.     drawASCIIbox nodeY%, nodeX%, 14, 11, "", 1 ' user input instructions box
  697.     drawASCIIbox nodeY%, nodeX% + 15, 4, 2, "ACC", 1 '     ¿
  698.     drawASCIIbox nodeY% + 3, nodeX% + 15, 4, 2, "BAK", 1 ' ³ box over
  699.     drawASCIIbox nodeY% + 6, nodeX% + 15, 4, 2, "MODE", 1 '³ box
  700.     drawASCIIbox nodeY% + 9, nodeX% + 15, 4, 2, "LAST", 1 'Ù
  701.  
  702.     LOCATE nodeY%, nodeX% + 15 '            ¿
  703.     PRINT CHR$(194); ' Â                    ³
  704.     LOCATE nodeY% + 12, nodeX% + 15 '       ³
  705.     PRINT CHR$(193); ' Á                    ³
  706.     '                                       ³ then correct
  707.     FOR i% = 3 TO 9 STEP 3 '                ³ the corners
  708.         LOCATE nodeY% + i%, nodeX% + 15 '   ³ nedded
  709.         PRINT CHR$(195); ' Ã                ³
  710.     NEXT i% '                               ³ (the usual
  711.     '                                       ³ deciving)
  712.     FOR i% = 3 TO 9 STEP 3 '                ³
  713.         LOCATE nodeY% + i%, nodeX% + 20 '   ³
  714.         PRINT CHR$(180); ' ´                ³
  715.     NEXT i% '                               Ù
  716.  
  718.  
  719. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  720. SUB PRINTslowly (originY%, originX%, message$, preBlink%)
  721.  
  722.     DIM i%
  723.     DIM buildingMessage$
  724.  
  725.     IF originY% < 1 THEN EXIT SUB '     ¿ check if logic
  726.     IF originX% < 1 THEN EXIT SUB '     Ù
  727.  
  728.     IF preBlink% = 1 THEN PCthinking originY%, originX% ' wanna see some blinking before start writing?
  729.  
  730.     i% = 0 '                                                Ä¿
  731.     DO '                                                     ³
  732.         _DELAY .05 '                                         ³
  733.         i% = i% + 1 '                                        ³ print message$
  734.         buildingMessage$ = LEFT$(message$, i%) + CHR$(219) ' ³ character by character
  735.         LOCATE originY%, originX% '                          ³ and erease the cursor
  736.         PRINT buildingMessage$; '                            ³
  737.     LOOP UNTIL LEN(buildingMessage$) = LEN(message$) + 1 '  ÄÙ
  738.  
  739.     LOCATE CSRLIN, originX% + LEN(message$): PRINT " "; ' erease cursor
  740.  
  742.  
  743. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  744. SUB PCthinking (originY%, originX%)
  745.  
  746.     DIM i%
  747.  
  748.     IF originY% < 1 THEN EXIT SUB '     ¿ check if logic
  749.     IF originX% < 1 THEN EXIT SUB '     Ù
  750.  
  751.     FOR i% = 1 TO 11 '                  ¿
  752.         _LIMIT 5 '                      ³
  753.         LOCATE originY%, originX% '     ³
  754.         IF i% MOD 2 = 0 THEN '          ³ bliking cursor
  755.             PRINT CHR$(219); '          ³
  756.         ELSE '                          ³
  757.             PRINT " "; '                ³
  758.         END IF '                        ³
  759.     NEXT i% '                           Ù
  760.  
  762.  
  763. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  764. SUB fakeCLS (originY%, originX%, width%, height%)
  765.  
  766.     DIM y%
  767.     DIM x%
  768.  
  769.     IF originY% < 1 THEN EXIT SUB '               ¿
  770.     IF originX% < 1 THEN EXIT SUB '               ³ check if logic
  771.     IF width% < 1 THEN EXIT SUB '                 ³
  772.     IF height% < 1 THEN EXIT SUB '                Ù
  773.  
  774.     FOR x% = 0 TO width% '                        ¿
  775.         FOR y% = 0 TO height% '                   ³ print
  776.             LOCATE originY% + y%, originX% + x% ' ³ " " (space)
  777.             PRINT " "; '                          ³ repeatedly
  778.         NEXT y% '                                 ³
  779.     NEXT x% '                                     Ù
  780.  
  782.  
  783. '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  784. SUB drawASCIIbox (originY%, originX%, width%, height%, message$, style%)
  785.  
  786.     DIM char%
  787.     DIM char1%
  788.     DIM char2%
  789.     DIM y%
  790.     DIM x%
  791.  
  792.     IF originY% < 1 OR originX% < 1 THEN EXIT SUB '     ÄÄÄ¿
  793.     IF width% < 1 OR height% < 1 THEN EXIT SUB '           ³ check if logic
  794.     IF style% < 1 OR style% > 3 THEN EXIT SUB '         ÄÄÄÙ
  795.  
  796.     LOCATE originY%, originX% '                         ÄÄÄ¿
  797.     IF style% = 1 THEN PRINT CHR$(218); 'Ú                 ³
  798.     IF style% = 2 THEN PRINT CHR$(201); ' É   up,left      ³
  799.     '                                                      ³
  800.     LOCATE originY% + height% + 1, originX% '              ³
  801.     IF style% = 1 THEN PRINT CHR$(192); ' À                ³
  802.     IF style% = 2 THEN PRINT CHR$(200); ' È  down, left    ³ corners
  803.     '                                                      ³
  804.     LOCATE originY%, originX% + width% + 1 '               ³
  805.     IF style% = 1 THEN PRINT CHR$(191); ' ¿                ³
  806.     IF style% = 2 THEN PRINT CHR$(187); ' » up, right      ³
  807.     '                                                      ³
  808.     LOCATE originY% + height% + 1, originX% + width% + 1 ' ³
  809.     IF style% = 1 THEN PRINT CHR$(217); ' Ù                ³
  810.     IF style% = 2 THEN PRINT CHR$(188); ' ¼ down, right ÄÄÄÙ
  811.  
  812.     IF style% = 1 THEN char% = 179 ' ³                  ÄÄÄ¿
  813.     IF style% = 2 THEN char% = 186 ' º  determinate style  ³
  814.     IF style% = 3 THEN char% = 219 ' Û                     ³
  815.     FOR y% = 1 TO height% '                                ³
  816.         LOCATE originY% + y%, originX% ' locate and print  ³ sides
  817.         PRINT CHR$(char%); '                               ³
  818.         LOCATE originY% + y%, originX% + width% + 1 '      ³
  819.         PRINT CHR$(char%); '                               ³
  820.     NEXT y% '                                           ÄÄÄÙ
  821.  
  822.     IF style% < 3 THEN ' styles 1 and 2                 ÄÄÄ¿
  823.         IF style% = 1 THEN char% = 196 ' Ä                 ³
  824.         IF style% = 2 THEN char% = 205 ' Í                 ³
  825.         FOR x% = 1 TO width% '                             ³
  826.             LOCATE originY%, originX% + x% '               ³
  827.             PRINT CHR$(char%); '                           ³
  828.             LOCATE originY% + height% + 1, originX% + x% ' ³
  829.             PRINT CHR$(char%); '                           ³ top &
  830.         NEXT x% '                                          ³ bottom
  831.     ELSE ' special case of style 3                         ³
  832.         char1% = 220 ' Ü                                   ³
  833.         char2% = 223 ' ß                                   ³
  834.         FOR x% = 0 TO width% + 1 '                         ³
  835.             LOCATE originY%, originX% + x% '               ³
  836.             PRINT CHR$(char1%); '                          ³
  837.             LOCATE originY% + height% + 1, originX% + x% ' ³
  838.             PRINT CHR$(char2%); '                          ³
  839.         NEXT x% '                                          ³
  840.     END IF '                                            ÄÄÄÙ
  841.  
  842.     LOCATE originY% + 1, originX% + 1 '                 ÄÄÄ¿ message
  843.     PRINT message$; '                                   ÄÄÄÙ
  844.  
  846.  
  847.  

textProccesor() could have some improvement, but for the moment it acomplish its work
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Trying to imitate TIS-100
« Reply #31 on: September 10, 2020, 11:38:24 pm »
String those 3 letter guys up with some char like * after each including the last.
 StrungUp3LetterGuys$ = "NOP*MOV*SWP*..... JRO*"

Match$ =  LEFT$(analyzing$, 3) + "*"

find = INSTR(StrungUp3LetterGuys$, Match$)

if find then no complaints else complain
« Last Edit: September 10, 2020, 11:41:25 pm by bplus »
Logged
Pages: 1 2 [3]   Go Up
« previous next »