Quake 3 Level Loader - Work in progress

[Unseen Machine]

Hi Folks,

So i decided to attempt adding level support to GDK_GL. I looked into it and decided that i'd do Quake 3 levels first (if i can get this working then apparently Quake 2 and Quake 1 levels require just a few modifications to the loader code).

ID games use Binary Space Partitioning for their levels which is WAY over my understanding (at present) so i know i'll come across problems in trying to get this to work.

The resource : http://www.mralligator.com/q3/

So far all i've done is convert the structures to QB64 type defintions (cause we can't use arrays inside types i've had to make a few of my own custom types and WILL have to use _MEM for a few bits later on.

Code: QB64: [Select]

1. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
2. '//                                Quake 3 .BSP File loader v.01                              \\
3. '//                             By John Onyon a.k.a Unseen Machine                            \\
4. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
5.  
6. SUB BSP_TYPE_DEFS
7.  
8.  '// BSP_Float2/3, BSP_Int2/3, BSP_RGBA, BSP_LM_VEC and BSP_Light are used where arrays inside types are needed.
9.  TYPE BSP_Float2
10.   Flt1 AS SINGLE
11.   Flt2 AS SINGLE
12.  END TYPE
13.  
14.  TYPE BSP_Float3
15.   X AS SINGLE
16.   Y AS SINGLE
17.   Z AS SINGLE
18.  END TYPE
19.  
20.  TYPE BSP_Int2
21.   Int1 AS INTEGER
22.   Int2 AS INTEGER
23.  END TYPE
24.  
25.  TYPE BSP_Int3
26.   Int1 AS INTEGER
27.   Int2 AS INTEGER
28.   Int3 AS INTEGER
29.  END TYPE
30.  
31.  TYPE BSP_RGBA
32.   R AS _UNSIGNED _BYTE
33.   G AS _UNSIGNED _BYTE
34.   B AS _UNSIGNED _BYTE
35.   A AS _UNSIGNED _BYTE
36.  END TYPE
37.  
38.  TYPE BSP_LM_Vec
39.   Set1 AS BSP_Float3
40.   Set2 AS BSP_Float3
41.  END TYPE
42.  
43.  TYPE BSP_Light
44.   R AS _UNSIGNED _BYTE
45.   G AS _UNSIGNED _BYTE
46.   B AS _UNSIGNED _BYTE
47.  END TYPE
48.  
49.  TYPE BSP_DirEntry
50.   Start AS INTEGER '// Offset into file
51.   Size AS INTEGER '// How big (number of bytes) it is
52.  END TYPE
53.  
54.  TYPE BSP_HEADER
55.   Magic AS STRING * 4 '// Magic number. Always "IBSP".
56.   Version AS INTEGER '//  0x2e for the BSP files distributed with Quake 3.
57.   DirEntries AS _MEM '// Lump directory, seventeen entrie of type BSP_DirEntry
58.  END TYPE
59.  
60.  TYPE BSP_TEXTURE
61.   Name AS STRING * 64
62.   Flags AS INTEGER
63.   Contents AS INTEGER
64.  END TYPE
65.  
66.  TYPE BSP_Plane
67.   Normal AS BSP_Float3
68.   Distance AS SINGLE
69.  END TYPE
70.  
71.  TYPE BSP_Node
72.   Plane AS INTEGER '// Plane index.
73.   Children AS BSP_Int2 '// Children indices. Negative numbers are leaf indices: -(leaf+1).
74.   Mins AS BSP_Int3 '// Integer bounding box min coord.
75.   Maxs AS BSP_Int3 '//
76.  END TYPE
77.  
78.  TYPE BSP_Leaf
79.   Cluster AS INTEGER '//  Visdata cluster index.
80.   Area AS INTEGER '// Areaportal area.
81.   Mins AS BSP_Int3 '// Integer bounding box min coord.
82.   Maxs AS BSP_Int3 '// Integer bounding box max coord.
83.   LeafFace AS INTEGER '// First leafface for leaf.
84.   NumLeafFaces AS INTEGER '// Number of leaffaces for leaf.
85.   LeafBrush AS INTEGER '// First leafbrush for leaf.
86.   NumLeafBrushes AS INTEGER '// Number of leafbrushes for leaf.
87.  END TYPE
88.  
89.  TYPE BSP_LeafFace
90.   Face AS INTEGER '// Face index.
91.  END TYPE
92.  
93.  TYPE BSP_LeafBrush
94.   Brush AS INTEGER '// Brush index.
95.  END TYPE
96.  
97.  TYPE BSP_Model
98.   Mins AS BSP_Float3 '// Bounding box min coord.
99.   Maxs AS BSP_Float3 '// Bounding box max coord.
100.   Face AS INTEGER '// First face for model.
101.   NumFaces AS INTEGER '//  Number of faces for model.
102.   Brush AS INTEGER '// First brush for model.
103.   NumBrushes AS INTEGER '// Number of brushes for model.
104.  END TYPE
105.  
106.  TYPE BSP_Brush
107.   BrushSide AS INTEGER '// First brushside for brush.
108.   NumBrushSides AS INTEGER '// Number of brushsides for brush.
109.   Texture AS INTEGER '// Texture index.
110.  END TYPE
111.  
112.  TYPE BSP_BrushSide
113.   Plane AS INTEGER '//  Plane index.
114.   Texture AS INTEGER '// Texture index.
115.  END TYPE
116.  
117.  TYPE BSP_Vertex
118.   Position AS BSP_Float3 '// Vertex position.
119.   TexCoord_Surface AS BSP_Float2 '//  Vertex texture coordinates. 0=surface, 1=lightmap.
120.   TexCoord_Lightmap AS BSP_Float2
121.   Normal AS BSP_Float3 '// Vertex normal.
122.   Color AS BSP_RGBA '// Vertex color. RGBA.
123.  END TYPE
124.  
125.  TYPE BSP_MeshVert
126.   Offset AS INTEGER '// Vertex index offset, relative to first vertex of corresponding face.
127.  END TYPE
128.  
129.  TYPE BSP_Effect
130.   Name AS STRING * 64 '// Effect shader.
131.   Brush AS INTEGER '// Brush that generated this effect.
132.   Unknown AS INTEGER 'Always 5, except in q3dm8, which has one effect with -1.
133.  END TYPE
134.  
135.  TYPE BSP_Face
136.   Texture AS INTEGER '// Texture index.
137.   Effect AS INTEGER '// Index into lump 12 (Effects), or -1.
138.   FaceType AS INTEGER '// Face type. 1=polygon, 2=patch, 3=mesh, 4=billboard
139.   Vertex AS INTEGER '// Index of first vertex.
140.   NumVertexes AS INTEGER '// Number of vertices.
141.   MeshVert AS INTEGER '// Index of first meshvert.
142.   NumMeshVerts AS INTEGER '// Number of meshverts.
143.   LMIndex AS INTEGER '// Lightmap index.
144.   LMStart AS BSP_Int2 '// Corner of this face's lightmap image in lightmap.
145.   LMSize AS BSP_Int2 '// Size of this face's lightmap image in lightmap.
146.   LMOrigin AS BSP_Float3 '// World space origin of lightmap.
147.   LMVecs AS BSP_LM_Vec '// World space lightmap s and t unit vectors.
148.   Normal AS BSP_Float3 '// Surface normal.
149.   Size AS BSP_Int2 '// Patch dimensions.
150.  END TYPE
151.  
152.  TYPE BSP_LightVol
153.   Ambient AS BSP_Light '// Ambient color component. RGB.
154.   Directional AS BSP_Light '// Directional color component. RGB.
155.   LightDirPhi AS _UNSIGNED _BYTE '//  Direction to light. 0=phi, 1=theta.
156.   LightDirtheta AS _UNSIGNED _BYTE '//  Direction to light. 0=phi, 1=theta.
157.  END TYPE
158.  
159.  TYPE BSP_VisData
160.   NumVecs AS INTEGER '// Number of vectors.
161.   SizeVecs AS INTEGER '// Size of each vector, in bytes.
162.   Vecs AS _MEM 'ubyte[n_vecs * sz_vecs] vecs  Visibility data. One bit per cluster per vector.
163.  END TYPE
164.  
165. END SUB
166.  
167.  
168. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
169.  
170.  

