Author Topic: Running strings (Read 7042 times)

DANILIN · « **on:** September 18, 2019, 03:11:55 am »

Running strings from ost to west and from left to right
plus width of screen include in velocity
and I'm searching for same programs

Code: QB64: [Select]

' strunqb64.bas
' running strings from ost to west and from left to right
' plus width of screen include in velocity
 
ost$ = "Russian Export Orientirovannoe Importo Zameschenie"
west$ = "Russian Export Oriented Replace of Import"
ekran = 66: s$ = " ": FOR i = 1 TO ekran + 10: s$ = s$ + " ": NEXT
 
ost$ = s$ + ost$ + s$: west$ = s$ + west$ + s$
ost = LEN(ost$): west = LEN(west$)
 
FOR i = 1 TO west - ekran
    LOCATE 2, 1: PRINT MID$(ost$, i, ekran)
    LOCATE 5, 1: PRINT MID$(west$, west - ekran + 1 - i, ekran)
    _DELAY (.1 - ekran / 1000)
    ' FOR j = 1 TO 10 ^ 7 - ekran ^ (1.5) * 1 * 10 ^ 4: NEXT
NEXT

SMcNeill · « **Reply #1 on:** September 18, 2019, 03:38:06 am »

Question — WTH is: FOR j = 1 TO 10 ^ 7 - ekran ^ (1.5) * 1 * 10 ^ 4: NEXT

A loop with a complex formula that does nothing?? What purpose does it hold? Is it just there to help obfuscate the code, or to purposefully use a ton of CPU power just counting nothing?? What’s it for?

If it’s just to delay printing, why not use a SLEEP, _DELAY, or _LIMIT command inside the loop instead, and play nice with the CPU without needing the obtuse complexity.

DANILIN · « **Reply #2 on:** September 18, 2019, 04:16:43 am »

ok I picked up a pause depending on width of screen
_DELAY (.1 - ekran / 1000)

sleep comand so there used
to be an extensive solution

bplus · « **Reply #3 on:** September 18, 2019, 09:58:15 am »

Code: QB64: [Select]

_TITLE "East meets West" 'B+ 2019-09-18  Outer Limits > [youtube]https://www.youtube.com/watch?v=8CtjhWhw2I8[/youtube]
east$ = "> East >": west$ = "< West <": L = LEN(east$): Outer = 7
DO
    FOR i = 1 TO _WIDTH - L
        FOR j = 1 TO _HEIGHT
            IF j MOD 2 THEN LOCATE j, i: PRINT east$; ELSE LOCATE j, _WIDTH - i - L + 1: PRINT west$;
        NEXT
        _LIMIT Outer
        IF i = 40 - L + 1 THEN CLS: Outer = Outer + 7
    NEXT
    CLS
LOOP
 

https://www.qb64.org/forum/index.php?topic=1674.msg109114#msg109114

DANILIN · « **Reply #4 on:** September 18, 2019, 11:52:24 am »

I will look at another links later
and conveniently attach programs and pictures
or set program name in 1st line as in this Rissian IQ

and now: multi-line running string

Code: QB64: [Select]

' struniq.bas
' running strings from ost to west and from left to right
' multi-string plus width of screen include in velocity
 
DIM q$(5): ekran = 66: s$ = " "
FOR i = 1 TO ekran + 10: s$ = s$ + " ": NEXT
 
q$(1) = "RRR  U U  SSS  SSS  I   A   N  N    III  QQ  "
q$(2) = "R R  U U  S    S    I  AAA  NN N     I  Q  Q "
q$(3) = "RR   U U  SSS  SSS  I  A A  N NN     I  Q  Q "
q$(4) = "R R  U U    S    S  I  AAA  N  N     I  Q QQ "
q$(5) = "R R  UUU  SSS  SSS  I  A A  N  N    III  QQ Q"
 
FOR i = 1 TO 5: q$(i) = s$ + q$(i) + s$: NEXT: q = LEN(q$(1))
 
FOR n = 1 TO 5
    FOR i = 1 TO q - ekran
        FOR j = 1 TO 5
            LOCATE j + 5, 5: COLOR j + i / 15: PRINT MID$(q$(j), i, ekran)
            LOCATE j + 15, 5: COLOR j + i / 22: PRINT MID$(q$(j), q - ekran + 1 - i, ekran)
