Built-in function to loads SVG image format?

[ForSe]

It would be good if QB64 has one.

Any possibility to add one in the future?

[Ashish]

Hi! I don't know whether QB64 developer will add this feature or not but for now, you can code your own function to load SVG files.
Oh! I think Fellippe have already done one.....

[Ashish]

Okay, So I found Fellippe's code in my QB64 code archive. :D

Code: QB64: [Select]

1. 'Simple SVG reader for QB64
2. 'Fellippe Heitor, 2017
3. 'A lot of code borrowed as indicated in the comments.
4. '----------------------------------------------------
5. IF LEN(COMMAND$) THEN f$ = COMMAND$ ELSE f$ = "wikisample.svg"
6. IF _FILEEXISTS(f$) = 0 THEN PRINT "File "; f$; " not found.": END
7.  
8. thisScreen& = _NEWIMAGE(800, 600, 32)
9. SCREEN thisScreen&
10. _PRINTMODE _KEEPBACKGROUND
11. CLS , GetColor("white", 1)
12.  
13. OPEN f$ FOR BINARY AS #1
14. DIM Total AS LONG
15. DO
16.     IF EOF(1) THEN EXIT DO
17.     LINE INPUT #1, l0$
18.     l$ = RTRIM$(LTRIM$(LCASE$(l0$)))
19.  
20.     DO
21.         IF RIGHT$(l$, 1) = ">" THEN 'fetch more lines until we close the current tag
22.             EXIT DO
23.         ELSE
24.             IF EOF(1) THEN EXIT DO
25.             LINE INPUT #1, l2$
26.             l0$ = l0$ + l2$
27.             l$ = l$ + RTRIM$(LTRIM$(LCASE$(l2$)))
28.         END IF
29.     LOOP
30.  
31.     sp = INSTR(l$, " ")
32.     IF sp = 0 THEN
33.         IF l$ = "</svg>" THEN
34.             EXIT DO
35.         END IF
36.     END IF
37.  
38.     Style$ = FindS(l$, "style")
39.     IF LEN(Style$) THEN
40.         FillOpacity! = 1
41.         StrokeOpacity! = 1
42.         IF INSTR(Style$, "fill-opacity") THEN
43.             FillOpacity! = Find2(Style$, "fill-opacity")
44.         ELSEIF INSTR(Style$, "opacity") THEN
45.             FillOpacity! = Find2(Style$, "opacity")
46.         END IF
47.         IF INSTR(Style$, "stroke-opacity") THEN
48.             StrokeOpacity! = Find2(Style$, "stroke-opacity")
49.         ELSEIF INSTR(Style$, "opacity") THEN
50.             StrokeOpacity! = Find2(Style$, "opacity")
51.         END IF
52.  
53.         Fill$ = FindS2(Style$, "fill")
54.         FillColor~& = GetColor(Fill$, FillOpacity!)
55.         Stroke~& = GetColor(FindS2(Style$, "stroke"), StrokeOpacity!)
56.         StrokeWidth% = Find2(Style$, "stroke-width")
57.     ELSE
58.         Fill$ = FindS(l$, "fill")
59.         FillColor~& = GetColor(Fill$, 1)
60.         Stroke~& = GetColor(FindS(l$, "stroke"), 1)
61.         StrokeWidth% = Find(l$, "stroke-width")
62.     END IF
63.  
64.     SELECT CASE LEFT$(l$, sp - 1)
65.         CASE "<svg"
66.             width% = Find(l$, "width")
67.             height% = Find(l$, "height")
68.             IF width% > 0 AND height% > 0 THEN
69.                 newScreen& = _NEWIMAGE(width%, height%, 32)
70.                 SCREEN newScreen&
71.                 _PRINTMODE _KEEPBACKGROUND
72.                 CLS , GetColor("white", 1)
73.                 _FREEIMAGE thisScreen&
74.                 thisScreen& = newScreen&
75.             END IF
76.         CASE "<rect"
77.             Total = Total + 1
78.             x! = Find(l$, "x")
79.             y! = Find(l$, "y")
80.             width% = Find(l$, "width")
81.             height% = Find(l$, "height")
82.  
83.             IF Fill$ <> "none" THEN
84.                 IF INSTR(l$, "rx=") THEN
85.                     rx! = Find(l$, "rx")
86.                     RoundRectFill x!, y!, x! + width% - 1, y! + height% - 1, rx!, FillColor~&
87.                 ELSE
88.                     LINE (x!, y!)-STEP(width% - 1, height% - 1), FillColor~&, BF
89.                 END IF
90.             END IF
91.  
92.             IF INSTR(l$, "rx=") = 0 THEN
93.                 LINE (x!, y!)-STEP(width% - 1, height% - 1), Stroke~&, B
94.                 FOR i = 1 TO ((StrokeWidth% - 1) / 2)
95.                     LINE (x! - i, y! - i)-STEP(width% + (i * 2) - 1, height% + (i * 2) - 1), Stroke~&, B
96.                 NEXT
97.             END IF
98.         CASE "<circle"
99.             Total = Total + 1
100.             cx! = Find(l$, "cx")
101.             cy! = Find(l$, "cy")
102.             r! = Find(l$, "r")
103.  
104.             IF Fill$ <> "none" THEN
105.                 CircleFill cx!, cy!, r!, FillColor~&
106.             END IF
107.  
108.             CIRCLE (cx!, cy!), r!, Stroke~&
109.         CASE "<ellipse"
110.             Total = Total + 1
111.             cx! = Find(l$, "cx")
112.             cy! = Find(l$, "cy")
113.             rx! = Find(l$, "rx")
114.             ry! = Find(l$, "ry")
115.  
116.             IF ry! > rx! THEN SWAP ry!, rx!
117.  
118.             IF Stroke~& = 0 THEN Stroke~& = FillColor~&
119.  
120.             CIRCLE (cx!, cy!), rx!, Stroke~&, , , ry! / rx!
121.  
122.             IF Fill$ <> "none" THEN
123.                 PAINT (cx!, cy!), FillColor~&, Stroke~&
124.             END IF
125.         CASE "<polyline"
126.             Total = Total + 1
127.             Points$ = FindS(l$, "points")
128.  
129.             sp = INSTR(Points$, " ")
130.             comma = INSTR(Points$, ",")
131.             x1! = VAL(LEFT$(Points$, comma - 1))
132.             IF sp THEN
133.                 y1! = VAL(MID$(Points$, comma + 1, sp - comma))
134.                 Points$ = MID$(Points$, sp + 1)
135.             ELSE
136.                 y1! = VAL(MID$(Points$, comma + 1))
137.                 Points$ = ""
138.             END IF
139.  
140.             DO WHILE LEN(Points$)
141.                 sp = INSTR(Points$, " ")
142.                 comma = INSTR(Points$, ",")
143.                 x2! = VAL(LEFT$(Points$, comma - 1))
144.                 IF sp THEN
145.                     y2! = VAL(MID$(Points$, comma + 1, sp - comma))
146.                 ELSE
147.                     y2! = VAL(MID$(Points$, comma + 1))
148.                 END IF
149.  
150.                 fline x1!, y1!, x2!, y2!, Stroke~&, StrokeWidth%
151.                 x1! = x2!
152.                 y1! = y2!
153.  
154.                 IF sp THEN
155.                     Points$ = MID$(Points$, sp + 1)
156.                 ELSE
157.                     Points$ = ""
158.                 END IF
159.             LOOP
160.         CASE "<polygon"
161.             Total = Total + 1
162.             Points$ = FindS(l$, "points")
163.  
164.             sp = INSTR(Points$, " ")
165.             comma = INSTR(Points$, ",")
166.             x1! = VAL(LEFT$(Points$, comma - 1))
167.             IF sp THEN
168.                 y1! = VAL(MID$(Points$, comma + 1, sp - comma))
169.                 Points$ = MID$(Points$, sp + 1)
170.             ELSE
171.                 y1! = VAL(MID$(Points$, comma + 1))
172.                 Points$ = ""
173.             END IF
174.  
175.             x! = x1!
176.             y! = y1!
177.  
178.             DO WHILE LEN(Points$)
179.                 sp = INSTR(Points$, " ")
180.                 comma = INSTR(Points$, ",")
181.                 x2! = VAL(LEFT$(Points$, comma - 1))
182.                 IF sp THEN
183.                     y2! = VAL(MID$(Points$, comma + 1, sp - comma))
184.                 ELSE
185.                     y2! = VAL(MID$(Points$, comma + 1))
186.                 END IF
187.  
188.                 fline x1!, y1!, x2!, y2!, Stroke~&, StrokeWidth%
189.  
190.                 x1! = x2!
191.                 y1! = y2!
192.  
193.                 IF sp THEN
194.                     Points$ = MID$(Points$, sp + 1)
195.                 ELSE
196.                     Points$ = ""
197.                 END IF
198.             LOOP
199.  
200.             fline x1!, y1!, x!, y!, Stroke~&, StrokeWidth%
201.  
202.             PAINT (x!, y! + 3), FillColor~&, Stroke~&
203.         CASE "<line"
204.             Total = Total + 1
205.             x1! = Find(l$, "x1")
206.             y1! = Find(l$, "y1")
207.             x2! = Find(l$, "x2")
208.             y2! = Find(l$, "y2")
209.  
210.             fline x1!, y1!, x2!, y2!, Stroke~&, StrokeWidth%
211.         CASE "<text"
212.             Total = Total + 1
213.             '<text x="0" y="15" fill="red">I love SVG!</text>
214.             x! = Find(l$, "x")
215.             y! = Find(l$, "y")
216.  
217.             closingTag% = INSTR(l0$, ">")
218.             endTag% = INSTR(l0$, "</text>")
219.             text$ = MID$(l0$, closingTag% + 1, endTag% - closingTag% - 1)
220.  
221.             COLOR FillColor~&
222.             _PRINTSTRING (x!, y!), text$
223.     END SELECT
224. LOOP
225. CLOSE
226. _TITLE "SVG:" + LTRIM$(STR$(Total)) + " instructions processed"
227. SLEEP
228. SYSTEM
229.  
230. FUNCTION FindS$ (theline$, key$)
231. line$ = LCASE$(theline$)
232. TheKey% = INSTR(LCASE$(line$), LCASE$(key$) + "=" + CHR$(34))
233. IF TheKey% THEN
234.     TheKey% = TheKey% + LEN(key$) + 2
235.     ClosingQuote% = INSTR(TheKey% + 1, line$, CHR$(34))
236.     FindS = MID$(line$, TheKey%, ClosingQuote% - TheKey%)
237. END IF
238. END FUNCTION
239.  
240. FUNCTION FindS2$ (theline$, key$)
241. line$ = LCASE$(theline$) + ";"
242. TheKey% = INSTR(LCASE$(line$), LCASE$(key$) + ":")
243. IF TheKey% THEN
244.     TheKey% = TheKey% + LEN(key$) + 1
245.     ClosingQuote% = INSTR(TheKey% + 1, line$, ";")
246.     FindS2 = MID$(line$, TheKey%, ClosingQuote% - TheKey%)
247. END IF
248. END FUNCTION
249.  
250. FUNCTION Find## (theline$, key$)
251. line$ = LCASE$(theline$)
252. TheKey% = INSTR(LCASE$(line$), LCASE$(key$) + "=" + CHR$(34))
253. IF TheKey% THEN
254.     TheKey% = TheKey% + LEN(key$) + 2
255.     ClosingQuote% = INSTR(TheKey%, line$, CHR$(34))
256.     Find = VAL(MID$(line$, TheKey%, ClosingQuote% - TheKey%))
257. END IF
258. END FUNCTION
259.  
260. FUNCTION Find2## (theline$, key$)
261. line$ = LCASE$(theline$) + ";"
262. TheKey% = INSTR(LCASE$(line$), LCASE$(key$) + ":")
263. IF TheKey% THEN
264.     TheKey% = TheKey% + LEN(key$) + 1
265.     ClosingQuote% = INSTR(TheKey%, line$, ";")
266.     Find2 = VAL(MID$(line$, TheKey%, ClosingQuote% - TheKey%))
267. END IF
268. END FUNCTION
269.  
270. SUB RoundRectFill (x AS INTEGER, y AS INTEGER, x1 AS INTEGER, y1 AS INTEGER, r AS INTEGER, c AS _UNSIGNED LONG)
271. 'This sub from _vincent at the #qb64 chatroom on freenode.net
272. LINE (x, y + r)-(x1, y1 - r), c, BF
273.  
274. a = r
275. b = 0
276. e = -a
277.  
278. DO WHILE a >= b
279.     LINE (x + r - b, y + r - a)-(x1 - r + b, y + r - a), c, BF
280.     LINE (x + r - a, y + r - b)-(x1 - r + a, y + r - b), c, BF
281.     LINE (x + r - b, y1 - r + a)-(x1 - r + b, y1 - r + a), c, BF
282.     LINE (x + r - a, y1 - r + b)-(x1 - r + a, y1 - r + b), c, BF
283.  
284.     b = b + 1
285.     e = e + b + b
286.     IF e > 0 THEN
287.         a = a - 1
288.         e = e - a - a
289.     END IF
290. LOOP
291. END SUB
292.  
293. SUB CircleFill (CX AS LONG, CY AS LONG, R AS LONG, C AS LONG)
294. 'This sub from here: http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1848.msg17254#msg17254
295. DIM Radius AS LONG
296. DIM RadiusError AS LONG
297. DIM X AS LONG
298. DIM Y AS LONG
299.  
300. Radius = ABS(R)
301. RadiusError = -Radius
302. X = Radius
303. Y = 0
304.  
305. IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
306.  
307. ' Draw the middle span here so we don't draw it twice in the main loop,
308. ' which would be a problem with blending turned on.
309. LINE (CX - X, CY)-(CX + X, CY), C, BF
310.  
311. WHILE X > Y
312.  
313.     RadiusError = RadiusError + Y * 2 + 1
314.  
315.     IF RadiusError >= 0 THEN
316.  
317.         IF X <> Y + 1 THEN
318.             LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
319.             LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
320.         END IF
321.  
322.         X = X - 1
323.         RadiusError = RadiusError - X * 2
324.  
325.     END IF
326.  
327.     Y = Y + 1
328.  
329.     LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
330.     LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
331.  
332. WEND
333.  
334. END SUB
335.  
336. SUB fline (x1 AS INTEGER, y1 AS INTEGER, x2 AS INTEGER, y2 AS INTEGER, c AS _UNSIGNED LONG, t AS INTEGER)
337. 'Adapted from http://www.antonis.de/faq/progs/fatlines.bas
338. '***************************************************************************
339. ' FATLINES.BAS - Draws a fat line from (x1|y1) to (x2|y2) with color c and
340. ' ============   thickness t
341. '                Zeichnet eine dicke Linie von (x1|y1) nach (x2|y2) mit der
342. '                Farbe c und der Dicke t. Die dicke Linie wird aus mehreren
343. '                normalen Linien zusammengesetzt.
344. '
345. '===========================================================================
346. ' Subject: FAT LINES                         Date: 08-06-99 (20:08)
347. ' Author:  Marius Andra                      Code: QB, QBasic, PDS
348. ' Origin:  marius.andra*mail.ee            Packet: GRAPHICS.ABC
349. '***************************************************************************
350. LINE (x1, y1)-(x2, y2), c
351. IF t = 0 THEN EXIT SUB
352.  
353. IF x1 = x2 AND y1 <> y2 THEN 'vertical line
354.     FOR i = 1 TO (t - 1) / 2
355.         LINE (x1 - i, y1)-(x2 - i, y2), c
356.         LINE (x1 + i, y1)-(x2 + i, y2), c
357.     NEXT i
358.     LINE (x1 - i, y1)-(x2 - i, y2), c
359. END IF
360.  
361. IF y1 = y2 AND x1 <> x2 THEN 'horizontal line
362.     FOR i = 1 TO (t - 1) / 2
363.         LINE (x1, y1 - i)-(x2, y2 - i), c
364.         LINE (x1, y1 + i)-(x2, y2 + i), c
365.     NEXT i
366.     LINE (x1, y1 - i)-(x2, y2 - i), c
367. END IF
368.  
369. IF x1 < x2 AND y2 > y1 THEN 'falling line
370.     FOR i = 1 TO (t - 1) / 2
371.         LINE (x1 + i, y1)-(x2, y2 - i), c
372.         LINE (x1, y1 + i)-(x2 - i, y2), c
373.     NEXT i
374.     LINE (x1 + i, y1)-(x2, y2 - i), c
375. END IF
376.  
377. IF x2 < x1 AND y2 > y1 THEN 'rising line
378.     FOR i = 1 TO (t - 1) / 2
379.         LINE (x1 - i, y1)-(x2, y2 - i), c
380.         LINE (x1, y1 + i)-(x2 + i, y2), c
381.     NEXT i
382.     LINE (x1 - i, y1)-(x2, y2 - i), c
383. END IF
384.  
385. IF x1 < x2 AND y2 < y1 THEN 'rising line
386.     FOR i = 1 TO (t - 1) / 2
387.         LINE (x1, y1 - i)-(x2 - i, y2), c
388.         LINE (x1 + i, y1)-(x2, y2 + i), c
389.     NEXT i
390.     LINE (x1, y1 - i)-(x2 - i, y2), c
391. END IF
392.  
393. IF x2 < x1 AND y2 < y1 THEN 'falling line
394.     FOR i = 1 TO (t - 1) / 2
395.         LINE (x1, y1 + i)-(x2 - i, y2), c
396.         LINE (x1 - i, y1)-(x2, y2 + i), c
397.     NEXT i
398.     LINE (x1, y1 + i)-(x2 - i, y2), c
399. END IF
400. END SUB
401.  
402. FUNCTION GetColor~& (theColorName$, Alpha!)
403. ColorName$ = LCASE$(theColorName$)
404.  
405. IF LEFT$(ColorName$, 1) = "#" THEN
406.     c$ = MID$(ColorName$, 2)
407.     IF LEN(c$) = 6 THEN c$ = HEX$(Alpha! * 255) + c$
408.     GetColor~& = VAL("&H" + c$)
409. ELSEIF LEFT$(ColorName$, 4) = "rgb(" THEN
410.     cpos% = 5
411.     comma% = INSTR(cpos%, ColorName$, ",") - 1
412.     r% = VAL(MID$(ColorName$, cpos%, comma% - cpos% + 1))
413.  
414.     cpos% = comma% + 2
415.     comma% = INSTR(cpos%, ColorName$, ",") - 1
416.     g% = VAL(MID$(ColorName$, cpos%, comma% - cpos% + 1))
417.  
418.     cpos% = comma% + 2
419.     comma% = INSTR(cpos%, ColorName$, ")") - 1
420.     b% = VAL(MID$(ColorName$, cpos%, comma% - cpos% + 1))
421.  
422.     GetColor~& = _RGBA32(r%, g%, b%, Alpha! * 255)
423. ELSE
424.     RESTORE ColorData
425.     DO
426.         READ TheColor$
427.         IF TheColor$ = "END" THEN EXIT DO
428.         IF LCASE$(LEFT$(TheColor$, INSTR(TheColor$, "=") - 1)) = ColorName$ THEN
429.             GetColor~& = VAL("&H" + HEX$(Alpha! * 255) + MID$(TheColor$, INSTR(TheColor$, "=") + 4))
430.             EXIT DO
431.         END IF
432.     LOOP
433. END IF
434.  
435. 'Color data from SMcNeill (https://dl.dropboxusercontent.com/u/83161214/Color32.BI):
436. ColorData:
437. DATA "AliceBlue=&HFFF0F8FF"
438. DATA "Almond=&HFFEFDECD"
439. DATA "AntiqueBrass=&HFFCD9575"
440. DATA "AntiqueWhite=&HFFFAEBD7"
441. DATA "Apricot=&HFFFDD9B5"
442. DATA "Aqua=&HFF00FFFF"
443. DATA "Aquamarine=&HFF7FFFD4"
444. DATA "Asparagus=&HFF87A96B"
445. DATA "AtomicTangerine=&HFFFFA474"
446. DATA "Azure=&HFFF0FFFF"
447. DATA "BananaMania=&HFFFAE7B5"
448. DATA "Beaver=&HFF9F8170"
449. DATA "Beige=&HFFF5F5DC"
450. DATA "Bisque=&HFFFFE4C4"
451. DATA "Bittersweet=&HFFFD7C6E"
452. DATA "Black=&HFF000000"
453. DATA "BlanchedAlmond=&HFFFFEBCD"
454. DATA "BlizzardBlue=&HFFACE5EE"
455. DATA "Blue=&HFF0000FF"
456. DATA "BlueBell=&HFFA2A2D0"
457. DATA "BlueGray=&HFF6699CC"
458. DATA "BlueGreen=&HFF0D98BA"
459. DATA "BlueViolet=&HFF8A2BE2"
460. DATA "Blush=&HFFDE5D83"
461. DATA "BrickRed=&HFFCB4154"
462. DATA "Brown=&HFFA52A2A"
463. DATA "BurlyWood=&HFFDEB887"
464. DATA "BurntOrange=&HFFFF7F49"
465. DATA "BurntSienna=&HFFEA7E5D"
466. DATA "CadetBlue=&HFF5F9EA0"
467. DATA "Canary=&HFFFFFF99"
468. DATA "CaribbeanGreen=&HFF1CD3A2"
469. DATA "CarnationPink=&HFFFFAACC"
470. DATA "Cerise=&HFFDD4492"
471. DATA "Cerulean=&HFF1DACD6"
472. DATA "ChartReuse=&HFF7FFF00"
473. DATA "Chestnut=&HFFBC5D58"
474. DATA "Chocolate=&HFFD2691E"
475. DATA "Copper=&HFFDD9475"
476. DATA "Coral=&HFFFF7F50"
477. DATA "Cornflower=&HFF9ACEEB"
478. DATA "CornflowerBlue=&HFF6495ED"
479. DATA "Cornsilk=&HFFFFF8DC"
480. DATA "CottonCandy=&HFFFFBCD9"
481. DATA "CrayolaAquamarine=&HFF78DBE2"
482. DATA "CrayolaBlue=&HFF1F75FE"
483. DATA "CrayolaBlueViolet=&HFF7366BD"
484. DATA "CrayolaBrown=&HFFB4674D"
485. DATA "CrayolaCadetBlue=&HFFB0B7C6"
486. DATA "CrayolaForestGreen=&HFF6DAE81"
487. DATA "CrayolaGold=&HFFE7C697"
488. DATA "CrayolaGoldenrod=&HFFFCD975"
489. DATA "CrayolaGray=&HFF95918C"
490. DATA "CrayolaGreen=&HFF1CAC78"
491. DATA "CrayolaGreenYellow=&HFFF0E891"
492. DATA "CrayolaIndigo=&HFF5D76CB"
493. DATA "CrayolaLavender=&HFFFCB4D5"
494. DATA "CrayolaMagenta=&HFFF664AF"
495. DATA "CrayolaMaroon=&HFFC8385A"
496. DATA "CrayolaMidnightBlue=&HFF1A4876"
497. DATA "CrayolaOrange=&HFFFF7538"
498. DATA "CrayolaOrangeRed=&HFFFF2B2B"
499. DATA "CrayolaOrchid=&HFFE6A8D7"
500. DATA "CrayolaPlum=&HFF8E4585"
501. DATA "CrayolaRed=&HFFEE204D"
502. DATA "CrayolaSalmon=&HFFFF9BAA"
503. DATA "CrayolaSeaGreen=&HFF9FE2BF"
504. DATA "CrayolaSilver=&HFFCDC5C2"
505. DATA "CrayolaSkyBlue=&HFF80DAEB"
506. DATA "CrayolaSpringGreen=&HFFECEABE"
507. DATA "CrayolaTann=&HFFFAA76C"
508. DATA "CrayolaThistle=&HFFEBC7DF"
509. DATA "CrayolaViolet=&HFF926EAE"
510. DATA "CrayolaYellow=&HFFFCE883"
511. DATA "CrayolaYellowGreen=&HFFC5E384"
512. DATA "Crimson=&HFFDC143C"
513. DATA "Cyan=&HFF00FFFF"
514. DATA "Dandelion=&HFFFDDB6D"
515. DATA "DarkBlue=&HFF00008B"
516. DATA "DarkCyan=&HFF008B8B"
517. DATA "DarkGoldenRod=&HFFB8860B"
518. DATA "DarkGray=&HFFA9A9A9"
519. DATA "DarkGreen=&HFF006400"
520. DATA "DarkKhaki=&HFFBDB76B"
521. DATA "DarkMagenta=&HFF8B008B"
522. DATA "DarkOliveGreen=&HFF556B2F"
523. DATA "DarkOrange=&HFFFF8C00"
524. DATA "DarkOrchid=&HFF9932CC"
525. DATA "DarkRed=&HFF8B0000"
526. DATA "DarkSalmon=&HFFE9967A"
527. DATA "DarkSeaGreen=&HFF8FBC8F"
528. DATA "DarkSlateBlue=&HFF483D8B"
529. DATA "DarkSlateGray=&HFF2F4F4F"
530. DATA "DarkTurquoise=&HFF00CED1"
531. DATA "DarkViolet=&HFF9400D3"
532. DATA "DeepPink=&HFFFF1493"
533. DATA "DeepSkyBlue=&HFF00BFFF"
534. DATA "Denim=&HFF2B6CC4"
535. DATA "DesertSand=&HFFEFCDB8"
536. DATA "DimGray=&HFF696969"
537. DATA "DodgerBlue=&HFF1E90FF"
538. DATA "Eggplant=&HFF6E5160"
539. DATA "ElectricLime=&HFFCEFF1D"
540. DATA "Fern=&HFF71BC78"
541. DATA "FireBrick=&HFFB22222"
542. DATA "Floralwhite=&HFFFFFAF0"
543. DATA "ForestGreen=&HFF228B22"
544. DATA "Fuchsia=&HFFC364C5"
545. DATA "FuzzyWuzzy=&HFFCC6666"
546. DATA "Gainsboro=&HFFDCDCDC"
547. DATA "GhostWhite=&HFFF8F8FF"
548. DATA "Gold=&HFFFFD700"
549. DATA "GoldenRod=&HFFDAA520"
550. DATA "GrannySmithApple=&HFFA8E4A0"
551. DATA "Gray=&HFF808080"
552. DATA "Green=&HFF008000"
553. DATA "GreenBlue=&HFF1164B4"
554. DATA "GreenYellow=&HFFADFF2F"
555. DATA "HoneyDew=&HFFF0FFF0"
556. DATA "HotMagenta=&HFFFF1DCE"
557. DATA "HotPink=&HFFFF69B4"
558. DATA "Inchworm=&HFFB2EC5D"
559. DATA "IndianRed=&HFFCD5C5C"
560. DATA "Indigo=&HFF4B0082"
561. DATA "Ivory=&HFFFFFFF0"
562. DATA "JazzberryJam=&HFFCA3767"
563. DATA "JungleGreen=&HFF3BB08F"
564. DATA "Khaki=&HFFF0E68C"
565. DATA "LaserLemon=&HFFFEFE22"
566. DATA "Lavender=&HFFE6E6FA"
567. DATA "LavenderBlush=&HFFFFF0F5"
568. DATA "LawnGreen=&HFF7CFC00"
569. DATA "LemonChiffon=&HFFFFFACD"
570. DATA "LemonYellow=&HFFFFF44F"
571. DATA "LightBlue=&HFFADD8E6"
572. DATA "LightCoral=&HFFF08080"
573. DATA "LightCyan=&HFFE0FFFF"
574. DATA "LightGoldenRodYellow=&HFFFAFAD2"
575. DATA "LightGray=&HFFD3D3D3"
576. DATA "LightGreen=&HFF90EE90"
577. DATA "LightPink=&HFFFFB6C1"
578. DATA "LightSalmon=&HFFFFA07A"
579. DATA "LightSeaGreen=&HFF20B2AA"
580. DATA "LightSkyBlue=&HFF87CEFA"
581. DATA "LightSlateGray=&HFF778899"
582. DATA "LightSteelBlue=&HFFB0C4DE"
583. DATA "LightYellow=&HFFFFFFE0"
584. DATA "Lime=&HFF00FF00"
585. DATA "LimeGreen=&HFF32CD32"
586. DATA "Linen=&HFFFAF0E6"
587. DATA "MacaroniAndCheese=&HFFFFBD88"
588. DATA "Magenta=&HFFFF00FF"
589. DATA "MagicMint=&HFFAAF0D1"
590. DATA "Mahogany=&HFFCD4A4C"
591. DATA "Maize=&HFFEDD19C"
592. DATA "Manatee=&HFF979AAA"
593. DATA "MangoTango=&HFFFF8243"
594. DATA "Maroon=&HFF800000"
595. DATA "Mauvelous=&HFFEF98AA"
596. DATA "MediumAquamarine=&HFF66CDAA"
597. DATA "MediumBlue=&HFF0000CD"
598. DATA "MediumOrchid=&HFFBA55D3"
599. DATA "MediumPurple=&HFF9370DB"
600. DATA "MediumSeaGreen=&HFF3CB371"
601. DATA "MediumSlateBlue=&HFF7B68EE"
602. DATA "MediumSpringGreen=&HFF00FA9A"
603. DATA "MediumTurquoise=&HFF48D1CC"
604. DATA "MediumVioletRed=&HFFC71585"
605. DATA "Melon=&HFFFDBCB4"
606. DATA "MidnightBlue=&HFF191970"
607. DATA "MintCream=&HFFF5FFFA"
608. DATA "MistyRose=&HFFFFE4E1"
609. DATA "Moccasin=&HFFFFE4B5"
610. DATA "MountainMeadow=&HFF30BA8F"
611. DATA "Mulberry=&HFFC54B8C"
612. DATA "NavajoWhite=&HFFFFDEAD"
613. DATA "Navy=&HFF000080"
614. DATA "NavyBlue=&HFF1974D2"
615. DATA "NeonCarrot=&HFFFFA343"
616. DATA "OldLace=&HFFFDF5E6"
617. DATA "Olive=&HFF808000"
618. DATA "OliveDrab=&HFF6B8E23"
619. DATA "OliveGreen=&HFFBAB86C"
620. DATA "Orange=&HFFFFA500"
621. DATA "OrangeRed=&HFFFF4500"
622. DATA "OrangeYellow=&HFFF8D568"
623. DATA "Orchid=&HFFDA70D6"
624. DATA "OuterSpace=&HFF414A4C"
625. DATA "OutrageousOrange=&HFFFF6E4A"
626. DATA "PacificBlue=&HFF1CA9C9"
627. DATA "PaleGoldenRod=&HFFEEE8AA"
628. DATA "PaleGreen=&HFF98FB98"
629. DATA "PaleTurquoise=&HFFAFEEEE"
630. DATA "PaleVioletRed=&HFFDB7093"
631. DATA "PapayaWhip=&HFFFFEFD5"
632. DATA "Peach=&HFFFFCFAB"
633. DATA "PeachPuff=&HFFFFDAB9"
634. DATA "Periwinkle=&HFFC5D0E6"
635. DATA "Peru=&HFFCD853F"
636. DATA "PiggyPink=&HFFFDDDE6"
637. DATA "PineGreen=&HFF158078"
638. DATA "Pink=&HFFFFC0CB"
639. DATA "PinkFlamingo=&HFFFC74FD"
640. DATA "PinkSherbet=&HFFF78FA7"
641. DATA "Plum=&HFFDDA0DD"
642. DATA "PowderBlue=&HFFB0E0E6"
643. DATA "Purple=&HFF800080"
644. DATA "PurpleHeart=&HFF7442C8"
645. DATA "PurpleMountainsMajesty=&HFF9D81BA"
646. DATA "PurplePizzazz=&HFFFE4EDA"
647. DATA "RadicalRed=&HFFFF496C"
648. DATA "RawSienna=&HFFD68A59"
649. DATA "RawUmber=&HFF714B23"
650. DATA "RazzleDazzleRose=&HFFFF48D0"
651. DATA "Razzmatazz=&HFFE3256B"
652. DATA "Red=&HFFFF0000"
653. DATA "RedOrange=&HFFFF5349"
654. DATA "RedViolet=&HFFC0448F"
655. DATA "RobinsEggBlue=&HFF1FCECB"
656. DATA "RosyBrown=&HFFBC8F8F"
657. DATA "RoyalBlue=&HFF4169E1"
658. DATA "RoyalPurple=&HFF7851A9"
659. DATA "SaddleBrown=&HFF8B4513"
660. DATA "Salmon=&HFFFA8072"
661. DATA "SandyBrown=&HFFF4A460"
662. DATA "Scarlet=&HFFFC2847"
663. DATA "ScreaminGreen=&HFF76FF7A"
664. DATA "SeaGreen=&HFF2E8B57"
665. DATA "SeaShell=&HFFFFF5EE"
666. DATA "Sepia=&HFFA5694F"
667. DATA "Shadow=&HFF8A795D"
668. DATA "Shamrock=&HFF45CEA2"
669. DATA "ShockingPink=&HFFFB7EFD"
670. DATA "Sienna=&HFFA0522D"
671. DATA "Silver=&HFFC0C0C0"
672. DATA "SkyBlue=&HFF87CEEB"
673. DATA "SlateBlue=&HFF6A5ACD"
674. DATA "SlateGray=&HFF708090"
675. DATA "Snow=&HFFFFFAFA"
676. DATA "SpringGreen=&HFF00FF7F"
677. DATA "SteelBlue=&HFF4682B4"
678. DATA "Sunglow=&HFFFFCF48"
679. DATA "SunsetOrange=&HFFFD5E53"
680. DATA "Tann=&HFFD2B48C"
681. DATA "Teal=&HFF008080"
682. DATA "TealBlue=&HFF18A7B5"
683. DATA "Thistle=&HFFD8BFD8"
684. DATA "TickleMePink=&HFFFC89AC"
685. DATA "Timberwolf=&HFFDBD7D2"
686. DATA "Tomato=&HFFFF6347"
687. DATA "TropicalRainForest=&HFF17806D"
688. DATA "Tumbleweed=&HFFDEAA88"
689. DATA "Turquoise=&HFF40E0D0"
690. DATA "TurquoiseBlue=&HFF77DDE7"
691. DATA "UnmellowYellow=&HFFFFFF66"
692. DATA "Violet=&HFFEE82EE"
693. DATA "VioletBlue=&HFF324AB2"
694. DATA "VioletRed=&HFFF75394"
695. DATA "VividTangerine=&HFFFFA089"
696. DATA "VividViolet=&HFF8F509D"
697. DATA "Wheat=&HFFF5DEB3"
698. DATA "White=&HFFFFFFFF"
699. DATA "Whitesmoke=&HFFF5F5F5"
700. DATA "WildBlueYonder=&HFFA2ADD0"
701. DATA "WildStrawberry=&HFFFF43A4"
702. DATA "WildWatermelon=&HFFFC6C85"
703. DATA "Wisteria=&HFFCDA4DE"
704. DATA "Yellow=&HFFFFFF00"
705. DATA "YellowGreen=&HFF9ACD32"
706. DATA "YellowOrange=&HFFFFAE42"
707. DATA "END"
708. END FUNCTION
709.  
710.  
711.  

[FellippeHeitor]

It's a veeeeery limited xml parser focused on a subset of svg tags, and renders veeeeery crudely too, but it's a start if one wants to keep working on it. It was a fun exercise to write, hope it's useful to anyone.

As to "Any possibility to add one in the future?", it greatly depends on the existence of a good svg to raster c++ library out there. Anyone know of a good one?

[Ashish]

As to "Any possibility to add one in the future?", it greatly depends on the existence of a good svg to raster c++ library out there. Anyone know of a good one?

Will SVG++ (SVGPP) work?

[FellippeHeitor]

Good question.

[ForSe]

you can code your own function to load SVG files.

Yeah, I thought to make my own too.

As to "Any possibility to add one in the future?", it greatly depends on the existence of a good svg to raster c++ library out there. Anyone know of a good one?

Will SVG++ (SVGPP) work?

That's one of the reason why I suggested to add a built-in function, there are already some open source SVG library in C++ out there.

Okay, So I found Fellippe's code in my QB64 code archive. :D

I tested the code with some of my SVG files, I also tested https://www.svgrepo.com/show/123512/simple-cloud.svg, but it only show a blank, white screen.