Re: Spinning Sprite

[SMcNeill]

I tend to use my handy little DisplayImage routine for this type of task. 

Code: QB64: [Select]

1. SCREEN _NEWIMAGE(256, 256, 32)
2.  
3. Sprite = TextToImage("EXAMPLE", 16, &HFFFF0000, 0, 0)
4.  
5.  
6. DO
7.     CLS
8.     DisplayImage Sprite, 128, 128, angle, 0
9.     angle = angle + 4
10.     _DISPLAY
11.     _LIMIT 30
12. LOOP UNTIL _KEYHIT
13.  
14.  
15.  
16.  
17.  
18. FUNCTION TextToImage& (text$, font&, fc&, bfc&, mode AS _BYTE)
19.     'text$ is the text that we wish to transform into an image.
20.     'font& is the handle of the font we want to use.
21.     'fc& is the color of the font we want to use.
22.     'bfc& is the background color of the font.
23.  
24.     'Mode 1 is print forwards
25.     'Mode 2 is print backwards
26.     'Mode 3 is print from top to bottom
27.     'Mode 4 is print from bottom up
28.     'Mode 0 got lost somewhere, but it's OK.  We check to see if our mode is < 1 or > 4 and compensate automatically if it is to make it one (default).
29.  
30.     IF mode < 1 OR mode > 4 THEN mode = 1
31.     dc& = _DEFAULTCOLOR: bgc& = _BACKGROUNDCOLOR
32.     D = _DEST
33.     F = _FONT
34.     IF font& <> 0 THEN _FONT font&
35.     IF mode < 3 THEN
36.         'print the text lengthwise
37.         w& = _PRINTWIDTH(text$): h& = _FONTHEIGHT
38.     ELSE
39.         'print the text vertically
40.         FOR i = 1 TO LEN(text$)
41.             IF w& < _PRINTWIDTH(MID$(text$, i, 1)) THEN w& = _PRINTWIDTH(MID$(text$, i, 1))
42.         NEXT
43.         h& = _FONTHEIGHT * (LEN(text$))
44.     END IF
45.  
46.     TextToImage& = _NEWIMAGE(w&, h&, 32)
47.     _DEST TextToImage&
48.     IF font& <> 0 THEN _FONT font&
49.     COLOR fc&, bfc&
50.  
51.     SELECT CASE mode
52.         CASE 1
53.             'Print text forward
54.             _PRINTSTRING (0, 0), text$
55.         CASE 2
56.             'Print text backwards
57.             temp$ = ""
58.             FOR i = 0 TO LEN(text$) - 1
59.                 temp$ = temp$ + MID$(text$, LEN(text$) - i, 1)
60.             NEXT
61.             _PRINTSTRING (0, 0), temp$
62.         CASE 3
63.             'Print text upwards
64.             'first lets reverse the text, so it's easy to place
65.             temp$ = ""
66.             FOR i = 0 TO LEN(text$) - 1
67.                 temp$ = temp$ + MID$(text$, LEN(text$) - i, 1)
68.             NEXT
69.             'then put it where it belongs
70.             FOR i = 1 TO LEN(text$)
71.                 fx = (w& - _PRINTWIDTH(MID$(temp$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
72.                 _PRINTSTRING (fx, _FONTHEIGHT * (i - 1)), MID$(temp$, i, 1)
73.             NEXT
74.         CASE 4
75.             'Print text downwards
76.             FOR i = 1 TO LEN(text$)
77.                 fx = (w& - _PRINTWIDTH(MID$(text$, i, 1))) / 2 + .99 'This is to center any non-monospaced letters so they look better
78.                 _PRINTSTRING (fx, _FONTHEIGHT * (i - 1)), MID$(text$, i, 1)
79.             NEXT
80.     END SELECT
81.     _DEST D
82.     COLOR dc&, bgc&
83.     _FONT F
84. END FUNCTION
85.  
86.  
87.  
88.  
89.  
90. SUB DisplayImage (Image AS LONG, x AS INTEGER, y AS INTEGER, angle AS SINGLE, mode AS _BYTE)
91.     'Image is the image handle which we use to reference our image.
92.     'x,y is the X/Y coordinates where we want the image to be at on the screen.
93.     'angle is the angle which we wish to rotate the image.
94.     'mode determines HOW we place the image at point X,Y.
95.     'Mode 0 we center the image at point X,Y
96.     'Mode 1 we place the Top Left corner of oour image at point X,Y
97.     'Mode 2 is Bottom Left
98.     'Mode 3 is Top Right
99.     'Mode 4 is Bottom Right
100.  
101.  
102.     DIM px(3) AS INTEGER, py(3) AS INTEGER, w AS INTEGER, h AS INTEGER
103.     DIM sinr AS SINGLE, cosr AS SINGLE, i AS _BYTE
104.     w = _WIDTH(Image): h = _HEIGHT(Image)
105.     SELECT CASE mode
106.         CASE 0 'center
107.             px(0) = -w \ 2: py(0) = -h \ 2: px(3) = w \ 2: py(3) = -h \ 2
108.             px(1) = -w \ 2: py(1) = h \ 2: px(2) = w \ 2: py(2) = h \ 2
109.         CASE 1 'top left
110.             px(0) = 0: py(0) = 0: px(3) = w: py(3) = 0
111.             px(1) = 0: py(1) = h: px(2) = w: py(2) = h
112.         CASE 2 'bottom left
113.             px(0) = 0: py(0) = -h: px(3) = w: py(3) = -h
114.             px(1) = 0: py(1) = 0: px(2) = w: py(2) = 0
115.         CASE 3 'top right
116.             px(0) = -w: py(0) = 0: px(3) = 0: py(3) = 0
117.             px(1) = -w: py(1) = h: px(2) = 0: py(2) = h
118.         CASE 4 'bottom right
119.             px(0) = -w: py(0) = -h: px(3) = 0: py(3) = -h
120.             px(1) = -w: py(1) = 0: px(2) = 0: py(2) = 0
121.     END SELECT
122.     sinr = SIN(angle / 57.2957795131): cosr = COS(angle / 57.2957795131)
123.     FOR i = 0 TO 3
124.         x2 = (px(i) * cosr + sinr * py(i)) + x: y2 = (py(i) * cosr - px(i) * sinr) + y
125.         px(i) = x2: py(i) = y2
126.     NEXT
127.     _MAPTRIANGLE (0, 0)-(0, h - 1)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(1), py(1))-(px(2), py(2))
128.     _MAPTRIANGLE (0, 0)-(w - 1, 0)-(w - 1, h - 1), Image TO(px(0), py(0))-(px(3), py(3))-(px(2), py(2))
129. END SUB
130.  

You can see from the main loop how simple usage is for it:

DO
    CLS
    DisplayImage Sprite, 128, 128, angle, 0
    angle = angle + 4
    _DISPLAY
    _LIMIT 30
LOOP UNTIL _KEYHIT


And TextToImage isn't needed for it to work in any manner.  I just tend to use it to plug in a quick method to convert text to an image, so folks can use it instead of needing to download any resource files.

[FellippeHeitor]

@[banned user] your code already seems to be spinning the loaded image around an imaginary vertical axis:

If that's not what you originally intended then maybe you really wanted it to rotate instead of spin like Steve has demoed.

What is it that you actually wanted to do?

[FellippeHeitor]

Maybe you can show an example of something spinning in the fashion you're targeting because your verbal explanation isn't doing anything to help me visualize it.

[STxAxTIC]

[banned user] please paste working code in the top post. (include the MAP function?)

bet i can help ya

[FellippeHeitor]

Here:

Code: QB64: [Select]

1. FUNCTION map! (value!, minRange!, maxRange!, newMinRange!, newMaxRange!)
2.     map! = ((value! - minRange!) / (maxRange! - minRange!)) * (newMaxRange! - newMinRange!) + newMinRange!
3. END FUNCTION
4.  

[FellippeHeitor]

I am not sure how to show an example

I searched YouTube for spinning logo

[FellippeHeitor]

If it REALLY spun around then you would have the OGOL (letters reversed) and then that would spin around to show the word LOGO (Letters normal).

And you think your original code was doing that and that's what you wanted to change? Still trying to figure you out here.

[FellippeHeitor]

So you want a 3d model to spin in 3d. Not with _LOADIMAGE, not with that little code, indeed.

Likely not with QB64 unless you resort to OpenGL. Hopefully STx will be more useful (and cheerful) here.

Best of luck!

/me out.

[SMcNeill]

I am not sure how to show an example

I searched YouTube for spinning logo

Yeah and the first one seemed okay because the front and back were mirror image if eachother, but the word LOGO was all wrong.  If it REALLY spun around then you would have the OGOL (letters reversed) and then that would spin around to show the word LOGO (Letters normal).

From Fellippe’s screenshot, that’s what it’s doing.  The BR is printed forward, and then reversed, and then it goes back to BR again.  I’m not certain what it’s supposed to do differently either.

[FellippeHeitor]

No files provided.

[ForSe]

Do you mean like this?
 

I made something like that a few years ago (also with _MAPTRIANGLE).

[TempodiBasic]

Hi
following [banned user] example at the beginning of the post and using that image of note I get an image that rotates itself on a vertical axis from the left to the right for 180° and then comes back!

While in your fantastic GIF (how do you make gif from your screen?) shows a real 360° rotating image of Brazil flag.

[FellippeHeitor]

(how do you make gif from your screen?)

I use a screen capture software (QuickTime in my case) then I use an online tool to convert the video to GIF.

[TempodiBasic]

@Fellippe
Thanks
it's cool!


@[banned user]

IMHO it seems that using simmetrical images in front of vertical axis you can get an appareance of rotating of 360°...
but with asimmetrical images they seems to rotate only of 180° on the plan and then coming back.

Looking at it deeper I see that the values getting back from MAP function are ranging from 0 to 256 so it seems that with this function you can get a progressive value in a range.
The _PUTIMAGE keywork IMHO cannot give more than flipping in the 180° the image on the screen...
see here http://qb64sourcecode.com/Task16.html at this section (after parallax)

- Using _PUTIMAGE to Alter Images-

The next feature of _PUTIMAGE we'll discuss is how to use it to change the size of an image, flip it horizontally, vertically or both. _PUTIMAGE supports using two coordinates to identify where the upper left and lower right corners of the image should be. By manipulating these coordinates _PUTIMAGE can alter the image.

so really with that code you shrink and then stretch the image loaded  flip it on the vertical axis.

In this way you must get the Anti-image on a hide _newimage and then using it to get the rest of rotation to get 30° rotation.

Good Luck