Text distortion problem

[bplus]

I am working on a message box sub and got it working well in testing code program. So I try it out with the getArrayItem code to use as a Help screen (press h) and it does everything it is supposed to do BUT the text is distorted ??? I tested in a QB64 beta and got same results.

The message box is drawn in freshly minted _NEWIMAGE and just using _PUTIMAGE to new locations when mouse grabs title bar but the text image has weird shrinking of every 5 lines or so, the font is unclear to read in places and looks cut into in other places.

Here is the mBox test code:

Code: QB64: [Select]

1. _TITLE "simple message box test and demo"
2. 'QB64 X 64 version 1.2 20180228/86  from git b301f92
3.  
4. 'started 2018-09-05 by B+
5. ' as of 9/6 1am I have basic display working and mouse grabbing and moving,
6. ' this after getting main body of text wordwrapped and line count calc'd.
7. ' need smoother/faster action, what is slowing this down? locate and print?
8. ' 2018-09-06 Oh draw message box in dest and then _putImage over background = screen image
9. ' and this will leave main screen unbesmirched? and moving box around is as easy as image!
10. ' That's plan for tonight.  OK done. Added mouse click x-it.
11. ' 2018-09-07 bak 2018-09-07_3P and start testing in other apps
12. ' A disaster! something happened to the font in the getArrayItem app.
13.  
14. CONST WW = 800
15. CONST WH = 600
16. DIM SHARED curScn&
17. curScn& = _NEWIMAGE(WW, WH, 32)
18. SCREEN curScn&
19. _SCREENMOVE (1280 - WW) / 2 + 30, (760 - WH) / 2
20.  
21. 'draw stuff
22. FOR i = 1 TO 100
23.     LINE (RND * WW, RND * WH)-STEP(RND * 80, RND * 60), _RGB32(RND * 255, RND * 255, RND * 255), BF
24. NEXT
25.  
26. mess$ = "This is line 1 followed by LF" + CHR$(10)
27. mess$ = mess$ + "This is line 2 followed by CR + LF" + CHR$(13) + CHR$(10)
28. mess$ = mess$ + "Line 3 is followed by a double LF to make a space." + CHR$(10) + CHR$(10)
29. mess$ = mess$ + "Here is a long line that hopefully won't all fit across the screen, so I just keep going on and on ..."
30. mess$ = mess$ + "until the screen is half full of this single long, long line so I can test the wrapping my code does "
31. mess$ = mess$ + "with this long thing! ending with a double CR." + CHR$(13) + CHR$(13)
32. mess$ = mess$ + CHR$(9) + "This line started with a tab which should be replaced by spaces so now this line should be running too long. The End."
33. title$ = "1234567890123456789012345678901234567890123456789012345"
34. mBox mess$, title$
35. BEEP 'we're back!
36. WHILE _KEYDOWN(27) = 0
37.     LINE (RND * WW, RND * WH)-STEP(RND * 80, RND * 60), _RGB32(RND * 255, RND * 255, RND * 255), BF
38.     _DISPLAY
39.     _LIMIT 5
40. WEND
41.  
42. 'title$ limit is 57 chars, all lines are 58 chars max
43. ' version bak 2018-09-07_3P < fixing this version as it does not work well in another app
44. SUB mBox (m$, title$)
45.  
46.     'using const WW for Window Width, WH for Window Height
47.     DIM curScrn AS LONG, backScrn AS LONG, mbx AS LONG 'some handles
48.     DIM ti AS INTEGER, limit AS INTEGER 'ti = test index for t$(), limit is number of chars per line
49.     DIM i AS INTEGER, j AS INTEGER, ff AS _BIT, add AS _BYTE 'index, flag and
50.     DIM bxH AS INTEGER, bxW AS INTEGER 'first as cells then as pixels
51.     DIM mb AS INTEGER, mx AS INTEGER, my AS INTEGER, mi AS INTEGER, grabx AS INTEGER, graby AS INTEGER
52.     DIM tlx AS INTEGER, tly AS INTEGER 'top left corner of message box
53.     DIM lastx AS INTEGER, lasty AS INTEGER
54.  
55.     'screen snapshot
56.     curScrn = _DEST
57.     backScrn = _NEWIMAGE(WW, WH, 32)
58.     _PUTIMAGE , curScrn, backScrn
59.  
60.     'setup t$() to store strings with ti as index, linit 58 chars per line max, b$ is for build
61.     REDIM t$(0): ti = 0: limit = 58: b$ = ""
62.     FOR i = 1 TO LEN(m$)
63.         c$ = MID$(m$, i, 1)
64.         'are there any new line signals, CR, LF or both? take CRLF or LFCR as one break but dbl LF or CR means blank line
65.         SELECT CASE c$
66.             CASE CHR$(13) 'load line
67.                 IF MID$(m$, i + 1, 1) = CHR$(10) THEN i = i + 1
68.                 t$(ti) = b$: b$ = "": ti = ti + 1: REDIM _PRESERVE t$(ti)
69.             CASE CHR$(10)
70.                 IF MID$(m$, i + 1, 1) = CHR$(13) THEN i = i + 1
71.                 t$(ti) = b$: b$ = "": ti = ti + 1: REDIM _PRESERVE t$(ti)
72.             CASE ELSE
73.                 IF c$ = CHR$(9) THEN c$ = SPACE$(4): add = 4 ELSE add = 1
74.                 IF LEN(b$) + add > limit THEN
75.                     tail$ = "": ff = 0
76.                     FOR j = LEN(b$) TO 1 STEP -1 'backup until find a space, save the tail end for next line
77.                         d$ = MID$(b$, j, 1)
78.                         IF d$ = " " THEN
79.                             t$(ti) = MID$(b$, 1, j - 1): b$ = tail$ + c$: ti = ti + 1: REDIM _PRESERVE t$(ti)
80.                             ff = 1 'found space flag
81.                             EXIT FOR
82.                         ELSE
83.                             tail$ = d$ + tail$ 'the tail grows!
84.                         END IF
85.                     NEXT
86.                     IF ff = 0 THEN 'no break? OK
87.                         t$(ti) = b$: b$ = c$: ti = ti + 1: REDIM _PRESERVE t$(ti)
88.                     END IF
89.                 ELSE
90.                     b$ = b$ + c$ 'just keep building the line
91.                 END IF
92.         END SELECT
93.     NEXT
94.     t$(ti) = b$
95.     bxH = ti + 3: bxW = limit + 2
96.  
97.     'draw message box
98.     mbx = _NEWIMAGE(60 * 8, (bxH + 1) * 16, 32)
99.     _DEST mbx
100.     COLOR _RGB32(60, 40, 25), _RGB32(225, 225, 255)
101.     LOCATE 1, 1: PRINT LEFT$(SPACE$((bxW - LEN(title$) - 3) / 2) + title$ + SPACE$(bxW), bxW)
102.     COLOR _RGB32(225, 225, 255), _RGB32(200, 0, 0)
103.     LOCATE 1, bxW - 2: PRINT " X "
104.     COLOR _RGB32(60, 40, 25), _RGB32(255, 160, 90)
105.     LOCATE 2, 1: PRINT SPACE$(bxW);
106.     FOR r = 0 TO ti
107.         LOCATE 1 + r + 2, 1: PRINT LEFT$(" " + t$(r) + SPACE$(bxW), bxW);
108.     NEXT
109.     LOCATE 1 + bxH, 1: PRINT SPACE$(limit + 2);
110.  
111.     'now for the action
112.     _DEST curScrn
113.  
114.     'convert to pixels the top left corner of box at moment
115.     bxW = bxW * 8: bxH = bxH * 16
116.     tlx = (WW - bxW) / 2: tly = (WH - bxH) / 2
117.     lastx = tlx: lasty = tly
118.     'now allow user to move it around or just read it
119.     WHILE _KEYDOWN(27) = 0 AND _KEYDOWN(13) = 0 AND _KEYDOWN(32) = 0
120.         CLS
121.         _PUTIMAGE , backScrn
122.         _PUTIMAGE (tlx, tly)-STEP(bxW, bxH), mbx, curScrn
123.         _DISPLAY
124.         WHILE _MOUSEINPUT: WEND
125.         mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
126.         IF mb THEN
127.             IF mx >= tlx AND mx <= tlx + bxW AND my >= tly AND my <= tly + 16 THEN 'mouse down on title bar
128.                 IF mx >= tlx + bxW - 24 THEN EXIT WHILE
129.                 grabx = mx - tlx: graby = my - tly
130.                 DO WHILE mb 'wait for release
131.                     mi = _MOUSEINPUT: mb = _MOUSEBUTTON(1)
132.                     mx = _MOUSEX: my = _MOUSEY
133.                     IF mx - grabx >= 0 AND mx - grabx <= WW - bxW AND my - graby >= 0 AND my - graby <= WH - bxH THEN
134.                         'attempt to speed up with less updates
135.                         IF ((lastx - (mx - grabx)) ^ 2 + (lasty - (my - graby)) ^ 2) ^ .5 > 10 THEN
136.                             tlx = mx - grabx: tly = my - graby
137.                             CLS
138.                             _PUTIMAGE , backScrn
139.                             _PUTIMAGE (tlx, tly)-STEP(bxW, bxH), mbx, curScrn
140.                             lastx = tlx: lasty = tly
141.                             _DISPLAY
142.                         END IF
143.                     END IF
144.                     _LIMIT 400
145.                 LOOP
146.             END IF
147.         END IF
148.         _LIMIT 400
149.     WEND
150.     COLOR _RGB32(255, 255, 255), _RGB32(0, 0, 0): CLS
151.     _PUTIMAGE , backScrn
152.     _FREEIMAGE backScrn
153.     _FREEIMAGE mbx
154.     _DISPLAY
155. END SUB
156.  

