Author Topic: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus (Read 3504 times)

TempodiBasic · « **on:** September 01, 2018, 08:11:12 pm »

Hi Bplus

your thinking about map and movement have brougth me to combine square cell to octagonal movements....

Quote

I have just realized a problem with bitwise walls, it is incompatible to diagonal movements and thusly the Pathfinder problem that was part of what got me going with maps.

Maybe walls:
north = 1
northeast = 2
east = 4
southeast = 8
south = 16
southwest = 32
west = 64
north west = 128

so see this code....

Code: QB64: [Select]

_TITLE "B+ Flying Hero Mod of TempodiBasic Trap Mod of Terri Ritchie Simple Map Demo, 2018-08-21"
 
'*
'* Bitwise math demonstration
'*
'* Draws a simple map and allows player to move circle within map
'* rapresentation using a clockwise power of 2 for each segment first the 4 basilar
'*   and then the 4 diagonal   for optional directions
'* as       picture      power of 2 (2^n)         result of 2^n
'*            __            0                          1                     N
'*           /  \          7 4                      128  16               NE   NW
'*           |  |         3   1                    8       2             E       W
'*           \  /          6 5                      64   32               SE   SW
'*            --            2                          4                     S
 
'* example of how the value of cell in the map changes using octagonal movement controls
 
'*  a closed box    squared wall scoring        octagonal wall scoring
'*      --          1+2+4+8= 15                  1+2+4+8+ 16+32+64+128=255
'*     |  |
'*      --
'*  a U box    squared wall scoring        octagonal wall scoring
'*                 2+4+8= 14                  2+4+8+ 32+64+128+16=
'*     |  |        or 15 - 1 = 14               14 +  oblique directions forbidden
'*      --
'*  a C box    squared wall scoring        octagonal wall scoring
'*      --          1+4+8= 13                  1+4+8+ 64+128=205 moving NW W SW
'*     |            or 15-2 =13
'*      --
'*
'* squared wall      15  14   13  12  11 10   9   8  7  6  5  4  3  2  1 0
'*
 
'--------------------------------
'- Variable Declaration Section -
'--------------------------------
DEFSNG A-Z
'Window
CONST WW = 800 'Width
CONST WH = 600 'Height
 
'Map active arena
CONST MAPW = 5 'Width
CONST MAPH = 5 'Height
CONST SQ = 50 'Tile size
 
'special powers
CONST ONN = 1, OFFF = 0
 
'key codes
CONST UP = 18432
CONST DOWN = 20480
CONST LEFT = 19200
CONST RIGHT = 19712
CONST ESC = 27
CONST SPACE = 32
 
TYPE MAP '             set up map cell structure
    x AS INTEGER '     upper left x coordinate of cell
    y AS INTEGER '     upper left y coordinate of cell
    walls AS INTEGER ' identifies cell walls
END TYPE
 
TYPE HeroType
    X AS INTEGER
    Y AS INTEGER
    DX AS INTEGER
    DY AS INTEGER
END TYPE
 
DIM SHARED MAP(-100 TO MAPW + 100, -100 TO MAPH + 100) AS MAP
DIM SHARED XOFF, YOFF, FLAP, H AS HeroType
 
'get ready
XOFF = (WW - MAPW * SQ) / 2 - SQ
YOFF = (WH - MAPH * SQ) / 2 - SQ
H.X = 1: H.Y = 1
 
DIM SHARED RAT AS HeroType
RAT.X = 1: RAT.Y = 1
RAT.DX = 0: RAT.DY = 1 'moving right need these for heading calulations for drawing
 
DIM KH& '        player key presses
DIM MagicKey '        Magic Key to across the walls
 
 
'----------------------------
'- Main Program Begins Here -
'----------------------------
 
SCREEN _NEWIMAGE(WW, WH, 32) '                                  create 250x250 32bit screen
CLS '                                                             clear the screen
DRAWMAP '
 
