« previous next »
Pages: [1]   Go Down

Author Topic: Recaman Sequence  (Read 10595 times)

0 Members and 1 Guest are viewing this topic.

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Recaman Sequence
« on: February 18, 2019, 01:17:07 pm »
Stumbled onto this while surfing youtube (see link in code):
Code: QB64: [Select]
  1. _TITLE "Recaman Sequence" 'B+ 2019-02-18
  2.  
  3. 'reference and thanks:
  4. ' [youtube]https://www.youtube.com/watch?v=FGC5TdIiT9U[/youtube]
  5.  
  6. CONST xmax = 1200
  7. CONST ymax = 700
  8. SCREEN _NEWIMAGE(xmax, ymax, 32)
  9. _SCREENMOVE 100, 20
  10.  
  11. 'draw a number line spacing integers by SP
  12. CY = ymax / 2
  13. SP = 5 'so 1200/sp = 240 numbers on a numberline
  14. LINE (0, CY)-(xmax, CY)
  15. FOR i = 0 TO xmax / SP
  16.     CIRCLE (i * SP, CY), 1
  18. DIM n(0 TO 16000) 'save places where number is used
  19.  
  20. interval = 1
  21. current = 0
  22. n(current) = -1 'we've been here already!
  23.  
  24.  
  25. ' !!! The rule is to go back if (current position - interval) is not taken and is >= 0, otherwise go forward.
  26. ' The interval is increased by one after each hop.
  27.  
  29.     LINE (0, 0)-(200, 30), _RGB32(0, 0, 0) '  clean out old message
  30.     LOCATE 1, 1: PRINT "Interval:"; interval 'report interval or hop number
  31.     IF LEN(INKEY$) <> 0 THEN q = -1 '         allow bug out any key press
  32.  
  33.     R = interval / 2 'for radius of hop drawing
  34.     'alternate hops with semi circles
  35.     IF interval MOD 2 THEN
  36.         start = _PI: fini = 0 'semi circle start and end over the line
  37.     ELSE
  38.         start = 0: fini = _PI 'semi circle start and end under the line
  39.     END IF
  40.  
  41.     test = current - interval 'test against our Rule
  42.     IF test < 0 THEN
  43.         'draw current to current + interval
  44.         CIRCLE (SP * (current + R), CY), R * SP, , start, fini
  45.         current = current + interval
  46.         n(current) = -1 'we've been here
  47.     ELSEIF n(test) <> 0 THEN
  48.         'draw current to current + interval
  49.         CIRCLE (SP * (current + R), CY), R * SP, , start, fini
  50.         current = current + interval
  51.         n(current) = -1 'we've been here
  52.     ELSE
  53.         'draw back semi current - interval
  54.         CIRCLE (SP * (current - R), CY), R * SP, , start, fini
  55.         current = test
  56.         n(current) = -1 'we've been here
  57.     END IF
  58.     interval = interval + 1
  59.     _DISPLAY
  60.     _LIMIT 1 '<<< however fast you want 1, 10, 100
  61. LOOP UNTIL q OR interval = 3001 'good place to stop for this graph
  63.  
  65. PRINT "What numbers are left after 3000 hops? ":
  66. FOR i = 0 TO xmax / SP
  67.     IF n(i) = 0 THEN PRINT i,
  69. PRINT " the end."
  70.  
  71.  
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Recaman Sequence
« Reply #1 on: February 18, 2019, 03:00:11 pm »
Nice work, Bplus!
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Recaman Sequence
« Reply #2 on: February 18, 2019, 03:04:44 pm »
Thanks Petr, I was thinking about trying sound but have to track down 6 octaves of a Scale.
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Recaman Sequence
« Reply #3 on: February 18, 2019, 03:31:05 pm »
maybe - to line 59 insert:

SOUND 50 + interval, .5

