Inverse Julia Fractal Explorer by Zom-B

[The Librarian]

Inverse Julia Fractal Explorer

Author: Zom-B
Source: [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] Forum
URL: /forum/index.php?topic=1132.0]http://www.[abandoned, outdated and now likely malicious qb64 dot net website - don’t go there]/forum/index.php?topic=1132.0
Version: QB64
Tags: [fractal] [inverse julia set]

Description:
The longer you hold your mouse at one position, the more it starts to glow.

Source Code:

Code: QB64: [Select]

1. DEFSNG A-Z
2.  
3. DIM SHARED px, py, cx, cy
4.  
5. SCREEN _NEWIMAGE(1024, 768, 256)
6.  
7. COLOR 255
8. FOR i% = 0 TO 255
9.     r% = INT((i% / 255) ^ .9323335 * 255)
10.     g% = INT((i% / 255) ^ 1.576838 * 255)
11.     b% = INT((i% / 255) ^ 3.484859 * 255)
12.     _PALETTECOLOR i%, _RGB32(r%, g%, b%)
13. NEXT
14.  
15. '####################################################################################################################
16.  
17. setSeed _MOUSEX, _MOUSEY
18.  
19. DO
20.     IF _MOUSEINPUT THEN
21.         n% = 0
22.         _DISPLAY
23.         CLS
24.         setSeed _MOUSEX, _MOUSEY
25.     END IF
26.  
27.     DO 'Marsaglia polar method for random gaussian
28.         u = RND * 2 - 1
29.         v = RND2 * 2 - 1
30.         s = u * u + v * v
31.     LOOP WHILE s >= 1 OR s = 0
32.     s = SQR(-2 * LOG(s) / s) * 0.5
33.     u = u * s * 2
34.     v = v * s * 2
35.  
36.     calcInverseJulia u, v, 1
37.  
38.     n% = n% + 1
39.     IF n% = 300 THEN
40.         n% = 0
41.         _DISPLAY
42.     END IF
43. LOOP
44.  
45. '####################################################################################################################
46.  
47. SUB setSeed (x, y)
48.     cx = (x / _WIDTH - 0.5) * 4
49.     cy = (0.5 - y / _HEIGHT) * 3
50. END SUB
51.  
52. '####################################################################################################################
53.  
54. SUB calcInverseJulia (x, y, depth%)
55.     re = x - cx
56.     im = y - cy
57.  
58.     a = SQR(re * re + im * im)
59.     x = SQR((a + re) * 0.5)
60.     IF im < 0 THEN y = -SQR((a - re) * 0.5) ELSE y = SQR((a - re) * 0.5)
61.  
62.     PSET2 (x / 4 + 0.5) * _WIDTH, (0.5 - y / 3) * _HEIGHT, 0.02
63.     PSET2 (x / -4 + 0.5) * _WIDTH, (0.5 + y / 3) * _HEIGHT, 0.02
64.     IF depth% < 32 THEN
65.         IF RND < 0.5 THEN calcInverseJulia x, y, depth% + 1 ELSE calcInverseJulia -x, -y, depth% + 1
66.     END IF
67. END SUB
68.  
69. '####################################################################################################################
70.  
71. SUB PSET2 (x, y, i)
72.     x% = INT(x)
73.     y% = INT(y)
74.     dx = x - x%
75.     dy = y - y%
76.  
77.     q3 = dx * dy
78.     q2 = (1 - dx) * dy
79.     q1 = dx * (1 - dy)
80.     q0 = (1 - dx) * (1 - dy)
81.  
82.     PSET (x%, y%), (1 - (1 - q0 * i) * (1 - POINT(x%, y%) / 255)) * 255
83.     PSET (x% + 1, y%), (1 - (1 - q1 * i) * (1 - POINT(x% + 1, y%) / 255)) * 255
84.     PSET (x%, y% + 1), (1 - (1 - q2 * i) * (1 - POINT(x%, y% + 1) / 255)) * 255
85.     PSET (x% + 1, y% + 1), (1 - (1 - q3 * i) * (1 - POINT(x% + 1, y% + 1) / 255)) * 255
86. END SUB
87.  
88. '####################################################################################################################
89.  
90. FUNCTION RND2 STATIC
91.     seed&& = (25214903917&& * seed&& + 11&&) MOD 281474976710656&&
92.     RND2 = seed&& / 281474976710656&&
93. END FUNCTION
94.