NEXT: _DELAY (.1 - ekran / 3000): NEXT: NEXT

and multicolored lines and letters are also possible

SMcNeill · « **Reply #5 on:** September 18, 2019, 12:28:16 pm »

Quote from: bplus on September 18, 2019, 09:58:15 am

Code: QB64: [Select]
_TITLE "East meets West" 'B+ 2019-09-18 Outer Limits > [youtube]https://www.youtube.com/watch?v=8CtjhWhw2I8[/youtube]
east$ = "> East >": west$ = "< West <": L = LEN(east$): Outer = 7
DO
FOR i = 1 TO _WIDTH - L
FOR j = 1 TO _HEIGHT
IF j MOD 2 THEN LOCATE j, i: PRINT east$; ELSE LOCATE j, _WIDTH - i - L + 1: PRINT west$;
NEXT
_LIMIT Outer
IF i = 40 - L + 1 THEN CLS: Outer = Outer + 7
NEXT
CLS
LOOP

https://www.qb64.org/forum/index.php?topic=1674.msg109114#msg109114

I see your East and West, and give you this version of it:

Code: QB64: [Select]

SCREEN 12
e$ = "East": w$ = "West": l$ = "East meets West in an EPIC showdown!"
 
FOR i = 0 TO (_WIDTH - _PRINTWIDTH(e$)) \ 2
    CLS
    _PRINTSTRING (i - _PRINTWIDTH(e$) \ 2, 0), e$
    _PRINTSTRING (_WIDTH - i - _PRINTWIDTH(e$) \ 2, 0), w$
    _LIMIT 100
    _DISPLAY
NEXT
 
FOR i = 1 TO 80
    LOCATE 2, i: PRINT _TRIM$(STR$(i MOD 10)) 'just a line of numbers to help show centering
NEXT
 
FOR i = 0 TO LEN(l$) \ 2
    t1$ = MID$(l$, LEN(l$) \ 2 - i, 1)
    t2$ = MID$(l$, LEN(l$) \ 2 + i, 1)
    FOR j = 0 TO _WIDTH \ _FONTWIDTH \ 2 - i
        _PRINTSTRING ((j - 2) * _FONTWIDTH, 30), " " + t1$
        _PRINTSTRING (_WIDTH - (j + 1) * _FONTWIDTH, 30), t2$ + " "
        _LIMIT 100
        _DISPLAY
    NEXT
NEXT

bplus · « **Reply #6 on:** September 18, 2019, 12:53:04 pm »

Well I hope yose guys dont run mine (#3) for 30 secs and think you've seen the whole effect!

Like I think I've seen yours after 30 secs, and think I've seen the whole effect. :)

When you've seen the whole effect, you might understand why I post a link to 45 sec vid that DANLIN doesn't have time to see :D

TempodiBasic · « **Reply #7 on:** September 18, 2019, 06:58:05 pm »

Hi Bplus
yes the effect is clear after 30-40 sec and it goes on ad libitum

BUT you must advice that it is not for epileptic person...

TempodiBasic · « **Reply #8 on:** October 13, 2019, 05:34:41 pm »

Help! A zombie in my mind!

Yes guys
it went out of my mind in these hours while I was playing chess online!
So sorry for my poor style of coding but it seems working....

What about?
Yep a vertical scrolling added to the original horizonthal scrolling of Danilin

Code: QB64: [Select]

' strunqb64.bas
' running strings from ost to west and from left to right
' plus width of screen include in velocity
 
ost$ = "Russian Export Orientirovannoe Importo Zameschenie" ' a string
west$ = "Russian Export Oriented Replace of Import" ' another string
ekran = 66: s$ = " ": FOR i = 1 TO ekran + 10: s$ = s$ + " ": NEXT
' a single: third string: a FOR NEXT to set s$ = 77 spaces
ost$ = s$ + ost$ + s$: west$ = s$ + west$ + s$ 'ost$ and west$ are the middle layer of a sandwich of s$
ost = LEN(ost$): west = LEN(west$) ' ost and west are their lenghts 77+50 +77 , 77+41+77
 