for easy sound effect (of course it is not piano :-D)
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Recaman Sequence
« Reply #4 on: February 18, 2019, 05:04:12 pm »
In the key of C:
Code: QB64: [Select]
  1. _TITLE "Recaman Sequence" 'B+ 2019-02-18
  2.  
  3. 'reference and thanks:
  4. ' [youtube]https://www.youtube.com/watch?v=FGC5TdIiT9U[/youtube]
  5.  
  6. CONST xmax = 1200
  7. CONST ymax = 700
  8. SCREEN _NEWIMAGE(xmax, ymax, 32)
  9. _SCREENMOVE 100, 20
  10.  
  11. 'prep sound array
  12. DIM s(0 TO 41) '6 * 7  mod 42
  13. '      c             d             e             f             g             a             b
  14. s(0) = 65: s(1) = 73: s(2) = 82: s(3) = 87: s(4) = 98: s(5) = 110: s(6) = 123
  15. s(7) = 131: s(8) = 147: s(9) = 165: s(10) = 175: s(11) = 196: s(12) = 220: s(13) = 247
  16. s(14) = 262: s(15) = 294: s(16) = 330: s(17) = 349: s(18) = 392: s(19) = 440: s(20) = 494
  17. s(21) = 523: s(22) = 587: s(23) = 659: s(24) = 698: s(25) = 784: s(26) = 880: s(27) = 988
  18. s(28) = 1047: s(29) = 1175: s(30) = 1318: s(31) = 1397: s(32) = 1568: s(33) = 1760: s(34) = 1976
  19. s(35) = 2093: s(36) = 2349: s(37) = 2637: s(38) = 2794: s(39) = 3136: s(40) = 3520: s(41) = 3951
  20.  
  21. 'draw a number line spacing integers by SP
  22. CY = ymax / 2
  23. SP = 5 'so 1200/sp = 240 numbers on a numberline
  24. LINE (0, CY)-(xmax, CY)
  25. FOR i = 0 TO xmax / SP
  26.     CIRCLE (i * SP, CY), 1
  28. DIM n(0 TO 16000) 'save places where number is used
  29.  
  30. interval = 1
  31. current = 0
  32. n(current) = -1 'we've been here already!
  33.  
  34.  
  35. ' !!! The rule is to go back if (current position - interval) is not taken and is >= 0, otherwise go forward.
  36. ' The interval is increased by one after each hop.
  37.  
  39.     LINE (0, 0)-(200, 30), _RGB32(0, 0, 0) '  clean out old message
  40.     LOCATE 1, 1: PRINT "Interval:"; interval 'report interval or hop number
  41.     IF LEN(INKEY$) <> 0 THEN q = -1 '         allow bug out any key press
  42.  
  43.     R = interval / 2 'for radius of hop drawing
  44.     'alternate hops with semi circles
  45.     IF interval MOD 2 THEN
  46.         start = _PI: fini = 0 'semi circle start and end over the line
  47.     ELSE
  48.         start = 0: fini = _PI 'semi circle start and end under the line
  49.     END IF
  50.  
  51.     test = current - interval 'test against our Rule
  52.     IF test < 0 THEN
  53.         'draw current to current + interval
  54.         CIRCLE (SP * (current + R), CY), R * SP, , start, fini
  55.         current = current + interval
  56.         n(current) = -1 'we've been here
  57.     ELSEIF n(test) <> 0 THEN
  58.         'draw current to current + interval
  59.         CIRCLE (SP * (current + R), CY), R * SP, , start, fini
  60.         current = current + interval
  61.         n(current) = -1 'we've been here
  62.     ELSE
  63.         'draw back semi current - interval
  64.         CIRCLE (SP * (current - R), CY), R * SP, , start, fini
  65.         current = test
  66.         n(current) = -1 'we've been here
  67.     END IF
  68.     SOUND s(current MOD 42), 1
  69.     interval = interval + 1
  70.     _DISPLAY
  71.     _LIMIT 6 '<<< however fast you want 1, 10, 100
  72. LOOP UNTIL q OR interval = 3001 'good place to stop for this graph
  73. FOR i = 6 TO 1 STEP -1
  74.     SOUND s(i * 7 - 6), 2
  75.     _LIMIT 6
  77. SOUND s(16), 1
  78. SOUND s(15), 2
  79. SOUND s(14), 4
  80. SOUND s(16), 8
  81. SOUND s(15), 4
  82. SOUND s(14), 1
  83. SOUND s(14), 8
  85.  
  87. PRINT "What numbers are left after 3000 hops? ":
  88. FOR i = 0 TO xmax / SP
  89.     IF n(i) = 0 THEN PRINT i,
  91. PRINT " the end."
  92.  
  93. '      1* D#1 ...... 39           G3 ....... 196          A#5 ...... 932
  94. '         E1 ....... 41           G#3 ...... 208          B5 ....... 988
  95. '         F1 ....... 44           A3 ....... 220       6* C6 ....... 1047
  96. '         F#1 ...... 46           A#3 ...... 233          C#6 ...... 1109
  97. '         G1 ....... 49           B3 ....... 247          D6 ....... 1175
  98. '         G#1 ...... 51        4* C4 ....... 262          D#6 ...... 1245
  99. '         A1 ....... 55           C#4 ...... 277          E6 ....... 1318
  100. '         A#1 ...... 58           D4 ....... 294          F6 ....... 1397
  101. '         B1 ....... 62           D#4 ...... 311          F#6 ...... 1480
  102. '      2* C2 ....... 65           E4 ....... 330          G6 ....... 1568
  103. '         C#2 ...... 69           F4 ....... 349          G# ....... 1661
  104. '         D2 ....... 73           F#4 ...... 370          A6 ....... 1760
  105. '         D#2 ...... 78           G4 ....... 392          A#6 ...... 1865
  106. '         E2 ....... 82           G#4 ...... 415          B6 ....... 1976
  107. '         F2 ....... 87           A4 ....... 440       7* C7 ....... 2093
  108. '         F#2 ...... 92           A# ....... 466          C#7 ...... 2217
  109. '         G2 ....... 98           B4 ....... 494          D7 ....... 2349
  110. '         G#2 ...... 104       5* C5 ....... 523          D#7 ...... 2489
  111. '         A2 ....... 110          C#5 ...... 554          E7 ....... 2637
  112. '         A#2 ...... 117          D5 ....... 587          F7 ....... 2794
  113. '         B2 ....... 123          D#5 ...... 622          F#7 ...... 2960
  114. '      3* C3 ....... 131          E5 ....... 659          G7 ....... 3136
  115. '         C#3 ...... 139          F5 ....... 698          G#7 ...... 3322
  116. '         D3 ....... 147          F#5 ...... 740          A7 ....... 3520
  117. '         D#3 ...... 156          G5 ....... 784          A#7 ...... 3729
  118. '         E3 ....... 165          G#5 ...... 831          B7 ....... 3951
  119. '         F3 ....... 175          A5 ....... 880       8* C8 ....... 4186
  120. '         F#3 ...... 185
  121.  
  122.  
