Body Tree

[bplus]

Has anyone seen this before (besides Aurel)? We played with it for awhile at BP.org 2015 or 2016.

Code: QB64: [Select]

1. _TITLE "Body Tree recursive fill"
2. 'BodyTree recur fill.bas for SmallBASIC [B+=MGA] 2016-06-20
3. 'copied and translated from body tree by PeterMaria
4. '2016-06-20 even more color mods including using triangle fills
5. ' 2020-08-11 trans to QB64
6.  
7. CONST xmax = 1200, ymax = 700
8.  
9. SCREEN _NEWIMAGE(xmax, ymax, 32)
10. _DELAY .25
11. _SCREENMOVE _MIDDLE
12.  
13.  
14. DIM SHARED limit
15. limit = 14
16.  
17. 'sky
18. COLOR 0, _RGB32(40, 100, 180): CLS
19.  
20. 'the hill for tree
21. ax0 = xmax / 2 - ymax / 10
22. ay0 = ymax - 40
23. bx0 = xmax / 2 + ymax / 10
24.  
25. 'hill
26. FOR r = xmax / 1.5 TO 2 * xmax / 15 STEP -10
27.     EllipseFill xmax / 2, ay0, r, .15 * r, _RGB32(0, r / 5, 0)
28.     'circle , .1, rgb(0, r / 5, 0) filled
29. NEXT
30.  
31. 'tree
32. BodyTree ax0, ay0, bx0, ay0, 0
33. SLEEP
34.  
35.  
36. SUB BodyTree (ax, ay, bx, by, rc)
37.     DIM k AS _UNSIGNED LONG
38.     cx = ax - ay + by
39.     cy = ax + ay - bx
40.     dx = bx + by - ay
41.     dy = ax - bx + by
42.     ex = 0.5 * (cx - cy + dx + dy)
43.     ey = 0.5 * (cx + cy - dx + dy)
44.     k = _RGB32((15 - rc) * 8, 64 + rc * 8, .25 * (15 - rc) * 12)
45.     ftri cx, cy, ax, ay, bx, by, k
46.     ftri bx, by, dx, dy, cx, cy, k
47.     ftri cx, cy, dx, dy, ex, ey, k
48.     IF rc < limit THEN
49.         BodyTree cx, cy, ex, ey, rc + 1
50.         BodyTree ex, ey, dx, dy, rc + 1
51.     END IF
52. END SUB
53.  
54.  
55. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
56.     DIM D AS LONG
57.     STATIC a&
58.     D = _DEST
59.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
60.     _DEST a&
61.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
62.     PSET (0, 0), K
63.     _BLEND a& '<<<< new 2019-12-16 fix
64.     _DEST D
65.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
66. END SUB
67.  
68. SUB EllipseFill (CX AS INTEGER, CY AS INTEGER, a AS INTEGER, b AS INTEGER, C AS _UNSIGNED LONG)
69.     ' CX = center x coordinate
70.     ' CY = center y coordinate
71.     '  a = semimajor axis
72.     '  b = semiminor axis
73.     '  C = fill color
74.     IF a = 0 OR b = 0 THEN EXIT SUB
75.     DIM h2 AS _INTEGER64
76.     DIM w2 AS _INTEGER64
77.     DIM h2w2 AS _INTEGER64
78.     DIM x AS INTEGER
79.     DIM y AS INTEGER
80.     w2 = a * a
81.     h2 = b * b
82.     h2w2 = h2 * w2
83.     LINE (CX - a, CY)-(CX + a, CY), C, BF
84.     DO WHILE y < b
85.         y = y + 1
86.         x = SQR((h2w2 - y * y * w2) \ h2)
87.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
88.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
89.     LOOP
90. END SUB
91.  
92.  
93.  
94.  

[Aurel]

Maybe ...i doubt that people from here visit bp.org forum.
Looking into Ashish algos i figured that is possible to make some fractals without recursion and without
subroutines/functions ...but this one hmmm..i can try only...

[bplus]