When you start with that many typedefs you know this project is gonna be a BIG one!

Anyone who would like to help me in getting this further down the road please speak up and we can discuss where to go from here...finding a quake 3 .bsp to load is the first step cause i'e not got one yet!

Thanks folks,

Unseen

[Unseen Machine]

Hi Folks,

Just an update, thanks to steve i've now got a (almost) complete .bsp loader. (I've ignored entities and light map textures for the time being)

Code: QB64: [Select]

1. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
2. '//                                Quake 3 .BSP File loader v.01                              \\
3. '//                             By John Onyon a.k.a Unseen Machine                            \\
4. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
5.  
6. '// TEMP Consts
7. CONST True = -1, False = 0
8.  
9. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
10. '// File path
11. Root$ = "C:\qb64\3d Programs\bsp\MAPS" '// Level Directory
12. CHDIR Root$ '// Change directory to where our stuff is
13.  
14. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
15. '// Load the level
16. DIM Level AS Level '// DIM the memory for the level
17. 'LoadState& = BSP_Load(Level, "q3Dead1.bsp") '// Load the level data
18. LoadState& = BSP_Load(Level, "q3shw24.bsp") '// Load the level data
19.  
20. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
21.  
22. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
23. '// GDK_GL - New type definition for handling levels.
24.  
25. SUB GDK_GL_TYPEDEFS
26.  TYPE Level
27.   ID AS _BYTE '// Signifies the type of level (currently irrelevant as we dont support any other level formats)
28.   HeaderPntr AS _MEM '// Level information header
29.   DataPntr AS _MEM '// Level data - verts, normals, textures etc...
30.  END TYPE
31. END SUB
32.  
33. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
34.  
35. SUB BSP_TYPE_DEFS
36.  
37.  '// BSP_Float2/3, BSP_Int2/3, BSP_RGBA, BSP_LM_VEC and BSP_Light are used where arrays inside types are needed.
38.  TYPE BSP_Float2
39.   Flt1 AS SINGLE
40.   Flt2 AS SINGLE
41.  END TYPE
42.  
43.  TYPE BSP_Float3
44.   X AS SINGLE
45.   Y AS SINGLE
46.   Z AS SINGLE
47.  END TYPE
48.  
49.  TYPE BSP_Int2
50.   Int1 AS LONG
51.   Int2 AS LONG
52.  END TYPE
53.  
54.  TYPE BSP_Int3
55.   Int1 AS LONG
56.   Int2 AS LONG
57.   Int3 AS LONG
58.  END TYPE
59.  
60.  TYPE BSP_RGBA
61.   R AS _UNSIGNED _BYTE
62.   G AS _UNSIGNED _BYTE
63.   B AS _UNSIGNED _BYTE
64.   A AS _UNSIGNED _BYTE
65.  END TYPE
66.  
67.  TYPE BSP_LM_Vec
68.   Set1 AS BSP_Float3
69.   Set2 AS BSP_Float3
70.  END TYPE
71.  
72.  TYPE BSP_Light
73.   R AS _UNSIGNED _BYTE
74.   G AS _UNSIGNED _BYTE
75.   B AS _UNSIGNED _BYTE
76.  END TYPE
77.  
78.  TYPE BSP_DirEntry
79.   Start AS LONG '// Offset into file
80.   Size AS LONG '// How big (number of bytes) it is
81.  END TYPE
82.  
83.  TYPE BSP_Header
84.   Magic AS STRING * 4 '// Magic number. Always "IBSP".
85.   Version AS LONG '//  0x2e for the BSP files distributed with Quake 3.
86.   DirEntries AS _MEM '// Lump directory, seventeen entries of type BSP_DirEntry
87.  END TYPE
88.  
89.  TYPE BSP_Texture
90.   Name AS STRING * 64
91.   Flags AS LONG
92.   Contents AS LONG
93.  END TYPE
94.  
95.  TYPE BSP_Plane
96.   Normal AS BSP_Float3
97.   Distance AS SINGLE
98.  END TYPE
99.  
100.  TYPE BSP_Node
101.   Plane AS LONG '// Plane index.
102.   Children AS BSP_Int2 '// Children indices. Negative numbers are leaf indices: -(leaf+1).
103.   Mins AS BSP_Int3 '// LONG bounding box min coord.
104.   Maxs AS BSP_Int3 '//
105.  END TYPE
106.  
107.  TYPE BSP_Leaf
108.   Cluster AS LONG '//  Visdata cluster index.
109.   Area AS LONG '// Areaportal area.
110.   Mins AS BSP_Int3 '// LONG bounding box min coord.
111.   Maxs AS BSP_Int3 '// LONG bounding box max coord.
112.   LeafFace AS LONG '// First leafface for leaf.
113.   NumLeafFaces AS LONG '// Number of leaffaces for leaf.
114.   LeafBrush AS LONG '// First leafbrush for leaf.
115.   NumLeafBrushes AS LONG '// Number of leafbrushes for leaf.
116.  END TYPE
117.  
118.  TYPE BSP_LeafFace
119.   Face AS LONG '// Face index.
120.  END TYPE
121.  
122.  TYPE BSP_LeafBrush
123.   Brush AS LONG '// Brush index.
124.  END TYPE
125.  
126.  TYPE BSP_Model
127.   Mins AS BSP_Float3 '// Bounding box min coord.
128.   Maxs AS BSP_Float3 '// Bounding box max coord.
129.   Face AS LONG '// First face for model.
130.   NumFaces AS LONG '//  Number of faces for model.
131.   Brush AS LONG '// First brush for model.
132.   NumBrushes AS LONG '// Number of brushes for model.
133.  END TYPE
134.  
135.  TYPE BSP_Brush
136.   BrushSide AS LONG '// First brushside for brush.
137.   NumBrushSides AS LONG '// Number of brushsides for brush.
138.   Texture AS LONG '// Texture index.
139.  END TYPE
140.  
141.  TYPE BSP_BrushSide
142.   Plane AS LONG '//  Plane index.
143.   Texture AS LONG '// Texture index.
144.  END TYPE
145.  
146.  TYPE BSP_Vertex
147.   Position AS BSP_Float3 '// Vertex position.
148.   TexCoord_Surface AS BSP_Float2 '//  Vertex texture coordinates. 0=surface, 1=lightmap.
149.   TexCoord_Lightmap AS BSP_Float2
150.   Normal AS BSP_Float3 '// Vertex normal.
151.   Color AS BSP_RGBA '// Vertex color. RGBA.
152.  END TYPE
153.  
154.  TYPE BSP_MeshVert
155.   Offset AS LONG '// Vertex index offset, relative to first vertex of corresponding face.
156.  END TYPE
157.  
158.  TYPE BSP_Effect
159.   Name AS STRING * 64 '// Effect shader.
160.   Brush AS LONG '// Brush that generated this effect.
161.   Unknown AS LONG 'Always 5, except in q3dm8, which has one effect with -1.
162.  END TYPE
163.  
164.  TYPE BSP_Face
165.   Texture AS LONG '// Texture index.
166.   Effect AS LONG '// Index into lump 12 (Effects), or -1.
167.   FaceType AS LONG '// Face type. 1=polygon, 2=patch, 3=mesh, 4=billboard
168.   Vertex AS LONG '// Index of first vertex.
169.   NumVertexes AS LONG '// Number of vertices.
170.   MeshVert AS LONG '// Index of first meshvert.
171.   NumMeshVerts AS LONG '// Number of meshverts.
172.   LMIndex AS LONG '// Lightmap index.
173.   LMStart AS BSP_Int2 '// Corner of this face's lightmap image in lightmap.
174.   LMSize AS BSP_Int2 '// Size of this face's lightmap image in lightmap.
175.   LMOrigin AS BSP_Float3 '// World space origin of lightmap.
176.   LMVecs AS BSP_LM_Vec '// World space lightmap s and t unit vectors.
177.   Normal AS BSP_Float3 '// Surface normal.
178.   Size AS BSP_Int2 '// Patch dimensions.
179.  END TYPE
180.  
181.  TYPE BSP_LightVol
182.   Ambient AS BSP_Light '// Ambient color component. RGB.
183.   Directional AS BSP_Light '// Directional color component. RGB.
184.   LightDirPhi AS _UNSIGNED _BYTE '//  Phi - Direction to light.
185.   LightDirTheta AS _UNSIGNED _BYTE '//  Teta - Direction to light.
186.  END TYPE
187.  
188.  TYPE BSP_VisData
189.   NumVecs AS LONG '// Number of vectors.
190.   SizeVecs AS LONG '// Size of each vector, in bytes.
191.   Vecs AS _MEM 'ubyte[numvecs * sizevecs] vecs  '// Visibility data. One bit per cluster per vector.
192.  END TYPE
193.  
194. END SUB
195.  
196. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
197.  
198. '// Master function returns true (-1) if all was ok, or false (0) if failiure.
199. FUNCTION BSP_Load (Level AS Level, File$)
200.  
201.  InFile = FREEFILE '// Get a free file handle
202.  OPEN File$ FOR BINARY AS #InFile '// Open the file
203.  
204.  BytePos& = 1 '// Byte position variable
205.  
206.  '// DIM header
207.  DIM Header AS BSP_Header
208.  GET #InFile, BytePos&, Header.Magic '// Get the id, if not "IBSP" then failiure
209.  IF Header.Magic = "IBSP" THEN '// Valid file
210.   BytePos& = BytePos& + LEN(Header.Magic) '// Byte position increment
211.   GET #InFile, BytePos&, Header.Version '// Get the version id
212.   IF Header.Version = 46 THEN '// Valid format (Quake 3 level)
213.    BytePos& = BytePos& + LEN(Header.Version) '// Byte position increment
214.  
215.    DIM Entry(16) AS BSP_DirEntry
216.    GET #InFile, BytePos&, Entry() '// Load all the offsets
217.  
218.    Level.HeaderPntr = _MEMNEW(LEN(Header.Magic) + LEN(Header.Version) + (LEN(Entry(0)) * 17)) '// Allocate memory
219.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET, Header.Magic
220.    MemOffset& = LEN(Header.Magic)
221.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET + MemOffset&, Header.Version
222.    MemOffset& = MemOffset& + LEN(Header.Version)
223.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET + MemOffset&, Entry()
224.  
225.    '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
226.    '// We dont care about certain things in the file for now, we just want rendering and clipping data
227.    '// Need to calculate required memory block and then load data
228.    '// Create single defintions of each required type to use in caluation
229.  
230.    FOR Index& = 0 TO 16
231.  
232.     BytePos& = Entry(Index&).Start '// Offset of where data starts
233.  
234.     SELECT CASE Index&
235.      CASE 0 '// Entities  Game-related object descriptions. - We are not gonna worry about these for now
236.      CASE 1 '// Textures  Surface descriptions.
237.  
238.       DIM Tmp_Texture AS BSP_Texture
239.       NumTXRecs& = Entry(Index&).Size / LEN(Tmp_Texture)
240.       DIM Texture(NumTXRecs& - 1) AS BSP_Texture
241.       GET #InFile, BytePos&, Texture()
242.  
243.      CASE 2 '// Planes  Planes used by map geometry.
244.  
245.       DIM TmpPlane AS BSP_Plane
246.       NumPLRecs& = Entry(Index&).Size / LEN(TmpPlane)
247.       DIM Plane(NumPLRecs& - 1) AS BSP_Plane
248.       GET #InFile, BytePos&, Plane()
249.  
250.      CASE 3 '// Nodes  BSP tree nodes.
251.  
252.       DIM TmpNode AS BSP_Node
253.       NumNodeRecs& = Entry(Index&).Size / LEN(TmpNode)
254.       DIM Node(NumNodeRecs& - 1) AS BSP_Node
255.       GET #InFile, BytePos&, Node()
256.  
257.      CASE 4 '// Leafs  BSP tree leaves.
258.  
259.       DIM TmpLeaf AS BSP_Leaf
260.       NumLeafRecs& = Entry(Index&).Size / LEN(TmpLeaf)
261.       DIM Leaf(NumLeafRecs& - 1) AS BSP_Leaf
262.       GET #InFile, BytePos&, Leaf()
263.  
264.      CASE 5 '// Leaffaces  Lists of face indices, one list per leaf.
265.  
266.       DIM TmpLF AS BSP_LeafFace
267.       NumLFRecs& = Entry(Index&).Size / LEN(TmpLF)
268.       DIM LeafFace(NumLFRecs& - 1) AS BSP_LeafFace
269.       GET #InFile, BytePos&, LeafFace()
270.  
271.      CASE 6 '// Leafbrushes  Lists of brush indices, one list per leaf.
272.  
273.       DIM TmpLB AS BSP_LeafBrush
274.       NumLBRecs& = Entry(Index&).Size / LEN(TmpLB)
275.       DIM LeafBrush(NumLBRecs& - 1) AS BSP_LeafBrush
276.       GET #InFile, BytePos&, LeafBrush()
277.  
278.      CASE 7 '// Models  Descriptions of rigid world geometry in map.
279.  
280.       DIM TmpMDL AS BSP_Model
281.       NumMDLRecs& = Entry(Index&).Size / LEN(TmpMDL)
282.       DIM BSPMDL(NumMDLRecs& - 1) AS BSP_Model
283.       GET #InFile, BytePos&, BSPMDL()
284.  
285.      CASE 8 '// Brushes  Convex polyhedra used to describe solid space.
286.  
287.       DIM TmpBrush AS BSP_Brush
288.       NumBRecs& = Entry(Index&).Size / LEN(TmpBrush)
289.       DIM Brush(NumBRecs& - 1) AS BSP_Brush
290.       GET #InFile, BytePos&, Brush()
291.  
292.      CASE 9 '// Brushsides  Brush surfaces.
293.  
294.       DIM TmpBS AS BSP_BrushSide
295.       NumBSRecs& = Entry(Index&).Size / LEN(TmpBS)
296.       DIM BrushSide(NumBSRecs& - 1) AS BSP_BrushSide
297.       GET #InFile, BytePos&, BrushSide()
298.  
299.      CASE 10 '// Vertexes  Vertices used to describe faces.
300.  
301.       DIM TmpVert AS BSP_Vertex
302.       NumVRecs& = Entry(Index&).Size / LEN(TmpVert)
303.       DIM Vertex(NumVRecs& - 1) AS BSP_Vertex
304.       GET #InFile, BytePos&, Vertex()
305.  
306.      CASE 11 '// Meshverts  Lists of offsets, one list per mesh.
307.  
308.       DIM TmpMVert AS BSP_MeshVert
309.       NumMVRecs& = Entry(Index&).Size / LEN(TmpMVert)
310.       DIM MeshVertex(NumMVRecs& - 1) AS BSP_MeshVert
311.       GET #InFile, BytePos&, MeshVertex()
312.  
313.      CASE 12 '// Effects  List of special map effects.
314.  
315.       DIM TmpEffect AS BSP_Effect
316.       NumEFRecs& = Entry(Index&).Size / LEN(TmpEffect)
317.       DIM Effect(NumEFRecs& - 1) AS BSP_Effect
318.       GET #InFile, BytePos&, Effect()
319.  
320.      CASE 13 '// Faces  Surface geometry.
321.  
322.       DIM TmpFace AS BSP_Face
323.       NumFaceRecs& = Entry(Index&).Size / LEN(TmpFace)
324.       DIM Face(NumFaceRecs& - 1) AS BSP_Face
325.       GET #InFile, BytePos&, Face()
326.  
327.      CASE 14 '// Lightmaps  Packed lightmap data.
328.  
329.       '// array of (127,127,3) Using RGB
330.       '// Gonna ignore this for now
331.  
332.      CASE 15 '// Lightvols  Local illumination data.
333.  
334.       DIM TmpLVols AS BSP_LightVol
335.       NumLVRecs& = Entry(Index&).Size / LEN(TmpLVols)
336.       DIM LightVol(NumLVRecs& - 1) AS BSP_LightVol
337.       GET #InFile, BytePos&, LightVol()
338.  
339.      CASE 16 '// Visdata  Cluster-cluster visibility data.
340.  
341.       DIM TmpVD AS BSP_VisData
342.       NumVDRecs& = Entry(Index&).Size / LEN(TmpVD)
343.       DIM VD(NumVDRecs& - 1) AS BSP_VisData
344.       GET #InFile, BytePos&, VD()
345.  
346.     END SELECT
347.  
348.    NEXT
349.  
350.    '// Add up size of all the arrays and create _MEM block
351.  
352.    '// Put data in to _MEM
353.  
354.    BSP_Load = True '// All good!
355.   ELSE
356.    BSP_Load = False
357.   END IF
358.  ELSE
359.   BSP_Load = False
360.  END IF
361.  '// All done now so close the file
362.  CLOSE #InFile
363.  
364. END FUNCTION
365.  
366. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
367.  
368.  
369.  

