Fractal Art by Zom-B

[The Librarian]

Fractal Art

Author: Zom-B
Source: [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] Forum
URL: /forum/index.php?topic=1124.0]http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1124.0
Version: 2010
Tags: [2d], [fractal]

Description:
This is [...] a series of fractal artworks that I ported from Ultra Fractal to Quick Basic 4.5 with the Future library, and are currently upgrading to QB64. I received permission from the author(s) of the artworks to republish their works in this particular form. The original consists of a lot of include and routine files $included in the main, which I have merged here for convenience.

(Code edited by The Librarian to run in QB64 v1.2.)

Source Code (one of four):

Code: QB64: [Select]

1. '> Merged with Zom-B's smart $include merger 0.51
2.  
3. DEFSNG A-Z
4.  
5. '####################################################################################################################
6. '# Math Library V1.0 (include)
7. '# By Zom-B
8. '####################################################################################################################
9.  
10. CONST sqrt2 = 1.41421356237309504880168872420969807856967187537695 ' Knuth01
11. CONST sqrt3 = 1.73205080756887729352744634150587236694280525381038 ' Knuth02
12. CONST sqrt5 = 2.23606797749978969640917366873127623544061835961153 ' Knuth03
13. CONST sqrt10 = 3.16227766016837933199889354443271853371955513932522 ' Knuth04
14. CONST cubert2 = 1.25992104989487316476721060727822835057025146470151 ' Knuth05
15. CONST cubert3 = 1.44224957030740838232163831078010958839186925349935 ' Knuth06
16. CONST q2pow025 = 1.18920711500272106671749997056047591529297209246382 ' Knuth07
17. CONST phi = 1.61803398874989484820458683436563811772030917980576 ' Knuth08
18. CONST log2 = 0.69314718055994530941723212145817656807550013436026 ' Knuth09
19. CONST log3 = 1.09861228866810969139524523692252570464749055782275 ' Knuth10
20. CONST log10 = 2.30258509299404568401799145468436420760110148862877 ' Knuth11
21. CONST logpi = 1.14472988584940017414342735135305871164729481291531 ' Knuth12
22. CONST logphi = 0.48121182505960344749775891342436842313518433438566 ' Knuth13
23. CONST q1log2 = 1.44269504088896340735992468100189213742664595415299 ' Knuth14
24. CONST q1log10 = 0.43429448190325182765112891891660508229439700580367 ' Knuth15
25. CONST q1logphi = 2.07808692123502753760132260611779576774219226778328 ' Knuth16
26. CONST pi = 3.14159265358979323846264338327950288419716939937511 ' Knuth17
27. CONST deg2rad = 0.01745329251994329576923690768488612713442871888542 ' Knuth18
28. CONST q1pi = 0.31830988618379067153776752674502872406891929148091 ' Knuth19
29. CONST pisqr = 9.86960440108935861883449099987615113531369940724079 ' Knuth20
30. CONST gamma05 = 1.7724538509055160272981674833411451827975494561224 '  Knuth21
31. CONST gamma033 = 2.6789385347077476336556929409746776441286893779573 '  Knuth22
32. CONST gamma067 = 1.3541179394264004169452880281545137855193272660568 '  Knuth23
33. CONST e = 2.71828182845904523536028747135266249775724709369996 ' Knuth24
34. CONST q1e = 0.36787944117144232159552377016146086744581113103177 ' Knuth25
35. CONST esqr = 7.38905609893065022723042746057500781318031557055185 ' Knuth26
36. CONST eulergamma = 0.57721566490153286060651209008240243104215933593992 ' Knuth27
37. CONST expeulergamma = 1.7810724179901979852365041031071795491696452143034 '  Knuth28
38. CONST exppi025 = 2.19328005073801545655976965927873822346163764199427 ' Knuth29
39. CONST sin1 = 0.84147098480789650665250232163029899962256306079837 ' Knuth30
40. CONST cos1 = 0.54030230586813971740093660744297660373231042061792 ' Knuth31
41. CONST zeta3 = 1.2020569031595942853997381615114499907649862923405 '  Knuth32
42. CONST nloglog2 = 0.36651292058166432701243915823266946945426344783711 ' Knuth33
43.  
44. CONST logr10 = 0.43429448190325182765112891891660508229439700580367
45. CONST logr2 = 1.44269504088896340735992468100189213742664595415299
46. CONST pi05 = 1.57079632679489661923132169163975144209858469968755
47. CONST pi2 = 6.28318530717958647692528676655900576839433879875021
48. CONST q05log10 = 0.21714724095162591382556445945830254114719850290183
49. CONST q05log2 = 0.72134752044448170367996234050094606871332297707649
50. CONST q05pi = 0.15915494309189533576888376337251436203445964574046
51. CONST q13 = 0.33333333333333333333333333333333333333333333333333
52. CONST q16 = 0.16666666666666666666666666666666666666666666666667
53. CONST q2pi = 0.63661977236758134307553505349005744813783858296183
54. CONST q2sqrt5 = 0.89442719099991587856366946749251049417624734384461
55. CONST rad2deg = 57.2957795130823208767981548141051703324054724665643
56. CONST sqrt02 = 0.44721359549995793928183473374625524708812367192231
57. CONST sqrt05 = 0.70710678118654752440084436210484903928483593768847
58. CONST sqrt075 = 0.86602540378443864676372317075293618347140262690519
59. CONST y2q112 = 1.05946309435929526456182529494634170077920431749419 ' Chromatic base
60.  
61. '####################################################################################################################
62. '# Screen mode selector v1.0 (include)
63. '# By Zom-B
64. '####################################################################################################################
65.  
66. videoaspect:
67. DATA "all aspect",15
68. DATA "4:3",11
69. DATA "16:10",10
70. DATA "16:9",14
71. DATA "5:4",13
72. DATA "3:2",12
73. DATA "5:3",9
74. DATA "1:1",7
75. DATA "other",8
76. DATA ,
77.  
78. videomodes:
79. DATA 256,256,7
80. DATA 320,240,1
81. DATA 400,300,1
82. DATA 512,384,1
83. DATA 512,512,7
84. DATA 640,480,1
85. DATA 720,540,1
86. DATA 768,576,1
87. DATA 800,480,2
88. DATA 800,600,1
89. DATA 854,480,3
90. DATA 1024,600,8
91. DATA 1024,640,2
92. DATA 1024,768,1
93. DATA 1024,1024,7
94. DATA 1152,768,5
95. DATA 1152,864,1
96. DATA 1280,720,3
97. DATA 1280,768,6
98. DATA 1280,800,2
99. DATA 1280,854,5
100. DATA 1280,960,1
101. DATA 1280,1024,4
102. DATA 1366,768,3
103. DATA 1400,1050,1
104. DATA 1440,900,2
105. DATA 1440,960,5
106. DATA 1600,900,3
107. DATA 1600,1200,1
108. DATA 1680,1050,2
109. DATA 1920,1080,3
110. DATA 1920,1200,2
111. DATA 2048,1152,3
112. DATA 2048,1536,1
113. DATA 2048,2048,7
114. DATA ,,
115.  
116. '####################################################################################################################
117. '# Ultra Fractal Gradient library v1.0 (include)
118. '# By Zom-B
119. '#
120. '# Smooth Gradient algorithm from Ultra Fractal (www.ultrafractal.com)
121. '####################################################################################################################
122.  
123. TYPE GRADIENTPOINT
124.     index AS SINGLE
125.     r AS SINGLE
126.     g AS SINGLE
127.     b AS SINGLE
128.     rdr AS SINGLE
129.     rdl AS SINGLE
130.     gdr AS SINGLE
131.     gdl AS SINGLE
132.     bdr AS SINGLE
133.     bdl AS SINGLE
134. END TYPE
135.  
136. '$dynamic
137.  
138. DIM SHARED gradientSmooth(1) AS _BYTE '_BIT <- bugged
139. DIM SHARED gradientPoints(1) AS INTEGER
140. DIM SHARED gradient(1, 1) AS GRADIENTPOINT
141.  
142.  
143. '####################################################################################################################
144. '# Sierpinsky Rays+aet for QB64
145. '# By Zom-B
146. '#
147. '# Original art by Daniele (alcamese@libero.it)
148. '# Tweaked by Athena Tracey (athena_1963@hotmail.com)
149. '####################################################################################################################
150.  
151. CONST Doantialias = -1
152. CONST Usegaussian = 0
153.  
154. '####################################################################################################################
155.  
156. _TITLE "Sierpinsky Rays+aet"
157. WIDTH 80, 40
158.  
159. COLOR 11
160. PRINT
161. PRINT TAB(30); "Sierpinsky Rays+aet"
162. COLOR 7
163. PRINT
164. PRINT TAB(18); "Original art by Daniele (alcamese@libero.it)"
165. PRINT TAB(15); "Tweaked by Athena Tracey (athena_1963@hotmail.com)"
166. PRINT TAB(19); "Converted to Quick Basic and QB64 by Zom-B"
167.  
168. selectScreenMode 7, 32
169.  
170. '####################################################################################################################
171.  
172. DIM SHARED sizeX%, sizeY%
173. DIM SHARED maxX%, maxY%
174. DIM SHARED halfX%, halfY%
175.  
176. sizeX% = _WIDTH
177. sizeY% = _HEIGHT
178. maxX% = sizeX% - 1
179. maxY% = sizeY% - 1
180. halfX% = sizeX% \ 2
181. halfY% = sizeY% \ 2
182.  
183. DIM SHARED magX, magY
184.  
185. magX = 1.300052002080083203328133125325 / halfY%
186. magY = 1.300052002080083203328133125325 / halfY%
187.  
188. DIM SHARED zx(149), zy(149)
189.  
190. '####################################################################################################################
191.  
192. setNumGradients 5
193.  
194. addGradientPoint 0, -0.0450, 0.710, 1.000, 1.000
195. addGradientPoint 0, 0.0025, 1.000, 0.702, 0.729
196. addGradientPoint 0, 0.0850, 0.082, 0.431, 0.000
197. addGradientPoint 0, 0.2300, 0.812, 0.745, 0.824
198. addGradientPoint 0, 0.5500, 0.380, 0.000, 0.000
199. addGradientPoint 0, 0.7600, 1.000, 0.757, 1.000
200. addGradientPoint 0, 0.8800, 0.000, 0.263, 0.000
201. addGradientPoint 0, 0.9550, 0.710, 1.000, 1.000
202. addGradientPoint 0, 1.0025, 1.000, 0.702, 0.729
203. setGradientSmooth 0, -1
204.  
205. addGradientPoint 1, -0.0450, 0.165, 0.000, 0.184
206. addGradientPoint 1, 0.7475, 0.718, 0.918, 1.000
207. addGradientPoint 1, 0.8425, 0.945, 0.710, 1.000
208. addGradientPoint 1, 0.9550, 0.165, 0.000, 0.184
209. addGradientPoint 1, 1.7475, 0.718, 0.918, 1.000
210. setGradientSmooth 1, -1
211.  
212. addGradientPoint 2, -0.2750, 0.000, 0.973, 0.114
213. addGradientPoint 2, 0.0475, 1.000, 0.545, 0.875
214. addGradientPoint 2, 0.1725, 0.000, 0.345, 0.000
215. addGradientPoint 2, 0.5500, 1.000, 0.071, 1.000
216. addGradientPoint 2, 0.7250, 0.000, 0.973, 0.114
217. addGradientPoint 2, 1.0475, 1.000, 0.545, 0.875
218. setGradientSmooth 2, -1
219.  
220. addGradientPoint 3, -0.0675, 1.000, 0.502, 1.000
221. addGradientPoint 3, 0.0700, 0.000, 0.000, 0.698
222. addGradientPoint 3, 0.1650, 0.725, 0.741, 0.000
223. addGradientPoint 3, 0.3300, 0.290, 0.000, 0.757
224. addGradientPoint 3, 0.4550, 0.000, 0.251, 0.039
225. addGradientPoint 3, 0.6375, 0.584, 0.918, 1.000
226. addGradientPoint 3, 0.8250, 0.000, 0.165, 0.000
227. addGradientPoint 3, 0.9325, 1.000, 0.502, 1.000
228. addGradientPoint 3, 1.0700, 0.000, 0.000, 0.698
229. setGradientSmooth 3, -1
230.  
231. addGradientPoint 4, -0.1025, 1.000, 0.282, 0.082
232. addGradientPoint 4, 0.0775, 0.306, 0.376, 1.000
233. addGradientPoint 4, 0.2225, 0.333, 0.298, 0.000
234. addGradientPoint 4, 0.3000, 1.000, 1.000, 0.208
235. addGradientPoint 4, 0.3800, 0.337, 0.271, 0.741
236. addGradientPoint 4, 0.6400, 0.651, 0.404, 0.220
237. addGradientPoint 4, 0.8075, 0.000, 1.000, 1.000
238. addGradientPoint 4, 0.8975, 1.000, 0.282, 0.082
239. addGradientPoint 4, 1.0775, 0.306, 0.376, 1.000
240. setGradientSmooth 4, -1
241.  
242. renderProgressive 256, 4
243.  
244. i$ = INPUT$(1)
245. END
246.  
247. '####################################################################################################################
248.  
249. SUB renderProgressive (startSize%, endSize%)
250.     pixStep% = startSize%
251.  
252.     pixWidth% = pixStep% - 1
253.     FOR y% = 0 TO maxY% STEP pixStep%
254.         FOR x% = 0 TO maxX% STEP pixStep%
255.             calcPoint x%, y%, r%, g%, b%
256.             LINE (x%, y%)-STEP(pixWidth%, pixWidth%), _RGB(r%, g%, b%), BF
257.         NEXT
258.         IF INKEY$ = CHR$(27) THEN SYSTEM
259.     NEXT
260.  
261.     DO
262.         pixSize% = pixStep% \ 2
263.         pixWidth% = pixSize% - 1
264.         FOR y% = 0 TO maxY% STEP pixStep%
265.             y1% = y% + pixSize%
266.             FOR x% = 0 TO maxX% STEP pixStep%
267.                 x1% = x% + pixSize%
268.  
269.                 IF x1% < sizeX% THEN
270.                     calcPoint x1%, y%, r%, g%, b%
271.                     LINE (x1%, y%)-STEP(pixWidth%, pixWidth%), _RGB(r%, g%, b%), BF
272.                 END IF
273.                 IF y1% < sizeY% THEN
274.                     calcPoint x%, y1%, r%, g%, b%
275.                     LINE (x%, y1%)-STEP(pixWidth%, pixWidth%), _RGB(r%, g%, b%), BF
276.                     IF x1% < sizeX% THEN
277.                         calcPoint x1%, y1%, r%, g%, b%
278.                         LINE (x1%, y1%)-STEP(pixWidth%, pixWidth%), _RGB(r%, g%, b%), BF
279.                     END IF
280.                 END IF
281.             NEXT
282.             IF INKEY$ = CHR$(27) THEN SYSTEM
283.         NEXT
284.         pixStep% = pixStep% \ 2
285.     LOOP WHILE pixStep% > 2
286.  
287.     FOR y% = 0 TO maxY% STEP 2
288.         y1% = y% + 1
289.         FOR x% = 0 TO maxX% STEP 2
290.             x1% = x% + 1
291.  
292.             IF x1% < sizeX% THEN
293.                 calcPoint x1%, y%, r%, g%, b%
294.                 PSET (x1%, y%), _RGB(r%, g%, b%)
295.             END IF
296.             IF y1% < sizeY% THEN
297.                 calcPoint x%, y1%, r%, g%, b%
298.                 PSET (x%, y1%), _RGB(r%, g%, b%)
299.                 IF x1% < sizeX% THEN
300.                     calcPoint x1%, y1%, r%, g%, b%
301.                     PSET (x1%, y1%), _RGB(r%, g%, b%)
302.                 END IF
303.             END IF
304.         NEXT
305.         IF INKEY$ = CHR$(27) THEN SYSTEM
306.     NEXT
307.  
308.     IF NOT Doantialias THEN EXIT SUB
309.  
310.     endArea% = endSize% * endSize%
311.  
312.     IF Usegaussian THEN
313.         FOR y% = 0 TO maxY%
314.             FOR x% = 0 TO maxX%
315.                 c& = POINT(x%, y%)
316.                 r% = _RED(c&)
317.                 g% = _GREEN(c&)
318.                 b% = _BLUE(c&)
319.                 FOR i% = 2 TO endArea%
320.                     DO 'Marsaglia polar method for random gaussian
321.                         u! = RND * 2 - 1
322.                         v! = RND * 2 - 1
323.                         s! = u! * u! + v! * v!
324.                     LOOP WHILE s! >= 1 OR s! = 0
325.                     s! = SQR(-2 * LOG(s!) / s!) * 0.5
326.                     u! = u! * s!
327.                     v! = v! * s!
328.  
329.                     calcPoint x% + u!, y% + v!, r1%, g1%, b1%
330.  
331.                     r% = r% + r1%
332.                     g% = g% + g1%
333.                     b% = b% + b1%
334.                 NEXT
335.  
336.                 PSET (x%, y%), _RGB(CINT(r% / endArea%), CINT(g% / endArea%), CINT(b% / endArea%))
337.                 IF INKEY$ = CHR$(27) THEN SYSTEM
338.             NEXT
339.         NEXT
340.     ELSE
341.         FOR y% = 0 TO maxY%
342.             FOR x% = 0 TO maxX%
343.                 r% = 0
344.                 g% = 0
345.                 b% = 0
346.                 FOR v% = 0 TO endSize% - 1
347.                     y1! = y% + v% / endSize%
348.                     FOR u% = 0 TO endSize% - 1
349.                         IF u% = 0 AND v& = 0 THEN
350.                             c& = POINT(x%, y%)
351.                         ELSE
352.                             x1! = x% + u% / endSize%
353.                             calcPoint x1!, y1!, r1%, g1%, b1%
354.                         END IF
355.                         r% = r% + r1%
356.                         g% = g% + g1%
357.                         b% = b% + b1%
358.                     NEXT
359.                 NEXT
360.                 PSET (x%, y%), _RGB(CINT(r% / endArea%), CINT(g% / endArea%), CINT(b% / endArea%))
361.                 IF INKEY$ = CHR$(27) THEN SYSTEM
362.             NEXT
363.         NEXT
364.     END IF
365. END SUB
366.  
367. '####################################################################################################################
368.  
369. SUB calcPoint (screenX!, screenY!, r%, g%, b%)
370.     applyLocation screenX!, screenY!, px, py
371.  
372.     fractal px, py, numIter1%, numIter2%
373.  
374.     outside1 numIter1%, index!
375.     getGradient 0, index!, r!, g!, b!
376.  
377.     outside2 numIter2%, index!
378.     getGradient 1, index!, r2!, g2!, b2!
379.     r! = ABS(r! - r2!): g! = ABS(g! - g2!): b! = ABS(b! - b2!)
380.  
381.     outside3 numIter2%, index!
382.     getGradient 2, index!, r2!, g2!, b2!
383.     r1! = r!: g1! = g!: b1! = b!
384.     mergeOverlay r!, g!, b!, r2!, g2!, b2!
385.     r! = r1! + (r! - r1!) * 0.45
386.     g! = g1! + (g! - g1!) * 0.45
387.     b! = b1! + (b! - b1!) * 0.45
388.  
389.     outside4 numIter2%, index!
390.     getGradient 3, index!, r2!, g2!, b2!
391.     r! = r! + r2!: g! = g! + g2!: b! = b! + b2!
392.  
393.     outside5 px, py, numIter2%, index!
394.     getGradient 4, index!, r2!, g2!, b2!
395.     r1! = r!: g1! = g!: b1! = b!
396.     mergeColor r!, g!, b!, r2!, g2!, b2!
397.     r! = r1! + (r! - r1!) * 0.5
398.     g! = g1! + (g! - g1!) * 0.5
399.     b! = b1! + (b! - b1!) * 0.5
400.  
401.     r% = r! * 255
402.     g% = g! * 255
403.     b% = b! * 255
404. END SUB
405.  
406. '####################################################################################################################
407.  
408. SUB applyLocation (inX!, inY!, outX, outY)
409.     x = (inX! - halfX%) * magX
410.     y = (halfY% - inY!) * magY
411.     outX = 0.99999998476912904932780850903444 * x - 1.7453292431333680334067268304459D-4 * y - 0.01168313399#
412.     outY = 1.7453292431333680334067268304459D-4 * x + 0.99999998476912904932780850903444 * y - 0.00626625065#
413. END SUB
414.  
415. '####################################################################################################################
416.  
417. SUB fractal (px, py, numIter1%, numIter2%)
418.     xx = px * px: yy = py * py
419.  
420.     x = ABS(px * xx - 3 * px * yy) * 0.2
421.     y = ABS(3 * xx * py - py * yy) * 0.2
422.     x = x - INT(x * 2.5 + 0.5) * 0.4
423.     y = y - INT(y * 2.5 + 0.5) * 0.4
424.  
425.     zx(0) = x: zy(0) = y
426.  
427.     numIter1% = -1
428.     numIter2% = -1
429.     FOR numIter% = 1 TO 149
430.         x = x * 2: y = y * 2
431.  
432.         IF y > 1 THEN
433.             y = y - 1
434.         ELSEIF x > 1 THEN
435.             x = x - 1
436.         END IF
437.  
438.         zx(numIter%) = x: zy(numIter%) = y
439.  
440.         IF x * x + y * y > 127 THEN
441.             IF numIter2% = -1 THEN numIter2% = numIter% - 1
442.             IF numIter1% >= 0 THEN EXIT SUB
443.         END IF
444.  
445.         bail = ABS(x + y)
446.         IF bail * bail > 127 THEN
447.             IF numIter1% = -1 THEN numIter1% = numIter% - 1
448.             IF numIter2% >= 0 THEN EXIT SUB
449.         END IF
450.     NEXT
451.  
452.     IF numIter1% = -1 THEN numIter1% = 149
453.     IF numIter2% = -1 THEN numIter2% = 149
454. END SUB
455.  
456. '####################################################################################################################
457.  
458. SUB outside1 (numIter%, index!)
459.     index! = ATN(numIter% / 25)
460. END SUB
461.  
462. '####################################################################################################################
463.  
464. SUB outside2 (numIter%, index!)
465.     closest = 1E+38
466.     ix = 0
467.     iy = 0
468.  
469.     FOR a% = 1 TO numIter%
470.         x = zx(a%) * zx(a%): y = zy(a%) * zy(a%)
471.         d = x * x + y * y
472.  
473.         IF d < closest THEN
474.             closest = d
475.             ix = zx(a%)
476.             iy = zy(a%)
477.         END IF
478.     NEXT
479.  
480.     index! = SQR(SQR(ix * ix + iy * iy) * 2) / 2
481. END SUB
482.  
483. '####################################################################################################################
484.  
485. SUB outside3 (numIter%, index!)
486.     x = zx(numIter% + 1)
487.     y = zy(numIter% + 1)
488.     d = atan2(y, x) / pi2
489.     index! = SQR((6.349563872353654# - 4.284804271440222# * LOG(LOG(SQR(x * x + y * y))) + ABS((d - INT(d)) * 4 - 2)) * 2) / 2
490. END SUB
491.  
492. '####################################################################################################################
493.  
494. SUB outside4 (numIter%, index!)
495.     closest = 1E+38
496.  
497.     FOR a% = 1 TO numIter%
498.         zy2 = zy(a%) * zy(a%)
499.         d = zx(a%) + zx(a%) * zx(a%) + zy2
500.         d = SQR(d * d + zy2)
501.  
502.         IF d < closest THEN
503.             closest = d
504.         END IF
505.     NEXT
506.  
507.     index! = asin(closest ^ .1) ^ (1 / 1.5) * .41577394#
508. END SUB
509.  
510. '####################################################################################################################
511.  
512. SUB outside5 (px, py, numIter%, index!)
513.     r = SQR(px * px + py * py)
514.     cost = px / r
515.     sint = py / r
516.  
517.     ave = 0
518.     i% = 0
519.     FOR a% = 1 TO numIter%
520.         prevave = ave
521.  
522.         x = zx(a%)
523.         y = zy(a%)
524.         r = SQR(x * x + y * y)
525.         x = zx(a%) / r + cost
526.         y = zy(a%) / r + sint
527.  
528.         ave = ave + SQR(x * x + y * y)
529.  
530.         cost = -cost
531.         sint = -sint
532.         i% = i% + 1
533.     NEXT
534.  
535.     ave = ave / numIter%
536.     prevave = prevave / (numIter% - 1)
537.     x = zx(numIter% + 1)
538.     y = zy(numIter% + 1)
539.     f = 2.2762545841680618369458486886285 - 1.4426950408889634073599246810019 * LOG(LOG(SQR(x * x + y * y)))
540.     index! = prevave + (ave - prevave) * f
541.  
542.     index! = index! * 2
543. END SUB
544.  
545. '####################################################################################################################
546. '# Math Library V0.11 (routines)
547. '# By Zom-B
548. '####################################################################################################################
549.  
550. '> merger: Skipping unused FUNCTION remainder% (a%, b%)
551.  
552. '> merger: Skipping unused FUNCTION fRemainder (a, b)
553.  
554. '####################################################################################################################
555.  
556. '> merger: Skipping unused FUNCTION safeLog (x)
557.  
558. '####################################################################################################################
559.  
560. FUNCTION asin (y)
561.     IF y = -1 THEN asin = -pi05: EXIT FUNCTION
562.     IF y = 1 THEN asin = pi05: EXIT FUNCTION
563.     asin = ATN(y / SQR(1 - y * y))
564. END FUNCTION
565.  
566. '> merger: Skipping unused FUNCTION acos (y)
567.  
568. '> merger: Skipping unused FUNCTION safeAcos (y)
569.  
570. FUNCTION atan2 (y, x)
571.     IF x > 0 THEN
572.         atan2 = ATN(y / x)
573.     ELSEIF x < 0 THEN
574.         IF y > 0 THEN
575.             atan2 = ATN(y / x) + pi
576.         ELSE
577.             atan2 = ATN(y / x) - pi
578.         END IF
579.     ELSEIF y > 0 THEN
580.         atan2 = pi / 2
581.     ELSE
582.         atan2 = -pi / 2
583.     END IF
584. END FUNCTION
585.  
586. '####################################################################################################################
587. '# Screen mode selector v1.0 (routines)
588. '# By Zom-B
589. '####################################################################################################################
590.  
591. SUB selectScreenMode (yOffset%, colors%)
592.     DIM aspectName$(10), aspectCol%(10)
593.     RESTORE videoaspect
594.     FOR y% = 0 TO 10
595.         READ aspectName$(y%), aspectCol%(y%)
596.         IF aspectCol%(y%) = 0 THEN numAspect% = y% - 1: EXIT FOR
597.     NEXT
598.  
599.     DIM vidX%(100), vidY%(100), vidA%(100)
600.     RESTORE videomodes
601.     FOR y% = 1 TO 100
602.         READ vidX%(y%), vidY%(y%), vidA%(y%)
603.         IF (vidX%(y%) <= 0) THEN numModes% = y% - 1: EXIT FOR
604.     NEXT
605.  
606.     IF numModes% > _HEIGHT - yOffset% - 1 THEN numModes% = _HEIGHT - yOffset% - 1
607.  
608.     DEF SEG = &HB800
609.     LOCATE yOffset% + 1, 1
610.     PRINT "Select video mode:"; TAB(61); "Click "
611.     POKE yOffset% * 160 + 132, 31
612.  
613.     y% = 0
614.     lastY% = 0
615.     selectedAspect% = 0
616.     reprint% = 1
617.     lastButton% = 0
618.     DO
619.         IF INKEY$ = CHR$(27) THEN CLS: SYSTEM
620.         IF reprint% THEN
621.             reprint% = 0
622.  
623.             FOR x% = 1 TO numModes%
624.                 LOCATE yOffset% + x% + 1, 1
625.                 COLOR 7, 0
626.                 PRINT USING "##:"; x%;
627.                 IF selectedAspect% = 0 THEN
628.                     COLOR aspectCol%(vidA%(x%))
629.                 ELSEIF selectedAspect% = vidA%(x%) THEN
630.                     COLOR 15
631.                 ELSE
632.                     COLOR 8
633.                 END IF
634.                 PRINT STR$(vidX%(x%)); ","; vidY%(x%);
635.             NEXT
636.  
637.             FOR x% = 0 TO numAspect%
638.                 IF x% > 0 AND selectedAspect% = x% THEN
639.                     COLOR aspectCol%(x%), 3
640.                 ELSE
641.                     COLOR aspectCol%(x%), 0
642.                 END IF
643.                 LOCATE yOffset% + x% + 2, 64
644.                 PRINT "<"; aspectName$(x%); ">"
645.             NEXT
646.         END IF
647.         IF _MOUSEINPUT THEN
648.             IF lastY% > 0 THEN
649.                 FOR x% = 0 TO 159 STEP 2
650.                     POKE lastY% + x%, PEEK(lastY% + x%) AND &HEF
651.                 NEXT
652.             END IF
653.  
654.             x% = _MOUSEX
655.             y% = _MOUSEY - yOffset% - 1
656.  
657.             IF x% <= 60 THEN
658.                 IF y% > 0 AND y% <= numModes% THEN
659.                     IF _MOUSEBUTTON(1) = 0 AND lastButton% THEN EXIT DO
660.                     y% = (yOffset% + y%) * 160 + 1
661.                     FOR x% = 0 TO 119 STEP 2
662.                         POKE y% + x%, PEEK(y% + x%) OR &H10
663.                     NEXT
664.                 ELSE
665.                     y% = 0
666.                 END IF
667.             ELSE
668.                 IF y% > 0 AND y% - 1 <= numAspect% THEN
669.                     IF _MOUSEBUTTON(1) THEN
670.                         selectedAspect% = y% - 1
671.                         reprint% = 1
672.                     END IF
673.                     y% = (yOffset% + y%) * 160 + 1
674.                     FOR x% = 120 TO 159 STEP 2
675.                         POKE y% + x%, PEEK(y% + x%) OR &H10
676.                     NEXT
677.                 ELSE
678.                     y% = 0
679.                 END IF
680.             END IF
681.             lastY% = y%
682.             lastButton% = _MOUSEBUTTON(1)
683.         END IF
684.     LOOP
685.  
686.     CLS 'bug evasion for small video modes
687.     SCREEN _NEWIMAGE(vidX%(y%), vidY%(y%), colors%)
688. END SUB
689.  
690. '####################################################################################################################
691. '# Ultra Fractal Gradient library v1.1 (routines)
692. '# By Zom-B
693. '#
694. '# Smooth Gradient algorithm from Ultra Fractal (www.ultrafractal.com)
695. '####################################################################################################################
696.  
697. '> merger: Skipping unused SUB defaultGradient (gi%)
698.  
699. '> merger: Skipping unused SUB grayscaleGradient (gi%)
700.  
701. '####################################################################################################################
702.  
703. SUB setNumGradients (gi%)
704.     offset% = LBOUND(gradientPoints) - 1
705.     REDIM _PRESERVE gradientSmooth(gi% + offset%) AS _BYTE '_BIT <- bugged
706.     REDIM _PRESERVE gradientPoints(gi% + offset%) AS INTEGER
707.     REDIM _PRESERVE gradient(gi% + offset%, 1) AS GRADIENTPOINT
708. END FUNCTION
709.  
710. SUB addGradientPoint (gi%, index!, r!, g!, b!)
711.     p% = gradientPoints(gi%)
712.  
713.     IF UBOUND(gradient, 2) < p% THEN
714.         REDIM _PRESERVE gradient(0 TO UBOUND(gradient, 1), 0 TO p%) AS GRADIENTPOINT
715.     END IF
716.  
717.     gradient(gi%, p%).index = index!
718.     gradient(gi%, p%).r = r!
719.     gradient(gi%, p%).g = g!
720.     gradient(gi%, p%).b = b!
721.     gradientPoints(gi%) = p% + 1
722. END SUB
723.  
724. SUB setGradientSmooth (gi%, s%)
725.     gradientSmooth(gi%) = s%
726.  
727.     IF gradientSmooth(0) = 0 THEN EXIT SUB
728.  
729.     FOR i% = 0 TO gradientPoints(gi%) - 1
730.         ip1% = i% + 1
731.         IF ip1% = gradientPoints(gi%) THEN ip1% = 2
732.         in1% = i% - 1
733.         IF in1% = -1 THEN in1% = gradientPoints(gi%) - 3
734.  
735.         dxl! = gradient(gi%, i%).index - gradient(gi%, in1%).index
736.         dxr! = gradient(gi%, ip1%).index - gradient(gi%, i%).index
737.         IF dxl! < 0 THEN dxl! = dxl! + 1
738.         IF dxr! < 0 THEN dxr! = dxr! + 1
739.  
740.         d! = (gradient(gi%, i%).r - gradient(gi%, in1%).r) * dxr!
741.         IF d! = 0 THEN
742.             gradient(gi%, i%).rdr = 0
743.             gradient(gi%, i%).rdl = 0
744.         ELSE
745.             d! = (gradient(gi%, ip1%).r - gradient(gi%, i%).r) * dxl! / d!
746.             IF d! <= 0 THEN
747.                 gradient(gi%, i%).rdr = 0
748.                 gradient(gi%, i%).rdl = 0
749.             ELSE
750.                 gradient(gi%, i%).rdr = 1 / (1 + d!)
751.                 gradient(gi%, i%).rdl = gradient(gi%, i%).rdr - 1
752.             END IF
753.         END IF
754.  
755.         d! = (gradient(gi%, i%).g - gradient(gi%, in1%).g) * dxr!
756.         IF d! = 0 THEN
757.             gradient(gi%, i%).gdr = 0
758.             gradient(gi%, i%).gdl = 0
759.         ELSE
760.             d! = (gradient(gi%, ip1%).g - gradient(gi%, i%).g) * dxl! / d!
761.             IF d! <= 0 THEN
762.                 gradient(gi%, i%).gdr = 0
763.                 gradient(gi%, i%).gdl = 0
764.             ELSE
765.                 gradient(gi%, i%).gdr = 1 / (1 + d!)
766.                 gradient(gi%, i%).gdl = gradient(gi%, i%).gdr - 1
767.             END IF
768.         END IF
769.  
770.         d! = (gradient(gi%, i%).b - gradient(gi%, in1%).b) * dxr!
771.         IF d! = 0 THEN
772.             gradient(gi%, i%).bdr = 0
773.             gradient(gi%, i%).bdl = 0
774.         ELSE
775.             d! = (gradient(gi%, ip1%).b - gradient(gi%, i%).b) * dxl! / d!
776.             IF d! <= 0 THEN
777.                 gradient(gi%, i%).bdr = 0
778.                 gradient(gi%, i%).bdl = 0
779.             ELSE
780.                 gradient(gi%, i%).bdr = 1 / (1 + d!)
781.                 gradient(gi%, i%).bdl = gradient(gi%, i%).bdr - 1
782.             END IF
783.         END IF
784.     NEXT
785. END SUB
786.  
787. '####################################################################################################################
788.  
789. SUB getGradient (gi%, index!, red!, green!, blue!)
790.     IF index! < 0 THEN x! = 0 ELSE x! = index! - INT(index!)
791.  
792.     FOR l% = gradientPoints(gi%) - 2 TO 1 STEP -1
793.         IF gradient(gi%, l%).index <= x! THEN
794.             EXIT FOR
795.         END IF
796.     NEXT
797.  
798.     r% = l% + 1
799.     u! = (x! - gradient(gi%, l%).index) / (gradient(gi%, r%).index - gradient(gi%, l%).index)
800.  
801.     IF gradientSmooth(gi%) THEN
802.         u2! = u! * u!
803.         u3! = u2! * u!
804.         ur! = u3! - (u2! + u2!) + u!
805.         ul! = u2! - u3!
806.  
807.         red! = gradient(gi%, l%).r + (gradient(gi%, r%).r - gradient(gi%, l%).r) * (u3! + 3 * (gradient(gi%, l%).rdr * ur! + (1 + gradient(gi%, r%).rdl) * ul!))
808.         green! = gradient(gi%, l%).g + (gradient(gi%, r%).g - gradient(gi%, l%).g) * (u3! + 3 * (gradient(gi%, l%).gdr * ur! + (1 + gradient(gi%, r%).gdl) * ul!))
809.         blue! = gradient(gi%, l%).b + (gradient(gi%, r%).b - gradient(gi%, l%).b) * (u3! + 3 * (gradient(gi%, l%).bdr * ur! + (1 + gradient(gi%, r%).bdl) * ul!))
810.     ELSE
811.         red! = gradient(gi%, l%).r + (gradient(gi%, r%).r - gradient(gi%, l%).r) * u!
812.         green! = gradient(gi%, l%).g + (gradient(gi%, r%).g - gradient(gi%, l%).g) * u!
813.         blue! = gradient(gi%, l%).b + (gradient(gi%, r%).b - gradient(gi%, l%).b) * u!
814.     END IF
815. END SUB
816.  
817. '> merger: Skipping unused SUB testGradient (gi%)
818.  
819. '####################################################################################################################
820. '# Merge modes library v0.1 (routines)
821. '# By Zom-B
822. '####################################################################################################################
823.  
824. '> merger: Skipping unused SUB testMerge
825.  
826. '####################################################################################################################
827.  
828. SUB mergeOverlay (br!, bg!, bb!, tr!, tg!, tb!)
829.     IF br! <= 0.5 THEN br! = br! * tr! * 2 ELSE br! = 1 - (1 - br!) * (1 - tr!) * 2
830.     IF bg! <= 0.5 THEN bg! = bg! * tg! * 2 ELSE bg! = 1 - (1 - bg!) * (1 - tg!) * 2
831.     IF bb! <= 0.5 THEN bb! = bb! * tb! * 2 ELSE bb! = 1 - (1 - bb!) * (1 - tb!) * 2
832. END SUB
833.  
834. '> merger: Skipping unused SUB mergeHardLight (br!, bg!, bb!, tr!, tg!, tb!)
835.  
836. '> merger: Skipping unused SUB mergeSoftLight (br!, bg!, bb!, tr!, tg!, tb!)
837.  
838. SUB mergeColor (r!, g!, b!, r2!, g2!, b2!)
839.     max! = r!
840.     min! = r!
841.     IF max! < g! THEN max! = g!
842.     IF min! > g! THEN min! = g!
843.     IF max! < b! THEN max! = b!
844.     IF min! > b! THEN min! = b!
845.  
846.     lum1! = max! + min!
847.  
848.     max! = r2!
849.     min! = r2!
850.     IF max! < g2! THEN max! = g2!
851.     IF min! > g2! THEN min! = g2!
852.     IF max! < b2! THEN max! = b2!
853.     IF min! > b2! THEN min! = b2!
854.  
855.     sum! = max! + min!
856.     dif! = max! - min!
857.  
858.     IF sum! < 1 THEN
859.         sat2! = dif! / sum!
860.     ELSE
861.         sat2! = dif! / (2 - sum!)
862.     END IF
863.  
864.     IF dif! = 0 THEN
865.         lum1! = lum1! * 0.5
866.         r! = lum1!: g! = lum1!: b! = lum1!
867.         EXIT SUB
868.     END IF
869.  
870.     IF lum1! < 1 THEN
871.         chr! = sat2! * lum1!
872.     ELSE
873.         chr! = sat2! * (2 - lum1!)
874.     END IF
875.     min! = (lum1! - chr!) * 0.5
876.  
877.     IF max! = r2! THEN
878.         hue2! = (g2! - b2!) / dif!
879.         IF hue2! < 0 THEN
880.             r! = chr! + min!: g! = min!: b! = chr! * -hue2! + min!
881.         ELSE
882.             r! = chr! + min!: g! = chr! * hue2! + min!: b! = min!
883.         END IF
884.     ELSEIF max! = g2! THEN
885.         hue2! = (b2! - r2!) / dif!
886.         IF hue2! < 0 THEN
887.             r! = chr! * -hue2! + min!: g! = chr! + min!: b! = min!
888.         ELSE
889.             r! = min!: g! = chr! + min!: b! = chr! * hue2! + min!
890.         END IF
891.     ELSE
892.         hue2! = (r2! - g2!) / dif!
893.         IF hue2! < 0 THEN
894.             r! = min!: g! = chr! * -hue2! + min!: b! = chr! + min!
895.         ELSE
896.             r! = chr! * hue2! + min!: g! = min!: b! = chr! + min!
897.         END IF
898.     END IF
899. END SUB
900.  
901. '> merger: Skipping unused SUB mergeHSLAddition (r!, g!, b!, r2!, g2!, b2!)
902.  
903. '####################################################################################################################
904.  
905. '> merger: Skipping unused SUB mergeHue (r!, g!, b!, r2!, g2!, b2!)
906.  
907. '> merger: Skipping unused SUB rgb2hsl (r!, g!, b!, chr!, smallest!, hue!, sat!, lum!)
908.  
909. '> merger: Skipping unused SUB hsl2rgb (hue!, sat!, lum!, r!, g!, b!)
910.  
911. '> merger: Skipping unused SUB hsl2rgb2 (hue!, chr!, smallest!, r!, g!, b!)
912.