DO '                                                              MAIN LOOP begins here
    PCOPY 1, 0 '                                                  copy page 1 to current screen
    DrawHero MagicKey
    'diagonal movements are managed here
    IF _KEYDOWN(LEFT) AND _KEYDOWN(DOWN) THEN
        LOCATE 1, 1: COLOR _RGB(255, 0, 0): PRINT "DOWN+LEFT":
        IF (NOT MAP(RAT.X, RAT.Y).walls AND 64) OR MagicKey THEN RAT.X = RAT.X - 1: RAT.Y = RAT.Y + 1: RAT.DX = -1: RAT.DY = 1
    END IF
    IF _KEYDOWN(UP) AND _KEYDOWN(LEFT) THEN
        LOCATE 1, 1: COLOR _RGB(255, 0, 0): PRINT "UP+LEFT":
        IF (NOT MAP(RAT.X, RAT.Y).walls AND 128) OR MagicKey THEN RAT.X = RAT.X - 1: RAT.Y = RAT.Y - 1: RAT.DX = -1: RAT.DY = -1
    END IF
 
    IF _KEYDOWN(RIGHT) AND _KEYDOWN(DOWN) THEN
        LOCATE 1, 1: COLOR _RGB(255, 0, 0): PRINT "DOWN+RIGHT":
        IF (NOT MAP(RAT.X, RAT.Y).walls AND 32) OR MagicKey THEN RAT.X = RAT.X + 1: RAT.Y = RAT.Y + 1: RAT.DX = 1: RAT.DY = 1
    END IF
 
    IF _KEYDOWN(UP) AND _KEYDOWN(RIGHT) THEN
        LOCATE 1, 1: COLOR _RGB(255, 0, 0): PRINT "UP+RIGHT"
        IF (NOT MAP(RAT.X, RAT.Y).walls AND 16) OR MagicKey THEN RAT.X = RAT.X + 1: RAT.Y = RAT.Y - 1: RAT.DX = 1: RAT.DY = -1
    END IF
 
 
    'previous key's commands are managed here
    IF _KEYDOWN(ESC) THEN SYSTEM
    IF _KEYDOWN(SPACE) THEN IF MagicKey = OFFF THEN MagicKey = ONN ELSE MagicKey = OFFF
    IF _KEYDOWN(UP) THEN IF (NOT MAP(RAT.X, RAT.Y).walls AND 1) OR MagicKey THEN RAT.Y = RAT.Y - 1: RAT.DX = 0: RAT.DY = -1
    IF _KEYDOWN(RIGHT) THEN IF (NOT MAP(RAT.X, RAT.Y).walls AND 2) OR MagicKey THEN RAT.X = RAT.X + 1: RAT.DX = 1: RAT.DY = 0
    IF _KEYDOWN(DOWN) THEN IF (NOT MAP(RAT.X, RAT.Y).walls AND 4) OR MagicKey THEN RAT.Y = RAT.Y + 1: RAT.DX = 0: RAT.DY = 1
    IF _KEYDOWN(LEFT) THEN IF (NOT MAP(RAT.X, RAT.Y).walls AND 8) OR MagicKey THEN RAT.X = RAT.X - 1: RAT.DX = -1: RAT.DY = 0
 
    _DISPLAY '                                                    update the screen without flicker
 
    DO: LOOP UNTIL _KEYHIT = 0 ' clear buffer of keyboard
    FLAP = FLAP + 1 MOD 60
    _LIMIT 10 'save the fan!
LOOP '                                                            MAIN LOOP back
 
'-----------------------------------
'- Function and Subroutine section -
'-----------------------------------
SUB DrawHero (Status)
    DIM heading AS SINGLE
    rx = RAT.X * SQ + .5 * SQ + XOFF
    ry = RAT.Y * SQ + .5 * SQ + YOFF
    rr = .2 * SQ
    IF Status THEN rc& = _RGB32(50, 100, 200) ELSE rc& = _RGB32(200, 100, 50)
    heading = _ATAN2(RAT.DY, RAT.DX)
    noseX = rx + 2 * rr * COS(heading)
    noseY = ry + 2 * rr * SIN(heading)
    neckX = rx + .75 * rr * COS(heading)
    neckY = ry + .75 * rr * SIN(heading)
    tailX = rx + 2 * rr * COS(heading + _PI)
    tailY = ry + 2 * rr * SIN(heading + _PI)
    earLX = rx + rr * COS(heading - _PI(1 / 12))
    earLY = ry + rr * SIN(heading - _PI(1 / 12))
    earRX = rx + rr * COS(heading + _PI(1 / 12))
    earRY = ry + rr * SIN(heading + _PI(1 / 12))
    fcirc rx, ry, .65 * rr, rc&
    fcirc neckX, neckY, rr * .3, rc&
    ftri noseX, noseY, earLX, earLY, earRX, earRY, rc&
    fcirc earLX, earLY, rr * .3, rc&
    fcirc earRX, earRY, rr * .3, rc&
    wX = .5 * rr * COS(heading - _PI(11 / 18))
    wY = .5 * rr * SIN(heading - _PI(11 / 18))
    LINE (noseX + wX, noseY + wY)-(noseX - wX, noseY - wY), rc&
    wX = .5 * rr * COS(heading - _PI(7 / 18))
    wY = .5 * rr * SIN(heading - _PI(7 / 18))
    LINE (noseX + wX, noseY + wY)-(noseX - wX, noseY - wY), rc&
    LINE (rx, ry)-(tailX, tailY), rc&
    IF Status AND (FLAP MOD 60 > 10) THEN 'how about some wings?
        wingx = rx + .25 * rr * COS(heading)
        wingy = ry + .25 * rr * SIN(heading)
        pieSlice wingx, wingy, 4 * rr, heading + _PI(.5) - _PI(1 / 24), heading + _PI(.5) + _PI(1 / 6), _RGB32(0, 255, 255)
        pieSlice wingx, wingy, 4 * rr, heading - _PI(.5) - _PI(1 / 6), heading - _PI(.5) + _PI(1 / 24), _RGB32(0, 255, 255)
        PAINT (wingx + 2 * rr * COS(heading + _PI(.5)), wingy + 2 * rr * SIN(heading + _PI(.5))), _RGBA32(10, 255, 255, 255), _RGB32(0, 255, 255)
        PAINT (wingx + 2 * rr * COS(heading - _PI(.5)), wingy + 2 * rr * SIN(heading - _PI(.5))), _RGBA32(10, 255, 255, 255), _RGB32(0, 255, 255)
    END IF
