Syntax Highlighting (This gonna be hard! :P)

[Prithak]

Ok, So I've made a really simple Text Editor here. The code:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _FULLSCREEN _SQUAREPIXELS
3. DIM y(100000000) AS INTEGER
4. DIM text(100000000) AS STRING
5. leng = 1
6. DO
7.     FOR i = 1 TO leng
8.         _PRINTSTRING (0, y(i)), text(i)
9.         k$ = INKEY$
10.         IF k$ = CHR$(13) THEN
11.             leng = leng + 1
12.             y(leng) = y(leng - 1) + 15
13.         ELSEIF k$ = CHR$(8) THEN
14.             text(leng) = LEFT$(text(leng), LEN(text(leng)) - 1)
15.         ELSE
16.             text(leng) = text(leng) + k$
17.         END IF
18.     NEXT i
19.  
20.     _DISPLAY
21.     CLS
22. LOOP
23.  

Now, can I get a concept as to how the hell can I highlight the syntax here? Thank you in advance!

~Prithak

[bplus]

Ok, So I've made a really simple Text Editor here. The code:

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(800, 600, 32)
2. _FULLSCREEN _SQUAREPIXELS
3. DIM y(100000000) AS INTEGER
4. DIM text(100000000) AS STRING
5. leng = 1
6. DO
7.     FOR i = 1 TO leng
8.         _PRINTSTRING (0, y(i)), text(i)
9.         k$ = INKEY$
10.         IF k$ = CHR$(13) THEN
11.             leng = leng + 1
12.             y(leng) = y(leng - 1) + 15
13.         ELSEIF k$ = CHR$(8) THEN
14.             text(leng) = LEFT$(text(leng), LEN(text(leng)) - 1)
15.         ELSE
16.             text(leng) = text(leng) + k$
17.         END IF
18.     NEXT i
19.  
20.     _DISPLAY
21.     CLS
22. LOOP
23.  

Now, can I get a concept as to how the hell can I highlight the syntax here? Thank you in advance!

~Prithak

Dang! How do you escape that contraption?

Are you sure you want to highlight syntax and not just text? And shouldn't you get the editor part further along before highlighting either syntax or text?

[bplus]

Here is a simple Screen Editor I posted at [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] sometime ago.

Code: QB64: [Select]

