Re: Screen 0 as LED

[TerryRitchie]

Cool! I like the marching robot.

[FellippeHeitor]

Wait, wait, wait... "Buddy the Robot"? Is that Norby's last name? Norby Buddy the Robot?

[bplus]

That is fun!

[codeguy]

I liked it too:
modified to be self-contained for inclusion in QB64 Demos, perhaps.

Code: QB64: [Select]

1.  
2. _TITLE "Screen 0 as LED"
3.  
4. CONST ROUND = 0, SQUARE = 1
5.  
6. TYPE Sign
7.     Screen AS LONG ' the Sign screen to show on screen
8.     Image AS LONG '  the Sign image to work on in the background
9.     Mask AS LONG '   the Sign mask to place over the Sign image
10. END TYPE
11.  
12. DIM SHARED Sign AS Sign
13.  
14. MAKELED 640, 400, 2, ROUND
15.  
16. DIM SHARED Parts(46) AS STRING
17. 'OPEN "Robot.dat" FOR INPUT AS #1
18.  
19. FOR p = 1 TO 45
20.     READ Parts(p)
21. NEXT
22.  
23. CLOSE #1
24.  
25. SCREEN Sign.Screen
26.  
27. Start = Main
28.  
29. FUNCTION Main
30.     DIM Touch AS STRING
31.  
32.     DIM Title AS STRING
33.     Title = SPACE$(80) + "Screen 0 as LED using code from Terry Ritchie's LED Maker. "
34.  
35.     tPos = 1
36.     WHILE NOT Quit
37.         _DEST Sign.Image
38.         COLOR _RGB(0, 255, 255)
39.  
40.         LOCATE 1, 1
41.         PRINT MID$(Title, tPos, 80);
42.  
43.         AnimBot
44.  
45.         _DEST 0
46.         _PUTIMAGE , Sign.Image
47.         _PUTIMAGE , Sign.Mask
48.  
49.         tPos = tPos + 1
50.         IF tPos > LEN(Title) THEN tPos = 1
51.  
52.         Touch = INKEY$
53.         IF Touch = CHR$(27) THEN SYSTEM
54.  
55.         _DISPLAY
56.         _LIMIT 10
57.     WEND
58. END FUNCTION
59.  
60. SUB AnimBot
61.     ' Save Arm and Leg Positions
62.     SHARED arm
63.     SHARED leg
64.  
65.     DIM temp AS STRING
66.  
67.     ' Get Arm and Leg Positions
68.     temp = MID$("0010203020100102030201", 2 * arm + 1, 2)
69.  
70.     b1 = VAL(LEFT$(temp, 1))
71.     b2 = VAL(RIGHT$(temp, 1))
72.  
73.     ' Show Buddy the Robot
74.     Buddy 20, 1, 1, 1, b1, b2, b2, b1
75.  
76.     ' Increase his Arm and Leg Positions
77.     arm = arm + 1: IF arm > 10 THEN arm = 0
78.     leg = leg + 1: IF leg > 10 THEN leg = 0
79. END SUB
80.  
81. SUB MAKELED (w AS INTEGER, h AS INTEGER, pSize AS INTEGER, pShape AS INTEGER)
82.     DIM x AS INTEGER
83.     DIM y AS INTEGER
84.  
85.     DIM c AS INTEGER
86.     c = 8
87.  
88.     DIM LEDPixel AS LONG
89.     DIM OriginalDest AS LONG
90.     OriginalDest = _DEST
91.  
92.     Sign.Screen = _NEWIMAGE(w * pSize, h * pSize, 32)
93.     Sign.Image = _NEWIMAGE(w, h, 32)
94.     Sign.Mask = _COPYIMAGE(Sign.Screen)
95.     LEDPixel = _NEWIMAGE(pSize, pSize, 32)
96.  
97.     _DEST LEDPixel
98.     LINE (0, 0)-(pSize - 1, pSize - 1), _RGB32(c, c, c), BF
99.  
100.     SELECT CASE pShape
101.         CASE ROUND
102.             CIRCLE (pSize \ 2, pSize \ 2), pSize \ 2 - 1, _RGB32(0, 0, 2)
103.             PAINT (pSize \ 2, pSize \ 2), _RGB32(0, 0, 1), _RGB32(0, 0, 2)
104.  
105.         CASE SQUARE
106.             LINE (1, 1)-(pSize - 1, pSize - 1), _RGB32(0, 0, 2), B
107.             LINE (2, 2)-(pSize - 2, pSize - 2), _RGB32(0, 0, 1), BF
108.     END SELECT
109.  
110.     _DEST Sign.Mask
111.     FOR x = 0 TO w * pSize - 1 STEP pSize
112.         FOR y = 0 TO h * pSize - 1 STEP pSize
113.             _PUTIMAGE (x, y), LEDPixel&
114.         NEXT y
115.     NEXT x
116.  
117.     FOR x = 0 TO w * pSize - 1 STEP pSize * 8
118.         LINE (x, 0)-(x, h * pSize - 1), _RGB32(c, c, c)
119.     NEXT x
120.  
121.     FOR y = 0 TO h * pSize - 1 STEP pSize * 8
122.         LINE (0, y)-(w * pSize - 1, y), _RGB32(c, c, c)
123.     NEXT y
124.  
125.     _SETALPHA 0, _RGB32(0, 0, 1)
126.     _SETALPHA 63, _RGB32(0, 0, 2)
127.  
128.     _DEST OriginalDest
129.     _FREEIMAGE LEDPixel
130. END SUB
131.  
132. SUB Scroll (Text AS STRING)
133.     DIM Touch AS STRING
134.  
135.     DIM Title AS STRING
136.     Title = SPACE$(16) + "Multi-Line LED "
137.  
138.     DIM tPos AS INTEGER
139.     textPos = 1
140.     titlePos = 1
141.  
142.     WHILE tPos < LEN(Text)
143.         _DEST Sign.Image
144.         COLOR _RGB32(255, 215, 32)
145.  
146.         LOCATE 1, 1
147.         PRINT MID$(Title, titlePos, 16);
148.  
149.         LOCATE 2, 1
150.         PRINT MID$(Text, textPos, 16);
151.  
152.         _DEST 0
153.         _PUTIMAGE , Sign.Image
154.         _PUTIMAGE , Sign.Mask
155.  
156.         textPos = textPos + 1
157.         titlePos = titlePos + 1
158.         IF titlePos > 31 THEN titlePos = 1
159.  
160.         Touch = INKEY$
161.         IF Touch = CHR$(27) THEN SYSTEM
162.  
163.         _DISPLAY
164.         _LIMIT 6
165.     WEND
166. END SUB
167.  
168. SUB Buddy (botX, botY, headV, bodyV, ArmV1, ArmV2, LegV1, LegV2)
169.     COLOR _RGB(255, 218, 185)
170.  
171.     ' Head
172.     FOR head = 1 TO 6
173.         LOCATE botY + (head - 1), botX + 8
174.         PRINT MID$(Parts(head), 24 * headV + 1, 24);
175.     NEXT
176.  
177.     ' Body
178.     FOR body = 7 TO 19
179.         LOCATE botY + (body - 1), botX + 7
180.         PRINT MID$(Parts(body), 26 * bodyV + 1, 26);
181.     NEXT
182.  
183.     ' Arms
184.     FOR arm = 20 TO 29
185.         ' Left Arm
186.         LOCATE botY + (arm - 13), botX
187.         PRINT MID$(Parts(arm), 7 * ArmV1 + 1, 7);
188.  
189.         ' Right Arm
190.         LOCATE botY + (arm - 13), botX + 33
191.         PRINT MID$(Parts(arm + 10), 7 * ArmV2 + 1, 7);
192.     NEXT
193.  
194.     ' Legs
195.     FOR leg = 40 TO 45
196.         ' Left Leg
197.         LOCATE botY + (leg - 21), botX + 10
198.         PRINT MID$(Parts(leg), 10 * LegV1 + 1, 10);
199.  
200.         ' Right Leg
201.         LOCATE botY + (leg - 21), botX + 20
202.         PRINT MID$(Parts(leg), 10 * LegV2 + 1, 10);
203.     NEXT
204.  
205.     ' Eyes
206.     COLOR _RGB(135, 206, 235)
207.     LOCATE botY + 1, botX + 15: PRINT "0";
208.     LOCATE botY + 1, botX + 24: PRINT "0";
209. END SUB
210.  
211. DATA "     .---.    .---.          .---.    .---."
212. DATA "    |     |__|     |        (((0)))--(((0)))"
213. DATA " _.'                `._  _.'_`---'_/\_`---'_`._"
214. DATA "|_:                  :_||_:   ____________   :_|"
215. DATA "  |                  |    |   \__________/   |"
216. DATA "  |__________________|    |__________________|"
217. DATA "__..-'              `-..____..-'              `-..____..-'              `-..__"
218. DATA " |                      |  | .------------------. |  | .------------------. |"
219. DATA " |                      |  | |\________________/| |  | |\________________/| |"
220. DATA " |                      |  | ||   __  __  __   || |  | ||                || |"
221. DATA ".|                      |..| ||  '--''--''--'  || |..| ||                || |."
222. DATA " |                      |  | ||  .----------.  || |  | ||                || |"
223. DATA " |                      |  | ||  `----------'  || |  | ||                || |"
224. DATA " |                      |  | ||   _        _   || |  | ||                || |"
225. DATA " |                      |  | ||  (_)  ()  (_)  || |  | ||                || |"
226. DATA " |                      |  | ||________________|| |  | ||________________|| |"
227. DATA " |                      |  | |/________________\| |  | |/________________\| |"
228. DATA " |______________________|  |______________________|  |______________________|"
229. DATA " `\____________________/'  `\____________________/'  `\____________________/'"
230. DATA "    .-|    .-|    .-|    .-|"
231. DATA "  ./ :|  ./ :|  ./ :|  ./ :|"
232. DATA " /`.\:| /`.\:| /`.\:| /`.\:|"
233. DATA "|`-._\:|`-._\:|`-._\:|`-._\:"
234. DATA ":    : |    | |    | :.--.:"
235. DATA "|    | |    | :.--.: (`-'|)"
236. DATA "|    | :.--.: (`-'|)  `--'"
237. DATA ":.--.: (`-'|)  `--'"
238. DATA "(`-'|)  `--'"
239. DATA " `--'"
240. DATA "|-.    |-.    |-.    |-."
241. DATA "|: \.  |: \.  |: \.  |: \."
242. DATA "|:/,'\ |:/,'\ |:/,'\ |:/,'\"
243. DATA ":/_.-'::/_.-'::/_.-'::/_.-':"
244. DATA " :    : |    | |    | :,--.:"
245. DATA " |    | |    | :,--.: (|`-')"
246. DATA " |    | :,--.: (|`-')  `--'"
247. DATA " :,--.: (|`-')  `--'"
248. DATA " (|`-')  `--'"
249. DATA "  `--'"
250. DATA " (______)  (______)  (______)  (______)"
251. DATA " (______)  (______)  (______) |        |"
252. DATA " (______)  (______) |        |`--------'"
253. DATA " (______) |        |`--------'"
254. DATA "|        |`--------'"
255. DATA "`--------'"
256.  

