4 Letter Word Invaders Game

[SierraKen]

Great rendition B+! My games do have the score in the _TITLE bar. B+, the difference between yours and mine is that on yours the player has to click the right sequence as well, mine can be any of them on the screen. That is probably what got me stuck to begin with.

[bplus]

Yeah I tried to figure out what you were doing but my brain got frazzled specially on that gosub.

So I tried to write a simple version with the basic game for clarity.

[_vince]

B+ mod!

Code: QB64: [Select]

1. _Title "Quick Falling Letters Game B+ mod" 'b+ 2022-02-08
2.  
3. const nn = 1
4. Const twidth = 640, theight = 480, zoom = 128
5. Dim Shared noise(nn*twidth * theight) '//the noise array
6. Dim Shared texture(nn*twidth * theight) '//texture array
7. Dim Shared pal(256) As _Unsigned Long '//color palette
8.  
9. Dim letters$(1 To 25), lx(1 To 25) As Integer ' screen 0 25 lines 80 letters across
10. Dim hits, letterPos, i, K$, GameOver
11.  
12. screen _newimage(640,480,32)
13. MakePalette 255, 155, 255, 10, 100, 180
14. GenerateNoise
15. buildtexture
16.  
17. dim vs as long
18. vs = _newimage(twidth, theight, 32)
19. _dest vs
20. drawtexture 0
21. _dest 0
22.  
23. ii = 0
24. jj = -1
25. kk = 0
26. Do
27.         kk = kk + 1
28.         ii = ii + 1
29.         if ii >= 640 then
30.                 ii = 0
31.                 jj = not jj
32.         end if         
33.  
34.         if jj then
35.                 _putimage (ii , 0)-step(640,480), vs
36.                 _putimage (ii , 0)-step(-640,480), vs
37.         else
38.                 _putimage (ii + 640, 0)-step(-640,480), vs
39.                 _putimage (ii - 640 , 0)-step(640,480), vs
40.         end if
41.  
42.     'Cls
43.         if kk mod 50 = 0 then
44.                 letterPos = letterPos + 1 ' generate new letter at each round
45.                 If letterPos > 24 Then GameOver = -1
46.                 For i = letterPos - 1 To 1 Step -1 ' cycle letters and positions down
47.                         letters$(i + 1) = letters$(i)
48.                         lx(i + 1) = lx(i)
49.                 Next
50.                 letters$(1) = Chr$(Int(Rnd * 26) + 97) ' start a new letter
51.                 lx(1) = Int(Rnd * 80) + 1 ' at a new place
52.                 K$ = InKey$ ' check key presses for match to current letterPos
53.                 While K$ = letters$(letterPos) ' catch up with all keypresses
54.                         hits = hits + 1 '            add to score
55.                         letterPos = letterPos - 1
56.                         K$ = InKey$ '                check next keypress
57.                 Wend
58.         end if
59.  
60.         For i = 1 To letterPos 'show board what's left of letters
61.                 Locate i, lx(i): Print letters$(i);
62.         Next
63.         Locate 25, 36: Print "Hits:"; hits
64.  
65.         _display
66.     _Limit 50
67. Loop Until GameOver
68. Locate 25, 26: Print "Game Over"
69. _display
70. Sleep
71. system
72.  
73. '//interpolation code by rattrapmax6
74. Sub MakePalette (sr, sg, sb, er, eg, eb) ' (b+) start and end RGB's ? yes
75.     Dim i, istart(3), iend(3), ishow(3), rend(3), interpol(3)
76.  
77.     interpol(0) = 255
78.     istart(1) = sr
79.     istart(2) = sg
80.     istart(3) = sb
81.     iend(1) = er
82.     iend(2) = eg
83.     iend(3) = eb
84.     interpol(1) = (istart(1) - iend(1)) / interpol(0)
85.     interpol(2) = (istart(2) - iend(2)) / interpol(0)
86.     interpol(3) = (istart(3) - iend(3)) / interpol(0)
87.     rend(1) = istart(1)
88.     rend(2) = istart(2)
89.     rend(3) = istart(3)
90.  
91.     For i = 0 To 255
92.         ishow(1) = rend(1)
93.         ishow(2) = rend(2)
94.         ishow(3) = rend(3)
95.  
96.         pal(i) = _RGB32(ishow(1), ishow(2), ishow(3))
97.  
98.         rend(1) = rend(1) - interpol(1)
99.         rend(2) = rend(2) - interpol(2)
100.         rend(3) = rend(3) - interpol(3)
101.     Next i
102. End Sub
103.  
104. '//generates random noise.
105. Sub GenerateNoise ()
106.     Dim As Long x, y
107.  
108.     For x = 0 To nn*twidth - 1
109.         For y = 0 To theight - 1
110.                         zz = rnd
111.             noise(x + y * twidth) = zz
112.         Next y
113.     Next x
114.  
115. End Sub
116.  
117. Function SmoothNoise (x, y)
118.     '//get fractional part of x and y
119.     Dim fractx, fracty, x1, y1, x2, y2, value
120.     fractx = x - Int(x)
121.     fracty = y - Int(y)
122.  
123.     '//wrap around
124.     x1 = (Int(x) + nn*twidth) Mod twidth
125.     y1 = (Int(y) + theight) Mod theight
126.  
127.     '//neighbor values
128.     x2 = (x1 + nn*twidth - 1) Mod twidth
129.     y2 = (y1 + theight - 1) Mod theight
130.  
131.     '//smooth the noise with bilinear interpolation
132.     value = 0.0
133.     value = value + fractx * fracty * noise(x1 + y1 * twidth)
134.     value = value + fractx * (1 - fracty) * noise(x1 + y2 * twidth)
135.     value = value + (1 - fractx) * fracty * noise(x2 + y1 * twidth)
136.     value = value + (1 - fractx) * (1 - fracty) * noise(x2 + y2 * twidth)
137.  
138.     SmoothNoise = value
139. End Function
140.  
141. Function Turbulence (x, y, size)
142.     Dim value, initialsize
143.  
144.     initialsize = size
145.     While (size >= 1)
146.         value = value + SmoothNoise(x / size, y / size) * size
147.         size = size / 2.0
148.     Wend
149.     Turbulence = (128.0 * value / initialsize)
150. End Function
151.  
152. '//builds the texture.
153. Sub buildtexture
154.     Dim x, y
155.  
156.     For x = 0 To nn*twidth - 1
157.         For y = 0 To theight - 1
158.             texture(x + y * nn*twidth) = Turbulence(x, y, zoom)
159.         Next y
160.     Next x
161. End Sub
162.  
163. '//draws texture to screen.
164. Sub drawtexture (dx )
165.     Dim x, y
166.         dim as long c, r, g, b
167.  
168.     For x = 0 To twidth - 1
169.         For y = 0 To theight - 1
170.                         c = pal(texture(((x + dx) + y * nn*twidth)))
171.                         r = _red(c)
172.                         g = _green(c)
173.                         b = _blue(c)
174.                         c = _rgb(r - 0.2*y, g - 0.2*y, b - 0.2*b)
175.             PSet (x, y), c'pal(texture(((x + dx) + y * nn*twidth)))
176.         Next y
177.     Next x
178. End Sub
179.  

[SierraKen]

LOL totally cool Vince. 1980's text game turned into mid 1990's Windows 95 type game. :)))

[bplus]

And still it could be made so much better with:

Code: QB64: [Select]

1. _PrintMode _KeepBackground  
2.