1. _TITLE "Screen Editor by bplus, Ctrl + F1 for Help "
2. 'started 2017-10-04
3. '2017-10-05 post as work in progress for comments
4.  
5. _DEFINE A-Z AS INTEGER
6.  
7. CONST xmax = 800 '100 chars wide
8. CONST ymax = 600 ' 30 chars high (480) + 120 pixels
9.  
10. COMMON SHARED vS$(), FW, FH, maxCol, maxRow, cc, cr, fSaved, cyn&, ylw&, fn$
11. SCREEN _NEWIMAGE(xmax, ymax, 32)
12.  
13. FW = _FONTWIDTH
14. FH = _FONTHEIGHT
15. maxCol = xmax \ FW ' minCol = 1 for locate
16. maxRow = 480 \ FH '  minRow = 1 for locate
17. DIM vS$(1 TO maxCol, 1 TO maxRow) 'Ha! MarkSkit's charArray$() only  2D !!!
18. cyn& = _RGB(0, 205, 205)
19. ylw& = _RGB(255, 255, 0)
20.  
21. cScrn 'this loads vS$ with spaces and sets cc, cr the current row and current column
22. fSaved = -1
23. DO 'main interface loop
24.     CLS
25.     DO WHILE _MOUSEINPUT
26.         IF _MOUSEBUTTON(1) THEN 'mouse click in edit area?
27.             tx = _MOUSEX \ FW + 1
28.             ty = _MOUSEY \ FH + 1
29.             IF ty <= maxRow THEN cc = tx: cr = ty
30.         END IF
31.     LOOP
32.  
33.  
34.     k$ = INKEY$
35.     IF LEN(k$) THEN 'handle 1 and 2 char key presses, maybe replace with _keyhit later
36.  
37.         'this code at least as helpful as wiki
38.         'WHILE 1   'find code for keypress
39.         '    k$ = INKEY$
40.         '    IF LEN(k$) THEN
41.         '        SELECT CASE LEN(k$)
42.         '            CASE 1: PRINT "1 char keypress = "; ASC(k$)
43.         '                IF ASC(k$) = 27 THEN EXIT WHILE
44.         '            CASE 2: PRINT "2 char keypress = "; ASC(RIGHT$(k$, 1))
45.         '        END SELECT
46.         '    END IF
47.         '    _DISPLAY
48.         '    _LIMIT 60
49.         'WEND
50.         'SLEEP
51.         '
52.         ' HA! Ctrl + M = <enter>
53.  
54.         SELECT CASE LEN(k$)
55.  
56.             CASE 1
57.                 '                                ASCII Keyboard Codes
58.                 '
59.                 ' Esc  F1  F2  F3  F4  F5  F6  F7  F8  F9  F10  F11  F12  Sys ScL Pause
60.                 '  27 +59 +60 +61 +62 +63 +64 +65 +66 +67 +68  +133 +134   -   -    -
61.                 ' `~  1!  2@  3#  4$  5%  6^  7&  8*  9(  0) -_ =+ BkSp   Ins Hme PUp   NumL  /   *    -
62.                 ' 126 33  64  35  36  37  94  38  42  40  41 95 43   8    +82 +71 +73    -    47  42   45
63.                 '  96 49  50  51  52  53  54  55  56  57  48 45 61
64.                 ' Tab Q   W   E   R   T   Y   U   I   O   P  [{  ]}  \|   Del End PDn   7Hme 8/?  9PU  +
65.                 '  9  81  87  69  82  84  89  85  73  79  80 123 125 124  +83 +79 +81   +71  +72  +73  43
66.                 '    113 119 101 114 116 121 117 105 111 112  91  93  92                 55   56   57
67.                 ' CapL  A   S   D   F   G   H   J   K   L   ;:  '" Enter                4/?-  5   6/-?
68.                 '   -   65  83  68  70  71  72  74  75  76  58  34  13                  +75  +76  +77  E
69.                 '       97 115 100 102 103 104 106 107 108  59  39                       52   53   54  n
70.                 ' Shift  Z   X   C   V   B   N   M   ,<  .>  /?    Shift       ?        1End 2/?  3PD  t
71.                 '   *    90  88  67  86  66  78  77  60  62  63      *        +72       +79  +80  +81  e
72.                 '       122 120  99 118  98 110 109  44  46  47                          49   50   51  r
73.                 ' Ctrl Win Alt       Spacebar          Alt Win Menu Ctrl   ?-  ?   -?   0Ins     .Del
74.                 '  *    -   *           32              *   -   -    *    +75 +80 +77   +82       +83  13
75.                 '                                                                        48        46
76.                 '
77.                 '     Italics = LCase/NumLock On  * = 2 byte combo only,  + = 2 Byte: CHR$(0) + CHR$(code)
78.                 'PRINT "1 "; k$
79.                 'INPUT "OK "; t$
80.                 SELECT CASE ASC(k$)
81.                     CASE 1 'Ctrl + A
82.                         saveA
83.                     CASE 3 'Ctrl + C
84.                         cScrn
85.                     CASE 8 ' backspace          more to do
86.                         IF cc > 1 THEN
87.                             s$ = ""
88.                             FOR i = cc TO maxCol - 1
89.                                 vS$(i - 1, cr) = vS$(i, cr)
90.                             NEXT
91.                             vS$(maxCol, cr) = " "
92.                             cc = cc - 1
93.                             fSaved = 0
94.                         END IF
95.  
96.                     CASE 12 'Ctrl + L
97.                         fLoad
98.                     CASE 13 '                          more too
99.                         IF cr < maxRow THEN cr = cr + 1: cc = 1
100.  
101.                     CASE 19 'Ctrl + S
102.                         Save
103.                     CASE 27 'esc
104.                         checkSave
105.                         END
106.                     CASE ELSE
107.                         IF 31 < ASC(k$) AND ASC(k$) < 127 THEN 'normal print chars
108.                             vS$(cc, cr) = k$
109.                             fSaved = 0
110.                             IF cc < maxCol THEN
111.                                 cc = cc + 1
112.                             ELSE
113.                                 IF cr < maxRow THEN cr = cr + 1: cc = 1
114.                             END IF
115.                         END IF
116.                 END SELECT
117.  
118.             CASE 2
119.                 'CLS: PRINT "2 "; ASC(RIGHT$(k$, 1))
120.                 'INPUT "OK ", t$
121.                 SELECT CASE ASC(RIGHT$(k$, 1))
122.                     'from wiki help,
123.                     'Two Byte Characters        Key                 CHR$(0) + "?"
124.                     'CHR$(0) + CHR$(16-50)      [Alt] + letter
125.                     'CHR$(0) + CHR$(59)         [F1]                 ";"
126.                     'CHR$(0) + CHR$(60)         [F2]                 "<"
127.                     'CHR$(0) + CHR$(61)         [F3]                 "="
128.                     'CHR$(0) + CHR$(62)         [F4]                 ">"
129.                     'CHR$(0) + CHR$(63)         [F5]                 "?"
130.                     'CHR$(0) + CHR$(64)         [F6]                 "@"
131.                     'CHR$(0) + CHR$(65)         [F7]                 "A"
132.                     'CHR$(0) + CHR$(66)         [F8]                 "B"
133.                     'CHR$(0) + CHR$(67)         [F9]                 "C"
134.                     'CHR$(0) + CHR$(68)         [F10]                "D"
135.                     'CHR$(0) + CHR$(71)         [Home]               "G"
136.                     'CHR$(0) + CHR$(72)         [?] Arrow            "H"
137.                     'CHR$(0) + CHR$(73)         [Page Up]            "I"
138.                     'CHR$(0) + CHR$(75)         [?] Arrow            "K"
139.                     'CHR$(0) + CHR$(76)         [5 NumberPad]        "L" (NumLock off in QB64)
140.                     'CHR$(0) + CHR$(77)         [?] Arrow            "M"
141.                     'CHR$(0) + CHR$(79)         [End]                "O"
142.                     'CHR$(0) + CHR$(80)         [?] Arrow            "P"
143.                     'CHR$(0) + CHR$(81)         [Page Down]          "Q"
144.                     'CHR$(0) + CHR$(82)         [Insert]             "R"
145.                     'CHR$(0) + CHR$(83)         [Delete]             "S"
146.                     'CHR$(0) + CHR$(84-93)      [Shift] + F1-10
147.                     'CHR$(0) + CHR$(94-103)     [Ctrl] + F1-10
148.                     'CHR$(0) + CHR$(104-113)    [Alt] + F1-10
149.                     'CHR$(0) + CHR$(114-119)    [Ctrl] + keypad
150.                     'CHR$(0) + CHR$(120-129)    [Alt] + number
151.                     'CHR$(0) + CHR$(130 or 131) [Alt] + _/- or +/=   "é" or "â"
152.                     'CHR$(0) + CHR$(133)        [F11]                "à"
153.                     'CHR$(0) + CHR$(134)        [F12]                "å"
154.                     'CHR$(0) + CHR$(135)        [Shift] + [F11]      "ç"
155.                     'CHR$(0) + CHR$(136)        [Shift] + [F12]      "ê"
156.                     'CHR$(0) + CHR$(137)        [Ctrl] + [F11]       "ë"
157.                     'CHR$(0) + CHR$(138)        [Ctrl] + [F12]       "è"
158.                     'CHR$(0) + CHR$(139)        [Alt] + [F11]        "ï"
159.                     'CHR$(0) + CHR$(140)        [Alt] + [F12]        "î"
160.  
161.  
162.                     CASE 72 ' up
163.                         IF cr > 1 THEN cr = cr - 1
164.                     CASE 80 'down
165.                         IF cr < maxRow THEN cr = cr + 1
166.                     CASE 75 'left
167.                         IF cc > 1 THEN cc = cc - 1
168.                     CASE 77 'right
169.                         IF cc < maxCol THEN cc = cc + 1
170.                     CASE 94 'Ctrl + F1
171.                         menu
172.  
173.                 END SELECT
174.         END SELECT
175.     END IF
176.  
177.     pScrn 'shows exactly what is in vS$() that gets saved to file or loaded from file
178.     drwCrs 'updates file, save status, current position of "cursor"
179.     _DISPLAY 'flicker free
180.     _LIMIT 60 'easy on the cpu?
181. LOOP
182.  
183. SUB menu
184.     CLS
185.     cP 2, "Edit Menu press:"
186.     lp 10, 4, "1 to clear screen or while editing             Ctrl + C"
187.     lp 10, 5, "2 prompts for file name to open and Load text, Ctrl + L"
188.     lp 10, 6, "3 Save text to last file name loaded,          Ctrl + S"
189.     lp 10, 7, "4 Save text to Another file name (save As),    Ctrl + A"
190.     lp 10, 8, "0 Exit Menu"
191.     LOCATE 10, 10: INPUT "Enter your choice ", choice
192.     SELECT CASE choice
193.         CASE 0: EXIT SUB
194.         CASE 1: cScrn
195.         CASE 2: fLoad
196.         CASE 3: Save
197.         CASE 4: saveA
198.     END SELECT
199. END SUB
200.  
201.  
202. SUB saveA
203.     CLS
204.     cP 2, "(" + fn$ + ") Save As File:"
205.     LOCATE 5, 3: INPUT "Enter file name for Save or nothing ", test$
206.     IF fn$ <> "" THEN
207.         IF _FILEEXISTS(test$) THEN
208.             cP 7, "Warning: " + test$ + " already exists."
209.             LOCATE 9, 15: INPUT "Do you wish to overwite that file? use y for yes ", yes$
210.             IF UCASE$(yes$) = "Y" THEN fn$ = test$: Save
211.         ELSE
212.             fn$ = test$: Save
213.         END IF
214.     END IF
215. END SUB
216.  
217. SUB Save
218.     IF fn$ <> "" THEN
219.         OPEN fn$ FOR OUTPUT AS #1
220.         FOR y = 1 TO maxRow
221.             s$ = ""
222.             FOR x = 1 TO maxCol
223.                 s$ = s$ + vS$(x, y)
224.             NEXT
225.             PRINT #1, s$
226.         NEXT
227.         CLOSE #1
228.         fSaved = -1
229.     END IF
230. END SUB
231.  
232. SUB fLoad () 'to do a .txt file getter plug-in here
233.     checkSave
234.     CLS
235.     cP 2, "Load File:"
236.     LOCATE 5, 3: INPUT "Enter filename for Load or nothing ", fn$
237.     IF fn$ <> "" THEN
238.         IF _FILEEXISTS(fn$) THEN
239.             OPEN fn$ FOR INPUT AS #1
240.             WHILE NOT EOF(1) AND lc < maxRow
241.                 LINE INPUT #1, fline$
242.                 lc = lc + 1
243.                 IF LEN(fline$) > maxCol THEN stopit = maxCol ELSE stopit = LEN(fline$)
244.                 FOR i = 1 TO stopit
245.                     vS$(i, lc) = MID$(fline$, i, 1)
246.                 NEXT
247.             WEND
248.             CLOSE #1
249.         END IF
250.     END IF
251. END SUB
252.  
253. SUB cP (row, txt$) 'on row center Print txt$
254.     col = (maxCol - LEN(txt$)) \ 2
255.     LOCATE row, col: PRINT txt$
256. END SUB
257.  
258. SUB drwCrs
259.     COLOR ylw&
260.     LINE ((cc - 1) * FW, (cr - 1) * FH)-(cc * FW, cr * FH), , B
261.     IF fSaved THEN s$ = " Saved  " ELSE s$ = " Unsaved  "
262.     LOCATE 33, 70: PRINT fn$; s$; cc; " : "; cr;
263.     LOCATE cr, cc
264. END SUB
265.  
266. SUB cScrn
267.     FOR y = 1 TO maxRow
268.         FOR x = 1 TO maxCol
269.             vS$(x, y) = " "
270.         NEXT
271.     NEXT
272.     cc = 1: cr = 1: fn$ = "untitled.txt"
273. END SUB
274.  
275. SUB pScrn
276.     COLOR cyn&
277.     FOR y = 1 TO maxRow
278.         FOR x = 1 TO maxCol
279.             LOCATE y, x: PRINT vS$(x, y);
280.         NEXT
281.     NEXT
282.     LINE (0, 485)-(xmax, 485), ylw&
283. END SUB
284.  
285. SUB checkSave
286.     IF fSaved = 0 THEN
287.         CLS
288.         COLOR ylw&
289.         cP 10, fn$ + " changes have not been saved."
290.         cP 15, "Do you wish to Save them to same file?"
291.         LOCATE 20, 1: INPUT " Enter y for yes ", yes$
292.         IF UCASE$(yes$) = "Y" THEN Save
293.     END IF
294. END SUB
295.  
296. SUB lp (col, row, txt$) 'just to save some typing
297.     LOCATE row, col: PRINT txt$
298. END SUB
299.  

  [ You are not allowed to view this attachment ]  

[Pete]