The resulting text image is fine!

Now here is same code tested with getArrayIndex code as a Help Window:

Code: QB64: [Select]

1. _TITLE "getArrayItemClicked v4 mbox"
2.  
3. ' Main testing and demo of the FUNCTION  getArrayItemNumber%
4.  
5. 'started 2018-08-31 B+  developing a general purpose display and select app of a string array
6. ' in this version want
7. ' 1 to be able to select item from larger arrays that take several pages to screen
8. ' 2 highlite mouse over ?
9. ' 3 colorize print? Eh! bloats parameters in call, if really want, modify function for app.
10. '   Using dark blue on sky blue and reverse for highlite, pretty easy on eyes and sets off
11. '   selection area.
12. ' 4 keep modifiable for possibly adding fonts, I think that means use only locate and print,
13. '  as _printstring works in pixels, no good for different fonts. (Neither is LOCATE)
14.  
15. ' 2018-09-01 yea, finally got everything working and playing together
16. ' oh yeah, to mouse click an escape along with expected escape button press.
17. ' I might to build a frame around the list box control? (No, just a bar above and below)
18.  
19. '2018-09-03 OK everything working great! But I have added two lines to maxHeight.
20. ' Do I adjust maxHeight to reflect actual height of box on screen, I think better do it.
21. ' Oh heck that was easy!  Just calc maxHeight off boxHeight!
22. ' Clean up instructions for using the function.
23. ' NEXT project is message box that doesn't need Windows OS calls,
24. ' so I could offer help here with h keypress!
25. ' Just tested a font with locate and print and locate does not work.
26. ' So this is done until I get messageBox working.
27.  
28. '2018-09-04 post v2 bak 9-3_9PM
29. '2018-09-07 getArrayItem v4 mbox - time to test mbox with help window
30.  
31. CONST nArr = 92 'ubound of array = actual amount of items if LBound = 1
32. CONST LB = 1 'try different lower bounds not just 0, 1
33. CONST WW = 1200 'Window Width
34. CONST WH = 600 'Window Height
35.  
36. SCREEN _NEWIMAGE(WW, WH, 32)
37. _SCREENMOVE 100, 60
38.  
39.  
40. 'test string array, use indexes in lines for alignment to code for function
41. REDIM arr(LB TO nArr) AS STRING
42. FOR i = LB TO nArr
43.     arr(i) = "This is arr item:" + STR$(i)
44. NEXT
45.  
46. WHILE 1
47.     CLS
48.     PRINT
49.     cp "*** Mouse and Key Instructions ***"
50.     PRINT
51.     cp "Mouse, mouse wheel, and arrow keys should work as expected for item selection."
52.     cp "Press spacebar to select a highlighted item or just click it."
53.     cp "Use number(s) + enter to select an array item by it's index number,"
54.     cp "backspace will remove last number pressed, c will clear a number started."
55.     cp "Numbers started are shown in bottom right PgDn bar."
56.     cp "Enter will also select the highlighted item, if no number has been started."
57.     cp "Home starts you at lowest array index, End highlights then highest index."
58.     cp "Use PgUp and PgDn keys or bars to flip through pages of array items."
59.     PRINT
60.     cp "Escape returns -1719 to allow a Cancel function and signal no slection."
61.     PRINT ""
62.     locRow = 16: locCol = (WW / 8 - 25) / 2: boxWidth = 25: boxHeight = 17 '< displays 15 lines of array items
63.     'boxHeight is actual screen space in character units, the display uses 2 of the lines for control bars.
64.     'boxWidth will include item numbers displayed to left of array string item
65.     CH = getArrayItemNumber(locRow, locCol, boxWidth, boxHeight, arr())
66.     _AUTODISPLAY
67.     COLOR _RGB32(255, 255, 255), _RGB32(0, 0, 0): LOCATE 32, 1
68.     IF CH = -1719 THEN cp "You canceled selection process." ELSE cp "You chose index (" + LTRIM$(STR$(CH)) + ") = " + arr(CH)
69.     IF NOT goAgain THEN EXIT WHILE
70. WEND
71.  
72. CLS
73. _KEYCLEAR
74. 'see this file
75. REDIM fArr(500) AS STRING
76. lnCnt = fLines("getArrayItem v4 mbox.bas", fArr()) '<<<<<<<<<<<<<<<<<<< or whatever name you gave this file AND SAVED!
77. CLS
78. CH = getArrayItemNumber(5, 5, 140, 30, fArr())
79. LOCATE 1, 1: PRINT CH
80. END
81.  
82. ' Future Help Message Box for the function.
83. ' "*** Mouse and Key Instructions ***"
84. '
85. ' "Mouse, mouse wheel, and arrow keys should work as expected for item selection."
86. ' "Press spacebar to select a highlighted item or just click it."
87. ' "Use number(s) + enter to select an array item by it's index number,"
88. ' "backspace will remove last number pressed, c will clear a number started."
89. ' "Numbers started are shown in bottom right PgDn bar."
90. ' "Enter will also select the highlighted item, if no number has been started."
91. ' "Home starts you at lowest array index, End highlights then highest index."
92. ' "Use PgUp and PgDn keys to flip through pages of array items."
93. '
94. ' "Escape returns -1719 to allow a Cancel function and signal no slection."
95. FUNCTION getArrayItemNumber& (locateRow, locateColumn, boxWidth, boxHeight, arr() AS STRING)
96.     'Notes: locateRow, locateColumn for top right corner of selection box on screen in characters for LOCATE.
97.     'boxWidth and boxHeight are in character units, again for locate and print at correct places.
98.     'All displaying is restricted to inside the box, which has PgUP and PgDn as top and bottom lines in the display.
99.     '
100.     DIM maxWidth AS INTEGER, maxHeight AS INTEGER, page AS INTEGER, hlite AS INTEGER, mx AS INTEGER, my AS INTEGER
101.     DIM lba AS LONG, uba AS LONG, choice AS LONG
102.     maxWidth = boxWidth '       number of characters in box
103.     maxHeight = boxHeight - 2 ' number of lines displayed of array at one time = 1 page
104.     lba = LBOUND(arr)
105.     uba = UBOUND(arr)
106.     page = 0
107.     hlite = 0 '                 line in display ready for selection by spacebar or if no number is started, enter
108.     clrStr$ = SPACE$(maxWidth) 'clearing a display line
109.  
110.     GOSUB update '              show the beginning of the array items for selection
111.  
112.     'signal cancel selection process, exit sub with this unlikely index to signal canel
113.     choice = -1719 'primes 7 and 8, not likely to be a select index of an array
114.  
115.     DO 'until get a selection or demand exit
116.  
117.         'handle the key stuff
118.         kh& = _KEYHIT
119.         IF kh& THEN
120.             IF kh& > 0 AND kh& < 255 THEN
121.                 IF INSTR("0123456789", CHR$(kh&)) > 0 THEN b$ = b$ + CHR$(kh&): GOSUB update
122.                 IF CHR$(kh&) = "h" THEN HELP: _KEYCLEAR
123.  
124.                 IF CHR$(kh&) = "c" THEN b$ = "": GOSUB update
125.                 IF kh& = 13 THEN 'enter pressed check if number is being entered?
126.                     IF LEN(b$) THEN
127.                         IF VAL(b$) >= lba AND VAL(b$) <= uba THEN 'we have number started
128.                             choice = VAL(b$): EXIT DO
129.                         ELSE 'clear b$ to show some response to enter
130.                             b$ = "": GOSUB update 'clear the value that doesn't work
131.                         END IF
132.                     ELSE
133.                         choice = hlite + page * maxHeight + lba 'must mean to select the highlighted item
134.                     END IF
135.                 END IF
136.                 IF kh& = 27 THEN EXIT DO 'escape clause offered to Cancel selection process
137.                 IF kh& = 32 THEN choice = hlite + page * maxHeight + lba 'best way to choose highlighted selection
138.                 IF kh& = 8 THEN 'backspace to edit number
139.                     IF LEN(b$) THEN b$ = LEFT$(b$, LEN(b$) - 1): GOSUB update
140.                 END IF
141.             ELSE
142.                 SELECT CASE kh& 'choosing sections of array to display and highlighted item
143.                     CASE 20736 'pg dn
144.                         IF (page + 1) * maxHeight + lba <= uba THEN page = page + 1: GOSUB update
145.                     CASE 18688 'pg up
146.                         IF (page - 1) * maxHeight + lba >= lba THEN page = page - 1: GOSUB update
147.                     CASE 18432 'up
148.                         IF hlite - 1 < 0 THEN
149.                             IF page > 0 THEN
150.                                 page = page - 1: hlite = maxHeight - 1: GOSUB update
151.                             END IF
152.                         ELSE
153.                             hlite = hlite - 1: GOSUB update
154.                         END IF
155.                     CASE 20480 'down
156.                         IF (hlite + 1) + page * maxHeight + lba <= uba THEN 'ok to move up
157.                             IF hlite + 1 > maxHeight - 1 THEN
158.                                 page = page + 1: hlite = 0: GOSUB update
159.                             ELSE
160.                                 hlite = hlite + 1: GOSUB update
161.                             END IF
162.                         END IF
163.                     CASE 18176 'home
164.                         page = 0: hlite = 0: GOSUB update
165.                     CASE 20224 ' end
166.                         page = INT((uba - lba) / maxHeight): hlite = maxHeight - 1: GOSUB update
167.                 END SELECT
168.             END IF
169.         END IF
170.  
171.         'handle the mouse stuff
172.         WHILE _MOUSEINPUT
173.             IF _MOUSEWHEEL = -1 THEN 'up?
174.                 IF hlite - 1 < 0 THEN
175.                     IF page > 0 THEN
176.                         page = page - 1: hlite = maxHeight - 1: GOSUB update
177.                     END IF
178.                 ELSE
179.                     hlite = hlite - 1: GOSUB update
180.                 END IF
181.             ELSEIF _MOUSEWHEEL = 1 THEN 'down?
182.                 IF (hlite + 1) + page * maxHeight + lba <= uba THEN 'ok to move up
183.                     IF hlite + 1 > maxHeight - 1 THEN
184.                         page = page + 1: hlite = 0: GOSUB update
185.                     ELSE
186.                         hlite = hlite + 1: GOSUB update
187.                     END IF
188.                 END IF
189.             END IF
190.         WEND
191.         mx = INT((_MOUSEX - locateColumn * 8) / 8) + 2: my = INT((_MOUSEY - locateRow * 16) / 16) + 2
192.         IF _MOUSEBUTTON(1) THEN 'click contols or select array item
193.             _DELAY .2
194.             IF mx >= 1 AND mx <= maxWidth AND my >= 1 AND my <= maxHeight THEN
195.                 choice = my + page * maxHeight + lba - 1 'select item clicked
196.             ELSEIF mx >= 1 AND mx <= maxWidth AND my = 0 THEN 'page up or exit
197.                 IF my = 0 AND (mx <= maxWidth AND mx >= maxWidth - 2) THEN 'exit sign
198.                     EXIT DO 'escape plan for mouse click top right corner of display box
199.                 ELSE 'PgUp bar clicked
200.                     IF (page - 1) * maxHeight + lba >= lba THEN page = page - 1: GOSUB update
201.                 END IF
202.             ELSEIF mx >= 1 AND mx <= maxWidth AND my = maxHeight + 1 THEN 'page down bar clicked
203.                 IF (page + 1) * maxHeight + lba <= uba THEN page = page + 1: GOSUB update
204.             END IF
205.         ELSE '   mouse over highlighting, only if mouse has moved!
206.             IF mx >= 1 AND mx <= maxWidth AND my >= 1 AND my <= maxHeight THEN
207.                 IF mx <> lastmx OR my <> lastmy THEN
208.                     IF my - 1 <> hlite AND (my - 1 + page * maxHeight + lba <= uba) THEN
209.                         hlite = my - 1
210.                         lastmx = mx: lastmy = my
211.                         GOSUB update
212.                     END IF
213.                 END IF
214.             END IF
215.         END IF
216.         _LIMIT 200
217.     LOOP UNTIL choice >= lba AND choice <= uba
218.     getArrayItemNumber& = choice
219.     EXIT SUB
220.  
221.     'display of array sections and controls on screen
222.     update:
223.  
224.     'fix hlite if it has dropped below last array item
225.     WHILE hlite + page * maxHeight + lba > uba
226.         hlite = hlite - 1
227.     WEND
228.  
229.     'main display of array items at page * maxHeight (lines high)
230.     FOR row = 0 TO maxHeight - 1
231.         IF hlite = row THEN COLOR _RGB(200, 200, 255), _RGB32(0, 0, 88) ELSE COLOR _RGB32(0, 0, 88), _RGB(200, 200, 255)
232.         LOCATE locateRow + row, locateColumn: PRINT clrStr$
233.         index = row + page * maxHeight + lba
234.         IF index >= lba AND index <= uba THEN
235.             LOCATE locateRow + row, locateColumn
236.             PRINT LEFT$(LTRIM$(STR$(index)) + ") " + arr(index), maxWidth)
237.         END IF
238.     NEXT
239.  
240.     'make page up and down bars to click, print PgUp / PgDn if available
241.     COLOR _RGB32(200, 200, 255), _RGB32(0, 100, 50)
242.     LOCATE locateRow - 1, locateColumn: PRINT SPACE$(maxWidth)
243.     IF page <> 0 THEN LOCATE locateRow - 1, locateColumn: PRINT LEFT$(" Pg Up" + SPACE$(maxWidth), maxWidth)
244.     LOCATE locateRow + maxHeight, locateColumn: PRINT SPACE$(maxWidth)
245.     IF page <> INT(uba / maxHeight) THEN
246.         LOCATE locateRow + maxHeight, locateColumn: PRINT LEFT$(" Pg Dn" + SPACE$(maxWidth), maxWidth)
247.     END IF
248.     'make exit sign for mouse click
249.     COLOR _RGB32(255, 255, 255), _RGB32(200, 100, 0)
250.     LOCATE locateRow - 1, locateColumn + maxWidth - 3
251.     PRINT " X "
252.  
253.     'if a number selection has been started show it's build = b$
254.     IF LEN(b$) THEN
255.         COLOR _RGB(255, 255, 0), _RGB32(0, 0, 0)
256.         LOCATE locateRow + maxHeight, locateColumn + maxWidth - LEN(b$) - 1
257.         PRINT b$;
258.     END IF
259.     _DISPLAY
260.     _LIMIT 100
261.     RETURN
262. END FUNCTION
263.  
264. '                              These are needed only for the demo and testing of the function:
265. '  It should be noted I had trouble using INPUT and INKEY$ after using the function being tested, ie inquiring about another test.
266. '                              Something about clearing keypresses (and enter specially).
267. FUNCTION goAgain% ()
268.     WHILE LEN(INKEY$): WEND 'clear inkey$
269.     PRINT: cp "Go again? press y for yes, any other for no."
270.     k$ = ""
271.     WHILE k$ = "": k$ = INKEY$: WEND
272.     IF k$ = "y" THEN goAgain% = -1
273. END FUNCTION
274.  
275. SUB cp (s$)
276.     LOCATE CSRLIN, (WW / 8 - LEN(s$)) / 2: PRINT s$
277. END SUB
278.  
279. FUNCTION fLines (fileName$, arr() AS STRING)
280.     filecount% = 0
281.     IF _FILEEXISTS(fileName$) THEN
282.         OPEN fileName$ FOR INPUT AS #1
283.         DO UNTIL EOF(1)
284.             LINE INPUT #1, arr(filecount%)
285.             'PRINT filecount%, arr(filecount%)
286.             filecount% = filecount% + 1
287.         LOOP
288.         CLOSE #1
289.         REDIM _PRESERVE arr(filecount% - 1)
290.     END IF
291.     fLines = filecount% 'this file returns the number of lines loaded, 0 means file did not exist
292. END FUNCTION
293.  
294. SUB HELP
295.     n$ = CHR$(10)
296.     t$ = "*** Mouse and Key Instructions ***"
297.     m$ = "Mouse, mouse wheel, and arrow keys should work as expected for item selection." + n$
298.     m$ = m$ + "Press spacebar to select a highlighted item or just click it." + n$
299.     m$ = m$ + "Use number(s) + enter to select an array item by it's index number," + n$
300.     m$ = m$ + "backspace will remove last number pressed, c will clear a number started." + n$
301.     m$ = m$ + "Numbers started are shown in bottom right PgDn bar." + n$
302.     m$ = m$ + "Enter will also select the highlighted item, if no number has been started." + n$
303.     m$ = m$ + "Home starts you at lowest array index, End highlights then highest index." + n$
304.     m$ = m$ + "Use PgUp and PgDn keys to flip through pages of array items." + n$ + n$
305.     m$ = m$ + "Escape (returns -1719) to allow a Cancel function and signal no slection."
306.     mBox m$, t$
307. END SUB
308.  
309. 'title$ limit is 57 chars, all lines are 58 chars max
310. ' version bak 2018-09-07_3P
311. 'title$ limit is 57 chars, all lines are 58 chars max
312. ' version bak 2018-09-07_3P < fixing this version as it does not work well in another app
313. SUB mBox (m$, title$)
314.  
315.     'using const WW for Window Width, WH for Window Height
316.     DIM curScrn AS LONG, backScrn AS LONG, mbx AS LONG 'some handles
317.     DIM ti AS INTEGER, limit AS INTEGER 'ti = test index for t$(), limit is number of chars per line
318.     DIM i AS INTEGER, j AS INTEGER, ff AS _BIT, add AS _BYTE 'index, flag and
319.     DIM bxH AS INTEGER, bxW AS INTEGER 'first as cells then as pixels
320.     DIM mb AS INTEGER, mx AS INTEGER, my AS INTEGER, mi AS INTEGER, grabx AS INTEGER, graby AS INTEGER
321.     DIM tlx AS INTEGER, tly AS INTEGER 'top left corner of message box
322.     DIM lastx AS INTEGER, lasty AS INTEGER
323.  
324.     'screen snapshot
325.     curScrn = _DEST
326.     backScrn = _NEWIMAGE(WW, WH, 32)
327.     _PUTIMAGE , curScrn, backScrn
328.  
329.     'setup t$() to store strings with ti as index, linit 58 chars per line max, b$ is for build
330.     REDIM t$(0): ti = 0: limit = 58: b$ = ""
331.     FOR i = 1 TO LEN(m$)
332.         c$ = MID$(m$, i, 1)
333.         'are there any new line signals, CR, LF or both? take CRLF or LFCR as one break but dbl LF or CR means blank line
334.         SELECT CASE c$
335.             CASE CHR$(13) 'load line
336.                 IF MID$(m$, i + 1, 1) = CHR$(10) THEN i = i + 1
337.                 t$(ti) = b$: b$ = "": ti = ti + 1: REDIM _PRESERVE t$(ti)
338.             CASE CHR$(10)
339.                 IF MID$(m$, i + 1, 1) = CHR$(13) THEN i = i + 1
340.                 t$(ti) = b$: b$ = "": ti = ti + 1: REDIM _PRESERVE t$(ti)
341.             CASE ELSE
342.                 IF c$ = CHR$(9) THEN c$ = SPACE$(4): add = 4 ELSE add = 1
343.                 IF LEN(b$) + add > limit THEN
344.                     tail$ = "": ff = 0
345.                     FOR j = LEN(b$) TO 1 STEP -1 'backup until find a space, save the tail end for next line
346.                         d$ = MID$(b$, j, 1)
347.                         IF d$ = " " THEN
348.                             t$(ti) = MID$(b$, 1, j - 1): b$ = tail$ + c$: ti = ti + 1: REDIM _PRESERVE t$(ti)
349.                             ff = 1 'found space flag
350.                             EXIT FOR
351.                         ELSE
352.                             tail$ = d$ + tail$ 'the tail grows!
353.                         END IF
354.                     NEXT
355.                     IF ff = 0 THEN 'no break? OK
356.                         t$(ti) = b$: b$ = c$: ti = ti + 1: REDIM _PRESERVE t$(ti)
357.                     END IF
358.                 ELSE
359.                     b$ = b$ + c$ 'just keep building the line
360.                 END IF
361.         END SELECT
362.     NEXT
363.     t$(ti) = b$
364.     bxH = ti + 3: bxW = limit + 2
365.  
366.     'draw message box
367.     mbx = _NEWIMAGE(60 * 8, (bxH + 1) * 16, 32)
368.     _DEST mbx
369.     COLOR _RGB32(60, 40, 25), _RGB32(225, 225, 255)
370.     LOCATE 1, 1: PRINT LEFT$(SPACE$((bxW - LEN(title$) - 3) / 2) + title$ + SPACE$(bxW), bxW)
371.     COLOR _RGB32(225, 225, 255), _RGB32(200, 0, 0)
372.     LOCATE 1, bxW - 2: PRINT " X "
373.     COLOR _RGB32(60, 40, 25), _RGB32(255, 160, 90)
374.     LOCATE 2, 1: PRINT SPACE$(bxW);
375.     FOR r = 0 TO ti
376.         LOCATE 1 + r + 2, 1: PRINT LEFT$(" " + t$(r) + SPACE$(bxW), bxW);
377.     NEXT
378.     LOCATE 1 + bxH, 1: PRINT SPACE$(limit + 2);
379.  
380.     'now for the action
381.     _DEST curScrn
382.  
383.     'convert to pixels the top left corner of box at moment
384.     bxW = bxW * 8: bxH = bxH * 16
385.     tlx = (WW - bxW) / 2: tly = (WH - bxH) / 2
386.     lastx = tlx: lasty = tly
387.     'now allow user to move it around or just read it
388.     WHILE _KEYDOWN(27) = 0 AND _KEYDOWN(13) = 0 AND _KEYDOWN(32) = 0
389.         CLS
390.         _PUTIMAGE , backScrn
391.         _PUTIMAGE (tlx, tly)-STEP(bxW, bxH), mbx, curScrn
392.         _DISPLAY
393.         WHILE _MOUSEINPUT: WEND
394.         mx = _MOUSEX: my = _MOUSEY: mb = _MOUSEBUTTON(1)
395.         IF mb THEN
396.             IF mx >= tlx AND mx <= tlx + bxW AND my >= tly AND my <= tly + 16 THEN 'mouse down on title bar
397.                 IF mx >= tlx + bxW - 24 THEN EXIT WHILE
398.                 grabx = mx - tlx: graby = my - tly
399.                 DO WHILE mb 'wait for release
400.                     mi = _MOUSEINPUT: mb = _MOUSEBUTTON(1)
401.                     mx = _MOUSEX: my = _MOUSEY
402.                     IF mx - grabx >= 0 AND mx - grabx <= WW - bxW AND my - graby >= 0 AND my - graby <= WH - bxH THEN
403.                         'attempt to speed up with less updates
404.                         IF ((lastx - (mx - grabx)) ^ 2 + (lasty - (my - graby)) ^ 2) ^ .5 > 10 THEN
405.                             tlx = mx - grabx: tly = my - graby
406.                             CLS
407.                             _PUTIMAGE , backScrn
408.                             _PUTIMAGE (tlx, tly)-STEP(bxW, bxH), mbx, curScrn
409.                             lastx = tlx: lasty = tly
410.                             _DISPLAY
411.                         END IF
412.                     END IF
413.                     _LIMIT 400
414.                 LOOP
415.             END IF
416.         END IF
417.         _LIMIT 400
418.     WEND
419.     COLOR _RGB32(255, 255, 255), _RGB32(0, 0, 0): CLS
420.     _PUTIMAGE , backScrn
421.     _FREEIMAGE backScrn
422.     _FREEIMAGE mbx
423.     _DISPLAY
424. END SUB
425.  

And here is a snap of the distorted text:
 

[FellippeHeitor]

When you _PUTIMAGE with STEP, make sure it's width minus 1 and height minus 1.

[bplus]

When you _PUTIMAGE with STEP, make sure it's width minus 1 and height minus 1.

That didn't work but this did the trick!

Code: QB64: [Select]

1.  _PUTIMAGE (tlx, tly), mbx, curScrn

Get rid of the bottom corner / 2nd coordinate altogether.

Thanks, I hadn't a clue what to fiddle with.