Screen Saver #3 Mystic Rectangles

[bplus]

Yep! Another bplus graphics thingy.

Code: QB64: [Select]

1. _TITLE " *** Screen Saver #3 - Mystic Rectangles *** by bplus 2018-03-01"
2. ' translated from
3. ' Screen Saver #3 Mystic Rectangles.bas SmallBASIC 0.12.11 (B+=MGA) 2018-02-28
4. ' instead of wire frame triangles try solid color rectangles
5. ' arrays? we don't need no dang arrays!
6. ' oh to share everything use GOSUBs instead of SUBs
7.  
8. RANDOMIZE TIMER
9. CONST xmax = 1200
10. CONST ymax = 700
11. SCREEN _NEWIMAGE(xmax, ymax, 32)
12. _SCREENMOVE 100, 20
13.  
14. nT = 150 'number of Things per screen
15. GOSUB newRect
16. savex1 = x1: savey1 = y1: savedx1 = dx1: savedy1 = dy1
17. savex2 = x2: savey2 = y2: savedx2 = dx2: savedy2 = dy2
18. cN = nT
19. GOSUB resetPlasma
20. WHILE 1
21.     CLS
22.  
23.     'reset color Number back to beginning + 1
24.     cN = cN - nT + 1
25.  
26.     'reset rect back to beginning and then update it once and save this for next round
27.     x1 = savex1: y1 = savey1: dx1 = savedx1: dy1 = savedy1
28.     x2 = savex2: y2 = savey2: dx2 = savedx2: dy2 = savedy2
29.     GOSUB updateRect
30.     savex1 = x1: savey1 = y1: savedx1 = dx1: savedy1 = dy1
31.     savex2 = x2: savey2 = y2: savedx2 = dx2: savedy2 = dy2
32.  
33.     FOR j = 1 TO nT
34.         GOSUB updateRect
35.         GOSUB changePlasma
36.         LINE (x1 - 12, y1 - 7)-(x2, y2), , BF
37.         'inverse image and color
38.         xx1 = xmax - x1: yy1 = ymax - y1
39.         xx2 = xmax - x2: yy2 = ymax - y2
40.         IF xx1 > xx2 THEN SWAP xx1, xx2
41.         IF yy1 > yy2 THEN SWAP yy1, yy2
42.         LINE (xx1 - 12, yy1 - 7)-(xx2, yy2), invColor&&, BF
43.     NEXT
44.     _DISPLAY
45.     _LIMIT 10
46.     k$ = INKEY$
47.     IF k$ = " " THEN GOSUB resetPlasma
48. WEND
49.  
50. newRect:
51. x1 = RND * xmax
52. y1 = RND * ymax
53. dx1 = (RND * 9 + 3) * rdir
54. dy1 = (RND * 5 + 2) * rdir
55. x2 = RND * xmax
56. y2 = RND * ymax
57. dx2 = (RND * 9 + 3) * rdir
58. dy2 = (RND * 5 + 2) * rdir
59. 'keep x1, y1 the lesser corner and x2, y2 the greater
60. IF x1 > x2 THEN SWAP x1, x2: SWAP dx1, dx2
61. IF y1 > y2 THEN SWAP y1, y2: SWAP dy1, dy2
62. RETURN
63.  
64. updateRect:
65. IF x1 + dx1 < 0 THEN dx1 = -dx1
66. IF x1 + dx1 > xmax THEN dx1 = -dx1
67. x1 = x1 + dx1
68. IF y1 + dy1 < 0 THEN dy1 = -dy1
69. IF y1 + dy1 > ymax THEN dy1 = -dy1
70. y1 = y1 + dy1
71. IF x2 + dx2 < 0 THEN dx2 = -dx2
72. IF x2 + dx2 > xmax THEN dx2 = -dx2
73. x2 = x2 + dx2
74. IF y2 + dy2 < 0 THEN dy2 = -dy2
75. IF y2 + dy2 > ymax THEN dy2 = -dy2
76. y2 = y2 + dy2
77. 'keep x1, y1 the lesser corner and x2, y2 the greater
78. IF x1 > x2 THEN SWAP x1, x2: SWAP dx1, dx2
79. IF y1 > y2 THEN SWAP y1, y2: SWAP dy1, dy2
80. RETURN
81.  
82. changePlasma:
83. cN = cN + 1
84. COLOR _RGB32(127 + 127 * SIN(pR * .2 * cN), 127 + 127 * SIN(pG * .2 * cN), 127 + 127 * SIN(pB * .2 * cN))
85. invColor&& = _RGB32(255 - (127 + 127 * SIN(pR * .2 * cN)), 255 - (127 + 127 * SIN(pG * .2 * cN)), 255 - (127 + 17 * SIN(pB * .2 * cN)))
86. RETURN
87.  
88. resetPlasma:
89. pR = RND ^ 2: pG = RND ^ 2: pB = RND ^ 2
90. RETURN
91.  
92. FUNCTION rdir ()
93.     IF RND < .5 THEN rdir = -1 ELSE rdir = 1
94. END FUNCTION
95.  

[bplus]

Pete has reminded me that I should mention the ton of instructions that come with the screen saver:

Press spacebar for a new color pattern, one of the infinitely many available with my Plasma System*.

*Mark wouldn't trade it for any other. 

[Ashish]

Nice work, bplus! :)

[bplus]

Hi Ashish,

Thanks! incomaprable to your 3d stuff but you might like plasma (my version of name) and inverse color idea.