FireFox Management App for Windows

[Pete]

When I got upgraded to Firefox Quantum, I noticed my session tab manager was no longer supported. It seems updates can rip away some of our favorite things. Dammit, I must be channeling Oprah again.

Anyway, I decided I wanted to lean some new tricks and make an app I could use to manage Firefox. This is a work in progress and it uses some keywords that are only supported in Windows, and Windows API calls. It will not work properly in Linux or Mac.

Since the days of easily finding and reading urls from the temporary internet files folder in earlier editions of Windows is long gone, I decided to take advantage of _SCREENCLICK and _SCREENPRINT to find and read urls displayed in the browser. It can save them to a file, so sessions can be named and reloaded.

WARNING: It works for me, but be aware it makes single clicks to your screen. That should be OK if the browser is covering your screen, and OK if it isn't, provided you don't have your system set to activate things on a single click. My desktop is default, two clicks to activate a program.

The program makes session files with .ses extension. You can drag them to Notepad to read them.

The program makes a settings file called session-manager-settings.dat upon RUN.

It uses Bing.com so a window title can be found by the API. You could make a local html file and title it to fit the program. That would load faster. I may get around to that sometime.

You will need to map "Close" and "Load Previous Session" to take advantage of those two features. You can click either and the program will take you to the settings screen, so you can map them. Basically all that involves is choosing "close" or "Load Previous Session" and the program will make an image of the browser and prompt you to click, say the Close tab, on that image. It will record and save the coordinates. If you go "Back" to the menu, you can click "Close" and the program will click the X button on the browser.

Anyway, it's a work in progress, but I've run out of time and need to get busy on other projects, so this may be as far as I get for awhile.

Code: QB64: [Select]

