Off center?

[SMcNeill]

Code: QB64: [Select]

1. DIM HandColor AS _UNSIGNED LONG
2. HandColor = &HFF000000
3.  
4. SCREEN _NEWIMAGE(640, 640, 32)
5. _SCREENMOVE _MIDDLE
6. DEFLNG A-Z
7. _DONTBLEND
8.  
9. Texture = _LOADIMAGE("wood.jpg", 32)
10.  
11. CircleFill 320, 320, 320, -1
12.  
13. FOR x = 0 TO 639: FOR y = 0 TO 639 'Paint the clock our wooden texture to make it pretty...
14.         IF POINT(x, y) THEN _SOURCE Texture: PSET (x, y), POINT(x, y): _SOURCE 0
15. NEXT y, x
16.  
17.  
18. Minute = _NEWIMAGE(500, 80, 32)
19. _DEST Minute
20. FOR x = 250 TO 450
21.     FOR y = 35 TO 45
22.         PSET (x, y), HandColor
23.     NEXT
24. NEXT
25. LINE (450, 35)-STEP(0, -5), HandColor
26. LINE -STEP(50, 11), HandColor
27. LINE -STEP(-50, 10), HandColor
28. LINE -STEP(0, -10), HandColor
29. PAINT (451, 35), HandColor
30. CircleFill 250, 40, 20, HandColor
31.  
32. _DEST 0
33. _BLEND
34.  
35. Hour = ScaleImage(Minute, .75, 1)
36. second = ScaleImage(Minute, 1, .25)
37.  
38. DisplayImage Minute, 320, 320, 90, 0
39. DisplayImage Hour, 320, 320, 0, 0
40. DisplayImage second, 320, 320, -90, 0
41.  
42. SLEEP
43.  
44. SUB DisplayImage (Image AS LONG, x AS INTEGER, y AS INTEGER, angle AS SINGLE, mode AS _BYTE)
45.     'Image is the image handle which we use to reference our image.
46.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
47.     'angle is the angle which we wish to rotate the image.
48.     'mode determines HOW we place the image at point X,Y.
49.     'Mode 0 we center the image at point X,Y
50.     'Mode 1 we place the Top Left corner of oour image at point X,Y
51.     'Mode 2 is Bottom Left
52.     'Mode 3 is Top Right
53.     'Mode 4 is Bottom Right
54.  
55.  
56.     DIM px(3) AS INTEGER, py(3) AS INTEGER, w AS INTEGER, h AS INTEGER
57.     DIM sinr AS SINGLE, cosr AS SINGLE, i AS _BYTE
58.     w = _WIDTH(Image): h = _HEIGHT(Image)
59.     SELECT CASE mode
60.         CASE 0 'center
61.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
62.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
63.         CASE 1 'top left
64.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
65.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
66.         CASE 2 'bottom left
67.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
68.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
69.         CASE 3 'top right
70.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
71.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
72.         CASE 4 'bottom right
73.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
74.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
75.     END SELECT
76.     sinr = SIN(angle / 57.2957795131): cosr = COS(angle / 57.2957795131)
77.     FOR i = 0 TO 3
78.         x2 = (px(i) * cosr + sinr * py(i)) + x: y2 = (py(i) * cosr - px(i) * sinr) + y
79.         px(i) = x2: py(i) = y2
80.     NEXT
81.     _MAPTRIANGLE (0, 0)-(0, h - 1)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
82.     _MAPTRIANGLE (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
83. END SUB
84.  
85. SUB CircleFill (CX AS INTEGER, CY AS INTEGER, R AS INTEGER, C AS _UNSIGNED LONG)
86.     ' CX = center x coordinate
87.     ' CY = center y coordinate
88.     '  R = radius
89.     '  C = fill color
90.     DIM Radius AS INTEGER, RadiusError AS INTEGER
91.     DIM X AS INTEGER, Y AS INTEGER
92.     Radius = ABS(R)
93.     RadiusError = -Radius
94.     X = Radius
95.     Y = 0
96.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
97.     LINE (CX - X, CY)-(CX + X, CY), C, BF
98.     WHILE X > Y
99.         RadiusError = RadiusError + Y * 2 + 1
100.         IF RadiusError >= 0 THEN
101.             IF X <> Y + 1 THEN
102.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
103.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
104.             END IF
105.             X = X - 1
106.             RadiusError = RadiusError - X * 2
107.         END IF
108.         Y = Y + 1
109.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
110.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
111.     WEND
112. END SUB
113.  
114. FUNCTION ScaleImage (Image AS LONG, xscale AS SINGLE, yscale AS SINGLE)
115.     w = _WIDTH(Image): h = _HEIGHT(Image)
116.     w2 = w * xscale: h2 = h * yscale
117.     NewImage& = _NEWIMAGE(w2, h2, 32)
118.     _PUTIMAGE (0, 0)-(w2 - 1, h2 - 1), Image&, NewImage&, (0, 0)-(w - 1, h - 1)
119.     ScaleImage = NewImage&
120. END FUNCTION
121.  

Since everybody has been playing around with fancy little clocks, I thought I'd have some fun and return to the classics -- a simple wood grained circle clock. 

For this, I decided to make my own simple little hands which I can rotate and spin to make all pretty, as in the program above.  It all looks fairly nice, with one minor exception -- the arrow at the end of the lines looks off center to me, as if it's slightly askew.  (I think the effect is very noticeable with the second hand as it's displayed for the current clock.)

The hands are made with a simple set of LINE commands, and should be centered properly to make a perfect little triangle, but they don't seem to do that to me.  It's probably something really simple off here, but I'm not seeing it, so I thought  I'd share and see if anybody notices the type/math error which I'm producing here. 

You'll need the wood.jpg texture from below to make the clock look pretty and proper.  ;)

[Pete]

What no rooster? Look you cock-a-doodle doofus, I've been holding back on every time you want to update a rooster clock, I can post, "Well hurry up, the cock is ticking!" But instead you give me wood. What am I supposed to do with that? It's hard sometimes. I mean when I ask for... oh wait, this isn't going to end well... rooster, I expect to get rooster!

It does have an old fashioned look to it, good job achieving that. I wonder if there is a way to apply that anti-alias trick to the triangles, that make up the points of the hands? If so, it would be polished off. Hey, polished off wood... I'm back!

Pete

 

[bplus]

Hey Steve, try this:

Code: QB64: [Select]

1. LINE (450, 35)-STEP(0, -15), HandColor
2. LINE -STEP(50, 20), HandColor ' <<<<<<<<<<<<<<<<<<<< 10 not 11, oh make arrows points bigger for second hand
3. LINE -STEP(-50, 20), HandColor
4. LINE -STEP(0, -20), HandColor
5. PAINT (451, 35), HandColor
6. CircleFill 250, 40, 20, HandColor
7.  
8.  
9.  

  [ You are not allowed to view this attachment ]