Save Black-White BMP file [2 color BMP]

[Petr]

Code: QB64: [Select]

1. 'inspired with SMCNeill Christmas theme program (this is not Christmas theme program)
2. 'my goal was to enable the storage of two-color bitmaps. This only succeeded after two days,
3. 'because my sources contained a serious error, after comparing with other sources, I found it.
4. 'For this to work, the X-axis (width) image resolution must always be divisible by 32.
5. '
6.  
7. image$ = "The Season to Color.JPG" '                      image name for convert to 2 color bmp file
8. imageO = _LoadImage(image$, 32)
9.  
10. Type BW '                                 File Header + Info Header + 2 * _UNSIGNED LONG mask record all in one
11.     'Header
12.     signature As String * 2 '                             BM
13.     FileSize As Long '                                    Size of file
14.     Res1 As Integer '                                     not used [res = reserved]
15.     Res2 As Integer '                                     not used [res = reserved]
16.     DataOffset As Long '                                  62 always in this bitmap type
17.     'infoHeader                                           -----------------------------
18.     SizeOfInfoHeader As Long '                            always 40
19.     Width As Long '                                       image width
20.     Height As Long '                                      image height
21.     Planes As Integer '                                   always 1
22.     BitsPerPixel As Integer '                             1 bit for this use
23.     Compression As Long '                                 0 = none
24.     ImageSize As Long '                                   0, this is size for COMPRESSED IMAGE, 0 for uncompressed
25.     XPixels As Long '                                     pixels/meter X [0]
26.     YPixels As Long '                                     pixels/meter Y [0]
27.     ColorsUsed As Long '                                  0 = used all colors in mask
28.     ImportantColors As Long '                             0 = all
29.     'color table                                          2 * _unsigned long record ---> 2 colors image
30.     ColorA As _Unsigned Long
31.     ColorB As _Unsigned Long
32. End Type
33.  
34. Dim BMP1 As BW '
35. Dim As Long Size, W, H
36. Wo = _Width(imageO): H = _Height(imageO)
37.  
38. Do Until Wo Mod 32 = 0 '                                    resize image so, that width is dividible by 32 [is condition for this image format]
39.     Wo = Wo + 1
40. Loop
41. W = Wo
42.  
43. image = _NewImage(Wo, H, 32)
44. clr~& = &HFFFFFFFF '_BackgroundColor(imageO)              for christmas theme - all images using white background, for own use set it as you need
45. _Dest image
46. Cls , clr~&
47.  
48. _PutImage (0, 0), imageO, image
49. _FreeImage imageO
50.  
51. Size = _Ceil(W * H / 8) + 62 '                           calculate file size (62 bytes is header + infoheader + 2 colors mask)
52.  
53. BMP1.signature = "BM"
54. BMP1.FileSize = Size
55. 'BMP1.Unused = 0
56. BMP1.DataOffset = 62
57. BMP1.SizeOfInfoHeader = 40
58. BMP1.Width = W
59. BMP1.Height = H
60. BMP1.Planes = 0
61. BMP1.BitsPerPixel = 1
62. BMP1.Compression = 0
63. BMP1.ImageSize = Size - 62
64. BMP1.XPixels = 0
65. BMP1.YPixels = 0
66. BMP1.ColorsUsed = 0
67. BMP1.ImportantColors = 0
68. BMP1.ColorA = &HFF000000
69. BMP1.ColorB = &HFFFFFFFF
70.  
71. i = 0
72. S$ = ""
73.  
74. Dim outpt(Size - 63 + corr) As _Unsigned _Byte '      array for binaries [0 or 1] if image use color mask 0 or color mask 1
75. For fill = 0 To UBound(outpt)
76.     outpt(fill) = 0 '                                 first set all binaries as zero
77. Next
78.  
79. _Source image '                                       This image format write image informations to file from bottom to top
80. For y = H - 1 To 0 Step -1
81.     For x = 0 To W - 1
82.         Bp~& = Point(x, y)
83.         r = _Red32(Bp~&)
84.         g = _Green32(Bp~&)
85.         b = _Blue32(Bp~&)
86.         If r > 200 Or g > 200 Or b > 200 Then S$ = S$ + "1" Else S$ = S$ + "0" ' Steve's whiting routine....
87.         If Len(S$) = 8 Then '                                                    You have 8 points writed as 0/1? Create byte from this 8 bites!
88.             outpt(i) = BINtoDEC(S$) '                                            Write this byte to array outpt
89.             S$ = ""
90.             i = i + 1
91.         End If
92.     Next
93. Next
94.  
95. If Len(S$) Then
96.     outpt(i) = BINtoDEC(S$) '                                                   if here are some binaries, create byte from it and write it to array outpt
97.     S$ = ""
98. End If
99.  
100. If _FileExists("Black-White.bmp") Then Kill "Black-White.bmp"
101.  
102. Open "Black-White.bmp" For Binary As #1 '                                       write file, done.
103. Put #1, 1, BMP1
104. Put #1, 63, outpt()
105. Print Seek(1)
106. Close 1
107. ReDim outpt(0)
108. _FreeImage image
109. End
110.  
111. Function BINtoDEC (b As String)
112.     For Si = 1 To Len(b)
113.         e$ = Mid$(b$, Si, 1)
114.         c = Val(e$) '
115.         Sj = Len(b) - Si
116.         sBINtoDEC = sBINtoDEC + (c * 2 ^ Sj)
117.         BINtoDEC = sBINtoDEC
118.     Next Si
119.     sBINtoDEC = 0
120. End Function
121.  

 

[SMcNeill]

For this to work, the X-axis (width) image resolution must always be divisible by 32.


Are you certain?  BMP files require packing at each line, unless the line is evenly divisible by 4.  What you're seeing is probably related to that.  https://www.qb64.org/forum/index.php?topic=3602.msg129449#msg129449

[Petr]

If i am sure? Not. During the output testing, I deduced that it works with the condition that it is divisible by 32, but of course, I will check whether it will also work with the condition that the x-axis be divisible by four. Thanks for warning.

[Petr]

The most outputs (all test pass) is with 32. With 4 are some images uncompatible - unusable. You can test it on row 38 in my source code, if you rewrite it to 4 and use some your JPG file from Christmas theme, with 32 are all usable, with 4 not.

Here is one test - image created with my daughter after BW process:

 

[Petr]

@SMcNeill

Actually, we're both talking about the same thing! Look: If you're encoding a bitmap in this format, I'm talking about 32 bits and you're talking about 4 bytes. And we are home! After all, it's the same (8x4), in this format you encode bits, what one bit, that one pixel.

[bplus]

@Petr

You have a very distinct style to your drawing. I've only seen the volley ball thing (2x's: program and old avatar snip) and this little sketch but it seems cool, playful "tell". I wonder if cartoons can be cultural and if you picked up from that.

[Petr]

@bplus
Thank you for your response. It's like this: Volleyball is a graphic drawn by my hand using a mouse (MX Master). This mouse is excellent, and very sensitive. The picture here is a hand-painted drawing of my younger daughter's hands. The only thing I have to do with this is that I scanned it and converted it into a black and white image. And yes, I do write something in QB64 with pictures of my daughter, but it's too early to talk about it. Namely, it is not the only thing, there is another big program where is MEMSOUND the king and I am developing it at the same time, even though the programs are to different theme and do not affect each other.