END SUB
 
SUB DRAWMAP ()
 
    '*
    '* draws a map based on the value of each map cell
    '*
 
    DIM x, y '          x,y map coordinates
 
    FOR y = 1 TO MAPH '                                                 cycle through map rows
        FOR x = 1 TO MAPW '                                             cycle through map columns
            READ MAP(x, y).walls '                                  read wall DATA
            MAP(x, y).x = x * SQ + XOFF '                                 compute upper left x coordinate of cell
            MAP(x, y).y = y * SQ + YOFF '                                 compute upper left y coordinate of cell
            IF MAP(x, y).walls AND 1 THEN '                         is NORTH wall present?
                LINE (MAP(x, y).x, MAP(x, y).y)-STEP(SQ - 1, 0), _RGB32(255, 255, 255) ' yes, draw it
            END IF
            IF MAP(x, y).walls AND 2 THEN '                         is EAST wall present?
                LINE (MAP(x, y).x + SQ - 1, MAP(x, y).y)-STEP(0, SQ - 1), _RGB32(255, 255, 255) ' yes, draw it
            END IF
            IF MAP(x, y).walls AND 4 THEN '                         is SOUTH wall present?
                LINE (MAP(x, y).x, MAP(x, y).y + SQ - 1)-STEP(SQ - 1, 0), _RGB32(255, 255, 255) ' yes, draw it
            END IF
            IF MAP(x, y).walls AND 8 THEN '                         is WEST wall present?
                LINE (MAP(x, y).x, MAP(x, y).y)-STEP(0, SQ - 1), _RGB32(255, 255, 255) ' yes, draw it
            END IF
        NEXT x
    NEXT y
    COLOR _RGB32(0, 255, 255)
    _PRINTSTRING (40, 40), "The Magic Key is the spacebar."
 
    PCOPY 0, 1 '                                                      save a copy of the map
 
END SUB
 
SUB fcirc (CX AS LONG, CY AS LONG, R AS LONG, K AS LONG)
    DIM subRadius AS LONG, RadiusError AS LONG
    DIM X AS LONG, Y AS LONG
 
    subRadius = ABS(R)
    RadiusError = -subRadius
    X = subRadius
    Y = 0
 
    IF subRadius = 0 THEN PSET (CX, CY), K: EXIT SUB
 
    ' Draw the middle span here so we don't draw it twice in the main loop,
    ' which would be a problem with blending turned on.
    LINE (CX - X, CY)-(CX + X, CY), K, BF
 
    WHILE X > Y
        RadiusError = RadiusError + Y * 2 + 1
        IF RadiusError >= 0 THEN
            IF X <> Y + 1 THEN
                LINE (CX - Y, CY - X)-(CX + Y, CY - X), K, BF
                LINE (CX - Y, CY + X)-(CX + Y, CY + X), K, BF
            END IF
            X = X - 1
            RadiusError = RadiusError - X * 2
        END IF
        Y = Y + 1
        LINE (CX - X, CY - Y)-(CX + X, CY - Y), K, BF
        LINE (CX - X, CY + Y)-(CX + X, CY + Y), K, BF
    WEND
END SUB
 