io% = 0
iw% = 0
ost2$ = SPACE$(64) + " " + LTRIM$(RTRIM$(ost$)) + " "
west2$ = " " + LTRIM$(RTRIM$(west$)) + " " + SPACE$(74)
 
FOR i = 1 TO west - ekran 'for 1 to 77+41+77-66=129
    LOCATE 2, 1: PRINT MID$(ost$, i, ekran)
    LOCATE 5, 1: PRINT MID$(west$, west - ekran + 1 - i, ekran)
 
    GOSUB Vertical
 
    _DELAY (.1 - ekran / 1000)
    ' FOR j = 1 TO 10 ^ 7 - ekran ^ (1.5) * 1 * 10 ^ 4: NEXT
NEXT
END
 
Vertical:
'COLOR 7, 1
FOR i2 = 1 TO 25
    LOCATE i2, (_WIDTH / 2) - 2
    PRINT MID$(ost2$, i2 + io%, 1);
    LOCATE 26 - i2, (_WIDTH / 2) + 2
    PRINT MID$(west2$, LEN(west2$) - i2 - iw%, 1);
NEXT
'COLOR 7, 0
IF io% < LEN(ost$) THEN io% = io% + 1 ELSE io% = 0
IF iw% < LEN(west$) THEN iw% = iw% + 1 ELSE iw% = 0
RETURN

TempodiBasic · « **Reply #9 on:** October 13, 2019, 06:42:33 pm »

And this is zombie 2 ! Revenge.

:-P

Code: QB64: [Select]

' struniq.bas
' running strings from ost to west and from left to right
' multi-string plus width of screen include in velocity
 
DIM q$(5): ekran = 66: s$ = " "
FOR i = 1 TO ekran + 10: s$ = s$ + " ": NEXT
 
q$(1) = "RRR  U U  SSS  SSS  I   A   N  N    III  QQ  "
q$(2) = "R R  U U  S    S    I  AAA  NN N     I  Q  Q "
q$(3) = "RR   U U  SSS  SSS  I  A A  N NN     I  Q  Q "
q$(4) = "R R  U U    S    S  I  AAA  N  N     I  Q QQ "
q$(5) = "R R  UUU  SSS  SSS  I  A A  N  N    III  QQ Q"
 
DIM p$(5), q1, iQ
FOR i = 1 TO 5: p$(i) = " " + q$(i) + " ": NEXT i: q1 = LEN(p$(1)): iQ = 0
 
FOR i = 1 TO 5: q$(i) = s$ + q$(i) + s$: NEXT: q = LEN(q$(1))
 
FOR n = 1 TO 5
    FOR i = 1 TO q - ekran
        FOR j = 1 TO 5
            LOCATE j + 5, 5: COLOR j + i / 15: PRINT MID$(q$(j), i, ekran)
            LOCATE j + 15, 5: COLOR j + i / 22: PRINT MID$(q$(j), q - ekran + 1 - i, ekran)
            GOSUB vertical
NEXT: _DELAY (.1 - ekran / 3000): NEXT: NEXT
END
 
vertical:
FOR i2 = 1 TO 25
    FOR j2 = 1 TO 5
        COLOR j2 + i2 / 15
        LOCATE i2, (_WIDTH / 2) - 8 + j2
        PRINT MID$(p$(j2), i2 + iQ, 1);
        COLOR j2 + i2 / 22
        LOCATE 26 - i2, (_WIDTH / 2) + 8 - j2
        PRINT MID$(p$(j2), q1 - i2 - iQ, 1);
    NEXT
NEXT
_DELAY .1
IF iQ < q1 THEN iQ = iQ + 1 ELSE iQ = 0
RETURN

News:

Author Topic: Running strings (Read 7042 times)

DANILIN

Running strings

SMcNeill

Re: Running strings

DANILIN

Re: Running strings

bplus

Re: Running strings

DANILIN

Re: Running strings

SMcNeill

Re: Running strings

bplus

Re: Running strings

TempodiBasic

Re: Running strings

TempodiBasic

Re: Running strings

TempodiBasic

Re: Running strings