1. REDIM SHARED tabx(1000) AS INTEGER, taby(1000) AS INTEGER
2. REDIM SHARED settings$(100), session$(100)
3. REDIM SHARED title$, findbrowsertitle$, numofspaces%, inputindex, inputcount, word$(1000), crow%, ccol%
4. REDIM SHARED scindent%, srindent%, fw%, fh%, cwidth%, rheight%, num%, p1%, p2%, p3%, p4%, fileextension$
5. REDIM SHARED maxwinheight%, mintopindent%, browsertab$, hwnd%&, ClassName, WindowName$, nVirtKey, nCmdShow
6.  
7. DECLARE DYNAMIC LIBRARY "user32"
8.     FUNCTION FindWindowA%& (BYVAL ClassName AS _OFFSET, WindowName$) 'find process handle by title
9.     FUNCTION GetKeyState% (BYVAL nVirtKey AS LONG) 'Windows virtual key presses
10.     FUNCTION ShowWindow& (BYVAL hwnd AS _OFFSET, BYVAL nCmdShow AS LONG) 'maximize process
11.     FUNCTION GetForegroundWindow%& 'find currently focused process handle
12.     FUNCTION SetForegroundWindow& (BYVAL hwnd AS _OFFSET) 'set foreground window process(focus)
13. END DECLARE
14.  
15. title$ = "FireFox Session Manager" 'Title of program window
16. _TITLE title$ 'Set program title
17. findbrowsertitle$ = "Bing - mozilla firefox"
18. browsertab$ = "bing.com"
19. fileextension$ = ".ses"
20. numofspaces% = 60
21. scindent% = 10 ' To be centered to screen.
22. mintopindent% = 5 ' Minimum rows indented from the top needed to see clickable areas above.
23. maxwinheight% = _DESKTOPHEIGHT \ _FONTHEIGHT - mintopindent%
24.  
25. IF maxwinheight% > 42 THEN
26.     maxwinheight% = 42
27.     rheight% = 42 - 4 ' Last width that supports font size 16 height.
28. ELSE
29.     rheight% = maxwinheight% - 4 ' -4 is to keep window bottom above taskbar.
30. END IF
31.  
32. CALL setscreen
33.  
34. IF _FILEEXISTS("session-manager-settings.dat") THEN
35. ELSE
36.     RESTORE settingslist
37.     REDIM settings$(100)
38.     OPEN "session-manager-settings.dat" FOR OUTPUT AS #2
39.     i = 0
40.     DO
41.         READ a$
42.         IF LCASE$(a$) = "eof" THEN EXIT DO
43.         i = i + 1
44.         settings$(i) = a$ + "," + "(Undefined)"
45.         PRINT #2, settings$(i)
46.     LOOP
47.     CLOSE #2
48. END IF
49.  
50. RESTORE tasklist
51. i = 0
52. crow% = 9
53. DO
54.     READ a$, action$
55.     IF LCASE$(a$) = "eof" THEN EXIT DO
56.     a$ = LTRIM$(STR$(i)) + ") " + a$
57.     IF w4 < LEN(a$) THEN w4 = LEN(a$)
58. LOOP
59. ccol% = cwidth% \ 2 - w4 \ 2
60. w3 = 0
61. w4 = w4 + 2 ' margin buffer for menu box.
62. heading$ = "FireFox Session Menu"
63. LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
64. PRINT heading$;
65. LOCATE crow%, ccol%
66. RESTORE tasklist
67. DO
68.     READ a$, action$
69.     IF LCASE$(a$) = "eof" THEN EXIT DO
70.     w3 = w3 + 1
71.     a$ = LTRIM$(STR$(w3)) + ") " + a$
72.     PRINT a$;
73.     LOCATE crow% + w3, ccol%
74. LOOP
75. p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
76.  
77. CALL box(w3, w4)
78.  
79. CALL selection(w3, b$)
80.  
81. RESTORE tasklist
82. FOR i = 1 TO VAL(b$)
83.     READ a$, action$
84.     a$ = LTRIM$(STR$(i)) + ") " + a$
85. NEXT
86.  
87. CALL highlight(a$, b$)
88.  
89. SELECT CASE VAL(b$)
90.     CASE 1 ' Firefox Full Screen
91.         CALL startbrowser
92.         RUN
93.     CASE 2 ' Firefox minimized
94.         CALL startbrowser
95.         _DELAY .1
96.         CALL minimizewindow
97.         RUN
98.     CASE 3
99.         task$ = "load previous session" ' Load Previous Session.
100.         CALL taskactions(task$, flag)
101.         IF flag THEN flag = 0: CALL makesettings
102.         RUN
103.     CASE 4
104.         SHELL _HIDE "dir /b *." + fileextension$ + ">tmp.tmp"
105.         OPEN "tmp.tmp" FOR INPUT AS #1
106.         w3 = 0: REDIM session$(100)
107.         DO UNTIL EOF(1)
108.             LINE INPUT #1, a$
109.             IF INSTR(a$, fileextension$) <> 0 THEN ' Strip off file extension.
110.                 a$ = RTRIM$(MID$(a$, 1, INSTR(a$, fileextension$) - 1))
111.             END IF
112.             w3 = w3 + 1
113.             session$(w3) = a$
114.         LOOP
115.         CLOSE #1
116.         w4 = 0
117.         IF w3 > 1 THEN ' More than one saved session in database.
118.             FOR j = 1 TO w3
119.                 IF LEN(session$(j)) > w4 THEN w4 = LEN(session$(j))
120.             NEXT
121.             crow% = 10
122.             ccol% = cwidth% \ 2 - w4 \ 2
123.             p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
124.             w4 = w4 + 2 ' margin buffer for menu box.
125.             CLS
126.             LOCATE crow%, ccol%
127.             FOR j = 1 TO w3
128.                 PRINT session$(j)
129.                 LOCATE , ccol%
130.             NEXT
131.             heading$ = "Click to Load Session"
132.             LOCATE crow% - 3, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
133.             PRINT heading$;
134.             heading$ = "Back  |  Quit"
135.             LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
136.             COLOR 3, 0
137.             PRINT heading$;
138.             COLOR 7, 0
139.             LOCATE crow%, ccol%
140.  
141.             CALL box(w3, w4)
142.  
143.             DO
144.                 CALL selection(w3, b$)
145.  
146.                 IF b$ = "run" THEN RUN
147.                 IF b$ = "esc" THEN SYSTEM
148.                 IF VAL(b$) > 0 THEN EXIT DO
149.             LOOP
150.             a$ = session$(VAL(b$))
151.  
152.             CALL highlight(a$, b$)
153.  
154.         ELSE
155.             b$ = "1" ' Only one selection.
156.         END IF
157.  
158.         OPEN session$(VAL(b$)) + fileextension$ FOR INPUT AS #1
159.         DO UNTIL EOF(1)
160.             LINE INPUT #1, a$
161.             SHELL _HIDE "firefox.exe " + a$
162.             _DELAY .2
163.         LOOP
164.         _DELAY 2
165.         RUN
166.     CASE 5
167.         task$ = "session"
168.         CALL mapping(task$)
169.         _DELAY 3
170.         RUN
171.     CASE 6
172.         task$ = "close"
173.         CALL taskactions(task$, flag)
174.         IF flag THEN flag = 0: CALL makesettings
175.         RUN
176.     CASE 7
177.         CALL makesettings
178.         RUN
179.     CASE 8
180.         SYSTEM
181. END SELECT
182.  
183. tasklist:
184. DATA FireFox Full Screen,Starting FireFox...
185. DATA FireFox Minimized,Starting FireFox Minimized...
186. DATA FireFox Load Previous Session,Starting Firefox Last Session...
187. DATA Load a Saved Session,Loading Session Menu...
188. DATA Map a New Session,Map a New Session...
189. DATA Close Firefox,Close Firefox...
190. DATA Settings,Go to Settings...
191. DATA Quit,Quit
192. DATA eof,eof
193.  
194. programcommands:
195. DATA back,run
196. DATA quit,esc
197. DATA eof,eof
198.  
199. settingslist:
200. DATA Close
201. DATA Load Previous Session
202. DATA eof
203.  
204. SUB mouse (x%, y%, mb%, rb%)
205. WHILE _MOUSEINPUT: WEND
206. x% = _MOUSEX
207. y% = _MOUSEY
208. mb% = _MOUSEBUTTON(1)
209. rb% = _MOUSEBUTTON(2)
210. IF INKEY$ = CHR$(27) THEN SYSTEM
211. END SUB
212.  
213. SUB mapping (task$)
214. _DELAY .1
215. hwnd%& = FindWindowA(0, title$ + CHR$(0)) 'find this program's process handle
216. oldx% = -1: w = 0: v = 0: num% = 0
217. DO
218.     IF oldx% <> x% OR oldy% <> y% THEN
219.         IF dispon% = 0 THEN
220.             CLS
221.  
222.             CALL startbrowser
223.  
224.             CALL focusapp
225.  
226.             IF task$ = "session" THEN
227.                 LOCATE crow%, ccol%
228.                 PRINT "Open all websites you want"
229.                 LOCATE , ccol%
230.                 PRINT "saved in this session."
231.                 PRINT
232.                 LOCATE , ccol%
233.                 PRINT "Click the taskbar icon to"
234.                 LOCATE , ccol%
235.                 PRINT "record and save session..."
236.  
237.                 DO
238.                     _LIMIT 30
239.                     FGwin%& = GetForegroundWindow%&
240.                     CALL mouse(x%, y%, mb%, rb%)
241.                     IF mb% THEN EXIT DO
242.                     b$ = INKEY$
243.                     IF b$ = CHR$(27) THEN SYSTEM
244.                     IF b$ <> "" THEN EXIT DO
245.                     IF FGwin%& <> hwnd%& THEN EXIT DO ' Exit when Firefox is clicked.
246.                 LOOP
247.                 'Minimize here.
248.                 CALL minimizewindow
249.                 _DELAY 1
250.                 CLS
251.                 LOCATE crow% + 1, ccol%
252.                 PRINT "Working..."
253.                 DO
254.                     _LIMIT 30
255.                     FGwin%& = GetForegroundWindow%&
256.                     _DELAY 1
257.                     IF FGwin%& = hwnd%& THEN EXIT DO ' Exit when program window is restored from task bar.
258.                 LOOP
259.                 CALL restorewindow
260.             END IF
261.  
262.             CLS
263.             _DELAY .1
264.             z& = SetForegroundWindow&(hwnd%&) 'set focus
265.  
266.             GOSUB putimage
267.  
268.             LOCATE crow% + 1, ccol%
269.  
270.             SELECT CASE task$
271.                 CASE "session"
272.                     PRINT "Left click the tabs you want saved in this session."
273.                     PRINT: LOCATE , ccol%
274.                     PRINT "Right click anywhere when finished..."
275.                 CASE "close"
276.                     PRINT "Left click the [X] Close symbol in Firefox."
277.                 CASE "load previous session"
278.                     SELECT CASE num%
279.                         CASE 0
280.                             PRINT "Click browser: " + CHR$(34) + "History" + CHR$(34)
281.                             PRINT
282.                         CASE 1
283.                             LOCATE , ccol%
284.                             PRINT "Click: " + CHR$(34) + "Restore Previous Session"
285.                     END SELECT
286.             END SELECT
287.         END IF
288.         LOCATE crow% + 6, ccol%
289.         PRINT "Row ="; y%; "   "; "Column ="; x%; "   ";
290.         oldx% = x%: oldy% = y%
291.     END IF
292.     WHILE _MOUSEINPUT: WEND
293.     x% = _MOUSEX
294.     y% = _MOUSEY
295.     mb% = _MOUSEBUTTON(1)
296.     rb% = _MOUSEBUTTON(2)
297.     IF mb% THEN
298.         mb% = 0
299.         'PRINT "Confirmed: Row ="; y%; "   Column ="; x%,
300.         num% = num% + 1
301.         tabx(num%) = x%
302.         taby(num%) = y%
303.         DO: i = _MOUSEINPUT: LOOP UNTIL _MOUSEBUTTON(1) = 0
304.         SELECT CASE task$
305.             CASE "close"
306.                 EXIT SUB
307.             CASE "load previous session"
308.                 CALL minimizewindow
309.                 _DELAY .1
310.                 _SCREENCLICK x%, y%
311.                 _DELAY .25
312.                 GOSUB putimage
313.                 _DELAY .25
314.                 CALL restorewindow
315.                 LOCATE 10, 75
316.                 FOR i = 1 TO 3
317.                     LOCATE , 75
318.                     PRINT SPACE$(40)
319.                 NEXT
320.                 LOCATE 11, 75
321.                 PRINT " Click " + CHR$(34) + "Restore Previous Session" + CHR$(34)
322.                 DO
323.                     CALL mouse(x%, y%, mb%, rb%)
324.                     IF mb% THEN EXIT DO
325.                 LOOP
326.                 num% = num% + 1
327.                 tabx(num%) = x%
328.                 taby(num%) = y%
329.                 CALL setscreen
330.                 EXIT SUB
331.         END SELECT
332.     ELSE
333.         IF rb% AND task$ = "session" THEN
334.             _SCREENHIDE
335.             SCREEN 0
336.             WIDTH cwidth%, rheight%
337.             _SCREENMOVE scindent% * fw%, srindent% * fh%
338.             CLS
339.             _DELAY .25
340.             REDIM url$(num%)
341.             FOR i = 1 TO num%
342.                 _SCREENCLICK tabx(i), taby(i)
343.                 _DELAY .25
344.                 _SCREENCLICK 700, 80 ' Firefox URL input field.
345.                 _DELAY .1
346.                 _SCREENPRINT CHR$(1) ' Select the URL.
347.                 _DELAY .1
348.                 _SCREENPRINT CHR$(3) ' Copy the URL.
349.                 _DELAY .25
350.                 url$(i) = _CLIPBOARD$
351.             NEXT
352.             _SCREENSHOW
353.             _DELAY .1
354.             sdate$ = MID$(DATE$, 7, 4) + "-" + MID$(DATE$, 1, 2) + "-" + MID$(DATE$, 4, 2)
355.             LOCATE 2, 2
356.             PRINT "Name and Save this Session as: "; sdate$ + ": ";
357.             yy% = CSRLIN: xx% = POS(0)
358.             COLOR 0, 7
359.             LOCATE , xx% - 1
360.             PRINT SPACE$(60 + 2);
361.             COLOR 7, 0
362.             LOCATE yy%, xx%
363.             PRINT
364.             _DELAY .25
365.             PRINT
366.             FOR i = 1 TO num%
367.                 LOCATE , 2
368.                 PRINT LTRIM$(STR$(i)); ") "; MID$(url$(i), 1, cwidth% - 5)
369.             NEXT
370.             LOCATE yy%, xx%
371.  
372.             z& = SetForegroundWindow&(hwnd%&) 'Set focus for key input.
373.  
374.             CALL keyinput(word$, b$, flag)
375.  
376.             CALL savefile(word$, sdate$, url$())
377.  
378.             EXIT SUB
379.         END IF
380.     END IF
381. LOOP UNTIL INKEY$ = CHR$(27)
382. SYSTEM
383.  
384. putimage:
385. img& = _SCREENIMAGE
386. s& = _NEWIMAGE(_DESKTOPWIDTH, _DESKTOPHEIGHT - 60, 32)
387. SCREEN s&
388. CLS
389. _SCREENMOVE 0, -25 ' Hides title bar above computer top screen margin.
390. _PUTIMAGE (0, 0), img&
391. _DELAY .1
392. _FREEIMAGE img&
393. dispon% = -1
394. RETURN
395. END SUB
396.  
397. SUB keyinput (word$, b$, flag)
398. startpos% = POS(1) - LEN(word$)
399. endpos% = startpos% + numofspaces%
400.  
401. DO
402.     COLOR 7, 0
403.     xx% = CSRLIN: yy% = POS(1)
404.     LOCATE 1, 1
405.     DO
406.         ii = ii + 1
407.         IF word$(ii) = "" THEN EXIT DO
408.         PRINT ii; word$(ii)
409.     LOOP
410.     COLOR 0, 7
411.     LOCATE xx%, yy%, 1, 7, 7
412.     ii = 0
413.     DO
414.         b$ = INKEY$
415.         IF b$ <> "" THEN EXIT DO
416.     LOOP
417.     xx% = CSRLIN: yy% = POS(1)
418.  
419.     SELECT CASE b$
420.         CASE CHR$(0) + "H"
421.             REM DOS-KEY-LIKE REPLACE INPUT
422.             IF inputindex > 0 THEN
423.                 IF word$ = "" THEN
424.                     inputindex = inputindex - 1: word$ = word$(inputindex)
425.                 ELSE
426.                     word$ = word$(inputindex): inputindex = inputindex - 1
427.                 END IF
428.                 flag = -1
429.                 EXIT SUB
430.             END IF
431.         CASE CHR$(0) + "K"
432.             mov% = -1: GOSUB action
433.         CASE CHR$(0) + "M"
434.             mov% = 1: GOSUB action
435.         CASE CHR$(0) + "S"
436.             GOSUB wash: GOSUB delete
437.         CASE CHR$(0) + "R"
438.             IF ins% = 0 THEN ins% = -1 ELSE ins% = 0
439.             IF ins% = 0 THEN LOCATE , , 1, 7, 7 ELSE LOCATE , , 1, 7, 30
440.         CASE CHR$(0) + "O"
441.             IF word$ <> "" THEN LOCATE xx%, startpos% + LEN(word$)
442.         CASE CHR$(0) + "G"
443.             LOCATE xx%, startpos%
444.         CASE CHR$(8)
445.             IF yy% > startpos% THEN
446.                 LOCATE , POS(1) - 1
447.                 yy% = POS(1)
448.                 GOSUB wash: GOSUB delete
449.             END IF
450.         CASE CHR$(13)
451.             COLOR 7, 0
452.             LOCATE , , 1, 7, 0
453.             EXIT SUB
454.         CASE CHR$(27)
455.             COLOR 7, 0: SYSTEM
456.         CASE CHR$(32) TO CHR$(126)
457.             key$ = b$: GOSUB action
458.     END SELECT
459.     mov% = 0: key$ = ""
460. LOOP
461.  
462. action:
463. IF POS(1) + mov% >= startpos% AND POS(1) + mov% < endpos% THEN
464.     DO
465.         IF key$ <> "" THEN
466.             SELECT CASE ins%
467.                 CASE 0
468.                     IF LEN(word$) + LEN(key$) > endpos% - startpos% THEN EXIT DO
469.                     word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 1)
470.                 CASE -1
471.                     word$ = MID$(word$, 1, POS(1) - startpos%) + key$ + MID$(word$, POS(1) - startpos% + 2)
472.             END SELECT
473.         END IF
474.         IF POS(1) - startpos% >= LEN(word$) - LEN(key$) AND key$ <> "" OR key$ = "" OR ins% = -1 THEN
475.             IF key$ = "" AND mov% = 1 THEN IF POS(1) - startpos% = LEN(word$) THEN EXIT DO
476.             LOCATE , POS(1) + mov%: PRINT key$;
477.         ELSE
478.             LOCATE xx%, startpos%: PRINT MID$(word$, 1, yy% - startpos%); key$;: yy2% = POS(1): PRINT MID$(word$, yy% - startpos% + 2);: LOCATE xx%, yy2%
479.         END IF
480.         EXIT DO
481.     LOOP
482. END IF
483. RETURN
484.  
485. wash:
486. IF POS(1) >= startpos% AND word$ <> "" AND POS(1) - startpos% < LEN(word$) THEN
487.     LOCATE xx%, startpos% + LEN(word$) - 1
488.     PRINT " ";
489.     LOCATE xx%, yy%
490. END IF
491. RETURN
492.  
493. delete:
494. IF POS(1) - startpos% = 0 THEN
495.     word$ = MID$(word$, 2)
496. ELSE
497.     word$ = MID$(word$, 1, POS(1) - startpos%) + MID$(word$, POS(1) - startpos% + 2)
498. END IF
499. PRINT MID$(word$, yy% - startpos% + 1);: LOCATE xx%, yy%
500. RETURN
501. END SUB
502.  
503. SUB savefile (word$, sdate$, url$())
504. OPEN sdate$ + " " + word$ + fileextension$ FOR OUTPUT AS #2
505. FOR i = 1 TO num%
506.     PRINT #2, url$(i)
507. NEXT
508. CLOSE #2
509. END SUB
510.  
511. SUB savesettings (b$)
512. OPEN "session-manager-settings.dat" FOR OUTPUT AS #2
513. i = 0
514. DO
515.     i = i + 1
516.     IF settings$(i) = "" OR i = 100 THEN EXIT DO
517.     IF INSTR(settings$(i), ")") THEN
518.         settings$(i) = LTRIM$(MID$(settings$(i), INSTR(settings$(i), ")") + 1)) ' Strip off any number.
519.     END IF
520.     PRINT #2, settings$(i)
521. LOOP
522. CLOSE #2
523. END SUB
524.  
525. SUB box (w3, w4)
526. LOCATE crow% - 1, ccol% - 2: PRINT CHR$(218);: PRINT STRING$(w4, 196) + CHR$(191)
527. FOR j = 1 TO w3
528.     LOCATE , ccol% - 2
529.     PRINT CHR$(179);
530.     LOCATE , ccol% + w4 - 1: PRINT CHR$(179)
531. NEXT
532. LOCATE , ccol% - 2: PRINT CHR$(192) + STRING$(w4, 196) + CHR$(217)
533. END SUB
534.  
535. SUB selection (w3, b$)
536. b$ = ""
537. DO
538.     _LIMIT 30
539.     CALL mouse(x%, y%, mb%, rb%)
540.     IF mb% THEN
541.         IF p1% <= x% AND p2% >= x% AND p3% <= y% AND p4% >= y% THEN
542.             b$ = CHR$(49 + y% - crow%)
543.         END IF
544.         IF VAL(b$) = 0 THEN ' Check for program choices above menu items.
545.             cmd$ = CHR$(SCREEN(y%, x%))
546.             IF LTRIM$(cmd$) = "" THEN
547.                 IF x% > 1 THEN cmd$ = CHR$(SCREEN(y%, x% - 1)) + cmd$ ' Look left
548.                 IF x% < cwidth% THEN cmd$ = cmd$ + CHR$(SCREEN(y%, x% + 1)) ' Look right
549.                 cmd$ = RTRIM$(LTRIM$(cmd$))
550.                 IF LEN(cmd$) <> 3 THEN cmd$ = "" ' Not in middle of a word."
551.             END IF
552.             IF cmd$ <> "" THEN
553.                 cmd$ = ""
554.                 FOR i = x% TO 1 STEP -1
555.                     cmd$ = CHR$(SCREEN(y%, i)) + cmd$
556.                     IF INSTR(cmd$, SPACE$(2)) THEN EXIT FOR ' IMPORTANT Only allows 1-space between clickable words.
557.                 NEXT
558.                 cmd$ = LTRIM$(cmd$)
559.                 IF cmd$ = "" THEN j = 0 ELSE j = 1
560.                 FOR i = x% + j TO cwidth%
561.                     cmd$ = cmd$ + CHR$(SCREEN(y%, i))
562.                     IF INSTR(cmd$, SPACE$(2)) THEN EXIT FOR
563.                 NEXT
564.                 cmd$ = LTRIM$(RTRIM$(LCASE$(cmd$)))
565.             END IF
566.             IF cmd$ <> "" THEN
567.                 RESTORE programcommands
568.                 b$ = ""
569.                 DO
570.                     READ a$, action$
571.                     IF LCASE$(a$) = "eof" THEN EXIT DO
572.                     IF LCASE$(a$) = cmd$ THEN b$ = action$: EXIT DO
573.                 LOOP
574.             END IF
575.         END IF
576.     ELSE
577.         b$ = INKEY$
578.     END IF
579.     IF b$ = CHR$(27) THEN SYSTEM
580.     IF VAL(b$) <= w3 AND VAL(b$) <> 0 OR LEN(b$) > 1 THEN EXIT DO
581. LOOP
582. END SUB
583.  
584. SUB highlight (a$, b$)
585. LOCATE crow% + VAL(b$) - 1, ccol%
586. COLOR 14, 0
587. PRINT a$;
588. COLOR 7, 0
589. _DELAY .25
590. END SUB
591.  
592. SUB taskactions (task$, flag)
593. REDIM settings$(100)
594. IF _FILEEXISTS("session-manager-settings.dat") THEN
595.     OPEN "session-manager-settings.dat" FOR INPUT AS #1
596.     i = 0
597.     DO UNTIL EOF(1)
598.         i = i + 1
599.         INPUT #1, a$, action$
600.         settings$(i) = a$ + "," + action$
601.     LOOP
602.     CLOSE #1
603.     flag = -1
604. END IF
605.  
606. IF flag THEN
607.     flag = 0
608.     FOR j = 1 TO i
609.         IF INSTR(LCASE$(settings$(j)), LCASE$(task$)) <> 0 THEN
610.             flag = -1
611.             a$ = MID$(settings$(j), INSTR(settings$(j), ",") + 1)
612.             EXIT FOR
613.         END IF
614.     NEXT
615.     IF flag THEN
616.         IF INSTR(LCASE$(a$), "(undefined)") <> 0 THEN
617.             CLS
618.             LOCATE crow%, ccol%
619.             PRINT "This feature requires making a"
620.             LOCATE , ccol%
621.             PRINT "setting before it can be used."
622.             PRINT
623.             LOCATE , ccol%
624.             PRINT "Opening the settings screen..."
625.             _DELAY 4
626.             CLS
627.             EXIT SUB
628.         END IF
629.         flag = 0
630.         SELECT CASE LCASE$(task$)
631.             CASE "load previous session"
632.                 CALL startbrowser
633.             CASE "close"
634.                 ' Taskkill could be substituted here but may report an ff crash on next start up.
635.                 CALL startbrowser ' Ensures browser is running full screen before _SCREENCLICK.
636.                 REM x& = ShowWindow&(hwnd%&, 0) ' Closes Firefox but loses restore last session info.
637.         END SELECT
638.         DO
639.             x% = VAL(a$)
640.             a$ = MID$(a$, INSTR(a$, "-") + 1)
641.             y% = VAL(a$)
642.             _SCREENCLICK y%, x%
643.             _DELAY 1
644.             IF INSTR(a$, "|") = 0 THEN EXIT DO
645.             a$ = MID$(a$, INSTR(a$, "|") + 1)
646.         LOOP
647.     END IF
648. ELSE
649.     CLS
650.     PRINT " ERROR: sessions-settings.dat file is missing."
651.     PRINT
652.     PRINT " Rerun program to re-install default data."
653.     END
654. END IF
655. END SUB
656.  
657. SUB makesettings
658. DO
659.     REDIM settings$(100) ' Load the settings data again.
660.     RESTORE settingslist
661.     IF _FILEEXISTS("session-manager-settings.dat") THEN
662.         CLS
663.         OPEN "session-manager-settings.dat" FOR INPUT AS #1
664.         i = 0: w4 = 0
665.         DO UNTIL EOF(1)
666.             i = i + 1
667.             INPUT #1, a$, action$
668.             settings$(i) = LTRIM$(STR$(i)) + ") " + a$ + "," + action$
669.             a$ = MID$(settings$(i), 1, INSTR(settings$(i), ",") - 1) ' Do not include actions in menu.
670.             IF LEN(a$) > w4 THEN w4 = LEN(a$)
671.         LOOP
672.         CLOSE #1
673.         w3 = i
674.         w4 = w4 + 2
675.         crow% = 10
676.         ccol% = cwidth% \ 2 - w4 \ 2
677.         p1% = ccol%: p2% = ccol% + w4: p3% = crow%: p4% = crow% + w3 ' selection parameters
678.         heading$ = "Settings"
679.         LOCATE crow% - 3, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
680.         PRINT heading$;
681.         heading$ = "Back  |  Quit"
682.         LOCATE crow% - 2, ccol% + (w4 - 2) \ 2 - LEN(heading$) \ 2
683.         COLOR 3, 0
684.         PRINT heading$;
685.         COLOR 7, 0
686.         LOCATE crow%, ccol%
687.  
688.         FOR i = 1 TO w3
689.             LOCATE , ccol%
690.             PRINT MID$(settings$(i), 1, INSTR(settings$(i), ",") - 1)
691.         NEXT
692.  
693.         CALL box(w3, w4)
694.  
695.         CALL selection(w3, b$)
696.  
697.         a$ = MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ",") - 1)
698.  
699.         CALL highlight(a$, b$)
700.  
701.         IF b$ = "run" THEN RUN
702.         IF b$ = "esc" THEN SYSTEM
703.  
704.         CLS
705.         task$ = LCASE$(MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ",") - 1))
706.         task$ = LTRIM$(MID$(task$, INSTR(task$, ")") + 1)) ' strip off number if present.
707.         LOCATE crow% + 1, ccol%
708.         PRINT "Working..."
709.  
710.         CALL mapping(task$)
711.  
712.         a$ = MID$(settings$(VAL(b$)), 1, INSTR(settings$(VAL(b$)), ","))
713.         a$ = LTRIM$(MID$(a$, INSTR(a$, ")") + 1)) ' Strip off any number.
714.         FOR i = 1 TO num%
715.             a$ = a$ + LTRIM$(STR$(taby(i))) + "-" + LTRIM$(STR$(tabx(i))) + "|"
716.         NEXT
717.         a$ = MID$(a$, 1, LEN(a$) - 1)
718.         settings$(VAL(b$)) = a$
719.  
720.         CALL savesettings(b$)
721.  
722.         CALL setscreen
723.     ELSE
724.         CLS
725.         PRINT " ERROR: sessions-settings.dat file is missing."
726.         PRINT
727.         PRINT " Rerun program to re-install default data."
728.         END
729.     END IF
730.     task$ = "": a$ = "": b$ = ""
731. LOOP
732. END SUB
733.  
734. SUB setscreen
735. SCREEN 0: CLS
736. srindent% = _DESKTOPHEIGHT \ _FONTHEIGHT - maxwinheight% ' To be indented from the top.
737. cwidth% = _DESKTOPWIDTH \ _FONTWIDTH - scindent% * 2
738. WIDTH cwidth%, rheight%
739. fw% = _FONTWIDTH: fh% = _FONTHEIGHT
740. ' Now that WIDTH has been set, the font heigh can be used to calculate window size.
741. _SCREENMOVE scindent% * fw%, srindent% * fh%
742. END SUB
743.  
744. SUB startbrowser
745. hwnd%& = FindWindowA(0, findbrowsertitle$ + CHR$(0))
746. _DELAY .1
747. IF hwnd%& = 0 THEN
748.     SHELL _DONTWAIT _HIDE "firefox.exe " + browsertab$
749. END IF
750. i = 0
751. DO ' Wait until title is registerd.
752.     i = i + 1
753.     hwnd%& = FindWindowA(0, findbrowsertitle$ + CHR$(0))
754.     _DELAY .2
755.     IF hwnd%& THEN EXIT DO
756. LOOP UNTIL i = 100
757.  
758. CALL maximizewindow
759.  
760. END SUB
761.  
762. SUB maximizewindow
763. x& = ShowWindow&(hwnd%&, 3) ' Maximize window from FindWindowA.
764. _DELAY .1
765. z& = SetForegroundWindow&(hwnd%&)
766. _DELAY .1
767. END SUB
768.  
769. SUB minimizewindow
770. x& = ShowWindow&(hwnd%&, 2) ' Minimize window from FindWindowA.
771. _DELAY .1
772. END SUB
773.  
774. SUB restorewindow
775. x& = ShowWindow&(hwnd%&, 1) ' Restore window from FindWindowA.
776. _DELAY .1
777. z& = SetForegroundWindow&(hwnd%&)
778. END SUB
779.  
780. SUB focusapp
781. hwnd%& = FindWindowA(0, title$ + CHR$(0))
782. _DELAY .1
783. z& = SetForegroundWindow&(hwnd%&)
784. _DELAY .1
785. END SUB
786.  

Pete

[TempodiBasic]

Cool!
Thanks to share.

[Cobalt]

Do you think this program could be modified to shutdown certain web pages if they are opened? like some kind of super parental controller?

[Pete]

Do you think this program could be modified to shutdown certain web pages if they are opened? like some kind of super parental controller?

No. The reason is it cannot shut down a tab. On the other hand, if a website you don't want your kids to visit is opened, like FreeBasic.com, it could just end the whole browser session. Now if a kid could figure out that taking the browser out of full screen mode and just run it in a window, just below the top of the screen, the _SCREENCLICK coordinates would no longer be valid and the program would fail to work. So _SCRRENCLICK programming is a bit Mickey Mouse, but it if you are not trying to thwart it, it does get the job done.

Pete