SUB ftri (x1, y1, x2, y2, x3, y3, K AS _UNSIGNED LONG)
    a& = _NEWIMAGE(1, 1, 32)
    _DEST a&
    PSET (0, 0), K
    _DEST 0
    _MAPTRIANGLE _SEAMLESS(0, 0)-(0, 0)-(0, 0), a& TO(x1, y1)-(x2, y2)-(x3, y3)
    _FREEIMAGE a& '<<< this is important!
END SUB
 
'use radians
SUB arc (x, y, r, raStart, raStop, c AS _UNSIGNED LONG)
    'x, y origin, r = radius, c = color
 
    'raStart is first angle clockwise from due East = 0 degrees
    ' arc will start drawing there and clockwise until raStop angle reached
 
    IF raStop < raStart THEN
        arc x, y, r, raStart, _PI(2), c
        arc x, y, r, 0, raStop, c
    ELSE
        ' modified to easier way suggested by Steve
        'Why was the line method not good? I forgot.
        al = _PI * r * r * (raStop - raStart) / _PI(2)
        FOR a = raStart TO raStop STEP 1 / al
            PSET (x + r * COS(a), y + r * SIN(a)), c
        NEXT
    END IF
END SUB
 
'draw lines from origin to arc on sides
SUB pieSlice (x, y, r, raStart, raStop, c AS _UNSIGNED LONG)
    arc x, y, r, raStart, raStop, c
    px = x + r * COS(raStart): py = y + r * SIN(raStart)
    LINE (x, y)-(px, py), c
    px = x + r * COS(raStop): py = y + r * SIN(raStop)
    LINE (x, y)-(px, py), c
END SUB
 
'------------------------
'- Program DATA section -
'------------------------
 
'*
'* Map cell values
'*
 
'DATA 11,15,15,11,15,12,5,5,4,3,15,15,15,15,10,11,15,9,5,6,12,5,6,15,15
 
' a different map
' DATA 11,15,15,11,15,12,5,5,4,3,15,11,15,15,10,9,0,1,5,6,12,4,5,15,15
'conversion of  the map above with square movement to octagonal movement
DATA 219,255,255,155,255,252,117,229,212,115,255,155,255,255,58,201,144,49,165,246,236,100,119,255,255
'* as       picture      power of 2 (2^n)         result of 2^n
'*            __            0                          1
'*           /  \          7 4                      128 16
'*           |  |         3   1                     8     2
'*           \  /          6 5                       64  32
'*            --            2                          4
 
 

I have just a bug about how many steps the mouse does, but this is why I have not seen in dept how do you use variables rat.dx and rat.dy. I think the bug is there.

The value of each cell is easily calculated with formula 255 (no direction possible) - direction that you let to do

Code: QB64: [Select]

'* Bitwise math demonstration
'*
'* Draws a simple map and allows player to move circle within map
'* rapresentation using a clockwise power of 2 for each segment first the 4 basilar
'*   and then the 4 diagonal   for optional directions
'* as       picture      power of 2 (2^n)         result of 2^n
'*            __            0                          1                     N
'*           /  \          7 4                      128  16               NE   NW
'*           |  |         3   1                    8       2             E       W
'*           \  /          6 5                      64   32               SE   SW
'*            --            2                          4                     S
 
'* example of how the value of cell in the map changes using octagonal movement controls
 
'*  a closed box    squared wall scoring        octagonal wall scoring
'*      --          1+2+4+8= 15                  1+2+4+8+ 16+32+64+128=255
'*     |  |
'*      --
'*  a U box    squared wall scoring        octagonal wall scoring
'*                 2+4+8= 14                  2+4+8+ 32+64+128+16=
'*     |  |        or 15 - 1 = 14               14 +  oblique directions forbidden
'*      --
'*  a C box    squared wall scoring        octagonal wall scoring
'*      --          1+4+8= 13                  1+4+8+ 64+128=205 moving NW W SW
'*     |            or 15-2 =13
'*      --
'*
 

bplus · « **Reply #1 on:** September 01, 2018, 08:28:50 pm »

That reminds me, I was going to try Octagonal map, but got distracted by one thing and then other...

Yes, I had planned to code walls very like what you have illustrated TempodiBasic, perfect for _Byte Type.

TempodiBasic · « **Reply #2 on:** September 02, 2018, 09:50:04 am »

Hi Bplus
the real difference between the system that you have thought and that I have developed following Terry's map bitwise generator and your goal of 8 direction of movement is that you use a single circle clockwise to set the bitvalue and so in map creator and map evaluator you want make squared cell you need alternate bitvalue to evaluate N = 1 E = 4 S = 16 W=64; with my method a first circle clockwise gives values to bit for the 4 main directions N=1 E=2 S=4 W=8 and the second circle clockwise gives value to bit of the 4 secondary directions.
Two ways to go in the same direction.

