Re: midnight tic tac toe - exercise game

[bplus]

Well if you get too lonely there is AI guy to play against, it's hard (impossible) to beat.

 

[bplus]

It's more fun to play against something! :)

[bplus]

Hi ron77,

You might like this in your game or toolbox, wait for a key from certain set of key presses:

Code: QB64: [Select]

1. _TITLE "GetKey$ test" 'B+ 2019-06-15
2.  
3. DO
4.     PRINT "Press #'s 0 to 9 or escape..."
5.     ky$ = GetKey$(CHR$(27) + "1234567890")
6.     IF INSTR("1234567890", ky$) THEN PRINT "You pressed "; ky$ ELSE PRINT "Goodbye!"
7.     PRINT
8. LOOP UNTIL ASC(ky$) = 27
9.  
10. FUNCTION GetKey$ (keysToCatch$)
11.     DIM k$
12.     DO
13.         k$ = INKEY$
14.         WHILE LEN(k$) = 0
15.             k$ = INKEY$
16.             _LIMIT 60
17.         WEND
18.     LOOP UNTIL INSTR(keysToCatch$, k$)
19.     GetKey$ = k$
20. END FUNCTION
21.  

[bplus]

Hi ron77,

I still see a couple of places where GetKey$ could be used to eliminate all Enter key presses needed for INPUT's. In my opinion it is best to be consistent, all enter's or all just one key press.

You know, I think I play a game longer when it let's me win once in awhile, this latest version for instance. I remember being turned off early on by a version on NIM, it always won and was a bit snotty about it. So this might be more enjoyable than INVICTUS you have planned or the AI I showed here for that matter.

[bplus]

Hi ron77,

Ah! so much smoother without enter any where. The choice of 1 player or 2 might be made only once at the beginning for 1 less question each round...

Oh but you say final version...? so much more can be done eg, Center Print text lines on screen:
replace:

Code: QB64: [Select]

1.  
2. opening
3.  
4. DO
5.     ky2$ = GetKey$(CHR$(27) + CHR$(13))
6.     IF ky2$ = CHR$(27) THEN END
7. LOOP UNTIL ky2$ = CHR$(13)
8.  
9. PRINT "PLAY IN FULL SCREEN MODE? - y/n:"
10. DO
11.     ky3$ = GetKey$("yn")
12.     IF INSTR("y", ky3$) THEN _FULLSCREEN: EXIT DO
13. LOOP UNTIL ky3$ = "n"
14.  
15. '... and this
16. SUB opening
17.     PRINT "     " + DATE$ + " " + TIME$
18.     PRINT
19.     PRINT "   WELCOME FRIEND TO:"
20.     PRINT
21.     PRINT "       MIDNIGHT TIC TAC TOE GAME!"
22.     PRINT
23.     PRINT "  WINS = 10 POINTS: TIES = 5 POINTS EACH"
24.     PRINT
25.     PRINT " A SMALL GAME TO PLAY BEFORE BED-TIME"
26.     PRINT
27.     PRINT "    BY RON77 AND ITAY"
28.     PRINT
29.     PRINT "PRESS ENTER TO CONTINUE OR ESC TO QUIT"
30.     PRINT
31.  
32. END SUB
33.  

with this:

Code: QB64: [Select]

1. opening
2.  
3. '... and this
4. SUB opening
5.     DIM k$
6.     cp 3, DATE$ + " Time:" + TIME$
7.     cp 5, "WELCOME FRIEND TO:"
8.     cp 7, "MIDNIGHT TIC TAC TOE GAME!"
9.     cp 9, "WINS = 10 POINTS: TIES = 5 POINTS EACH"
10.     cp 11, "A SMALL GAME TO PLAY BEFORE BED-TIME"
11.     cp 13, "BY RON77 AND ITAY"
12.     cp 18, "PRESS ENTER TO CONTINUE OR ESC TO QUIT"
13.     k$ = GetKey$(CHR$(27) + CHR$(13))
14.     IF k$ = CHR$(27) THEN END
15.     cp 20, "PLAY IN FULL SCREEN MODE? - y/n:"
16.     k$ = GetKey$("yn")
17.     IF k$ = "y" THEN _FULLSCREEN
18. END SUB
19.  
20. SUB cp (row, s$) 'print text centered on screen row
21.     LOCATE row, (80 - LEN(s$)) / 2: PRINT s$
22. END SUB

