Simple Challenge Pattern Derivatives

[SMcNeill]

Playing around with the code which I wrote for bplus's challenge here (https://www.qb64.org/forum/index.php?topic=1467.0 ), I decided to play around with my numbers and see what other simple patterns I could generate, which led me to the little brain seizure inducing code below:

Code: QB64: [Select]

1. DEFLNG A-Z
2. SCREEN _NEWIMAGE(640, 480, 32)
3. DIM C(-1 TO 0): C(-1) = &HFFFF0000: C(0) = &HFF0000FF
4.  
5. DO
6.     variance = variance + 1
7.     IF variance > 640 THEN variance = 0
8.     CLS
9.  
10.     FOR i = 0 TO 8
11.         k = NOT k
12.         x = 25 * SIN(_D2R(30 * i)) + variance
13.         y = 25 * COS(_D2R(30 * i)) + 50
14.         CIRCLE (x, y), 25, C(k)
15.         PAINT (x, y), C(k)
16.     NEXT
17.  
18.     h = _NEWIMAGE(50, 100, 32)
19.     _PUTIMAGE , 0, h, (variance, 0)-(100, 100)
20.     f = _NEWIMAGE(100, 100, 32)
21.     _DEST f
22.     D h, 50, 0, 0, 1: D h, 0, 0, 180, 4
23.     _DEST 0
24.  
25.     CLS
26.     a = 0
27.     DO
28.         a = a + 3
29.         FOR y = -50 TO 530 STEP 82
30.             Z = NOT Z
31.             dir = 1: IF Z THEN dir = -1
32.             FOR x = -50 TO 690 STEP 100
33.                 D f, x + Z * 50, y, dir * a, 0
34.         NEXT x, y
35.     LOOP UNTIL a >= 180
36.  
37. LOOP
38.  
39. SUB D (Im, x, y, a, m)
40.     DIM px(3), py(3)
41.     w = _WIDTH(Im) - 1: h = 99
42.     SELECT CASE m
43.         CASE 0: px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2: px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
44.         CASE 1: px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0: px(1) = 0: py(1) = h: px(2) = w: py(2) = h
45.         CASE 4: px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h: px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
46.     END SELECT
47.     s! = SIN(_D2R(a)): c! = COS(_D2R(a))
48.     FOR i = 0 TO 3
49.         x2 = (px(i) * c! + s! * py(i)) + x: y2 = (py(i) * c! - px(i) * s!) + y
50.         px(i) = x2: py(i) = y2
51.     NEXT
52.     _MAPTRIANGLE (0, 0)-(0, h)-(w, h), Im TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
53.     _MAPTRIANGLE (0, 0)-(w, 0)-(w, h), Im TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
54. END SUB
55.  

[TempodiBasic]

Wow
this challenge is sure out of my ability!

I'm at window waiting what will be post.
In the while I can say thanks you have remembered me the Degree/Radiant functions for SIN and COS that eat only radiant!

Good Coding

[Ashish]

Cool! Looks like optical illusion.

[Ashish]

Hi. I created a new Pattern. :)

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2. DO
3.     _LIMIT 30
4. LOOP
5. SUB drawPattern (a, s, c AS _BYTE, N)
6.     IF s < 0.001 THEN EXIT SUB
7.     IF c = 1 THEN _glColor3f 1, 1, 1 ELSE _glColor3f 0, 0, 0
8.     _glBegin _GL_POLYGON
9.     FOR i = a TO _PI(2) + a STEP _PI(2 / N)
10.         _glVertex2f s * COS(i), s * SIN(i)
11.     NEXT
12.     _glEnd
13.     IF c = 1 THEN drawPattern a + 0.1, s - 0.01, 0, N ELSE drawPattern a + 0.1, s - 0.01, 1, N
14. END SUB
15. SUB _GL ()
16.     STATIC c
17.     drawPattern c, 1.5, 1, 8
18.     c = c + 0.01
19. END SUB
20.  

[Ashish]

Okay. So, here is a dancing color MOD.

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(600, 600, 32)
2. DO
3.     _LIMIT 30
4. LOOP
5. SUB drawPattern (a, s, c AS _BYTE, N)
6.     IF s < 0.001 THEN EXIT SUB
7.     IF c = 1 THEN _glColor3f 1, 1, 1 ELSE _glColor3f RND, RND, RND
8.     _glBegin _GL_POLYGON
9.     FOR i = a TO _PI(2) + a STEP _PI(2 / N)
10.         _glVertex2f s * COS(i), s * SIN(i)
11.     NEXT
12.     _glEnd
13.     IF c = 1 THEN drawPattern a + 0.1, s - 0.01, 0, N ELSE drawPattern a + 0.1, s - 0.01, 1, N
14. END SUB
15. SUB _GL ()
16.     STATIC c
17.     drawPattern c, 2, 1, 8
18.     c = c + 0.01
19. END SUB
20.  
21.  
22.  

[johnno56]

Wow! I think ALL Optometrists should have THIS demo as part of the list of eye tests... lol
Very cool... a bit trippy... but cool none the less...