Thanks to read

SMcNeill · « **Reply #3 on:** September 02, 2018, 10:26:59 am »

Checking my notes for a game I was working on in the past, this is my map coordinate system:

N = 2^ 0 = 1
E = 2 ^ 1 = 2
NE = 2 ^ 2 = 4
NW = 2 ^ 3 = 8
SE = 2 ^ 4 = 16
SW = 2 ^ 5 = 32
W = 2 ^ 6 = 64
S = 2 ^ 7 = 128

Why so odd a numbering system??

One word: Opposites.

2 ^ 0 = North
2 ^ (7 - 0) = South

For each direction, we can find the opposite direction by just subtracting its power from 7.

This was important for some reason that I'd dreamed up and incorporated into the code back then, but I'll be danged now if I can remember WHY...

Just thought I'd offer it as a different coordinate system for you to think about. Heck, you might even be able to sort out why I thought it was a good idea at the time; I don't have a clue why I did it now, and I'm not always the most faithful of commenting thoughts/reasons in code sometimes...

bplus · « **Reply #4 on:** September 02, 2018, 12:04:03 pm »

"Why so odd a numbering system??"

Oh hey, I just noticed TempodiBasic number system jumpimg around. Missed that.

Perhaps he has hopes of hacking Terry Ritchie's maze generator? for octagons?

But Steve, your number system has a logic to it.

I am wondering why TempodiBasic posted the mod I made with wings and trap, loosing the trap and the great flapping of wings? The trap is why our hero needed wings to get out! And the flapping, I was so proud to get that working just right! Ruined! ;(
( I am crying crocodile tears, joking, I hope you all know, I am honored anyone copies and plays with code I post.)

(compare original post this thread to reply #18 https://www.qb64.org/forum/index.php?topic=417.msg3211#msg3211 )

But I do really think this title (in TempodiBasic's mod that starts this thread):
_TITLE "B+ Flying Hero Mod of TempodiBasic Trap Mod of Terri Ritchie Simple Map Demo, 2018-08-21"

Should say:
_TITLE "TempodiBasic Mod of B+ Flying Hero Mod of TempodiBasic Trap Mod of Terri Ritchie Simple Map Demo, (some other date after 2018-08-21)"
so the author of the code isn't confused with another author of some other similar earlier code.

It is a great aim to try for hacking maze generator already working great which is what TempodiBasic's main point was (I am thinking) because I was discouraged we couldn't have an easy maze generator for Octagons. I think TempodiBasic is saying well maybe we can.

bplus · « **Reply #5 on:** September 02, 2018, 03:22:25 pm »

Come to think of it, there was another fundamental question left unanswered and having me look around for something else to do.

That was the question of tiling maze generated maps, and imagine how much more difficult an octagonal setup.

TempodiBasic · « **Reply #6 on:** September 02, 2018, 05:45:48 pm »

Hi Bplus

yes you are right
Romans used to say dare Caesari quae Caesaris or in english giving a caesar to what is to be a Caesar...
sorry I must correct _TITLE of demo!
so please subsostitute to the _TITLE line this code

Code: QB64: [Select]

_TITLE "TempodiBasic mod of B+ Flying Hero Mod of TempodiBasic Trap Mod of Terri Ritchie Simple Map Demo, 2018-09-02"

and here there recovered the trap! Put this line at the place of previous or change the third number (119) counting from the last one on the right side of line with 117

Code: QB64: [Select]

'conversion of  the map above with square movement to octagonal movement
DATA 219,255,255,155,255,252,117,229,212,115,255,155,255,255,58,201,144,49,165,246,236,100,117,255,255
 

:-)
I hope to give happy to you doing this!

TempodiBasic · « **Reply #7 on:** September 02, 2018, 06:02:51 pm »

Hi Steve
yes I find very interesting you odd system to set directions,
the cause of why do you have thought important getting smartly and quickly the opposite direction can be related to collisions

that is the first cause I can imagine.
It remember me an old game for windows 95 Drod https://sillysoft.net/drod/

Thanks
Good Coding

News:

Author Topic: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus (Read 3504 times)

TempodiBasic

Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

bplus

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

TempodiBasic

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

SMcNeill

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

bplus

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

bplus

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

TempodiBasic

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus

TempodiBasic

Re: Map bitwise and octagonal movements (N NE E SE S SW W NW) @Bplus