Thanks to Terry and [banned user] for the entertainment.

[SMcNeill]

A quick toss of my hat into the LED emulation game:

Code: QB64: [Select]

1. DEFLNG A-Z
2.  
3.  
4. CONST W = 800, H = 600
5. DIM SHARED WorkScreen
6. DisplayScreen = _NEWIMAGE(W, H, 32)
7. SCREEN DisplayScreen
8.  
9.  
10.  
11. size = 10 'A nice size to start testing with
12. message$ = "Testing the code" 'A default message.  Feel free to change it.
13. kolor = _RGB32(255, 255, 0) 'And the color of our LED
14.  
15. GenerateWorkscreen size, message$, kolor
16.  
17. DO
18.     CLS
19.     _LIMIT 30
20.     k = _KEYHIT
21.     DisplayWorkscreen StartX, StartY
22.     SELECT CASE k
23.         CASE 19200 'left
24.             StartX = StartX - size: IF StartX < 0 THEN StartX = 0
25.         CASE 19712 'right
26.             StartX = StartX + size
27.             IF StartX > _WIDTH(WorkScreen) - _WIDTH THEN StartX = _WIDTH(WorkScreen) - _WIDTH
28.             IF StartX < 0 THEN StartX = 0
29.         CASE 18432 'up
30.             size = size + 1
31.             GenerateWorkscreen size, message$, kolor
32.         CASE 20480 'down
33.             size = size - 1: IF size < 1 THEN size = 1
34.             GenerateWorkscreen size, message$, kolor
35.         CASE 27, 32
36.             SYSTEM
37.     END SELECT
38.  
39.     _DISPLAY
40. LOOP
41.  
42. SUB DisplayWorkscreen (StartX, StartY)
43.     _PUTIMAGE (0, 0)-(_WIDTH - 1, _HEIGHT - 1), WorkScreen, Displayscreen, (StartX, StartY)-STEP(_WIDTH - 1, _HEIGHT - 1)
44. END SUB
45.  
46.  
47. SUB GenerateWorkscreen (size, message$, kolor)
48.     d = _DEST: s = _SOURCE 'play nice code
49.     IF WorkScreen THEN _FREEIMAGE WorkScreen
50.     WorkScreen = _NEWIMAGE(size * _FONTWIDTH * LEN(message$), size * _FONTHEIGHT, 32)
51.     'create ASCII characters
52.     AW = _FONTWIDTH * LEN(message$): AH = _FONTHEIGHT
53.     ASCII = _NEWIMAGE(AW, AH, 32)
54.     _DEST ASCII: _SOURCE ASCII
55.     _CONTROLCHR OFF
56.     COLOR -1, 0
57.     PRINT message$;
58.     _DEST WorkScreen
59.     FOR x = 0 TO AW - 1
60.         FOR y = 0 TO AH - 1
61.             IF POINT(x, y) THEN CircleFill x * size, y * size, size / 2 - 1, kolor
62.         NEXT
63.     NEXT
64.     _FREEIMAGE ASCII
65.     _DEST d: _SOURCE s 'to play nice with other routines
66. END SUB
67.  
68. SUB CircleFill (CX AS LONG, CY AS LONG, R AS LONG, C AS LONG)
69.     DIM Radius AS LONG, RadiusError AS LONG
70.     DIM X AS LONG, Y AS LONG
71.  
72.     Radius = ABS(R)
73.     RadiusError = -Radius
74.     X = Radius
75.     Y = 0
76.  
77.     IF Radius = 0 THEN PSET (CX, CY), C: EXIT SUB
78.  
79.     ' Draw the middle span here so we don't draw it twice in the main loop,
80.     ' which would be a problem with blending turned on.
81.     LINE (CX - X, CY)-(CX + X, CY), C, BF
82.  
83.     WHILE X > Y
84.         RadiusError = RadiusError + Y * 2 + 1
85.         IF RadiusError >= 0 THEN
86.             IF X <> Y + 1 THEN
87.                 LINE (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
88.                 LINE (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
89.             END IF
90.             X = X - 1
91.             RadiusError = RadiusError - X * 2
92.         END IF
93.         Y = Y + 1
94.         LINE (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
95.         LINE (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
96.     WEND
97. END SUB
98.  

Three import variables which you can change to play around with things:

size = 10 'A nice size to start testing with
message$ = "Testing the code" 'A default message.  Feel free to change it.
kolor = _RGB32(255, 255, 0) 'And the color of our LED

And a few basic controls:
UP/DOWN arrow keys will increase/decrease the size of the LEDs.
LEFT/RIGHT will scroll the screen so you can view any portion of the message which is currently off-screen.
SPACE/ESC will end the program

**********************

With just a little modification, one could make this an automatic scrolling routine, make the lights blink/flicker, or use it for multi-line displays (like with Buddy)...   The sky's the limit!!