Now comes the hard part, make the render bit!

Unseen

[Unseen Machine]

Well, after careful consideration i've decided that i'm going to do this a different way.

Currently i've gone about it the same way i have done with my model loaders, unpacking the data, sticking it into a custom type that utilises _MEM and then getting that data back out from _MEM each time i need to render it. Cause models are small files it's a fast enough method for the time being (until we get arrays inside type's), but these .bsp level's i'm working with! They aint so small and asking my cpu to unpack maybe 10meg of data 30 times a second to draw it is a bit of an ask!

So, after mulling it over i realised that as, unlike model files where there are often many in a level, there is only one level at a time! This means (i think) i can use a .bi file to store all the required arrays and stuff meaning it'll only need to be unpacked once! I'll be doing this thanks to REDIM SHARED!!!

So i'll be rewriting a lot of code over this weekend and i'll report back on my results, till then, here is where i'd got to with the loader in this form. Oh, and i just bought the quake pack of steam (£5) and got quake 1/2/3 and 6 different mission packs, what a deal!

Code: QB64: [Select]

1. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
2. '//                                Quake 3 .BSP File loader v.01                              \\
3. '//                             By John Onyon a.k.a Unseen Machine                            \\
4. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
5.  
6. REM $INCLUDE:'GDK_GL\GDK_GL.bi'
7.  
8. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
9. '// File path
10. Root$ = "C:\qb64\3d Programs\bsp" '// BSP Directory
11. CHDIR Root$ '// Change directory to where our stuff is
12.  
13. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
14. '// Load the level
15. DIM SHARED Level AS Level '// DIM the memory for the level
16.  
17. DIM SHARED KB(1) AS KeyBoardState, Mouse(1) AS MouseState '// Input handlers
18. DIM SHARED AllowGL AS _BYTE, InitGl AS _BYTE
19.  
20. SCREEN _NEWIMAGE(800, 600, 32)
21. SLEEP 1 '// Give the screen time to be created
22.  
23. InitGl = True
24. AllowGL = True
25.  
26.  
27. DO
28.  
29.  _LIMIT 30
30.  
31.  'CLS
32.  
33.  '// Input
34.  GDK_Keyboard_GetState KB(0)
35.  GDK_Mouse_GetState Mouse(0)
36.  
37.  '// Logic
38.  
39.  
40.  '_DISPLAY
41.  
42.  _DELAY .005 '// Give the CPU Breather
43.  
44.  '// Copy input handlers
45.  Mouse(1) = Mouse(0)
46.  KB(1) = KB(0)
47.  
48. LOOP UNTIL KB(0).ESC
49.  
50. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
51.  
52. REM $INCLUDE:'UnseenGDK.bm'
53.  
54. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
55. '//                 GDK_GL - New type definition for handling .bsp levels.                    \\
56.  
57. SUB GDK_GL_TYPEDEFS
58.  TYPE Level
59.   ID AS _BYTE '// Signifies the type of level (currently irrelevant as we dont support any other level formats)
60.   HeaderPntr AS _MEM '// Level information header
61.   DataPntr AS _MEM '// Level data - verts, normals, texture names etc...
62.   TexturePntr AS _MEM '// A series of _unsigned longs of loaded textures
63.  END TYPE
64. END SUB
65.  
66. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
67.  
68. SUB BSP_TYPE_DEFS
69.  
70.  
71.  '// BSP_Float2/3, BSP_Int2/3, BSP_RGBA, BSP_LM_VEC and BSP_Light are used where arrays inside types are needed.
72.  TYPE BSP_Float2
73.   Flt1 AS SINGLE
74.   Flt2 AS SINGLE
75.  END TYPE
76.  
77.  TYPE BSP_Float3
78.   X AS SINGLE
79.   Y AS SINGLE
80.   Z AS SINGLE
81.  END TYPE
82.  
83.  TYPE BSP_Int2
84.   Int1 AS LONG
85.   Int2 AS LONG
86.  END TYPE
87.  
88.  TYPE BSP_Int3
89.   Int1 AS LONG
90.   Int2 AS LONG
91.   Int3 AS LONG
92.  END TYPE
93.  
94.  TYPE BSP_RGBA
95.   R AS _UNSIGNED _BYTE
96.   G AS _UNSIGNED _BYTE
97.   B AS _UNSIGNED _BYTE
98.   A AS _UNSIGNED _BYTE
99.  END TYPE
100.  
101.  TYPE BSP_LM_Vec
102.   Set1 AS BSP_Float3
103.   Set2 AS BSP_Float3
104.  END TYPE
105.  
106.  TYPE BSP_Light
107.   R AS _UNSIGNED _BYTE
108.   G AS _UNSIGNED _BYTE
109.   B AS _UNSIGNED _BYTE
110.  END TYPE
111.  
112.  TYPE BSP_DirEntry
113.   Start AS LONG '// Offset into file
114.   Size AS LONG '// How big (number of bytes) it is
115.  END TYPE
116.  
117.  TYPE BSP_Header
118.   Magic AS STRING * 4 '// Magic number. Always "IBSP".
119.   Version AS LONG '//  0x2e for the BSP files distributed with Quake 3.
120.   DirEntries AS _MEM '// Lump directory, seventeen entries of type BSP_DirEntry
121.  END TYPE
122.  
123.  TYPE BSP_Texture
124.   Name AS STRING * 64
125.   Flags AS LONG
126.   Contents AS LONG
127.  END TYPE
128.  
129.  TYPE BSP_Plane
130.   Normal AS BSP_Float3
131.   Distance AS SINGLE
132.  END TYPE
133.  
134.  TYPE BSP_Node
135.   Plane AS LONG '// Plane index.
136.   Children AS BSP_Int2 '// Children indices. Negative numbers are leaf indices: -(leaf+1).
137.   Mins AS BSP_Int3 '// LONG bounding box min coord.
138.   Maxs AS BSP_Int3 '//
139.  END TYPE
140.  
141.  TYPE BSP_Leaf
142.   Cluster AS LONG '//  Visdata cluster index.
143.   Area AS LONG '// Areaportal area.
144.   Mins AS BSP_Int3 '// LONG bounding box min coord.
145.   Maxs AS BSP_Int3 '// LONG bounding box max coord.
146.   LeafFace AS LONG '// First leafface for leaf.
147.   NumLeafFaces AS LONG '// Number of leaffaces for leaf.
148.   LeafBrush AS LONG '// First leafbrush for leaf.
149.   NumLeafBrushes AS LONG '// Number of leafbrushes for leaf.
150.  END TYPE
151.  
152.  TYPE BSP_LeafFace
153.   Face AS LONG '// Face index.
154.  END TYPE
155.  
156.  TYPE BSP_LeafBrush
157.   Brush AS LONG '// Brush index.
158.  END TYPE
159.  
160.  TYPE BSP_Model
161.   Mins AS BSP_Float3 '// Bounding box min coord.
162.   Maxs AS BSP_Float3 '// Bounding box max coord.
163.   Face AS LONG '// First face for model.
164.   NumFaces AS LONG '//  Number of faces for model.
165.   Brush AS LONG '// First brush for model.
166.   NumBrushes AS LONG '// Number of brushes for model.
167.  END TYPE
168.  
169.  TYPE BSP_Brush
170.   BrushSide AS LONG '// First brushside for brush.
171.   NumBrushSides AS LONG '// Number of brushsides for brush.
172.   Texture AS LONG '// Texture index.
173.  END TYPE
174.  
175.  TYPE BSP_BrushSide
176.   Plane AS LONG '//  Plane index.
177.   Texture AS LONG '// Texture index.
178.  END TYPE
179.  
180.  TYPE BSP_Vertex
181.   Position AS BSP_Float3 '// Vertex position.
182.   TexCoord_Surface AS BSP_Float2 '//  Vertex texture coordinates. 0=surface, 1=lightmap.
183.   TexCoord_Lightmap AS BSP_Float2
184.   Normal AS BSP_Float3 '// Vertex normal.
185.   Color AS BSP_RGBA '// Vertex color. RGBA.
186.  END TYPE
187.  
188.  TYPE BSP_MeshVert
189.   Offset AS LONG '// Vertex index offset, relative to first vertex of corresponding face.
190.  END TYPE
191.  
192.  TYPE BSP_Effect
193.   Name AS STRING * 64 '// Effect shader.
194.   Brush AS LONG '// Brush that generated this effect.
195.   Unknown AS LONG 'Always 5, except in q3dm8, which has one effect with -1.
196.  END TYPE
197.  
198.  TYPE BSP_Face
199.   Texture AS LONG '// Texture index.
200.   Effect AS LONG '// Index into lump 12 (Effects), or -1.
201.   FaceType AS LONG '// Face type. 1=polygon, 2=patch, 3=mesh, 4=billboard
202.   Vertex AS LONG '// Index of first vertex.
203.   NumVertexes AS LONG '// Number of vertices.
204.   MeshVert AS LONG '// Index of first meshvert.
205.   NumMeshVerts AS LONG '// Number of meshverts.
206.   LMIndex AS LONG '// Lightmap index.
207.   LMStart AS BSP_Int2 '// Corner of this face's lightmap image in lightmap.
208.   LMSize AS BSP_Int2 '// Size of this face's lightmap image in lightmap.
209.   LMOrigin AS BSP_Float3 '// World space origin of lightmap.
210.   LMVecs AS BSP_LM_Vec '// World space lightmap s and t unit vectors.
211.   Normal AS BSP_Float3 '// Surface normal.
212.   Size AS BSP_Int2 '// Patch dimensions.
213.  END TYPE
214.  
215.  TYPE BSP_LightVol
216.   Ambient AS BSP_Light '// Ambient color component. RGB.
217.   Directional AS BSP_Light '// Directional color component. RGB.
218.   LightDirPhi AS _UNSIGNED _BYTE '//  Phi - Direction to light.
219.   LightDirTheta AS _UNSIGNED _BYTE '//  Teta - Direction to light.
220.  END TYPE
221.  
222.  TYPE BSP_VisData
223.   NumVecs AS LONG '// Number of vectors.
224.   SizeVecs AS LONG '// Size of each vector, in bytes.
225.   Vecs AS _MEM 'ubyte[numvecs * sizevecs] vecs  '// Visibility data. One bit per cluster per vector.
226.  END TYPE
227.  
228. END SUB
229.  
230. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
231.  
232. '// Master function returns true (-1) if all was ok, or false (0) if failiure.
233. FUNCTION BSP_Load (Level AS Level, File$)
234.  
235.  InFile = FREEFILE '// Get a free file handle
236.  OPEN File$ FOR BINARY AS #InFile '// Open the file
237.  
238.  BytePos& = 1 '// Byte position variable
239.  
240.  
241.  '// DIM header
242.  DIM Header AS BSP_Header
243.  GET #InFile, BytePos&, Header.Magic '// Get the id, if not "IBSP" then failiure
244.  IF Header.Magic = "IBSP" THEN '// Valid file
245.   BytePos& = BytePos& + LEN(Header.Magic) '// Byte position increment
246.   GET #InFile, BytePos&, Header.Version '// Get the version id
247.   IF Header.Version = 46 THEN '// Valid format (Quake 3 level)
248.    BytePos& = BytePos& + LEN(Header.Version) '// Byte position increment
249.  
250.    DIM Entry(16) AS BSP_DirEntry
251.    GET #InFile, BytePos&, Entry() '// Load all the offsets
252.  
253.    Level.HeaderPntr = _MEMNEW(LEN(Header.Magic) + LEN(Header.Version) + (LEN(Entry(0)) * 17)) '// Allocate memory
254.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET, Header.Magic
255.    MemOffset& = LEN(Header.Magic)
256.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET + MemOffset&, Header.Version
257.    MemOffset& = MemOffset& + LEN(Header.Version)
258.    _MEMPUT Level.HeaderPntr, Level.HeaderPntr.OFFSET + MemOffset&, Entry()
259.  
260.    '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
261.    '// We dont care about certain things in the file for now, we just want rendering and clipping data
262.    '// Need to calculate required memory block and then load data
263.    '// Create single defintions of each required type to use in caluation
264.  
265.    '// Add up size of all the arrays and create _MEM block
266.    DIM MemSize AS _UNSIGNED LONG, MemOffset AS _UNSIGNED LONG
267.  
268.    FOR i% = 0 TO 16
269.     IF i% > 0 AND i% <> 14 THEN '// Ignore blocks we dont want to load
270.      MemSize = MemSize + Entry(i%).Size '// Add up the size of all the memory blocks
271.     END IF
272.    NEXT
273.    Level.DataPntr = _MEMNEW(MemSize)
274.  
275.    '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
276.    '// Load all the bits n pieces
277.  
278.    FOR Index& = 0 TO 16
279.  
280.     BytePos& = Entry(Index&).Start '// Offset of where data starts
281.  
282.     SELECT CASE Index&
283.  
284.      CASE 0 '// Entities  Game-related object descriptions. - We are not gonna worry about these for now
285.      CASE 1 '// Textures  Surface descriptions.
286.  
287.       DIM Tmp_Texture AS BSP_Texture
288.       NumTXRecs& = Entry(Index&).Size / LEN(Tmp_Texture)
289.       DIM Texture(NumTXRecs& - 1) AS BSP_Texture
290.       GET #InFile, BytePos&, Texture()
291.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Texture()
292.  
293.  
294.       FOR i& = 0 TO NumTXRecs& - 1
295.        FName$ = BSP_File_Conform(Texture(i&).Name)
296.        IF _FILEEXISTS(FName$ + ".jpg") THEN
297.         NumTx% = NumTx% + 1
298.        ELSEIF _FILEEXISTS(FName$ + ".tga") THEN
299.         NumTx% = NumTx% + 1
300.        ELSE
301.         '        PRINT "File not found!"
302.        END IF
303.       NEXT
304.  
305.       '// Load all the texture files???
306.       DIM TxtHnd(NumTx% - 1) AS _UNSIGNED LONG
307.  
308.       FOR i& = 0 TO NumTXRecs& - 1
309.        FName$ = BSP_File_Conform(Texture(i&).Name)
310.        IF _FILEEXISTS(FName$ + ".jpg") THEN
311.         TxtHnd(FCnt%) = GDK_GL_LOAD_TEXTURE(FName$ + ".jpg")
312.         FCnt% = FCnt% + 1
313.        ELSEIF _FILEEXISTS(FName$ + ".tga") THEN
314.  
315.         FCnt% = FCnt% + 1
316.        ELSE
317.         '        PRINT "File not found!"
318.        END IF
319.       NEXT
320.  
321.  
322.      CASE 2 '// Planes  Planes used by map geometry.
323.  
324.       DIM TmpPlane AS BSP_Plane
325.       NumPLRecs& = Entry(Index&).Size / LEN(TmpPlane)
326.       DIM Plane(NumPLRecs& - 1) AS BSP_Plane
327.       GET #InFile, BytePos&, Plane()
328.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Plane()
329.  
330.      CASE 3 '// Nodes  BSP tree nodes.
331.  
332.       DIM TmpNode AS BSP_Node
333.       NumNodeRecs& = Entry(Index&).Size / LEN(TmpNode)
334.       DIM Node(NumNodeRecs& - 1) AS BSP_Node
335.       GET #InFile, BytePos&, Node()
336.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Node()
337.  
338.      CASE 4 '// Leafs  BSP tree leaves.
339.  
340.       DIM TmpLeaf AS BSP_Leaf
341.       NumLeafRecs& = Entry(Index&).Size / LEN(TmpLeaf)
342.       DIM Leaf(NumLeafRecs& - 1) AS BSP_Leaf
343.       GET #InFile, BytePos&, Leaf()
344.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Leaf()
345.  
346.      CASE 5 '// Leaffaces  Lists of face indices, one list per leaf.
347.  
348.       DIM TmpLF AS BSP_LeafFace
349.       NumLFRecs& = Entry(Index&).Size / LEN(TmpLF)
350.       DIM LeafFace(NumLFRecs& - 1) AS BSP_LeafFace
351.       GET #InFile, BytePos&, LeafFace()
352.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, LeafFace()
353.  
354.      CASE 6 '// Leafbrushes  Lists of brush indices, one list per leaf.
355.  
356.       DIM TmpLB AS BSP_LeafBrush
357.       NumLBRecs& = Entry(Index&).Size / LEN(TmpLB)
358.       DIM LeafBrush(NumLBRecs& - 1) AS BSP_LeafBrush
359.       GET #InFile, BytePos&, LeafBrush()
360.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, LeafBrush()
361.  
362.      CASE 7 '// Models  Descriptions of rigid world geometry in map.
363.  
364.       DIM TmpMDL AS BSP_Model
365.       NumMDLRecs& = Entry(Index&).Size / LEN(TmpMDL)
366.       DIM BSPMDL(NumMDLRecs& - 1) AS BSP_Model
367.       GET #InFile, BytePos&, BSPMDL()
368.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, BSPMDL()
369.  
370.      CASE 8 '// Brushes  Convex polyhedra used to describe solid space.
371.  
372.       DIM TmpBrush AS BSP_Brush
373.       NumBRecs& = Entry(Index&).Size / LEN(TmpBrush)
374.       DIM Brush(NumBRecs& - 1) AS BSP_Brush
375.       GET #InFile, BytePos&, Brush()
376.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Brush()
377.  
378.      CASE 9 '// Brushsides  Brush surfaces.
379.  
380.       DIM TmpBS AS BSP_BrushSide
381.       NumBSRecs& = Entry(Index&).Size / LEN(TmpBS)
382.       DIM BrushSide(NumBSRecs& - 1) AS BSP_BrushSide
383.       GET #InFile, BytePos&, BrushSide()
384.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, BrushSide()
385.  
386.      CASE 10 '// Vertexes  Vertices used to describe faces.
387.  
388.       DIM TmpVert AS BSP_Vertex
389.       NumVRecs& = Entry(Index&).Size / LEN(TmpVert)
390.       DIM Vertex(NumVRecs& - 1) AS BSP_Vertex
391.       GET #InFile, BytePos&, Vertex()
392.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Vertex()
393.  
394.      CASE 11 '// Meshverts  Lists of offsets, one list per mesh.
395.  
396.       DIM TmpMVert AS BSP_MeshVert
397.       NumMVRecs& = Entry(Index&).Size / LEN(TmpMVert)
398.       DIM MeshVertex(NumMVRecs& - 1) AS BSP_MeshVert
399.       GET #InFile, BytePos&, MeshVertex()
400.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, MeshVertex()
401.  
402.      CASE 12 '// Effects  List of special map effects.
403.  
404.       DIM TmpEffect AS BSP_Effect
405.       NumEFRecs& = Entry(Index&).Size / LEN(TmpEffect)
406.       DIM Effect(NumEFRecs& - 1) AS BSP_Effect
407.       GET #InFile, BytePos&, Effect()
408.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Effect()
409.  
410.      CASE 13 '// Faces  Surface geometry.
411.  
412.       DIM TmpFace AS BSP_Face
413.       NumFaceRecs& = Entry(Index&).Size / LEN(TmpFace)
414.       DIM Face(NumFaceRecs& - 1) AS BSP_Face
415.       GET #InFile, BytePos&, Face()
416.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, Face()
417.  
418.      CASE 14 '// Lightmaps  Packed lightmap data.
419.  
420.       '// array of (127,127,3) Using RGB
421.       '// Gonna ignore this for now
422.  
423.      CASE 15 '// Lightvols  Local illumination data.
424.  
425.       DIM TmpLVols AS BSP_LightVol
426.       NumLVRecs& = Entry(Index&).Size / LEN(TmpLVols)
427.       DIM LightVol(NumLVRecs& - 1) AS BSP_LightVol
428.       GET #InFile, BytePos&, LightVol()
429.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, LightVol()
430.  
431.      CASE 16 '// Visdata  Cluster-cluster visibility data.
432.  
433.       DIM TmpVD AS BSP_VisData
434.       NumVDRecs& = Entry(Index&).Size / LEN(TmpVD)
435.       DIM VD(NumVDRecs& - 1) AS BSP_VisData
436.       GET #InFile, BytePos&, VD()
437.       _MEMPUT Level.DataPntr, Level.DataPntr.OFFSET + MemOffset, VD()
438.  
439.     END SELECT
440.  
441.     IF Index& > 0 AND Index& <> 14 THEN '// Ignore blocks we dont use
442.      MemOffset = MemOffset + Entry(Index&).Size '// increase memory offset
443.     END IF
444.  
445.    NEXT
446.  
447.    BSP_Load = True '// All good!
448.   ELSE
449.    BSP_Load = False '// bad file or unsupported format
450.   END IF
451.  ELSE
452.   BSP_Load = False '// bad file or unsupported format
453.  END IF
454.  
455.  '// All done now so close the file
456.  CLOSE #InFile
457.  
458. END FUNCTION
459.  
460. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
461.  
462. FUNCTION BSP_File_Conform$ (File$) '// Changes file names so we can use them
463.  
464.  Allowed$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890_\/"
465.  
466.  FOR i% = 1 TO LEN(File$)
467.   Ltr$ = MID$(File$, i%, 1)
468.   IF INSTR(Allowed$, Ltr$) OR INSTR(Allowed$, UCASE$(Ltr$)) THEN
469.    IF Ltr$ = "/" THEN
470.     FName$ = FName$ + "\"
471.    ELSE
472.     FName$ = FName$ + Ltr$
473.    END IF
474.   END IF
475.  NEXT
476.  
477.  BSP_File_Conform$ = FName$
478.  
479. END FUNCTION
480.  
481.  
482. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
483.  
484. SUB BSP_Draw (Level AS Level)
485.  
486.  
487. END SUB
488.  
489. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
490.  
491. SUB _GL ()
492.  
493.  IF AllowGL THEN
494.  
495.   IF InitGl THEN
496.    IF BSP_Load(Level, "maps\q3Dead1.bsp") = True THEN '// Load the level data, if it returns true then run renderer
497.  
498.     InitGl = False
499.  
500.    ELSE
501.     '// It not work!
502.    END IF
503.   ELSE '// GL render
504.    BSP_Draw Level
505.  
506.   END IF
507.  END IF
508. END SUB
509.  
510. '///////////////////////////////////////////////\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
511.  
512. SUB GDK_GL_CLS
513.  _glClear _GL_COLOR_BUFFER_BIT OR _GL_DEPTH_BUFFER_BIT '// Clear screen and depth buffers
514.  _glLoadIdentity
515. END SUB
516.  
517. '########################################################################################################################
518. 'Texturing
519. '########################################################################################################################
520.  
521. FUNCTION GDK_GL_MAKE_TEXTURE (File&)
522.  Sx% = _WIDTH(File&)
523.  Sy% = _HEIGHT(File&)
524.  DIM h AS _UNSIGNED LONG, LoadTexture_Buffer(Sx% * Sy%) AS LONG, LoadTexture_Buffer2(Sx% * Sy%) AS LONG
525.  OldSrc& = _SOURCE
526.  _SOURCE File&
527.  GET (0, 0)-(Sx% - 1, Sy% - 1), LoadTexture_Buffer(0)
528.  _SOURCE OldSrc&
529.  FOR y% = 0 TO Sy% - 1
530.   FOR x% = 0 TO Sx% - 1
531.    clr& = LoadTexture_Buffer(PXCnt&)
532.    IF clr& >= _RGB32(245, 245, 245) THEN
533.     LoadTexture_Buffer2(PXCnt&) = ((clr& \ 65536) + 255) + (clr& AND &HFF00&) + ((clr& AND 255) * 65536)
534.    ELSE
535.     LoadTexture_Buffer2(PXCnt&) = ((clr& \ 65536) AND 255) + (clr& AND &HFF00&) + ((clr& AND 255) * 65536)
536.    END IF
537.    PXCnt& = PXCnt& + 1
538.   NEXT
539.  NEXT
540.  _glGenTextures 1, _OFFSET(h)
541.  _glBindTexture _GL_TEXTURE_2D, h
542.  gluBuild2DMipmaps _GL_TEXTURE_2D, _GL_RGBA, Sx%, Sy%, _GL_RGBA, _GL_UNSIGNED_BYTE, LoadTexture_Buffer2(0)
543.  _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_LINEAR
544.  _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_LINEAR_MIPMAP_LINEAR
545.  GDK_GL_MAKE_TEXTURE = h
546. END FUNCTION
547.  
548. '########################################################################################################################
549.  
550. FUNCTION GDK_GL_LOAD_TEXTURE (FileName$)
551.  File& = _LOADIMAGE(FileName$)
552.  IF File& < -1 THEN
553.   Sx% = _WIDTH(File&)
554.   Sy% = _HEIGHT(File&)
555.   DIM h AS _UNSIGNED LONG, LoadTexture_Buffer(Sx% * Sy%) AS LONG, LoadTexture_Buffer2(Sx% * Sy%) AS LONG
556.   OldSrc& = _SOURCE
557.   _SOURCE File&
558.   GET (0, 0)-(Sx% - 1, Sy% - 1), LoadTexture_Buffer(0)
559.   _SOURCE OldSrc&
560.   FOR y% = 0 TO Sy% - 1
561.    FOR x% = 0 TO Sx% - 1
562.     clr& = LoadTexture_Buffer(PXCnt&)
563.     IF clr& >= _RGB32(245, 245, 245) THEN
564.      LoadTexture_Buffer2(PXCnt&) = ((clr& \ 65536) + 255) + (clr& AND &HFF00&) + ((clr& AND 255) * 65536)
565.     ELSE
566.      LoadTexture_Buffer2(PXCnt&) = ((clr& \ 65536) AND 255) + (clr& AND &HFF00&) + ((clr& AND 255) * 65536)
567.     END IF
568.     PXCnt& = PXCnt& + 1
569.    NEXT
570.   NEXT
571.   _glGenTextures 1, _OFFSET(h)
572.   _glBindTexture _GL_TEXTURE_2D, h
573.   gluBuild2DMipmaps _GL_TEXTURE_2D, _GL_RGBA, Sx%, Sy%, _GL_RGBA, _GL_UNSIGNED_BYTE, LoadTexture_Buffer2(0)
574.   _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MAG_FILTER, _GL_LINEAR
575.   _glTexParameteri _GL_TEXTURE_2D, _GL_TEXTURE_MIN_FILTER, _GL_LINEAR_MIPMAP_LINEAR
576.   _FREEIMAGE File&
577.   GDK_GL_LOAD_TEXTURE = h
578.  ELSE
579.   GDK_GL_LOAD_TEXTURE = 0
580.  END IF
581. END FUNCTION
582.  

Happy coding

Unseen

[Unseen Machine]

So, i've run across a problem with missing texture files and have had to reach outside to find out why!

In the interest of keeping everything in one place in case someone needs to reference it later on (doubtful but one can hope) thread is https://discourse.ioquake.org/t/missing-texture-files/1509

Unseen

[Petr]

Hi, I don't know the problem, I'm just asking. Can't the missing textures be part of the basic (default) package with Quake 3?

[Unseen Machine]

Can't the missing textures be part of the basic (default) package with Quake 3?

I thought that so i bought Quake 3 and Quake 3 Team arena and have all the files in the right place. I can find most of the required textures but some seem to be missing or i dont understand the linkage properly.

Thanks though,

Unseen

[Unseen Machine]

Hi folks,

So it turns out (thanks to a gent at ioquake forums) that the missing textures are actually shader references! I havent got as far as even reading much about them yet let alone loading/using them but i'm sure i'll get there eventually!

Unseen