I am certain that the number of lines of code could be easily reduced below 200, wouldn't change the play of game but good coding challenge... to get inventive.

With solid study of game from reducing lines, might be ready to learn mouse skills.

[bplus]

Hi ron77,

Of course you can set ending code like opening to save some lines. In fact everywhere you print something you could probably use cp instead, even the board.

If gameArray() is shared don't need to use it in procedure calls.

Also there is hardly any difference between CheckWinner and CheckWinnerComp. I think if the function returned the mark of the winner if it finds one you wouldn't need the redundant procedure.
eg, if a(0) = a(1) = a(2) then function = a(0)
If function finds no winner after 8 checks then function = 0
 
Yes, for AI, if you go through open spots in the game array and substitute in the marker then check if winner then remove marker from game array you can save yourself all that crazy array copying!!!

Play again?

Code: QB64: [Select]

1.     PRINT "play again y/n?:"
2.     again$ = UCASE$(GetKey$("yn"))
3. LOOP UNTIL again$ = "N"
4.  

Over and over I see you are not using GetKey$ correctly:

Code: QB64: [Select]

1.     ky4$ = GetKey$("12")
2.     IF INSTR("12", ky4$) THEN numPlayer = VAL(ky4$)  '
3.  

GetKey$ will be either 1 or 2, no checking with INSTR necessary

Just say:

Code: QB64: [Select]