Logged

Offline Petr

  • Forum Resident
  • Posts: 1720
  • The best code is the DNA of the hops.
    • View Profile
Re: Recaman Sequence
« Reply #5 on: February 18, 2019, 05:15:43 pm »
My goodness! Very beautiful!
Logged

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Recaman Sequence
« Reply #6 on: February 19, 2019, 12:02:26 pm »
Thanks for your interest [banned user]. It did need a bit of "colour".

Perhaps a 42 color palette to go with the notes, 7 main hues for notes and a shade higher for each octave. Could have done frequencies that way.

math:
base = current mod 7
octave = (current mod 42)\7
sound s(base) * 2 ^ octave





« Last Edit: February 19, 2019, 12:08:30 pm by bplus »
Logged

Offline Ashish

  • Forum Resident
  • Posts: 630
  • Never Give Up!
    • View Profile
Re: Recaman Sequence
« Reply #7 on: February 21, 2019, 08:54:54 am »
Wow! It look like a amazing fractal to me. :D
Logged
if (Me.success) {Me.improve()} else {Me.tryAgain()}


My Projects - https://github.com/AshishKingdom?tab=repositories
OpenGL tutorials - https://ashishkingdom.github.io/OpenGL-Tutorials

Offline bplus

  • Global Moderator
  • Forum Resident
  • Posts: 8053
  • b = b + ...
    • View Profile