I have a bunch of versions including non recursive and your (Aurel's) Cherry Tree one.

I reworked the code from scratch and can draw an animation now. Paul Dunn was first to show one of those, blew my mind at time:

Code: QB64: [Select]

1. _TITLE "BodyTree Rework 2020-08" 'b+ 2020-08-14
2. 'BodyTree recur fill.bas for SmallBASIC [B+=MGA] 2016-06-20
3. 'copied and translated from body tree by PeterMaria
4. '2016-06-20 even more color mods including using triangle fills
5. ' 2020-08-11 trans to QB64
6. ' 2020-08-14 rework the recursive sub so can flex the body tree
7.  
8. CONST xmax = 1200, ymax = 700
9.  
10. SCREEN _NEWIMAGE(xmax, ymax, 32)
11. _DELAY .25
12. _SCREENMOVE _MIDDLE
13.  
14.  
15. DIM SHARED limit, ra
16. limit = 14
17. ra = _PI / -4 '45 degrees is standard angle for roof
18.  
19. 'sky
20. COLOR 0, _RGB32(40, 100, 180): CLS
21.  
22. 'the hill for tree
23. ax0 = xmax / 2 - ymax / 10
24. ay0 = ymax - 40
25. bx0 = xmax / 2 + ymax / 10
26.  
27.  
28. FOR ra = 0 TO _PI / 3.7 STEP _PI / 64
29.     CLS
30.     level = 0
31.     'hill
32.     FOR r = xmax / 1.5 TO 2 * xmax / 15 STEP -10
33.         EllipseFill xmax / 2, ay0, r, .15 * r, _RGB32(0, r / 5, 0)
34.         'circle , .1, rgb(0, r / 5, 0) filled
35.     NEXT
36.  
37.     'tree
38.     BodyTree ax0, ay0, bx0, ay0, level
39.     _DISPLAY
40.     _LIMIT 5
41. NEXT
42. SLEEP
43.  
44. SUB BodyTree (x1, y1, x2, y2, level)
45.     'dim shared ra = roof angle 0 to PI/4
46.     L = _HYPOT(x2 - x1, y2 - y1)
47.     pa = _ATAN2(y2 - y1, x2 - x1) - _PI / 2 'perpendicular angle to base line
48.     x3 = x1 + L * COS(pa)
49.     y3 = y1 + L * SIN(pa)
50.     x4 = x2 + L * COS(pa)
51.     y4 = y2 + L * SIN(pa)
52.     'build roof to square
53.     mx = (x3 + x4) / 2
54.     my = (y3 + y4) / 2
55.     adj = _HYPOT(x3 - mx, y3 - my)
56.     raise = TAN(ra) * adj
57.     x5 = mx + raise * COS(pa)
58.     y5 = my + raise * SIN(pa)
59.  
60.     'now that we have our drawing points draw our house
61.     'LINE (x2, y2)-(x1, y1), &HFFFFFFFF 'house base
62.     'LINE (x1, y1)-(x3, y3), &HFFFFFFFF ' left wall
63.     'LINE (x3, y3)-(x5, y5), &HFFFFFFFF 'left peak
64.     'LINE (x5, y5)-(x4, y4), &HFFFFFFFF ' right peak
65.     'LINE (x4, y4)-(x2, y2), &HFFFFFFFF ' right wall completes house
66.  
67.     k = _RGB32((15 - level) * 8, 64 + level * 8, .25 * (15 - level) * 12, 255 - level * 18)
68.     ftri x1, y1, x2, y2, x3, y3, k
69.     ftri x2, y2, x3, y3, x4, y4, k
70.     ftri x3, y3, x4, y4, x5, y5, k
71.  
72.     IF level < limit THEN
73.         BodyTree x3, y3, x5, y5, level + 1
74.         BodyTree x5, y5, x4, y4, level + 1
75.     END IF
76. END SUB
77.  
78.  
79. SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
80.     DIM D AS LONG
81.     STATIC a&
82.     D = _DEST
83.     IF a& = 0 THEN a& = _NEWIMAGE(1, 1, 32)
84.     _DEST a&
85.     _DONTBLEND a& '  '<<<< new 2019-12-16 fix
86.     PSET (0, 0), K
87.     _BLEND a& '<<<< new 2019-12-16 fix
88.     _DEST D
89.     _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
90. END SUB
91.  
92. SUB EllipseFill (CX AS INTEGER, CY AS INTEGER, a AS INTEGER, b AS INTEGER, C AS _UNSIGNED LONG)
93.     ' CX = center x coordinate
94.     ' CY = center y coordinate
95.     '  a = semimajor axis
96.     '  b = semiminor axis
97.     '  C = fill color
98.     IF a = 0 OR b = 0 THEN EXIT SUB
99.     DIM h2 AS _INTEGER64
100.     DIM w2 AS _INTEGER64
101.     DIM h2w2 AS _INTEGER64
102.     DIM x AS INTEGER
103.     DIM y AS INTEGER
104.     w2 = a * a
105.     h2 = b * b
106.     h2w2 = h2 * w2
107.     LINE (CX - a, CY)-(CX + a, CY), C, BF
108.     DO WHILE y < b
109.         y = y + 1
110.         x = SQR((h2w2 - y * y * w2) \ h2)
111.         LINE (CX - x, CY + y)-(CX + x, CY + y), C, BF
112.         LINE (CX - x, CY - y)-(CX + x, CY - y), C, BF
113.     LOOP
114. END SUB
115.  
116.  
117.  
118.  

[bplus]

Hey Aurel, I sweetened the cherries of your Tree a bit!

Code: QB64: [Select]

1. _TITLE "Mod Aurel Mod of Java Cherry Tree" ' b+ 2020-08-14
2. 'bodytree by Aurel /java
3. 'mods 2016-06-26 for SmallBASIC 0.12.6 [B+=MGA]
4. 'float limit
5. ' 2020-08-14 bring to QB64 trans as is leave original code lines not using commented
6.  
7. DIM SHARED limit
8. limit = 7 'wcolor 0,0,0  frontpen 220,200,0
9. 'print 10,10,"Java Cherry Tree"
10. SCREEN _NEWIMAGE(800, 600, 32)
11. _DELAY .25
12. _SCREENMOVE _MIDDLE
13. drawtree 800 / 2 - 800 / 12, 600 - 40, 800 / 2 + 800 / 12, 600 - 40, 1
14. 'pause
15. SLEEP
16.  
17. SUB drawtree (x1, y1, x2, y2, depth)
18.     'float dx,dy,x3,y3,x4,y4,x5,y5
19.     'local dx,dy, x3,y3, x4,y4, x5,y5
20.     dx = x2 - x1
21.     dy = y1 - y2
22.  
23.     x3 = x2 - dy
24.     y3 = y2 - dx
25.     x4 = x1 - dy
26.     y4 = y1 - dx
27.     x5 = x4 + 0.5 * (dx - dy)
28.     y5 = y4 - 0.5 * (dx + dy)
29.  
30.     'square
31.     'frontpen 220,200,0
32.     IF depth = 1 THEN LINE (x1, y1)-(x2, y2)
33.     LINE (x2, y2)-(x3, y3)
34.     'line x3,y3,x4,y4
35.     LINE (x4, y4)-(x1, y1)
36.     'trinagle
37.     'frontpen 0,160,0
38.     'line x3,y3,x4,y4 '<<<<<<<<<<<< just leave out
39.     'line x4,y4,x5,y5
40.     'frontpen 220,120,0
41.     ' just at the end
42.     IF depth = limit THEN
43.         LINE (x4, y4)-(x5, y5)
44.         LINE (x3, y3)-(x4, y4)
45.         'circle x5, y5, 4, 1, 12 filled
46.         FOR r = 0 TO 6 STEP .2
47.             CIRCLE (x5, y5), r, _RGB32(255 - 25 * r, 0, 0)
48.         NEXT
49.     END IF
50.  
51.     IF depth < limit THEN
52.         drawtree x4, y4, x5, y5, depth + 1
53.         drawtree x5, y5, x3, y3, depth + 1
54.  
55.     END IF
56.  
57. END SUB
58.  
59.  
60.  

[SierraKen]

These are incredible.

[Aurel]

That is really nice Mark !!!

[Ashish]

Some great fractal tree there...

Here's my version which I coded sometime ago.

1. Simple tree with changing base-angle

Code: QB64: [Select]

1. 'Coded By Ashish with <3
2. _TITLE "Fractal_Trees"
3. SCREEN _NEWIMAGE(800, 600, 32)
4. radius = 130
5. DO
6.     CLS
7.     drawTree 400, 400, radius, _PI(3 / 2), s
8.     internalp5line 400, 600, 400, 400, radius / 10, _RGB(160, 10, 10)
9.     _DISPLAY
10.     _LIMIT 40
11.     s = ABS(SIN(v#)) * 0.25 + 0.2
12.     v# = v# + 0.01
13. LOOP
14. SLEEP
15.  
16. SUB drawTree (x, y, r, a, s)
17.     IF r < 18 AND r > 3 THEN c~& = _RGB(10, 200, 10) ELSE c~& = _RGB(160, 10, 10)
18.     IF r < 3 THEN c~& = _RGB(200, 0, 200)
19.     internalp5line x, y, x + r * COS(a - s), y + r * SIN(a - s), r / 10, c~&
20.     internalp5line x, y, x + r * COS(a + s * 3), y + r * SIN(a + s * 3), r / 10, c~&
21.  
22.     IF r > 2 THEN
23.         drawTree x + r * COS(a - s), y + r * SIN(a - s), r * 0.67, a - s, s
24.         drawTree x + r * COS(a + s * 3), y + r * SIN(a + s * 3), r * 0.67, a + s * 3, s
25.     END IF
26.  
27. END SUB
28.  
29. SUB CircleFill (CX AS LONG, CY AS LONG, R AS LONG, C AS _UNSIGNED LONG)
30.     'This sub from here: http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1848.msg17254#msg17254
31.     DIM Radius AS LONG
32.     DIM RadiusError AS LONG
33.     DIM X AS LONG
34.     DIM Y AS LONG
35.  
36.     Radius = ABS(R)
37.     RadiusError = -Radius
38.     X = Radius
39.     Y = 0
40.  
41.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
42.  
43.     ' Draw the middle span here so we don't draw it twice in the main loop,
44.     ' which would be a problem with blending turned on.
45.     LINE (CX - X, CY)-(CX + X, CY), C, BF
46.  
47.     WHILE X > Y
48.  
49.         RadiusError = RadiusError + Y * 2 + 1
50.  
51.         IF RadiusError >= 0 THEN
52.  
53.             IF X <> Y + 1 THEN
54.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
55.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
56.             END IF
57.  
58.             X = X - 1
59.             RadiusError = RadiusError - X * 2
60.  
61.         END IF
62.  
63.         Y = Y + 1
64.  
65.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
66.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
67.  
68.     WEND
69.  
70. END SUB
71.  
72. 'taken from QB64's p5.js
73. 'http://bit.ly/p5jsbas
74.  
75. SUB internalp5line (x0!, y0!, x1!, y1!, s!, col~&)
76.     dx! = x1! - x0!
77.     dy! = y1! - y0!
78.     d! = SQR(dx! * dx! + dy! * dy!)
79.     FOR i = 0 TO d!
80.         CircleFill x0! + dxx!, y0! + dyy!, s!, col~&
81.         dxx! = dxx! + dx! / d!
82.         dyy! = dyy! + dy! / d!
83.     NEXT
84. END SUB
85.  
86. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
87.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
88. END FUNCTION
89.  

2. 3D Fractal Tree with cube leaves (was made especially for @bplus )

Code: QB64: [Select]

1. '3D Fall Foilage or Fractal Tree with cubed leaves
2. 'Made by Ashish, especially for Bplus. :)
3.  
4.  
5. _TITLE "3D Fall Foilage"
6. SCREEN _NEWIMAGE(800, 600, 32)
7. DECLARE LIBRARY
8.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#)
9.     SUB glutSolidCube (BYVAL dsize AS DOUBLE)
10. END DECLARE
11.  
12. TYPE vec3
13.     x AS SINGLE
14.     y AS SINGLE
15.     z AS SINGLE
16. END TYPE
17.  
18. FOR y = 0 TO _HEIGHT
19.     COLOR _RGB(map(y, 0, _WIDTH, 0, 10), map(y, 0, _HEIGHT, 0, 180), 128)
20.     LINE (0, y)-(_WIDTH, y)
21. NEXT y
22.  
23. DIM SHARED glAllow AS _BYTE, VertexCount, ZoomFactor
24. _GLRENDER _ONTOP
25. COLOR _rgb(255,255,255), 1
26. ZoomFactor = 2.0
27. glAllow = -1
28. _DELAY .2
29. DO
30.     IF NOT me THEN
31.         me = -1
32.         PRINT VertexCount; " Vertices are being rendered."
33.     END IF
34.         if _keydown(asc("w")) then ZoomFactor = ZoomFactor - 0.05
35.         if _keydown(asc("s")) then ZoomFactor = ZoomFactor + 0.05
36.     _LIMIT 40
37. LOOP
38.  
39. SUB _GL () STATIC
40.     IF NOT glAllow THEN EXIT SUB
41.     IF NOT glSetup THEN
42.         _glViewport 0, 0, _WIDTH, _HEIGHT
43.         aspect# = _WIDTH / _HEIGHT
44.     END IF
45.    
46.     _glMatrixMode _GL_PROJECTION
47.     _gluPerspective 45.0, aspect#, 1, 1000
48.    
49.     _glMatrixMode _GL_MODELVIEW
50.    
51.     _glEnable _GL_DEPTH_TEST
52.     _glEnable _GL_BLEND
53.    
54.     gluLookAt 0, 1.1, 2+ZoomFactor, 0, 0, 0, 0, 1, 0
55.     _glRotatef -clock# * 60, 0, 1, 0
56.    
57.     IF NOT glListGenerated THEN
58.         fractal_tree = _glGenLists(1)
59.         _glNewList fractal_tree, _GL_COMPILE
60.         _glTranslatef 0, 0, 0
61.         _glRotatef 180, 0, 0, 1
62.        
63.         _glLineWidth 10
64.         _glColor3f .6, .3, 0
65.         _glBegin _GL_LINES
66.         _glVertex3f 0, 0, 0
67.         _glVertex3f 0, 1.4, 0
68.         _glEnd
69.         drawTree3D 0, 0, 0, .76, 35, 35
70.        
71.         _glTranslatef 0, 1.4, 0
72.         _glColor3f 1, 1, 1
73.         drawGround3D
74.         _glEndList
75.         glListGenerated = -1
76.     END IF
77.     _glCallList fractal_tree
78.    
79.     _glFlush
80.     clock# = clock# + .01
81. END SUB
82.  
83. SUB drawTree3D (x, y, z, r, t1, t2)
84.     ' IF r < 0.4 THEN _glColor4f 0, .8, 0, 0.7 ELSE _glColor3f .6, .3, 0
85.     _glColor4f map(r, 0, 1, .8, .5), map(r, 0, 1, .5, .3), 0, .7
86.  
87.     _glLineWidth map(r, 0.8, 0.06, 10, 1)
88.  
89.     _glPushMatrix
90.     _glRotatef t1, 0, 0, 1
91.     _glBegin _GL_LINES
92.     _glVertex3f x, y, z
93.     _glVertex3f x, y - r, z
94.     _glEnd
95.     if rnd > 0 and rnd < 0.25 then drawLeaf3D x, y - r, z
96.     _glPopMatrix
97.    
98.     _glColor4f map(r, 0, 1, .8, .5), map(r, 0, 1, .5, .3), 0, .7
99.  
100.     _glPushMatrix
101.     _glRotatef -t1, 0, 0, 1
102.     _glBegin _GL_LINES
103.     _glVertex3f x, y, z
104.     _glVertex3f x, y - r, z
105.     _glEnd
106.     if rnd > 0.25 and rnd < 0.5 then drawLeaf3D x, y - r, z
107.     _glPopMatrix
108.  
109.     _glColor4f map(r, 0, 1, .8, .5), map(r, 0, 1, .5, .3), 0, .7
110.    
111.     _glPushMatrix
112.     _glRotatef t2, 1, 0, 0
113.     _glBegin _GL_LINES
114.     _glVertex3f x, y, z
115.     _glVertex3f x, y - r, z
116.     _glEnd
117.     if rnd > 0.5 and rnd < 0.75 then drawLeaf3D x, y - r, z
118.     _glPopMatrix
119.  
120.     _glColor4f map(r, 0, 1, .8, .5), map(r, 0, 1, .5, .3), 0, .7
121.    
122.     _glPushMatrix
123.     _glRotatef -t2, 1, 0, 0
124.     _glBegin _GL_LINES
125.     _glVertex3f x, y, z
126.     _glVertex3f x, y - r, z
127.     _glEnd
128.     if rnd > .75 then drawLeaf3D x, y - r, z
129.     _glPopMatrix
130.  
131.     VertexCount = VertexCount + 8
132.  
133.     IF r > 0.06 THEN
134.         _glPushMatrix
135.         _glRotatef t1, 0, 0, 1
136.         _glTranslatef x, y - r, z
137.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
138.         _glPopMatrix
139.  
140.         _glPushMatrix
141.         _glRotatef -t1, 0, 0, 1
142.         _glTranslatef x, y - r, z
143.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
144.         _glPopMatrix
145.  
146.         _glPushMatrix
147.         _glRotatef t2, 1, 0, 0
148.         _glTranslatef x, y - r, z
149.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
150.         _glPopMatrix
151.  
152.         _glPushMatrix
153.         _glRotatef -t2, 1, 0, 0
154.         _glTranslatef x, y - r, z
155.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
156.         _glPopMatrix
157.  
158.     END IF
159.  
160. END SUB
161.  
162. SUB drawLeaf3D (x, y, z)
163.     area = 0.2
164.     ' FOR n = 1 TO leafs
165.         _glColor4f p5random(0.19, 0.98), p5random(0.1, 1), p5random(0, 0.16), 0.6
166.         _glPushMatrix
167.         _glTranslatef x + RND * area - RND * area, y + RND * area - RND * area, z + RND * area - RND * area
168.         glutSolidCube 0.01 + RND * .02
169.         _glPopMatrix
170.         VertexCount = VertexCount + 8
171.     ' NEXT
172. END SUB
173.  
174. SUB drawGround3D ()
175.     _glBegin _GL_TRIANGLES
176.     _glColor3f 0.27, 0.42, 0.11
177.     _glVertex3f -2, 0, -2
178.     _glColor3f 0.03, 0.31, 0.02
179.     _glVertex3f -2, 0, 2
180.     _glVertex3f 2, 0, -2
181.    
182.     _glColor3f 0.03, 0.31, 0.02
183.     _glVertex3f 2, 0, -2
184.     _glColor3f 0.27, 0.42, 0.11
185.     _glVertex3f 2, 0, 2
186.     _glColor3f 0.03, 0.31, 0.02
187.     _glVertex3f -2, 0, 2
188.     _glEnd
189. END SUB
190.  
191. 'taken from a 2D rendering library, p5js.bas
192. 'http://bit.ly/p5jsbas
193. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
194.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
195. END FUNCTION
196.  
197. FUNCTION p5random! (mn!, mx!)
198.     IF mn! > mx! THEN
199.         SWAP mn!, mx!
200.     END IF
201.     p5random! = RND * (mx! - mn!) + mn!
202. END FUNCTION
203.  
204.  

3. 3D Fractal tree with changing angles with Mouse

Code: QB64: [Select]

1. '3D Tree Fractal!
2. 'By Ashish Kushwaha
3. 'Move mouse for new pattern
4.  
5. DECLARE LIBRARY
6.     SUB gluLookAt (BYVAL eyeX#, BYVAL eyeY#, BYVAL eyeZ#, BYVAL centerX#, BYVAL centerY#, BYVAL centerZ#, BYVAL upX#, BYVAL upY#, BYVAL upZ#)
7. END DECLARE
8.  
9. _TITLE "3D Fractal Tree"
10. SCREEN _NEWIMAGE(800, 600, 32)
11.  
12. DIM SHARED glAllow AS _BYTE, branchAngle1,branchAngle2
13.  
14. glAllow = -1
15. DO
16.     WHILE _MOUSEINPUT: WEND
17.     branchAngle1 = map(_MOUSEX, 0, _WIDTH, 15, 55)
18.     branchAngle2 = map(_MOUSEY, 0, _HEIGHT, 15, 55)
19.         _LIMIT 40
20. LOOP UNTIL INKEY$ <> ""
21.  
22. SUB _GL () STATIC
23.     IF NOT glAllow THEN EXIT SUB
24.  
25.     IF NOT glSetup THEN
26.         _glViewport 0, 0, _WIDTH, _HEIGHT
27.         aspect# = _WIDTH / _HEIGHT
28.         glSetup = -1
29.     END IF
30.  
31.     _glEnable _GL_DEPTH_TEST
32.     _glEnable _GL_BLEND
33.  
34.     _glMatrixMode _GL_PROJECTION
35.     _gluPerspective 45.0, aspect#, 1.0, 1000.0
36.  
37.     _glMatrixMode _GL_MODELVIEW
38.  
39.     gluLookAt 0, -3, 3, 0, -.6, 0, 0, -1, 0
40.  
41.     _glRotatef clock# * 60, 0, 1, 0
42.     _glLineWidth 10.0
43.  
44.     _glColor3f .6, .3, 0
45.     _glBegin _GL_LINES
46.     _glVertex3f 0, 0.0, 0
47.     _glVertex3f 0, 1.8, 0
48.     _glEnd
49.  
50.     drawTree3D 0, 0, 0, .8, branchAngle1, branchAngle2
51.     clock# = clock# + 0.01
52.     _glFlush
53. END SUB
54.  
55. SUB drawTree3D (x, y, z, r, t1, t2)
56.     IF r < 0.4 THEN _glColor4f 0, .8, 0, 0.7 ELSE _glColor3f .6, .3, 0
57.  
58.     _glLineWidth map(r, 0.8, 0.06, 10, 1)
59.  
60.     _glPushMatrix
61.     _glRotatef t1, 0, 0, 1
62.     _glBegin _GL_LINES
63.     _glVertex3f x, y, z
64.     _glVertex3f x, y - r, z
65.     _glEnd
66.     _glPopMatrix
67.  
68.     _glPushMatrix
69.     _glRotatef -t1, 0, 0, 1
70.     _glBegin _GL_LINES
71.     _glVertex3f x, y, z
72.     _glVertex3f x, y - r, z
73.     _glEnd
74.     _glPopMatrix
75.  
76.     _glPushMatrix
77.     _glRotatef t2, 1, 0, 0
78.     _glBegin _GL_LINES
79.     _glVertex3f x, y, z
80.     _glVertex3f x, y - r, z
81.     _glEnd
82.     _glPopMatrix
83.  
84.     _glPushMatrix
85.     _glRotatef -t2, 1, 0, 0
86.     _glBegin _GL_LINES
87.     _glVertex3f x, y, z
88.     _glVertex3f x, y - r, z
89.     _glEnd
90.     _glPopMatrix
91.  
92.  
93.  
94.     IF r > 0.06 THEN
95.         _glPushMatrix
96.         _glRotatef t1, 0, 0, 1
97.         _glTranslatef x, y - r, z
98.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
99.         _glPopMatrix
100.  
101.         _glPushMatrix
102.         _glRotatef -t1, 0, 0, 1
103.         _glTranslatef x, y - r, z
104.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
105.         _glPopMatrix
106.  
107.         _glPushMatrix
108.         _glRotatef t2, 1, 0, 0
109.         _glTranslatef x, y - r, z
110.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
111.         _glPopMatrix
112.  
113.         _glPushMatrix
114.         _glRotatef -t2, 1, 0, 0
115.         _glTranslatef x, y - r, z
116.         drawTree3D 0, 0, 0, r * 0.61, t1, t2
117.         _glPopMatrix
118.  
119.     END IF
120.  
121. END SUB
122.  
123. 'taken from a 2D rendering library, p5js.bas
124. 'http://bit.ly/p5jsbas
125. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
126.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
127. END FUNCTION
128.  
129.  
130.  

[bplus]

Hey @Ashish

New avatar I see.

Great trees! I like last one best can even assume the same pose as Body Tree when it is turned just right. You are a GL master! :-))