1. numPlayer = VAL(GetKey$("12")

[bplus]

Code: QB64: [Select]

1. SUB board (gameArray() AS STRING)
2.     cp 2, "Welcome to MIDNIGHT TIC TAC TOE GAME!"
3.     cp 4, greetings
4.     cp 6, "ֲֲִִִִִִִִִ¿"
5.     cp 7, "³   ³   ³   ³"
6.     cp 8, "³ " + gameArray(0) + " ³ " + gameArray(1) + " ³ " + gameArray(2) + " ³"
7.     cp 9, "³(0)³(1)³(2)³"
8.     cp 10, "ֳִִִִִִִִִֵֵ´"
9.     cp 11, "³   ³   ³   ³"
10.     cp 12, "³ " + gameArray(3) + " ³ " + gameArray(4) + " ³ " + gameArray(5) + " ³"
11.     cp 13, "³(3)³(4)³(5)³"
12.     cp 14, "ֳִִִִִִִִִֵֵ´"
13.     cp 15, "³   ³   ³   ³"
14.     cp 16, "³ " + gameArray(6) + " ³ " + gameArray(7) + " ³ " + gameArray(8) + " ³"
15.     cp 17, "³(6)³(7)³(8)³"
16.     cp 18, "ְֱֱִִִִִִִִִ"
17.  
18. END SUB
19.  

gameArray is Shared the board SUB does not need that argument passed to it

Code: QB64: [Select]

1. SUB board
2.  

is all that is needed.

Here is revised Winner$ function that replaces the two that are almost redundant.

Code: QB64: [Select]

1. FUNCTION Winner$
2.     IF game(0) = game(1) AND game(1) = game(2) AND game(0) <> " " THEN
3.         Winner$ = game(0)
4.     ELSEIF game(3) = game(4) AND game(4) = game(5) AND game(3) <> " " THEN
5.         Winner$ = game(3)
6.     ELSEIF game(6) = game(7) AND game(7) = game(8) AND game(6) <> " " THEN
7.         Winner$ = game(6)
8.     ELSEIF game(0) = game(3) AND game(3) = game(6) AND game(0) <> " " THEN
9.         Winner$ = game(0)
10.     ELSEIF game(1) = game(4) AND game(4) = game(7) AND game(1) <> " " THEN
11.         Winner$ = game(1)
12.     ELSEIF game(2) = game(5) AND game(5) = game(8) AND game(2) <> " " THEN
13.         Winner$ = game(2)
14.     ELSEIF game(0) = game(4) AND game(4) = game(8) AND game(0) <> " " THEN
15.         Winner$ = game(0)
16.     ELSEIF game(6) = game(4) AND game(4) = game(2) AND game(6) <> " " THEN
17.         Winner$ = game(6)
18.     ELSE
19.         Winner$ = ""
20.     END IF
21. END FUNCTION
22.  

I am in process of checking the computer moves (now called AI function) with the new Winner$ function now.
EDIT: oops! I thought I saved last change...

BTW I renamed gameArray game() since I changed game$ to again$ and dumped all the array copying that you guys were doing.

Again I say, where ever you use GetKey$, you don't have to check it again with INSTR() that's the beauty of GetKey$, you get what you require in CatchKeys$. see line 50 and 71 and 96

[bplus]

Hi ron77,

I'm sorry about your teacher. Once I got rolling with makeover, I couldn't stop until made my goal of less than 200 lines.

as for the dim shared not needed to passed as parameters to subs\functions i didn't know that yet that's how i am used to writing code (a legacy from VB.NET)

I was trying to say that if you DIM SHARE an array, then you don't have to include it in the parameters list of the sub definition:

Code: QB64: [Select]

1. SUB Board(myArray as string)

IF myArray was already in main code:

Code: QB64: [Select]

1. DIM SHARE myArray(1 to n) AS STRING

you can just do this:

Code: QB64: [Select]

1. SUB Board

because myArray is already available to any procedure.

well i checked your solution to the Winner$ function and it only works for 2 players but not for the AI function and as for your say that doing a copy of the Game Array is unnecessary i think it's a must cause the AI needs a copy of the game array so it can mess around with it without the original game array is changed...

I didn't have to copy the game() because when I switched an empty space with a sign$ and it didn't do anything for the AI, I switched it back to the empty space and tried another spot. So the array remains intact unless the AI finds a winner move, then it is already made in the array and does not have to be switched back to a space.

It all works and in less than 200 lines:

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. 'started by me ron77 on 6-15-2019 saturday night...
3. 'one boring lonley weekend night i started to feel sad with no one to talk to...
4. 'so i started this on my own so i won't feel lonely and sad all night
5. 'by morning i got it right as a begining of a it was a white-night coding thing
6. '5-6-7 cups of coffee and a few cigarettes and relaxing music was all that it took
7. 'by sun rise i felt better
8. '7 AM - add possiblemoves function
9. '10:30 AM - added a counter named turns to count turns and stop after 9 moves in case there is a tie and nobody wins
10. '9 PM - had a lesson with my teacher and we added a human vs. computer play with basic AI :) we also made some design modification
11. '6-17-2019 - more design modification to the board and to the code - added Bplus GetKey$ function and now no need for INPUT command to get user input added another loop to keep playing after first finished
12. 'me and my teacher are working on a second harder AI alogarithem to beat in HUMAN VS. COMPUTER called INVICTUS MODE which will hopefully be very hard to beat next lesson on WED this week...
13. '6-18-2019 - in the meanwhile i am posting this short version 1 of tic tac toe in QB64 FORUM without level 2 INVICTUS MODE AI alogarithem: ENJOY! :)
14. '6-19-2019 - final version! thanks to all how helped!
15. '6-19-2019 - Bplus makeover reduce to less than 200 lines
16.  
17. _TITLE "MIDNIGHT TIC TAC TOE"
18. DIM SHARED game(8) AS STRING, numPlayer AS INTEGER, greetings AS STRING, code$, turns AS INTEGER
19. DIM SHARED scoreX AS INTEGER, scoreO AS INTEGER, scoreComp AS INTEGER
20. DIM i AS INTEGER, again$
21.  
22. opening
23. DO
24.     FOR i = 0 TO 8: game(i) = " ": NEXT 'clear last board
25.     turns = 0 'reset count
26.     IF numPlayer = 2 THEN
27.         greetings = "TWO PLAYERS X AND O"
28.         DO
29.             player "X"
30.             IF code$ = "win" THEN scoreX = scoreX + 10: EXIT DO
31.             IF code$ = "tie" THEN scoreX = scoreX + 5: scoreO = scoreO + 5: EXIT DO
32.             player "O"
33.             IF code$ = "win" THEN scoreO = scoreO + 10: EXIT DO
34.             IF code$ = "tie" THEN scoreX = scoreX + 5: scoreO = scoreO + 5: EXIT DO
35.         LOOP
36.     ELSE
37.         greetings = "HUMAN PLAYER AS X VS. COMPUTER AS O"
38.         DO
39.             player "X"
40.             IF code$ = "win" THEN scoreX = scoreX + 10: EXIT DO
41.             IF code$ = "tie" THEN scoreX = scoreX + 5: scoreComp = scoreComp + 5: EXIT DO
42.             IF AI = -1 THEN
43.                 board
44.                 cp 19, "O is winner."
45.                 scoreComp = scoreComp + 10
46.                 EXIT DO
47.             ELSE
48.                 turns = turns + 1
49.             END IF
50.         LOOP
51.     END IF
52.     cp 21, "play again y/n?"
53.     again$ = UCASE$(GetKey$("yn"))
54. LOOP UNTIL again$ = "N"
55. ending
56.  
57. SUB player (sign$) 'replace 3 repeated code blocks with this
58.     DIM k$, inpt AS INTEGER
59.     code$ = ""
60.     board
61.     cp 19, "Where to mark " + sign$ + "? press 0-8 or ESC to stop:"
62.     k$ = GetKey$(CHR$(27) + "012345678")
63.     IF ASC(k$) = 27 THEN ending ELSE inpt = VAL(k$)
64.     IF game(inpt) = " " THEN
65.         game(inpt) = sign$
66.         board
67.         IF Winner$ = sign$ THEN
68.             code$ = "win": cp 19, sign$ + " wins!"
69.         ELSE
70.             turns = turns + 1
71.             IF turns = 9 THEN
72.                 code$ = "tie": cp 19, "Tie nobody wins!"
73.             END IF
74.         END IF
75.     ELSE
76.         board
77.         cp 19, "The square is occupied choose another."
78.         _DELAY 1.5
79.         player sign$ ' recursive do this again!
80.     END IF
81. END SUB
82.  
83. SUB ending
84.     CLS
85.     cp 7, "G O O D  -  N I G H T !"
86.     cp 9, "       AND SWEET DREAMS!"
87.     cp 11, "HUMAN PLAYER X HAS" + STR$(scoreX) + " points"
88.     cp 13, "HUMAN PLAYER O HAS" + STR$(scoreO) + " points"
89.     cp 15, "COMPUTER PLAYER O HAS" + STR$(scoreComp) + " points"
90.     SLEEP
91.     END
92. END SUB
93.  
94. SUB board
95.     CLS
96.     cp 1, "Welcome to MIDNIGHT TIC TAC TOE GAME!"
97.     cp 3, greetings
98.     cp 5, "ÚÄÄÄÂÄÄÄÂÄÄÄ¿"
99.     cp 6, "³   ³   ³   ³"
100.     cp 7, "³ " + game(0) + " ³ " + game(1) + " ³ " + game(2) + " ³"
101.     cp 8, "³(0)³(1)³(2)³"
102.     cp 9, "ÃÄÄÄÅÄÄÄÅÄÄÄ´"
103.     cp 10, "³   ³   ³   ³"
104.     cp 11, "³ " + game(3) + " ³ " + game(4) + " ³ " + game(5) + " ³"
105.     cp 12, "³(3)³(4)³(5)³"
106.     cp 13, "ÃÄÄÄÅÄÄÄÅÄÄÄ´"
107.     cp 14, "³   ³   ³   ³"
108.     cp 15, "³ " + game(6) + " ³ " + game(7) + " ³ " + game(8) + " ³"
109.     cp 16, "³(6)³(7)³(8)³"
110.     cp 17, "ÀÄÄÄÁÄÄÄÁÄÄÄÙ"
111. END SUB
112.  
113. SUB opening
114.     DIM k$
115.     cp 3, DATE$ + " " + TIME$
116.     cp 5, "WELCOME FRIEND TO:"
117.     cp 7, "MIDNIGHT TIC TAC TOE GAME!"
118.     cp 9, "WINS = 10 POINTS: TIES = 5 POINTS EACH"
119.     cp 11, "A SMALL GAME TO PLAY BEFORE BED-TIME"
120.     cp 13, "BY RON77, ITAY and BPLUS"
121.     cp 18, "PRESS ENTER TO CONTINUE OR ESC TO QUIT"
122.     k$ = GetKey$(CHR$(27) + CHR$(13))
123.     IF k$ = CHR$(27) THEN END
124.     cp 20, "Press 1 for One Player or 2 for Two Players?"
125.     numPlayer = VAL(GetKey$("12"))
126.     cp 22, "PLAY IN FULL SCREEN MODE? - y/n"
127.     k$ = GetKey$("yn")
128.     IF k$ = "y" THEN _FULLSCREEN
129. END SUB
130.  
131. SUB cp (row, s$) 'print text centered on screen row
132.     LOCATE row, (80 - LEN(s$)) / 2: PRINT s$;
133. END SUB
134.  
135. FUNCTION GetKey$ (keysToCatch$)
136.     DIM k$
137.     DO
138.         k$ = INKEY$
139.         WHILE LEN(k$) = 0
140.             k$ = INKEY$
141.             _LIMIT 60
142.         WEND
143.     LOOP UNTIL INSTR(keysToCatch$, k$)
144.     GetKey$ = k$
145. END FUNCTION
146.  
147. FUNCTION AI
148.     DIM i AS INTEGER, rndNumber AS INTEGER
149.     FOR i = 0 TO 8 'computer seeks win
150.         IF game(i) = " " THEN
151.             game(i) = "O"
152.             IF Winner$ = "O" THEN
153.                 AI = -1: EXIT FUNCTION 'signal win
154.             ELSE
155.                 game(i) = " "
156.             END IF
157.         END IF
158.     NEXT
159.     FOR i = 0 TO 8 'computer seeks spoiler
160.         IF game(i) = " " THEN
161.             game(i) = "X"
162.             IF Winner$ = "X" THEN
163.                 game(i) = "O": EXIT FUNCTION
164.             ELSE
165.                 game(i) = " "
166.             END IF
167.         END IF
168.     NEXT
169.     rndNumber = INT(RND * 9) 'computers picks random open space
170.     WHILE game(rndNumber) <> " "
171.         rndNumber = INT(RND * 9)
172.     WEND
173.     game(rndNumber) = "O"
174. END FUNCTION
175.  
176. FUNCTION Winner$
177.     IF game(0) = game(1) AND game(1) = game(2) AND game(0) <> " " THEN
178.         Winner$ = game(0)
179.     ELSEIF game(3) = game(4) AND game(4) = game(5) AND game(3) <> " " THEN
180.         Winner$ = game(3)
181.     ELSEIF game(6) = game(7) AND game(7) = game(8) AND game(6) <> " " THEN
182.         Winner$ = game(6)
183.     ELSEIF game(0) = game(3) AND game(3) = game(6) AND game(0) <> " " THEN
184.         Winner$ = game(0)
185.     ELSEIF game(1) = game(4) AND game(4) = game(7) AND game(1) <> " " THEN
186.         Winner$ = game(1)
187.     ELSEIF game(2) = game(5) AND game(5) = game(8) AND game(2) <> " " THEN
188.         Winner$ = game(2)
189.     ELSEIF game(0) = game(4) AND game(4) = game(8) AND game(0) <> " " THEN
190.         Winner$ = game(0)
191.     ELSEIF game(6) = game(4) AND game(4) = game(2) AND game(6) <> " " THEN
192.         Winner$ = game(6)
193.     ELSE
194.         Winner$ = ""
195.     END IF
196. END FUNCTION
197.  

The BIG screen is nice for late night Tic Tac Toe!

Oh yeah, I sort of figured out why you were using INSTR in some places after GetKey$ call. With CHR$(27) added to the CatchKey$ string, you did have to figure out first if ESCAPE was pressed and K$ was coming back with that! before processing the other key presses.

[bplus]

Oh hey ron77,

There is a wide open door to winning against the AI, (not 100% guarantee but still pretty good) see if you can figure it out ;-))