Re: Recaman Sequence
« Reply #8 on: February 21, 2019, 10:04:43 pm »
OK after writing up code for arcRing, I can now draw arcs in alpha at any width without overlap and now can colorize Recaman the way I envisioned plus modified sound as commented above:
Code: QB64: [Select]
  1. _TITLE "Recaman Sequence Sound and Color mod" 'B+ 2019-02-21
  2.  
  3. 'reference and thanks:
  4. ' [youtube]https://www.youtube.com/watch?v=FGC5TdIiT9U[/youtube]
  5.  
  6. CONST xmax = 1200
  7. CONST ymax = 700
  8. SCREEN _NEWIMAGE(xmax, ymax, 32)
  9. _SCREENMOVE 100, 20
  10.  
  11. 'prep sound array
  12. DIM s(0 TO 6) '6 * 7  mod 42
  13. '      c          d          e          f          g          a           b
  14. s(0) = 65: s(1) = 73: s(2) = 82: s(3) = 87: s(4) = 98: s(5) = 110: s(6) = 123
  15. 'prep palette multiples
  16. DIM C(0 TO 6, 0 TO 2)
  17. C(0, 0) = 1: C(0, 1) = 0: C(0, 2) = 0
  18. C(1, 0) = 1: C(1, 1) = 1: C(1, 2) = 0
  19. C(2, 0) = 1: C(2, 1) = 0: C(2, 2) = 1
  20. C(3, 0) = 0: C(3, 1) = 1: C(3, 2) = 0
  21. C(4, 0) = 0: C(4, 1) = 1: C(4, 2) = 1
  22. C(5, 0) = 0: C(5, 1) = 0: C(5, 2) = 1
  23. C(6, 0) = 1: C(6, 1) = 1: C(6, 2) = 1
  24.  
  25. 'draw a number line spacing integers by SP
  26. CY = ymax / 2
  27. SP = 5 'so 1200/sp = 240 numbers on a numberline
  28. 'LINE (0, CY)-(xmax, CY)
  29. 'FOR i = 0 TO xmax / SP
  30. '    CIRCLE (i * SP, CY), 1
  31. 'NEXT
  32. DIM n(0 TO 16000) 'save places where number is used
  33.  
  34. interval = 1
  35. current = 0
  36. n(current) = -1 'we've been here already!
  37. intLimit = 400
  38.  
  39. ' !!! The rule is to go back if (current position - interval) is not taken and is >= 0, otherwise go forward.
  40. ' The interval is increased by one after each hop.
  41.  
  43.  
  44.     LINE (0, 0)-(200, 30), _RGB32(0, 0, 0) '  clean out old message
  45.     COLOR _RGB32(220, 220, 220)
  46.     LOCATE 1, 1: PRINT "Interval:"; interval 'report interval or hop number
  47.     LOCATE 2, 1: PRINT " Current:"; current
  48.     IF LEN(INKEY$) <> 0 THEN q = -1 '         allow bug out any key press
  49.  
  50.     r = interval / 2 'for radius of hop drawing
  51.     'alternate hops with semi circles
  52.     IF interval MOD 2 THEN
  53.         start = _PI: fini = 0 'semi circle start and end over the line
  54.     ELSE
  55.         start = 0: fini = _PI 'semi circle start and end under the line
  56.     END IF
  57.     b = current MOD 7
  58.     octave = INT((current MOD 42) \ 7 + 1)
  59.     SOUND s(b) * 2 ^ octave, 1
  60.     c~& = _RGBA32(C(b, 0) * octave * 30 + 45, C(b, 1) * octave * 30 + 45, C(b, 2) * octave * 30 + 45, 120)
  61.     test = current - interval 'test against our Rule
  62.     IF test < 0 THEN
  63.         'draw current to current + interval
  64.         arcRing SP * (current + r), CY, r * SP, r * SP - SP, start, fini, c~&
  65.         current = current + interval
  66.         n(current) = -1 'we've been here
  67.     ELSEIF n(test) <> 0 THEN
  68.         'draw current to current + interval
  69.         arcRing SP * (current + r), CY, r * SP, r * SP - SP, start, fini, c~&
  70.         current = current + interval
  71.         n(current) = -1 'we've been here
  72.     ELSE
  73.         'draw back semi current - interval
  74.         arcRing SP * (current - r), CY, r * SP, r * SP - SP, start, fini, c~&
  75.         current = test
  76.         n(current) = -1 'we've been here
  77.     END IF
  78.  
  79.     interval = interval + 1
  80.     _DISPLAY
  81.     _LIMIT 6 '<<< however fast you want 1, 10, 100
  82. LOOP UNTIL q OR interval = intLimit + 1 'good place to stop for this graph
  83. FOR i = 6 TO 1 STEP -1
  84.     SOUND s(i) * 2 ^ 3 - 6, 2
  85.     _LIMIT 6
  87. SOUND s(2) * 8, 1
  88. SOUND s(1) * 8, 2
  89. SOUND s(0) * 8, 4
  90. SOUND s(2) * 8, 8
  91. SOUND s(1) * 8, 4
  92. SOUND s(0) * 8, 1
  93. SOUND s(0) * 8, 8
  95.  
  97. COLOR _RGB32(220, 220, 220)
  98. PRINT "What numbers are left after "; intLimit; " hops? ":
  99. FOR i = 0 TO xmax / SP
  100.     IF n(i) = 0 THEN PRINT i,
  102. PRINT " the end."
  103.  
  104. 'doing a circle fill with this runs 20 x's slower than Gold Std Circle Fill
  105. SUB arcRing (x0, y0, outerR, innerR, raStart, raEnd, colr AS _UNSIGNED LONG)
  106.     DIM x AS INTEGER, y AS INTEGER
  107.     PI2 = _PI(2)
  108.     PI32 = _PI(1.5)
  109.     PIh = _PI(.5)
  110.     PI = _PI
  111.     raS = raStart
  112.     WHILE raS >= PI2
  113.         raS = raS - PI2
  114.     WEND
  115.     WHILE raS < 0
  116.         raS = raS + PI2
  117.     WEND
  118.     raE = raEnd
  119.     WHILE raE < 0
  120.         raE = raE + PI2
  121.     WEND
  122.     WHILE raE >= PI2
  123.         raE = raE - PI2
  124.     WEND
  125.     IF raE > raS THEN ck1 = -1
  126.     FOR y = y0 - outerR TO y0 + outerR
  127.         FOR x = x0 - outerR TO x0 + outerR
  128.             dist = SQR((x - x0) * (x - x0) + (y - y0) * (y - y0))
  129.             IF dist >= innerR AND dist <= outerR THEN 'within 2 radii
  130.                 'angle of x, y to x0, y0
  131.                 IF x - x0 <> 0 AND y - y0 <> 0 THEN
  132.                     ra = _ATAN2(y - y0, x - x0)
  133.                     IF ra < 0 THEN ra = ra + PI2
  134.                 ELSEIF x - x0 = 0 THEN
  135.                     IF y >= y0 THEN ra = _PI / 2 ELSE ra = PI32
  136.                 ELSEIF y - y0 = 0 THEN
  137.                     IF x >= x0 THEN ra = 0 ELSE ra = PI
  138.                 END IF
  139.                 IF ck1 THEN 'raEnd > raStart
  140.                     IF ra >= raS AND ra <= raE THEN
  141.                         PSET (x, y), colr
  142.                     END IF
  143.                 ELSE 'raEnd < raStart, raEnd is falls before raStart clockwise so fill through 2 * PI
  144.                     IF ra >= raS AND ra < PI2 THEN
  145.                         PSET (x, y), colr
  146.                     ELSE
  147.                         IF ra >= 0 AND ra <= raE THEN
  148.                             PSET (x, y), colr
  149.                         END IF
  150.                     END IF
  151.                 END IF
  152.             END IF
  153.         NEXT
  154.     NEXT
  156.  
Recaman Seq.PNG
« Last Edit: February 21, 2019, 10:05:55 pm by bplus »
Logged
Pages: [1]   Go Up
« previous next »