Mark is right. First,  you've allocated way too much memory for arrays. It appears you are just getting familiar with keyboard input porgrams, so start small. Next, learn more about INKEY$. The way you have is not useful. You should at least make an IF LEN(k$) THEN, so blank INKEY$ readings are not feed to the variables. BTW, real WP projects are freakin' huge. 1000s of line of code. What you created, so far, will not work and will crash some systems. What I posted below is part of what you will need to get started. It at least shows how to position everything, and has a key method for displaying the input correctly to the screen. Highlighting would be just making a key toggle for highlighting characters when they are typed, and toggling it off when you're done. There are more advanced mouse methods, too. Anyway, have a look, ask questions if you have any, but see if any of this helps you gain a little more perspective. Sorry, I don't have any tutorials to share, and to be frank, I think what I'm posting may be ahead of where you are, which might make you feel like I'm expecting you to understand all this code. I don't, so don't worry about asking questions.

Code: QB64: [Select]

1. CLS
2. numofspaces% = 40
3. LOCATE 10, 29
4. COLOR 8, 7: PRINT "|";
5. COLOR 0, 7: PRINT SPACE$(numofspaces%);
6. COLOR 8, 7: PRINT "|";
7. COLOR 0, 7
8. LOCATE 10, 30, 1, 7, 7
9. startpos% = POS(1)
10. endpos% = startpos% + numofspaces%
11. DO
12. DO
13. b$ = INKEY$
14. IF b$ <> "" THEN EXIT DO
15. LOOP
16. xx% = CSRLIN: yy% = POS(1)
17.  
18. SELECT CASE b$
19. CASE CHR$(0) + "K"
20. mov% = -1: GOSUB action
21. CASE CHR$(0) + "M"
22. mov% = 1: GOSUB action
23. CASE CHR$(0) + "S"
24. GOSUB wash: GOSUB delete
25. CASE CHR$(0) + "R"
26. IF ins% = 0 THEN ins% = -1 ELSE ins% = 0
27. IF ins% = 0 THEN LOCATE , , 1, 7, 7 ELSE LOCATE , , 1, 7, 30
28. CASE CHR$(0) + "O"
29. IF word$ <> "" THEN LOCATE xx%, startpos% + LEN(word$)
30. CASE CHR$(0) + "G"
31. LOCATE xx%, startpos%
32. CASE CHR$(8)
33. IF yy% > startpos% THEN
34. LOCATE , POS(1) - 1
35. yy% = POS(1)
36. GOSUB wash: GOSUB delete
37. END IF
38. CASE CHR$(13)
39. STOP
40. REM Enter your routine here.
41. CASE CHR$(27)
42. COLOR 7, 0: SYSTEM
43. CASE CHR$(32) TO CHR$(126)
44. key$ = b$: GOSUB action
45. END SELECT
46. mov% = 0: key$ = ""
47. LOOP
48.  
49. action:
50. IF POS(1) + mov% >= startpos% AND POS(1) + mov% < endpos% THEN
51. DO
52. IF key$ <> "" THEN
53. SELECT CASE ins%
54. CASE 0
55. IF LEN(word$) + LEN(key$) > endpos% - startpos% THEN EXIT DO
56. word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 1)
57. CASE -1
58. word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 2)
59. END SELECT
60. END IF
61. IF POS(1) - startpos% >= LEN(word$) - LEN(key$) AND key$ <> "" OR key$ = "" OR ins% = -1 THEN
62. IF key$ = "" AND mov% = 1 THEN IF POS(1) - startpos% = LEN(word$) THEN EXIT DO
63. LOCATE , POS(1) + mov%: PRINT key$;
64. ELSE
65. LOCATE xx%, startpos%: PRINT MID$(word$, 1, yy% - startpos%); key$; : yy2% = POS(1): PRINT MID$(word$, yy% - startpos% + 2); : LOCATE xx%, yy2%
66. END IF
67. EXIT DO
68. LOOP
69. END IF
70. RETURN
71.  
72. wash:
73. IF POS(1) >= startpos% AND word$ <> "" AND POS(1) - startpos% < LEN(word$) THEN
74. LOCATE xx%, startpos% + LEN(word$) - 1
75. PRINT " ";
76. LOCATE xx%, yy%
77. END IF
78. RETURN
79.  
80. delete:
81. IF POS(1) - startpos% = 0 THEN
82. word$ = MID$(word$, 2)
83. ELSE
84. word$ = MID$(word$, 1, POS(1) - startpos%) + MID$(word$, POS(1) - startpos% + 2)
85. END IF
86. PRINT MID$(word$, yy% - startpos% + 1); : LOCATE xx%, yy%
87. RETURN
88.  

Pete

[bplus]

Yes a line editor is a good way to get your feet wet.

This is probably best taught as a building process, certainly with more comments.

[STxAxTIC]

Arrays are going to end up biting you. Go with a linked list:

Code: QB64: [Select]

1. '$EXEICON:'qXedlogo.ico'
2. '$RESIZE:ON
3.  
4. 'REM $Include: 'sxmath.bi'
5. 'REM $Include: 'sxript.bi'
6.  
7. scrHand& = _NEWIMAGE(90, 30, 0)
8. SCREEN scrHand&
9. '_FREEIMAGE scrHand&
10.  
11. ' Define fundamental structures.
12. TYPE Vector
13.     X AS INTEGER
14.     Y AS INTEGER
15. END TYPE
16.  
17. TYPE Cell
18.     Identity AS LONG
19.     Pointer AS LONG
20.     Lagger AS LONG
21.     Content AS STRING * 1
22. END TYPE
23.  
24. DIM SHARED ChainLimit AS LONG
25. DIM SHARED BOC AS LONG ' Beginning of chain.
26. DIM SHARED EOC AS LONG ' End of chain.
27. ChainLimit = 128000
28. BOC = -1
29. EOC = ChainLimit
30.  
31. ' Define text window properties.
32. DIM SHARED WindowHeight
33. DIM SHARED WindowWidth
34. DIM SHARED VisibleLines
35. DIM SHARED TopIndent
36. DIM SHARED LeftIndent
37. DIM SHARED TextHeight
38. DIM SHARED TextWidth
39. DIM SHARED HScroll
40. DIM SHARED TextWrapping
41. DIM SHARED TextFormatting
42. DIM SHARED InsertKey
43. TopIndent = 1
44. LeftIndent = 1
45. WindowWidth = _WIDTH '
46. WindowHeight = _HEIGHT '- 2
47. TextHeight = WindowHeight - 2 * TopIndent
48. TextWidth = WindowWidth - 2 * LeftIndent
49. HScroll = 1
50. TextWrapping = 0
51. TextFormatting = -1
52. InsertKey = -1
53.  
54. ' Initiate text inside window.
55. DIM SHARED StartIndex
56. DIM SHARED LineAsMapped(TextHeight) AS STRING
57. DIM SHARED Cursor1 AS Vector
58. DIM SHARED Cursor2 AS Vector
59. DIM SHARED ID1
60. DIM SHARED ID2
61.  
62. ' Auxiliary 2D text grid.
63. DIM SHARED GOLSwitch
64. DIM SHARED AuxGrid(TextWidth, TextHeight, 2) AS STRING
65. GOLSwitch = -1
66.  
67. ' Load text file into memory if applicable, use example string if not.
68. DIM SHARED FileName$
69. c$ = COMMAND$
70. IF (c$ <> "") THEN
71.     q$ = ""
72.     OPEN c$ FOR INPUT AS #1
73.     DO WHILE NOT EOF(1)
74.         LINE INPUT #1, r$
75.         q$ = q$ + r$ + CHR$(13)
76.     LOOP
77.     CLOSE #1
78.     i = INSTR(c$, ".")
79.     IF (i <> 0) THEN j = i - 1 ELSE j = LEN(c$)
80.     FileName$ = LEFT$(c$, j) + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
81.     _TITLE FileName$
82. ELSE
83.     FileName$ = "Newfile" + "-" + DATE$ + "-" + LTRIM$(RTRIM$(STR$(INT(TIMER)))) + ".txt"
84.     q$ = "I sank to the floor. I [experienced] this hallucination of tumbling forward into these fractal geometric spaces made of light and then I found myself in the equivalent of the Pope's private chapel and there were insect elf machines proffering strange little tablets with strange writing on them, and I was aghast, completely appalled, because [in] a matter of seconds . . . my entire expectation of the nature of the world was just being shredded in front of me. I've never actually gotten over it. These self-transforming machine elf creatures were speaking in a colored language which condensed into rotating machines that were like Faberge eggs but crafted out of luminescent superconducting ceramics and liquid crystal gels. All this stuff was just so weird and so alien and so un-English-able that it was a complete shock - I mean, the literal turning inside out of [my] intellectual universe!" + CHR$(13) + CHR$(13) + "This went on for two or three minutes, this situation of [discontinuous] orthogonal dimensions to reality just engulfing me. As I came out of it and the room reassembled itself, I said, " + CHR$(34) + "I can't believe it, it's impossible." + CHR$(34) + " To call that a drug is ridiculous; that just means that you just don't have a word for it and so you putter around and you come upon this sloppy concept [that] something goes into your body and there's a change. It's not like that; it's like being struck by noetic lightning. [Note: " + CHR$(34) + "Noetic" + CHR$(34) + " derives from the theologian Pierre Teilhard de Chardin's " + CHR$(34) + "noosphere" + CHR$(34) + " - the collective consciousness of humankind conceived of as a sort of philosophical virtuality.]" + CHR$(13) + CHR$(13) + "[What] astonished me was [that] . . . in the carpets of Central Asia, in the myths of the Maya, in the visions of an Arcimboldi or a Fra Angelico or a Bosch, there is not a hint, not a clue, not an atom of the presence of this thing, This was more [multiplex] than the universe that we share with each other. It was the victory of Neo-Platonic metaphysics; everything [was] made out of a fourth-dimensional mosaic of energy. I was knocked off my feet, and set myself the goal of understanding this. There was really no choice, you see."
85.     'q$ = " "
86. END IF
87.  
88. _TITLE "qXed"
89.  
90. ' Create memory space for string.
91. DIM SHARED TheChain(ChainLimit) AS Cell
92.  
93. ' Create character list.
94. CALL Assimilate(q$)
95.  
96. ' Prime main loop.
97. CALL MapText
98. CALL CalibrateCursor(ID1)
99. CALL CalibrateCursor(ID2)
100. CALL PrintEverything
101.  
102. DIM SHARED DEBUG$
103.  
104. ' Main loop.
105. DO
106.     IF (StateChange = 1) THEN
107.         CALL PrintEverything
108.     END IF
109.  
110.     IF (GOLSwitch = 1) THEN
111.         CALL ConvertToGrid
112.         CALL GOL
113.         CALL ConvertFromGrid
114.         CALL MapText
115.         CALL PrintEverything
116.     END IF
117.  
118.     'IF _RESIZE = -1 THEN
119.     '    _DELAY .1
120.     '    oldimage& = scrHand&
121.     '    scrHand& = _NEWIMAGE(_RESIZEWIDTH / 8, _RESIZEHEIGHT / 16, 0)
122.     '    SCREEN scrHand&
123.     '    _FREEIMAGE oldimage&
124.     '    WindowWidth = INT(_RESIZEWIDTH / 8)
125.     '    WindowHeight = INT(_RESIZEHEIGHT / 16)
126.     '    TextHeight = WindowHeight - 2 * TopIndent
127.     '    TextWidth = WindowWidth - 2 * LeftIndent
128.     '    REDIM LineAsMapped(TextHeight)
129.     '    REDIM AuxGrid(TextWidth, TextHeight, 2)
130.     '    CALL MapText
131.     '    CALL CalibrateCursor(ID1)
132.     '    CALL CalibrateCursor(ID2)
133.     '    CALL PrintEverything
134.     'END IF
135.  
136.     _DISPLAY
137.     _LIMIT 120
138. LOOP
139. SYSTEM
140.  
141. SUB PrintEverything
142.     CLS
143.  
144.     c$ = "qXed" + " " + DEBUG$
145.     CALL DisplayText(1, 1, 11, 0, c$)
146.  
147.     ' Main text
148.     FOR i = 1 TO VisibleLines
149.         c$ = LineAsMapped(i)
150.         IF ((TextFormatting = 1) AND (TextWrapping <> 2)) THEN
151.             FOR j = 1 TO TextWidth - LEN(c$)
152.                 c$ = c$ + "_"
153.             NEXT
154.         END IF
155.         d$ = MID$(c$, HScroll, TextWidth)
156.         CALL DisplayText(LeftIndent + 1, TopIndent + i, 7, 1, d$)
157.     NEXT
158.  
159.     ' Cursor2
160.     IF ((Cursor2.X > 0 AND Cursor2.X < WindowWidth) AND ((Cursor2.Y > 0) AND (Cursor2.Y < WindowHeight))) THEN
161.         p1 = LinearCount(StartIndex, ID1)
162.         p2 = LinearCount(StartIndex, ID2)
163.         pe = LinearCount(StartIndex, EOC)
164.         IF ((p2 > p1) AND (p2 < pe)) THEN
165.             c$ = TheChain(ID2).Content
166.             IF (c$ = " ") THEN c$ = "_"
167.             IF (c$ = CHR$(13)) THEN c$ = "~"
168.             CALL DisplayText(Cursor2.X, Cursor2.Y, 0, 6, c$)
169.         END IF
170.     END IF
171.  
172.     ' Cursor1
173.     IF ((Cursor1.X > 0 AND Cursor1.X < WindowWidth) AND ((Cursor1.Y > 0) AND (Cursor1.Y < WindowHeight))) THEN
174.         c$ = TheChain(ID1).Content
175.         IF (c$ = " ") THEN c$ = "_"
176.         IF (c$ = CHR$(13)) THEN c$ = "~"
177.         IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN
178.             a = 16: b = 5
179.         ELSE
180.             a = 16: b = 3
181.         END IF
182.         CALL DisplayText(Cursor1.X, Cursor1.Y, a, b, c$)
183.     END IF
184.  
185.     ' Cursor status
186.     d$ = TheChain(ID1).Content
187.     e$ = TheChain(ID2).Content
188.     IF ((ASC(d$) = 10) OR (ASC(d$) = 13)) THEN d$ = "~"
189.     IF ((ASC(e$) = 10) OR (ASC(e$) = 13)) THEN e$ = "~"
190.     IF (ASC(d$) = 32) THEN d$ = "_"
191.     IF (ASC(e$) = 32) THEN e$ = "_"
192.     c$ = "(" + LTRIM$(RTRIM$(STR$(Cursor1.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor1.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(d$)) + " " + LTRIM$(RTRIM$(STR$(ID1))) + ")"
193.     a = 0: b = 3
194.     IF ((Cursor1.X = Cursor2.X) AND (Cursor1.Y = Cursor2.Y)) THEN
195.         a = 15: b = 5
196.     END IF
197.     CALL DisplayText(2, WindowHeight, a, b, c$)
198.     g$ = "(" + LTRIM$(RTRIM$(STR$(Cursor2.X - LeftIndent))) + "," + LTRIM$(RTRIM$(STR$(Cursor2.Y - TopIndent))) + ":" + " " + LTRIM$(RTRIM$(e$)) + " " + LTRIM$(RTRIM$(STR$(ID2))) + ")"
199.     a = 6: b = 0
200.     IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
201.         a = 0: b = 6
202.     END IF
203.     CALL DisplayText(3 + LEN(c$), WindowHeight, a, b, g$)
204.     ' Horizontal scrollbar
205.     p = LinearCount(NthP(StartIndex, FindID(LeftIndent + 1, Cursor1.Y)), ID1)
206.     q = LEN(LineAsMapped(Cursor1.Y - TopIndent))
207.     r = p / q
208.     IF r > 1 THEN r = 1
209.     IF r < 0 THEN r = 0
210.     i = 2 + INT(r * (WindowWidth - 2))
211.     IF i < 1 THEN i = 1
212.     IF i > WindowWidth THEN i = WindowWidth
213.     CALL DisplayText(i, WindowHeight - 1, 8, 7, "^")
214.  
215.     ' Vertical scrollbar
216.     p = LinearCount(ID1, NthP(ID1, ChainLimit + 1))
217.     q = LinearCount(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
218.     IF (q = 0) THEN r = 1 ELSE r = 1 - p / q
219.     CALL DisplayText(WindowWidth, 1 + INT(r * (WindowHeight - 1)), 8, 7, "<")
220.  
221.     ' Help
222.     SELECT CASE TextWrapping
223.         CASE 0: d$ = "Square"
224.         CASE 1: d$ = "Fluid"
225.         CASE 2: d$ = "None"
226.     END SELECT
227.     c$ = "[F6=Save] [F11=Format] [F12=Wrap: " + d$ + "]"
228.     IF (TextWrapping = 2) THEN c$ = "[F1/2=HScroll] " + c$
229.     c$ = c$ + STR$(INT(100 * r)) + "%"
230.     IF (LEN(c$) >= TextWidth) THEN c$ = LEFT$(c$, TextWidth)
231.     CALL DisplayText(WindowWidth - LEN(c$), 1, 15, 0, c$)
232.     c$ = "[Esc=Sync] [Mouse2=Copy] [Mouse3=Paste]"
233.     IF (InsertKey = 1) THEN c$ = "[Ins] " + c$
234.     IF (LEN(c$) >= TextWidth) THEN c$ = LEFT$(c$, TextWidth)
235.     CALL DisplayText(WindowWidth - LEN(c$), WindowHeight, 15, 0, c$)
236.  
237.     ' Pointer
238.     IF ((_MOUSEX >= 1) AND (_MOUSEX <= WindowWidth) AND (_MOUSEY >= 1) AND (_MOUSEY <= WindowHeight)) THEN
239.         a$ = CHR$(SCREEN(_MOUSEY, _MOUSEX))
240.         CALL DisplayText(_MOUSEX, _MOUSEY, 0, 15, a$)
241.     END IF
242.  
243.     COLOR 15, 0
244.  
245. END SUB
246.  
247. SUB Assimilate (a AS STRING)
248.     ' Load a string to initialize chain.
249.     FOR k = 1 TO ChainLimit
250.         TheChain(k).Identity = 0
251.     NEXT
252.     StartIndex = 1
253.     PreviousIdentity = BOC
254.     NextIdentity = NextOpenIdentity(StartIndex)
255.     FOR k = 1 TO LEN(a)
256.         j = NextIdentity
257.         TheChain(j).Identity = j
258.         TheChain(j).Content = ReFormat$(MID$(a, k, 1))
259.         TheChain(j).Lagger = PreviousIdentity
260.         PreviousIdentity = j
261.         IF (k < LEN(a)) THEN
262.             NextIdentity = NextOpenIdentity(j)
263.             TheChain(j).Pointer = NextIdentity
264.         ELSE
265.             TheChain(j).Pointer = EOC
266.         END IF
267.         PRINT TheChain(j).Content
268.     NEXT
269.     ID1 = StartIndex
270.     ID2 = NthP(ID1, ChainLimit + 1)
271. END SUB
272.  
273. FUNCTION ReFormat$ (a AS STRING)
274.     c$ = a
275.     IF c$ = CHR$(10) THEN c$ = CHR$(13)
276.     IF c$ = CHR$(9) THEN c$ = "    "
277.     ReFormat = c$
278. END FUNCTION
279.  
280. FUNCTION NthP (a AS LONG, b AS LONG)
281.     ' Returns the address that is b jumps ahead of address a.
282.     i = a
283.     IF (i <> EOC) THEN
284.         k = 0
285.         j = 0
286.         DO WHILE (k < b)
287.             k = k + 1
288.             j = TheChain(i).Identity
289.             i = TheChain(j).Pointer
290.             IF (i = EOC) THEN EXIT DO
291.         LOOP
292.     END IF
293.     NthP = j
294. END FUNCTION
295.  
296. FUNCTION NthPC (a AS LONG, b AS STRING)
297.     ' Returns the address holding b first enLinearCountered from a.
298.     i = a
299.     DO
300.         j = TheChain(i).Identity
301.         i = TheChain(j).Pointer
302.         IF (TheChain(j).Content = b) THEN EXIT DO
303.         IF (i = EOC) THEN
304.             j = BOC
305.             EXIT DO
306.         END IF
307.     LOOP
308.     NthPC = j
309. END FUNCTION
310.  
311. FUNCTION NthL (a AS LONG, b AS LONG)
312.     ' Returns the address that is b jumps behind address a.
313.     i = a
314.     k = 0
315.     DO WHILE k < b
316.         k = k + 1
317.         j = TheChain(i).Identity
318.         i = TheChain(j).Lagger
319.         IF (i = BOC) THEN EXIT DO
320.     LOOP
321.     NthL = j
322. END FUNCTION
323.  
324. FUNCTION NextOpenIdentity (a AS LONG)
325.     ' Returns first nonzero identity.
326.     FOR j = a TO ChainLimit
327.         IF (TheChain(j).Identity = 0) THEN EXIT FOR
328.     NEXT
329.     IF (j > ChainLimit) THEN
330.         PRINT "Out of memory: "; ChainLimit
331.         SLEEP
332.         SYSTEM
333.     END IF
334.     NextOpenIdentity = j
335. END FUNCTION
336.  
337. FUNCTION BackBreak (a AS LONG)
338.     ' Function for scrolling up.
339.     j = a
340.     lastbreak = 0
341.     c$ = ""
342.     DO
343.         IF (j = BOC) THEN EXIT DO
344.         k = TheChain(j).Lagger
345.         IF (k = BOC) THEN
346.             lastbreak = j
347.             EXIT DO
348.         END IF
349.         j = k
350.         d$ = TheChain(j).Content
351.         IF ((TextWrapping = 1) AND (d$ = " ")) THEN lastbreak = j
352.         c$ = d$ + c$
353.         IF (TextWrapping <> 2) AND (LEN(c$) = TextWidth) THEN EXIT DO
354.         IF (d$ = CHR$(13)) THEN EXIT DO
355.     LOOP
356.     IF (lastbreak <> 0) THEN j = TheChain(lastbreak).Identity
357.     BackBreak = j
358. END FUNCTION
359.  
360. SUB InsertBefore (a AS LONG, b AS STRING)
361.     ' Inserts a single cell before address a in the chain.
362.     j = NextOpenIdentity(a)
363.     al = TheChain(a).Lagger
364.     TheChain(j).Identity = j
365.     TheChain(j).Pointer = a
366.     TheChain(j).Lagger = al
367.     TheChain(j).Content = ReFormat$(b)
368.     TheChain(a).Lagger = j
369.     IF (al = BOC) THEN StartIndex = j ELSE TheChain(al).Pointer = j
370. END SUB
371.  
372. SUB InsertAfter (a AS LONG, b AS STRING)
373.     ' Inserts a single cell after address a in the chain.
374.     j = NextOpenIdentity(a)
375.     ap = TheChain(a).Pointer
376.     TheChain(j).Identity = j
377.     TheChain(j).Pointer = ap
378.     TheChain(j).Lagger = a
379.     TheChain(j).Content = ReFormat$(b)
380.     TheChain(a).Pointer = j
381.     IF (ap <> EOC) THEN TheChain(ap).Lagger = j
382. END SUB
383.  
384. SUB InsertRange (a AS LONG, b AS STRING)
385.     ' Inserts a sub-chain anywhere.
386.     FOR k = 1 TO LEN(b)
387.         c$ = MID$(b, k, 1)
388.         CALL InsertBefore(a, c$)
389.     NEXT
390. END SUB
391.  
392. SUB UnlinkCell (a AS LONG)
393.     ' Remove single cell from chain and clear identity.
394.     ap = TheChain(a).Pointer
395.     al = TheChain(a).Lagger
396.     IF ((ap = EOC) AND (al = BOC)) THEN
397.         TheChain(a).Content = " "
398.         'ID1 = a
399.         'ID2 = ID1
400.     ELSE
401.         TheChain(a).Identity = 0
402.         IF ((ap <> EOC) AND (al <> BOC)) THEN
403.             TheChain(al).Pointer = ap
404.             TheChain(ap).Lagger = al
405.         END IF
406.         IF (ap = EOC) THEN TheChain(al).Pointer = EOC
407.         IF (al = BOC) THEN
408.             StartIndex = ap
409.             TheChain(ap).Lagger = BOC
410.         END IF
411.     END IF
412. END SUB
413.  
414. SUB UnlinkRange (a AS LONG, b AS LONG)
415.     ' Remove sub-chain and clear identity of each cell.
416.     bp = TheChain(b).Pointer
417.     al = TheChain(a).Lagger
418.     IF ((al = BOC) AND (bp = EOC)) THEN
419.         CALL UnlinkRange(NthP(a, 2), b)
420.         TheChain(a).Content = " "
421.         TheChain(a).Pointer = bp
422.     ELSE
423.         k = a
424.         DO WHILE ((k <> b) AND (k <> EOC))
425.             TheChain(k).Identity = 0
426.             k = TheChain(k).Pointer
427.         LOOP
428.         TheChain(b).Identity = 0
429.         TheChain(bp).Lagger = al
430.         IF (al = BOC) THEN StartIndex = bp ELSE TheChain(al).Pointer = bp
431.     END IF
432. END SUB
433.  
434. FUNCTION LinearCount (a AS LONG, b AS LONG)
435.     ' Returns number of links between two addresses.
436.     i = a
437.     k = 0
438.     DO WHILE (i <> b)
439.         k = k + 1
440.         j = TheChain(i).Identity
441.         i = TheChain(j).Pointer
442.         IF (i = EOC) THEN EXIT DO
443.     LOOP
444.     LinearCount = k
445. END FUNCTION
446.  
447. FUNCTION LinearCount2 (a AS LONG, b AS LONG, c AS LONG)
448.     ' Returns number of links between two addresses, with exit condition.
449.     i = a
450.     k = 0
451.     DO WHILE (i <> b)
452.         k = k + 1
453.         j = TheChain(i).Identity
454.         i = TheChain(j).Pointer
455.         IF (i = EOC) THEN EXIT DO
456.         IF (k = c) THEN EXIT DO
457.     LOOP
458.     LinearCount2 = k
459. END FUNCTION
460.  
461. FUNCTION Projection$ (a AS LONG, b AS LONG)
462.     ' Returns the linear content for all address between a and b, inclusive.
463.     DIM TheReturn AS STRING
464.     TheReturn = ""
465.     IF (a = b) THEN
466.         TheReturn = TheChain(a).Content
467.     ELSE
468.         j = a
469.         DO
470.             c$ = TheChain(j).Content
471.             TheReturn = TheReturn + c$
472.             k = TheChain(j).Pointer
473.             IF (j = b) THEN EXIT DO
474.             IF (k = EOC) THEN EXIT DO
475.             j = k
476.         LOOP
477.     END IF
478.     Projection$ = TheReturn
479. END SUB
480.  
481. SUB MapText
482.     IF (TextFormatting = 1) THEN br$ = "~" ELSE br$ = " "
483.     j = StartIndex
484.     i = 1
485.     q$ = ""
486.     d$ = ""
487.     DO ' Begin with any left-over text from previous iteration.
488.         q$ = d$
489.         d$ = ""
490.         r = TextWidth - LEN(q$)
491.         IF (TextWrapping <> 2) THEN k1 = NthP(j, r) ELSE k1 = EOC
492.         k2 = NthPC(j, CHR$(13))
493.         IF (TextWrapping <> 2) THEN c1 = LinearCount(j, k1) ELSE c1 = LinearCount2(j, k1, TextWidth * TextHeight)
494.         c2 = LinearCount(j, k2)
495.         IF (c2 = 0) THEN ' Line is blank-returned.
496.             k = k2
497.             q$ = q$ + br$
498.             j = NthP(k, 2)
499.         ELSE
500.             IF (c1 = c2) THEN ' Possible end of chain.
501.                 k = TheChain(k1).Lagger
502.                 q$ = q$ + Projection$(j, k)
503.                 j = NthP(k, 2)
504.             END IF
505.             IF (c1 < c2) THEN ' Width limit case (not always maximum).
506.                 k = k1
507.                 q$ = q$ + Projection$(j, k)
508.                 j = NthP(k, 2)
509.             END IF
510.             IF (c1 > c2) THEN ' Break return somewhere in line (not first).
511.                 k = k2
512.                 q$ = q$ + Projection$(j, TheChain(k).Lagger) + br$
513.                 n = TheChain(k).Pointer
514.                 IF (n <> EOC) THEN j = n
515.             END IF
516.         END IF
517.         IF (TextWrapping = 1) THEN ' Wrap text at first space from right, send remainder to next line.
518.             IF (LEN(q$) >= TextWidth) THEN
519.                 FOR m = LEN(q$) TO 1 STEP -1
520.                     c$ = MID$(q$, m, 1)
521.                     IF (c$ = " ") OR (c$ = "-") THEN
522.                         q$ = LEFT$(q$, m)
523.                         EXIT FOR
524.                     END IF
525.                     d$ = c$ + d$
526.                     IF (m = 1) THEN ' Line is too long for allowed space and contains no wrapping characters.
527.                         q$ = LEFT$(q$, TextWidth)
528.                         d$ = ""
529.                         EXIT FOR
530.                     END IF
531.                 NEXT
532.             END IF
533.         END IF
534.         LineAsMapped(i) = q$
535.         i = i + 1
536.         IF (i >= TextHeight) THEN EXIT DO
537.         IF (j = k) THEN EXIT DO
538.     LOOP
539.     VisibleLines = i - 1
540. END SUB
541.  
542. FUNCTION StateChange
543.     DIM TheReturn
544.     MH = 0
545.     MW = 0
546.     MT = 0
547.     DO WHILE _MOUSEINPUT
548.         MH1 = _MOUSEBUTTON(1)
549.         MH2 = _MOUSEBUTTON(2)
550.         MH3 = _MOUSEBUTTON(3)
551.         MW = _MOUSEWHEEL
552.         IF (MW <> 0) THEN MT = MW
553.     LOOP
554.     MW = MT
555.  
556.     IF (MH1 = -1) THEN
557.         ' Move Cursor1 among text.
558.         MH = 1
559.         IF ((_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight)) THEN
560.             Cursor1.X = _MOUSEX
561.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
562.             IF (Cursor1.X > q) THEN Cursor1.X = q
563.             Cursor1.Y = _MOUSEY
564.             CALL ReassignID1
565.         END IF
566.         ' Move by vertical scrollbar.
567.         IF (_MOUSEX = WindowWidth) THEN
568.             i = NthL(ID1, ChainLimit + 1)
569.             j = NthP(ID1, ChainLimit + 1)
570.             IF (_MOUSEY = WindowHeight) THEN i = j
571.             IF (_MOUSEY > 1) AND (_MOUSEY < WindowHeight) THEN
572.                 t = LinearCount(i, j)
573.                 f = _MOUSEY / WindowHeight
574.                 FOR k = 1 TO t
575.                     IF (k / t >= f) THEN EXIT FOR
576.                     i = TheChain(i).Pointer
577.                 NEXT
578.             END IF
579.             StartIndex = i
580.             ID1 = i
581.         END IF
582.         ' Move by horizontal scrollbar.
583.         IF (_MOUSEY = WindowHeight - 1) THEN
584.             j = ID1
585.             i = NthP(StartIndex, FindID(LeftIndent + 1, Cursor1.Y))
586.             'IF (_MOUSEX = windowwidth - 1) THEN i = NthP(StartIndex, FindID(LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent)), Cursor1.Y) + (HScroll - 1))
587.             IF (_MOUSEX > 1) AND (_MOUSEX < WindowWidth) THEN
588.                 t = LEN(LineAsMapped(Cursor1.Y - TopIndent))
589.                 f = _MOUSEX / WindowWidth
590.                 FOR k = 1 TO t
591.                     IF (k / t >= f) THEN EXIT FOR
592.                     i = TheChain(i).Pointer
593.                 NEXT
594.             END IF
595.             ID1 = i
596.             d = LinearCount(StartIndex, i) - LinearCount(StartIndex, j)
597.             IF (TextWrapping = 2) THEN HScroll = HScroll + d
598.             IF HScroll < 1 THEN HScroll = 1
599.         END IF
600.     END IF
601.     IF (MH2 = -1) THEN
602.         ' Move Cursor2 and copy anything between Cursor1 and Cursor2 to clipboard.
603.         MH = 1
604.         IF (_MOUSEX > LeftIndent) AND (_MOUSEX < TextWidth + LeftIndent + 1) AND (_MOUSEY > TopIndent) AND (_MOUSEY < TopIndent + TextHeight + 1) THEN
605.             Cursor2.X = _MOUSEX
606.             q = LeftIndent + LEN(LineAsMapped(_MOUSEY - TopIndent))
607.             IF (Cursor2.X > q) THEN Cursor2.X = q
608.             Cursor2.Y = _MOUSEY
609.             CALL ReassignID2
610.             IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN _CLIPBOARD$ = Projection$(ID1, ID2)
611.         END IF
612.     END IF
613.     IF (MH3 = -1) THEN
614.         ' Paste at Cursor1 position.
615.         MH = 1
616.         'IF (LinearCount(StartIndex, ID2) >= LinearCount(StartIndex, ID1)) THEN
617.         CALL InsertRange(ID1, _CLIPBOARD$)
618.     END IF
619.     IF (MW = -1) THEN
620.         ' Wheel up
621.         MH = 1
622.         StartIndex = BackBreak(StartIndex)
623.         CALL ReassignID1
624.     END IF
625.     IF (MW = 1) THEN
626.         ' Wheel down
627.         MH = 1
628.         IF (VisibleLines > 1) THEN
629.             StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
630.             CALL MapText
631.         END IF
632.         CALL ReassignID1
633.     END IF
634.  
635.     KH = 0
636.     '''k$ = ""
637.     '''k$ = INKEY$
638.     '''IF k$ <> "" THEN KH = ASC(k$)
639.     KH = _KEYHIT
640.  
641.     ' Bksp
642.     IF (KH = 8) THEN
643.         r = TheChain(ID1).Pointer
644.         q = TheChain(ID1).Lagger
645.         CALL UnlinkCell(ID1)
646.         IF ((r = EOC) AND (q = BOC)) THEN
647.         ELSE
648.             IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
649.             IF (r = EOC) THEN ID2 = ID1
650.         END IF
651.     END IF
652.     ' Tab
653.     IF (KH = 9) THEN CALL InsertRange(ID1, "    ")
654.     ' Esc
655.     IF (KH = 27) THEN
656.         IF (ID2 <> ID1) THEN ID2 = ID1 ELSE ID2 = StartIndex 'NthL(ID2, 2)
657.     END IF
658.     ' Enter, Alphanumerics
659.     IF (KH = 13) OR ((KH >= 32) AND (KH <= 126)) THEN
660.         IF (InsertKey = -1) THEN
661.             IF (ID1 = ID2) THEN
662.                 CALL InsertBefore(ID1, LTRIM$(RTRIM$(CHR$(KH))))
663.             ELSE
664.                 CALL InsertAfter(ID1, LTRIM$(RTRIM$(CHR$(KH))))
665.                 ID1 = NthP(ID1, 2)
666.             END IF
667.         ELSE
668.             TheChain(ID1).Content = LTRIM$(RTRIM$(CHR$(KH)))
669.             IF (ID1 = ID2) THEN
670.                 ID1 = NthP(ID1, 2)
671.                 ID2 = ID1
672.             ELSE
673.                 ID1 = NthP(ID1, 2)
674.             END IF
675.         END IF
676.         IF ((TextWrapping = 2) AND (Cursor1.X - LeftIndent = TextWidth)) THEN HScroll = HScroll + 1
677.     END IF
678.     ' F1
679.     IF (KH = 15104) THEN
680.         IF (TextWrapping = 2) THEN
681.             HScroll = HScroll - 1
682.             IF (HScroll < 1) THEN HScroll = 1
683.             CALL ReassignID1
684.             CALL ReassignID2
685.         END IF
686.     END IF
687.     ' F2
688.     IF (KH = 15360) THEN
689.         IF (TextWrapping = 2) THEN
690.             HScroll = HScroll + 1
691.             CALL ReassignID1
692.             CALL ReassignID2
693.         END IF
694.     END IF
695.     ' F5
696.     IF (KH = 16128) THEN
697.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
698.         Assimilate q$
699.     END IF
700.     ' F4
701.     IF (KH = 15872) THEN
702.         'CALL InsertRange(NthP(ID2, 2), CHR$(10) + "=" + CoreProcess$(Projection(ID1, ID2)))
703.         'CALL InsertRange(NthP(ID2, 2), CHR$(10) + "=" + SxriptEval$(Projection(ID1, ID2)))
704.         ID2 = StartIndex
705.     END IF
706.     ' F6
707.     IF (KH = 16384) THEN
708.         OPEN FileName$ FOR OUTPUT AS #1
709.         q$ = Projection$(NthL(ID1, ChainLimit + 1), NthP(ID1, ChainLimit + 1))
710.         PRINT #1, q$
711.         CLOSE #1
712.     END IF
713.     ' F7
714.     IF (KH = 16640) THEN
715.         GOLSwitch = -GOLSwitch
716.     END IF
717.     ' F8 IF (KH = 16896) THEN
718.     ' Home
719.     IF (KH = 18176) THEN
720.         IF (TextWrapping = 2) THEN HScroll = 1
721.         Cursor1.X = LeftIndent + 1
722.         CALL ReassignID1
723.     END IF
724.     ' UpArrow
725.     IF (KH = 18432) THEN
726.         IF (Cursor1.Y > TopIndent + 1) THEN
727.             Cursor1.Y = Cursor1.Y - 1
728.         ELSE
729.             StartIndex = BackBreak(StartIndex)
730.         END IF
731.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
732.         IF (Cursor1.X > q) THEN Cursor1.X = q
733.         CALL ReassignID1
734.     END IF
735.     ' PgUp
736.     IF (KH = 18688) THEN
737.         FOR k = 1 TO INT(TextHeight / 2)
738.             StartIndex = BackBreak(StartIndex)
739.         NEXT
740.         CALL ReassignID1
741.     END IF
742.     ' LeftArrow
743.     IF (KH = 19200) THEN
744.         ID1 = NthL(ID1, 2)
745.         IF (TextWrapping = 2) THEN
746.             IF (Cursor1.X = LeftIndent + 1) THEN
747.                 IF (HScroll > 1) THEN
748.                     HScroll = HScroll - 1
749.                 ELSE
750.                     j = Cursor1.Y - TopIndent - 1
751.                     IF (j >= 1) THEN
752.                         k = LEN(LineAsMapped(j)) - TextWidth + 1
753.                         IF (k >= 1) THEN
754.                             HScroll = k
755.                         END IF
756.                     END IF
757.                 END IF
758.             END IF
759.         ELSE
760.             IF ((Cursor1.X - LeftIndent = 1) AND Cursor1.Y - TopIndent = 1) THEN
761.                 StartIndex = BackBreak(StartIndex)
762.             END IF
763.         END IF
764.     END IF
765.     ' RightArrow
766.     IF (KH = 19712) THEN
767.         ID1 = NthP(ID1, 2)
768.         m = Cursor1.X - LeftIndent
769.         n = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - HScroll + 1
770.         IF (TextWrapping = 2) THEN
771.             IF (m >= TextWidth) THEN
772.                 HScroll = HScroll + 1
773.                 CALL ReassignID1
774.             END IF
775.             IF (m >= n) THEN
776.                 j = Cursor1.Y - TopIndent + 1
777.                 IF ((j <= TextHeight) AND (VisibleLines > 1)) THEN HScroll = 1
778.             END IF
779.         ELSE
780.             IF ((m >= n) AND (Cursor1.Y - TopIndent = VisibleLines)) THEN
781.                 IF (VisibleLines > 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
782.             END IF
783.         END IF
784.     END IF
785.     ' End
786.     IF (KH = 20224) THEN
787.         Cursor1.X = LeftIndent + LEN(LineAsMapped(Cursor1.Y - TopIndent))
788.         CALL ReassignID1
789.         IF (TextWrapping = 2) THEN
790.             q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) - TextWidth + 1
791.             IF (q >= 1) THEN HScroll = q
792.         END IF
793.     END IF
794.     ' DownArrow
795.     IF (KH = 20480) THEN
796.         IF (Cursor1.Y = TopIndent + VisibleLines) THEN
797.             IF (VisibleLines > 1) THEN
798.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
799.                 CALL MapText
800.             END IF
801.         ELSE
802.             Cursor1.Y = Cursor1.Y + 1
803.         END IF
804.         q = LEN(LineAsMapped(Cursor1.Y - TopIndent)) + 1
805.         IF (Cursor1.X > q) THEN
806.             Cursor1.X = q
807.         END IF
808.         CALL ReassignID1
809.     END IF
810.     ' PgDn
811.     IF (KH = 20736) THEN
812.         FOR k = 1 TO INT(TextHeight / 2)
813.             IF (VisibleLines > 1) THEN
814.                 StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
815.                 CALL MapText
816.             END IF
817.         NEXT
818.         CALL ReassignID1
819.     END IF
820.     ' Insert
821.     IF (KH = 20992) THEN
822.         InsertKey = -InsertKey
823.     END IF
824.     ' Del
825.     IF (KH = 21248) THEN
826.         IF (LinearCount(StartIndex, ID2) > LinearCount(StartIndex, ID1)) THEN
827.             r = TheChain(ID2).Pointer
828.             q = TheChain(ID1).Lagger
829.             p = ID1
830.             CALL UnlinkRange(ID1, ID2)
831.             IF ((r = EOC) AND (q = BOC)) THEN
832.                 ID1 = p
833.                 ID2 = ID1
834.                 StartIndex = p
835.             ELSE
836.                 IF (q <> BOC) THEN ID1 = q ELSE ID1 = r
837.                 ID2 = NthP(ID1, 2)
838.             END IF
839.         END IF
840.     END IF
841.     ' F11
842.     IF (KH = 34048) THEN TextFormatting = -TextFormatting
843.     ' F12
844.     IF (KH = 34304) THEN
845.         TextWrapping = TextWrapping + 1
846.         IF (TextWrapping > 2) THEN TextWrapping = 0
847.         ID1 = StartIndex
848.         ID2 = ID1
849.         HScroll = 1
850.     END IF
851.     ' Exit sequence
852.     TheReturn = 0
853.     IF ((MH <> 0) OR (KH > 0)) THEN
854.         TheReturn = 1
855.         CALL MapText
856.         CALL CalibrateCursor(ID1)
857.         CALL CalibrateCursor(ID2)
858.         ' Cursor sync and autoscrolling.
859.         IF (Cursor1.Y > TopIndent + TextHeight - 1) THEN StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
860.     END IF
861.     _KEYCLEAR
862.     StateChange = TheReturn
863. END FUNCTION
864.  
865. SUB CalibrateCursor (a AS LONG)
866.     ' Place Cursor under ID on rendered line.
867.     s = StartIndex
868.     IF ((TextWrapping = 2) AND (HScroll > 1)) THEN s = NthP(s, HScroll)
869.     c = LinearCount(s, a)
870.     k = 0
871.     i = -1
872.     FOR j = 1 TO VisibleLines
873.         n = LEN(LineAsMapped(j))
874.         IF (k + n < c) THEN
875.             k = k + n
876.         ELSE
877.             i = c - k + 1
878.             EXIT FOR
879.         END IF
880.     NEXT
881.     IF (i >= LeftIndent + LEN(LineAsMapped(j))) THEN
882.         IF (j <= VisibleLines) THEN
883.             i = 1
884.             j = j + 1
885.         END IF
886.     END IF
887.     IF (a = ID1) THEN
888.         Cursor1.X = LeftIndent + i
889.         Cursor1.Y = TopIndent + j
890.     END IF
891.     IF (a = ID2) THEN
892.         Cursor2.X = LeftIndent + i
893.         Cursor2.Y = TopIndent + j
894.     END IF
895. END SUB
896.  
897. FUNCTION FindID (a AS INTEGER, b AS LONG)
898.     ' Find identity under a map location.
899.     RelX = a - LeftIndent
900.     RelY = b - TopIndent
901.     FOR k = 1 TO RelY - 1
902.         t = t + LEN(LineAsMapped(k))
903.     NEXT
904.     t = t + RelX
905.     FindID = t
906. END FUNCTION
907.  
908. SUB ReassignID1
909.     ' Reassign identity under Cursor1.
910.     ID1 = NthP(StartIndex, FindID(Cursor1.X, Cursor1.Y) + (HScroll - 1))
911. END SUB
912.  
913. SUB ReassignID2
914.     ' Reassign identity under Cursor2.
915.     ID2 = NthP(StartIndex, FindID(Cursor2.X, Cursor2.Y) + (HScroll - 1))
916. END SUB
917.  
918. SUB ConvertToGrid
919.     FOR j = 1 TO VisibleLines
920.         c$ = LineAsMapped(j)
921.         FOR i = 1 TO LEN(c$) - 1 ' BR offset to exclude break return at line end.
922.             AuxGrid(i, j, 1) = MID$(c$, i, 1)
923.         NEXT
924.     NEXT
925. END SUB
926.  
927. SUB ConvertFromGrid
928.     q$ = ""
929.     FOR j = 1 TO VisibleLines
930.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
931.             q$ = q$ + AuxGrid(i, j, 1)
932.         NEXT
933.         q$ = q$ + CHR$(13) ' Undoes BR offset.
934.     NEXT
935.     Assimilate q$
936. END SUB
937.  
938. SUB GOL
939.     FOR j = 1 TO VisibleLines
940.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
941.             c$ = AuxGrid(i, j, 1)
942.             IF (c$ = " ") THEN c$ = "0" ELSE c$ = "1"
943.             AuxGrid(i, j, 1) = c$
944.             AuxGrid(i, j, 2) = c$
945.         NEXT
946.     NEXT
947.     FOR j = 2 TO VisibleLines - 2 ' BR offset.
948.         FOR i = 2 TO LEN(LineAsMapped(j)) - 2 ' BR offset.
949.             c$ = AuxGrid(i, j, 1)
950.             a1 = VAL(AuxGrid(i - 1, j + 1, 1))
951.             a2 = VAL(AuxGrid(i, j + 1, 1))
952.             a3 = VAL(AuxGrid(i + 1, j + 1, 1))
953.             a4 = VAL(AuxGrid(i - 1, j, 1))
954.             a6 = VAL(AuxGrid(i + 1, j, 1))
955.             a7 = VAL(AuxGrid(i - 1, j - 1, 1))
956.             a8 = VAL(AuxGrid(i, j - 1, 1))
957.             a9 = VAL(AuxGrid(i + 1, j - 1, 1))
958.             t = a1 + a2 + a3 + a4 + a6 + a7 + a8 + a9
959.             IF (c$ = "1") THEN
960.                 SELECT CASE t
961.                     CASE IS < 2
962.                         AuxGrid(i, j, 2) = "0"
963.                     CASE 2
964.                         AuxGrid(i, j, 2) = "1"
965.                     CASE 3
966.                         AuxGrid(i, j, 2) = "1"
967.                     CASE IS > 3
968.                         AuxGrid(i, j, 2) = "0"
969.                 END SELECT
970.             ELSE
971.                 IF (t = 3) THEN AuxGrid(i, j, 2) = "1"
972.             END IF
973.         NEXT
974.     NEXT
975.     FOR j = 1 TO VisibleLines
976.         FOR i = 1 TO LEN(LineAsMapped(j)) - 1
977.             c$ = AuxGrid(i, j, 2)
978.             IF (c$ = "0") THEN c$ = " " ELSE c$ = CHR$(219)
979.             AuxGrid(i, j, 1) = c$
980.             AuxGrid(i, j, 2) = c$
981.         NEXT
982.     NEXT
983. END SUB
984.  
985. SUB ThrowOutput
986.     'i = NthP(ID1, ChainLimit + 1)
987.     'FOR k = 1 TO LogTextCount
988.     '    CALL InsertRange(i, LogText(k) + CHR$(13))
989.     'NEXT
990.     LogTextCount = 0
991.     CALL MapText
992.     ID1 = NthP(ID1, ChainLimit + 1)
993.     CALL CalibrateCursor(ID1)
994.     CALL CalibrateCursor(ID2)
995.     DO WHILE (Cursor1.Y > TopIndent + TextHeight - 1)
996.         StartIndex = NthP(StartIndex, LEN(LineAsMapped(1)) + 1)
997.         CALL MapText
998.         CALL CalibrateCursor(ID1)
999.         CALL CalibrateCursor(ID2)
1000.     LOOP
1001.     ID1 = NthP(ID1, ChainLimit + 1)
1002.     CALL PrintEverything
1003. END SUB
1004.  
1005. SUB DisplayText (Col AS INTEGER, Row AS INTEGER, Shade1 AS INTEGER, Shade2 AS INTEGER, Text AS STRING)
1006.     COLOR Shade1, Shade2
1007.     _PRINTSTRING (Col, Row), Text
1008.     'LOCATE Row, Col: PRINT Text
1009. END SUB
1010.  
1011. 'REM $Include: 'sxmath.bm'
1012. 'REM $Include: 'sxript.bm'
1013.  

[Prithak]

Thank you for all the help bplus, Pete and STxAxTIC. You're right! I should get the text editor further along with the text editor before I do that lol. I just wanted to make an IDE for my programming language that I am making and I wanted to highlight the syntax. I made this program late at night with my eyes sore xD. So, I forgot to include IF LEN(k$). I would have done that lol. Thank you Pete for the code and also bplus! I would try to make it happen though with my own mind ;P

[bplus]

Thank you for all the help bplus, Pete and STxAxTIC. You're right! I should get the text editor further along with the text editor before I do that lol. I just wanted to make an IDE for my programming language that I am making and I wanted to highlight the syntax. I made this program late at night with my eyes sore xD. So, I forgot to include IF LEN(k$). I would have done that lol. Thank you Pete for the code and also bplus! I would try to make it happen though with my own mind ;P

When I play around with interpreters, I used a standard text editor to write the programs and saved them with a special extension like bas.txt so myNextProgram is named "myNextProgram bas.txt". I could drag and drop such a file onto the .exe interpreter and from a COMMAND$ check, it would recognize the file as meant to run with interpreter. If COMMAND$ was blank, when the interpreter was run or not a proper file, it would show the files in folder with a "* bas.txt" extension that could be selected to run. This saves you all the trouble of writing an editor/IDE and you can focus on the Interpreter or PL you are developing.

Arrays are going to end up biting you. Go with a linked list:

Not so much with lines to a program which naturally fall into an array. WP with word wrap and all the bells and whistles of text editor, yeah, after a certain size, arrays become too slow.

[Aurel]

I just wanted to make an IDE for my programming language

then you must use scintilla or something similar if you whish to do it on a quick way.
If you whish o do it from scratch then you can use richedit control ..but this require
windows api and lot of learning and thinkering.
for scintilla you may look into codeProject site or maybe you can look into my forum
for my own editor (witen in o2)....or you may look into DAVs IDE but then you need to know pureBasic.
hmmm lot of problems...