Author Topic: Gapper Playable to level 5 (Read 2392 times)

Cobalt · « **on:** November 14, 2021, 10:14:55 pm »

ok so its like super easy right now as the seeker speed doesn't scale yet. and I say up to level 5 because for some reason it wont complete all the boxes at that level.

@bplus any idea why BoxSurrounded stops working on that level?

Arrow Keys move your icon which starts in the top left corner, dont get caught by the seeker who starts in the bottom right corner.
ESC quits.

Code: QB64: [Select]

'Gapper(1986) Clone
'10\25\2019 Cobalt
'ÃInital Start; Layout, Gapper, Seeker, L1 Grid finished [13:55EDT]
'ÀCorreted 'Catcher' to 'Seeker' as per original game
'10\31\2021
'ÃFixed Seeker movement issue with help from Bplus and Keybone, used ABS as per Bplus
'Àadded startup screen, player initials input,game options
'11\1\2021
'ÃAdded the instructions screens
'Àenabled collision of Seeker and Gapper
'11\11\2021
'ÃFinished all 8 boards
'11\13\2021
'ÃInserted Bplus's code for detecting completed boxes.
'11\14\2021
'ÃIntegrated Bplus's code for detecting completed boxes and filling them.
'ÃAdded score amount to filled boxes
'ÃLevels now end when boxes are full
'ÀScore is now kept
 
TYPE GameData
 Player AS STRING * 4
 Score AS LONG
 Lives AS _BYTE
 Level AS _BYTE
 GX AS INTEGER 'Gapper X location
 GY AS INTEGER 'Gapper Y location
 GD AS _BYTE 'Gapper direction
 SX AS INTEGER
 SY AS INTEGER
 SS AS _BYTE 'Seeker speed
 SD AS _BYTE 'Seeker direction
 Start AS _BYTE 'is level started or not(nothing happens until started)
 FPS AS INTEGER
 Quit AS _BYTE
 Caught AS _BYTE 'has the seeker caught the gapper?
 'board info
 CellHeight AS _BYTE
 CellWidth AS _BYTE
 Rows AS _BYTE
 Columns AS _BYTE
 Offx AS _BYTE
 Offy AS _BYTE
 Needed AS _BYTE 'number of cells needing finished to win level
 Finished AS _BYTE 'number of cells currently boxed in
END TYPE
 
TYPE High_Scores
 Nam AS STRING * 4
 Score AS LONG
 Level AS INTEGER
END TYPE
 
CONST TRUE = -1, FALSE = NOT TRUE, Gapper = 1, Seeker = 2
CONST UP = 1, DOWN = 2, LEFT = 3, RIGHT = 4
CONST Key_Right = 19712, Key_Left = 19200, Key_Up = 18432, Key_Down = 20480
CONST Key_Space = 32, Key_Enter = 13
CONST Cyan = &HFF10E0E0~& '_RGB32(0, 170, 170)
CONST Magenta = &HFFC040C0~&
CONST OffWhite = &HFFC0C0C0~&
CONST Brown = &HFFB06000~&
CONST Yellow = &HFFFFFF00~&
CONST Black = &HFF000000~&
 
SCREEN _NEWIMAGE(640, 440, 32)
DIM SHARED Layer(11) AS LONG, G AS GameData, Frames%
DIM SHARED Scores(10) AS High_Scores
DIM SHARED FinishedBox(72) AS _BYTE
 
Layer(0) = _DISPLAY
Layer(1) = _NEWIMAGE(640, 440, 32) 'mix layer
Layer(2) = _NEWIMAGE(320, 220, 32) 'Grid Layer
Layer(3) = _NEWIMAGE(640, 440, 32) 'Sprite layer
Layer(4) = _NEWIMAGE(320, 220, 32) 'Info layer
Layer(5) = _NEWIMAGE(640, 440, 32) 'Collision 'Gapper\Catcher' layer
Layer(6) = _NEWIMAGE(640, 440, 32) 'Collision 'Grid' layer
Layer(7) = _NEWIMAGE(640, 440, 32) 'debug layer
Layer(8) = _NEWIMAGE(320, 220, 32) 'Menu layer
Layer(9) = _NEWIMAGE(320, 240, 32) 'instructions layer
Layer(10) = _NEWIMAGE(320, 8, 32) 'title bar layer
Layer(11) = _NEWIMAGE(320, 220, 32) 'point test location layer
 
_FONT 8, Layer(4)
_FONT 8, Layer(8)
_FONT 8, Layer(9)
_FONT 8, Layer(10)
_FONT 8, Layer(2)
_PRINTMODE _KEEPBACKGROUND , Layer(10)
_PRINTMODE _KEEPBACKGROUND , Layer(8)
_PRINTMODE _KEEPBACKGROUND , Layer(9)
_PRINTMODE _KEEPBACKGROUND , Layer(2)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(3)
_CLEARCOLOR _RGB32(0, 0, 0), Layer(7)
 
_SCREENMOVE 16, 16
_SOURCE Layer(6)
 
ON TIMER(t1&, 1) FPS
'Title_Startup
'END
Game_INIT
DrawBoard
TIMER(t1&) ON
DO
 IF _KEYDOWN(27) THEN ExitFlag%% = TRUE
 IF _KEYDOWN(Key_Up) THEN
  G.Start = TRUE
  IF NOT Collision_Grid(Gapper, UP) THEN G.GD = UP
 END IF
 IF _KEYDOWN(Key_Down) THEN
  G.Start = TRUE
  IF NOT Collision_Grid(Gapper, DOWN) THEN G.GD = DOWN
 END IF
 IF _KEYDOWN(Key_Left) THEN
  G.Start = TRUE
  IF NOT Collision_Grid(Gapper, LEFT) THEN G.GD = LEFT
 END IF
 IF _KEYDOWN(Key_Right) THEN
  G.Start = TRUE
  IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GD = RIGHT
 END IF
 
 IF G.Start THEN Move_Seeker: Move_Gapper
 
 FOR i%% = 1 TO G.Needed
  IF BoxSurrounded(i%%) THEN FinishedBox(i%%) = TRUE
  IF FinishedBox(i%%) THEN FillBox i%%
 NEXT i%%
 
 Game_Data_Update
 _PUTIMAGE (0, 0)-STEP(639, 15), Layer(10), Layer(1) 'title bar
 _PUTIMAGE , Layer(4), Layer(1) 'information bar
 _PUTIMAGE , Layer(2), Layer(1) 'game board
 Place_Gapper
 Place_Seeker
 IF G.Caught THEN 'seeker caught 'em
  ClearLayer Layer(5)
  Reset_Pos
  DrawBoard
  G.Lives = G.Lives - 1
  IF G.Lives = -1 THEN ExitFlag%% = TRUE
 END IF
 _PRINTSTRING (600, 0), STR$(G.FPS), Layer(7)
 _PUTIMAGE , Layer(7), Layer(1) 'debug layer
 _PUTIMAGE , Layer(1), Layer(0)
 _LIMIT 60
 ClearLayer Layer(1)
 Frames% = Frames% + 1
 IF G.Finished = G.Needed THEN Change_Level
LOOP UNTIL ExitFlag%%
 
SUB Place_Gapper
 old& = _DEST
 _DEST Layer(5)
 LINE (G.GX - 2, G.GY - 2)-STEP(20, 18), Black, BF
 _DEST old&
 'place gapper-----
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(1), (318, 218)-STEP(15, 13)
 'place Gapper shadow
 _PUTIMAGE (G.GX, G.GY), Layer(3), Layer(5), (318, 218)-STEP(15, 13)
END SUB
 
SUB Place_Seeker
 'place Seeker----
 _PUTIMAGE (G.SX, G.SY), Layer(3), Layer(1), (341, 218)-STEP(14, 11)
 '-----------------
END SUB
 
 
SUB Game_INIT
 _DEST Layer(3)
 'Player----
 DRAW "c" + STR$(Cyan) + "drurd8l2dr3u9d2rd5ru5rd5ru5ru2d9r3ul2u8r2dlbl3c" + STR$(Magenta) + "u3ld3lu3ld3"
 DRAW "bd7d3ru3rd3ru3bu3br3r4ul4bl9l4dr4"
 '----------
 DRAW "br20bu7"
 'Seeker----
 DRAW "c" + STR$(Cyan) + "r3dl3bd10r3ul3br10r3dl3bu10r3ul3c" + STR$(Magenta) + "bd2brl3dr3bd5l3dr3bl6l3ur3"
 DRAW "bu5l3ur3d2lr5dl5dr5dl5"
 '------------
 Title_Header
 _DEST Layer(5)
 LINE (0, 0)-STEP(639, 439), Black, BF
 _DEST Layer(0)
 G.Score = 0
 G.Lives = 2
 G.Level = 1
END SUB
 
SUB Title_Header
 'Header
 _DEST Layer(10)
 LINE (84, 0)-STEP(151, 8), Magenta, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Magenta
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
END SUB
 
SUB Game_Data_Update
 'Info area updating ---------------
 _PRINTSTRING (7, 192), "Score[      ]    Lives[ ]    Level[  ]", Layer(4)
 _PRINTSTRING (95 - ((LEN(LTRIM$(STR$(G.Score))) - 1) * 8), 192), LTRIM$(STR$(G.Score)), Layer(4)
 _PRINTSTRING (191, 192), LTRIM$(STR$(G.Lives)), Layer(4)
 _PRINTSTRING (295 - ((LEN(LTRIM$(STR$(G.Level))) - 1) * 8), 192), LTRIM$(STR$(G.Level)), Layer(4)
 '-----------------------------------
END SUB
 
SUB DrawBoard
 _DEST Layer(2)
 SELECT CASE G.Level
  CASE 1 'draw level 1 grid
   Level_1_Board
  CASE 2
   Level_2_Board
  CASE 3
   Level_3_Board
  CASE 4
   Level_4_Board
  CASE 5
   Level_5_Board
  CASE 6
   Level_6_Board
  CASE 7
   Level_7_Board
  CASE 8
   Level_8_Board
  CASE ELSE 'after level 8 board is random between 5 and 8
   SELECT CASE INT(RND * 4) + 5
    CASE 5
     Level_5_Board
    CASE 6
     Level_6_Board
    CASE 7
     Level_7_Board
    CASE 8
     Level_8_Board
   END SELECT
 END SELECT
 _DEST Layer(0)
 ClearLayer Layer(6)
 _PUTIMAGE , Layer(2), Layer(6) 'make a copy for the collision layer
END SUB
 
SUB ClearLayer (L&)
 _DEST L&
 CLS
 _DEST _DISPLAY
END SUB
 
SUB ClearLayerTrans (L&)
 _DEST L&
 CLS , 0
 _DEST _DISPLAY
END SUB
 
FUNCTION Collision_Seeker%%
 Result%% = FALSE
 _SOURCE Layer(5)
 IF POINT(G.SX, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY) <> Black THEN Result%% = TRUE
 IF POINT(G.SX, G.SY + 8) <> Black THEN Result%% = TRUE
 IF POINT(G.SX + 8, G.SY + 8) <> Black THEN Result%% = TRUE
 IF Result%% THEN LOCATE 1, 1: PRINT POINT(G.SX, G.SY), POINT(G.SX + 8, G.SY), POINT(G.SX, G.SY + 8), POINT(G.SX + 8, G.SY + 8)
 Collision_Seeker = Result%%
 _SOURCE Layer(6)
END FUNCTION
 
FUNCTION Collision_Grid%% (who%%, Direction%%)
 Result%% = TRUE 'always assume collision
 SELECT CASE who%% 'who are we checking collision for?
  CASE Gapper
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.GX + 8, G.GY + 5)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.GX + 8, G.GY + 9)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.GX + 6, G.GY + 7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.GX + 10, G.GY + 7)
   END SELECT
  CASE Seeker
   SELECT CASE Direction%%
    CASE UP 'see if there is grid up from Gappers position
     Check~& = POINT(G.SX + 8, G.SY + 5)
     _PRINTSTRING (250, 400), "UP   ", Layer(7)
    CASE DOWN 'see if there is Grid below Gapper
     Check~& = POINT(G.SX + 8, G.SY + 9)
     _PRINTSTRING (250, 400), "DOWN ", Layer(7)
    CASE LEFT 'check for grid to the left of Gapper
     Check~& = POINT(G.SX + 6, G.SY + 7)
     _PRINTSTRING (250, 400), "LEFT ", Layer(7)
    CASE RIGHT 'Check for grid to the Right of Gapper
     Check~& = POINT(G.SX + 10, G.SY + 7)
     _PRINTSTRING (240, 400), "RIGHT", Layer(7)
   END SELECT
 END SELECT
 Blue~%% = _BLUE32(Check~&) 'check for Blue, grid is Cyan in color
 IF Blue~%% THEN Result%% = FALSE 'there is grid to move onto, no collision with edge of grid
 
 
 Collision_Grid = Result%%
 '_SOURCE Layer(0)
END FUNCTION
 
 
SUB Move_Seeker
 STATIC Mover%%
 Seeker_Logic
 IF Mover%% < G.SS THEN
  Mover%% = Mover%% + 1 'Slow our seeker down
 ELSE
  Mover%% = 0
  SELECT CASE G.SD
   CASE UP
    IF NOT Collision_Grid(Seeker, UP) THEN G.SY = G.SY - 2
   CASE DOWN
    IF NOT Collision_Grid(Seeker, DOWN) THEN G.SY = G.SY + 2
   CASE LEFT
    IF NOT Collision_Grid(Seeker, LEFT) THEN G.SX = G.SX - 2
   CASE RIGHT
    IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SX = G.SX + 2
  END SELECT
 END IF
 IF Collision_Seeker THEN G.Caught = TRUE
END SUB
 
SUB Move_Gapper
 SELECT CASE G.GD
  CASE UP
   IF NOT Collision_Grid(Gapper, UP) THEN G.GY = G.GY - 2
  CASE DOWN
   IF NOT Collision_Grid(Gapper, DOWN) THEN G.GY = G.GY + 2
  CASE LEFT
   IF NOT Collision_Grid(Gapper, LEFT) THEN G.GX = G.GX - 2
  CASE RIGHT
   IF NOT Collision_Grid(Gapper, RIGHT) THEN G.GX = G.GX + 2
 END SELECT
 Color_Line
END SUB
 
SUB Seeker_Logic
 DistX% = (G.SX - G.GX) 'find X distance between seeker and gapper
 DistY% = (G.SY - G.GY) 'find Y distance between Seeker and Gapper
 IF ABS(DistX%) > ABS(DistY%) THEN 'if player is farther on the X then
  IF DistX% < 0 THEN
   Turn_Seeker RIGHT 'try going right to get closer
  ELSE
   Turn_Seeker LEFT 'try going left to get closer
  END IF
 ELSE 'player is farther on the Y then
  IF DistY% < 0 THEN
   Turn_Seeker DOWN 'try going down to get closer
  ELSE
   Turn_Seeker UP 'try going up to get closer
  END IF
 END IF
END SUB
 
SUB Turn_Seeker (Direction%%)
 SELECT CASE Direction%%
  CASE UP
   IF NOT Collision_Grid(Seeker, UP) THEN G.SD = UP
  CASE DOWN
   IF NOT Collision_Grid(Seeker, DOWN) THEN G.SD = DOWN
  CASE LEFT
   IF NOT Collision_Grid(Seeker, LEFT) THEN G.SD = LEFT
  CASE RIGHT
   IF NOT Collision_Grid(Seeker, RIGHT) THEN G.SD = RIGHT
 END SELECT
END SUB
 
SUB Color_Line
 _DEST Layer(2)
 LINE (4 + G.GX \ 2, 3 + G.GY \ 2)-STEP(0, 0), Magenta, BF
 _DEST Layer(0)
END SUB
 
SUB FPS
 G.FPS = Frames%
 Frames% = 0
END SUB
 
SUB Title_Startup
 _DEST Layer(8)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 LINE (0, 140)-STEP(639, 8), Brown, BF
 COLOR Black
 _PRINTSTRING (0, 141), "Score:"
 _PRINTSTRING (220, 141), "Level:"
 _PRINTSTRING (100 - (LEN(LTRIM$(STR$(G.Score))) * 8), 141), STR$(G.Score) + "."
 _PRINTSTRING (284 - (LEN(LTRIM$(STR$(G.Level))) * 8), 141), STR$(G.Level)
 
 COLOR Yellow
 _PRINTSTRING (100, 160), "P: Play a game."
 _PRINTSTRING (100, 170), "Q: Quit"
 _PRINTSTRING (100, 180), "N: New Player"
 _PRINTSTRING (100, 190), "I: Instuctions"
 COLOR Magenta
 _PRINTSTRING (0, 210), "Enter your initials:"
 COLOR OffWhite
 
 Get_Player
 IF Search_For_Player THEN AddPlayer 'first time this player has played!
 Display_HighScores
 IF NOT G.Quit THEN Get_Menu_Selection
END SUB
 
SUB Get_Player
 Blink%% = TRUE: I$ = ""
 DO 'Initials input Loop
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE 8 'delete
    IF LEN(I$) THEN I$ = LEFT$(I$, LEN(I$) - 1)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 32 TO 122 'characters
    IF LEN(I$) < 3 THEN I$ = I$ + CHR$(KBD&)
    LINE (168, 210)-(248, 219), Black, BF
   CASE 13 'accept input(if any)
    IF RTRIM$(I$) <> "" THEN ExitFlag%% = TRUE
   CASE 27
    ExitFlag%% = TRUE
    G.Quit = TRUE
  END SELECT
  COLOR OffWhite
  _PRINTSTRING (168, 210), I$
  IF Blink%% THEN COLOR Black ELSE COLOR OffWhite
  _PRINTSTRING (168 + LEN(I$) * 8, 210), "_"
  _PUTIMAGE , Layer(8), _DISPLAY
  _LIMIT 30
  t%% = t%% + 1
  IF t%% = 4 THEN Blink%% = NOT Blink%%: t%% = 0
 LOOP UNTIL ExitFlag%%
 G.Player = I$
END SUB
 
SUB Get_Menu_Selection
 LINE (0, 210)-STEP(200, 9), Black, BF
 _PRINTSTRING (0, 210), "Please enter selection:  "
 DO
  KBD& = _KEYHIT
  SELECT CASE KBD&
   CASE ASC("p") OR ASC("P")
   CASE ASC("q") OR ASC("Q")
    ExitFlag%% = TRUE
    G.Quit = TRUE
   CASE ASC("n") OR ASC("N")
   CASE ASC("i") OR ASC("I")
    Instructions
   CASE 27
    ExitFlag%% = TRUE
    G.Quit = TRUE
  END SELECT
  _PUTIMAGE , Layer(8), _DISPLAY
 LOOP UNTIL ExitFlag%%
END SUB
 
SUB Display_HighScores
 _DEST Layer(8)
 IF LTRIM$(RTRIM$(Scores(1).Nam)) <> "" THEN
  COLOR Magenta
  _PRINTSTRING (0, 24), "High scores:"
  FOR i%% = 1 TO 10
   IF G.Player = Scores(i%%).Nam THEN
    COLOR Yellow 'player shows up Yellow
   ELSEIF i%% = 1 THEN
    COLOR Magenta 'High score if not player shows magenta
   ELSE
    COLOR OffWhite 'everybody else is off white
   END IF
  NEXT i%%
 END IF
END SUB
 
SUB Instructions
 ClearLayer Layer(0)
 _DEST Layer(9)
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "OBJECT"
 _PRINTSTRING (1, 20), "To color all the blue lines"
 _PRINTSTRING (1, 30), "res by moving your man GAPPER"
 _PRINTSTRING (1, 40), "with the arrow keys.  At the"
 _PRINTSTRING (1, 50), "same time, you myst avoid"
 _PRINTSTRING (1, 60), "the SEEKER."
 
 _PRINTSTRING (84, 80), "POINTS"
 _PRINTSTRING (1, 90), "Fifty points are awarded for"
 _PRINTSTRING (1, 100), "each square that you surround"
 _PRINTSTRING (1, 110), "in red.  100 points are given"
 _PRINTSTRING (1, 120), "when you encircle the extra"
 _PRINTSTRING (1, 130), "point box while it is on. Each"
 _PRINTSTRING (1, 140), "gap costs 5 points."
 
 _PRINTSTRING (84, 150), "GAPPING"
 _PRINTSTRING (1, 160), "You can create a temporary"
 _PRINTSTRING (1, 170), "gap in the lines by pressing"
 _PRINTSTRING (1, 180), "the SPACE bar or RETURN.  The"
 _PRINTSTRING (1, 190), "word ON appears as long as the"
 _PRINTSTRING (1, 200), "gap is active.  Neither you nor"
 _PRINTSTRING (1, 210), "the seeker can cross the gap."
 
 _PRINTSTRING (0, 230), "Press a key..."
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 'end of page 1
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 CLS
 LINE (84, 0)-STEP(151, 8), Brown, BF
 LINE (132, 0)-STEP(52, 8), Cyan, BF
 COLOR Brown
 _PRINTSTRING (135, 1), "GAPPER"
 COLOR OffWhite
 _PRINTSTRING (84, 10), "LEVELS"
 _PRINTSTRING (1, 20), "The level increases each time"
 _PRINTSTRING (1, 30), "you complete a screen.  The"
 _PRINTSTRING (1, 40), "seeker gets faster, the gap"
 _PRINTSTRING (1, 50), "time shorter and there will"
 _PRINTSTRING (1, 60), "be more boxes."
 
 _PRINTSTRING (84, 80), "LIVES"
 _PRINTSTRING (1, 90), "You start out with 2 extra"
 _PRINTSTRING (1, 100), "men.  One more will be given"
 _PRINTSTRING (1, 110), "for each 5000 points."
 
 _PRINTSTRING (84, 130), "START"
 _PRINTSTRING (1, 140), "When the grid appears, you"
 _PRINTSTRING (1, 150), "Will be in the top left and"
 _PRINTSTRING (1, 160), "the seeker at the low right."
 _PRINTSTRING (1, 170), "Press a key to begin each new"
 _PRINTSTRING (1, 180), "screen."
 
 _PRINTSTRING (0, 230), "Press a key..."
 'end of page 2
 _PUTIMAGE , Layer(9), _DISPLAY
 _DELAY .5
 _KEYCLEAR
 DO: _LIMIT 24: LOOP WHILE INKEY$ = ""
 ClearLayer Layer(0)
END SUB
 
SUB Load_Scores
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 FOR i%% = 1 TO Count%%
  GET #1, , Scores(i%%).Nam
  GET #1, , Scores(i%%)
  GET #1, , Scores(i%%)
 NEXT i%%
 CLOSE #1
END SUB
 
FUNCTION Search_For_Player
 FOR i%% = 1 TO 10
  IF G.Player = Scores(i%%).Nam THEN Result%% = TRUE: i%% = 11 ELSE Result%% = FALSE
 NEXT i%%
 Search_For_Player = Result%%
END FUNCTION
 
SUB AddPlayer
 OPEN "Gapper.HSL" FOR BINARY AS #1
 GET #1, , Count%%
 IF Count%% < 10 THEN Count%% = Count%% + 1
 PUT #1, 1, Count%%
 PUT #1, 1 + 10 * Count%%, G.Player
 PUT #1, , NULL& 'filler for score
 PUT #1, , NULL% 'filler for level
 CLOSE #1
 Load_Scores 'reload score list
END SUB
 
SUB Reset_Pos
 PLAY "o1l32aacceegg"
 _DELAY .25
 G.Start = FALSE
 G.Caught = FALSE
 SELECT CASE G.Level
  CASE 1
   'Level 1 Start Pos.------
   G.GX = 0: G.GY = 14 'Gapper
   G.SX = 626: G.SY = 374 'Seeker
   '------------------------
 END SELECT
END SUB
 
SUB Level_1_Board
 FOR I%% = 0 TO 3
  LINE (4, 10 + I%% * 60)-STEP(311, 0), Cyan 'horizontal lines
  LINE (4 + I%% * 104, 10)-STEP(0, 180), Cyan 'vertical lines
 NEXT I%%
 G.SS = 2 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 1 Start Pos.------
 G.GX = 0: G.GY = 14 'Gapper
 G.SX = 626: G.SY = 374 'Seeker
 'Level 1 board info------
 G.CellWidth = 104
 G.CellHeight = 60
 G.Rows = 3
 G.Columns = 3
 G.Offx = 4
 G.Offy = 10
 G.Needed = 9
 G.Finished = 0
 '------------------------
 
END SUB
 
SUB Level_2_Board
 FOR I%% = 0 TO 4
  LINE (8, 12 + I%% * 44)-STEP(304, 0), Cyan 'horizontal lines
  LINE (8 + I%% * 76, 12)-STEP(0, 176), Cyan 'vertical lines
 NEXT I%%
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 2 Start Pos.------
 G.GX = 8: G.GY = 18 'Gapper
 G.SX = 616: G.SY = 370 'Seeker
 '------------------------
 'Level 2 board info------
 G.CellWidth = 76
 G.CellHeight = 44
 G.Rows = 4
 G.Columns = 4
 G.Offx = 8
 G.Offy = 12
 G.Needed = 16
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_3_Board
 FOR I%% = 0 TO 5
  LINE (10, 10 + I%% * 36)-STEP(300, 0), Cyan 'horizontal lines
  LINE (10 + I%% * 60, 10)-STEP(0, 180), Cyan 'vertical lines
 NEXT I%%
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 3 Start Pos.------
 G.GX = 12: G.GY = 14 'Gapper
 G.SX = 612: G.SY = 374 'Seeker
 '------------------------
 'Level 3 board info------
 G.CellWidth = 60
 G.CellHeight = 36
 G.Rows = 5
 G.Columns = 5
 G.Offx = 10
 G.Offy = 10
 G.Needed = 25
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_4_Board
 FOR I%% = 0 TO 6
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 48, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 4 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 4 board info------
 G.CellWidth = 48
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 6
 G.Offx = 16
 G.Offy = 16
 G.Needed = 42
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_5_Board
 FOR I%% = 0 TO 4
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 FOR I%% = 0 TO 2
  LINE (88, 136 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
  LINE (268 + I%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
 NEXT I%%
 
 G.SS = 1 'set seeker speed = player speed
 G.Start = FALSE
 'Level 5 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 458: G.SY = 362 'Seeker
 '------------------------
 'Level 5 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 44
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_6_Board
 FOR I%% = 0 TO 3
  LINE (16, 64 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 
 FOR I%% = 0 TO 1
  LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (88, 160 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
  LINE (268 + I%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
 NEXT I%%
 
 G.SS = 1 'set seeker speed = player speed
 G.Start = FALSE
 'Level 6 Start Pos.------
 G.GX = 168: G.GY = 26 'Gapper
 G.SX = 458: G.SY = 362 'Seeker
 '------------------------
 'Level 6 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 40
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_7_Board
 FOR I%% = 0 TO 4
  LINE (16, 88 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 FOR I%% = 0 TO 1
  LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
  LINE (268 + I%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
 NEXT I%%
 LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
 
 G.SS = 0 'set seeker speed = player speed
 G.Start = FALSE
 'Level 7 Start Pos.------
 G.GX = 168: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 7 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 44
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_8_Board
 FOR I%% = 0 TO 7
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (16 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 G.SS = 0 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 8 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 1 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 8
 G.Columns = 7
 G.Offx = 16
 G.Offy = 16
 G.Needed = 56
 G.Finished = 0
 '------------------------
END SUB
 
FUNCTION BoxSurrounded%% (boxNumber AS INTEGER) 'save already tested boxes in shared array BoxesSurrounded()
 'Bplus contributed code. 11\12\2021
 'some variables changed to use existing, `**` comments are added
 _SOURCE Layer(2)
 IF FinishedBox(boxNumber) = 0 THEN '**Is the box completed already?
  row = INT((boxNumber - 1) / G.Columns) '[cellsPerCpl)] '**which row
  col = (boxNumber - 1) MOD G.Columns + 1 '[cellsAcross + 1] '**which column
 
  Good%% = TRUE
  FOR I% = row * G.CellHeight TO (row + 1) * G.CellHeight STEP 4 '**No need to check every pixel
   IF POINT(G.Offx + (col - 1) * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
   IF POINT(G.Offx + col * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE
  NEXT I%
 
  IF Good%% THEN '**only check other lines if it hasn't failed yet
   FOR I% = (col - 1) * G.CellWidth TO col * G.CellWidth STEP 4 '**No need to check every pixel
    IF POINT(G.Offx + I%, G.Offy + row * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
    IF POINT(G.Offx + I%, G.Offy + (row + 1) * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE
   NEXT I%
  END IF
  IF Good%% THEN BoxSurrounded = -1: G.Finished = G.Finished + 1: G.Score = G.Score + 50 'all OK
 ELSE
  BoxSurrounded = -1
 END IF
 _SOURCE Layer(6)
END FUNCTION
 
SUB FillBox (boxNumber)
 _DEST Layer(2)
 row = INT((boxNumber - 1) / G.Columns)
 col = (boxNumber - 1) MOD G.Columns + 1
 LINE (G.Offx + (col - 1) * G.CellWidth + 3, G.Offy + row * G.CellHeight + 3)-STEP(G.CellWidth - 6, G.CellHeight - 6), OffWhite, BF
 COLOR Black
 _PRINTSTRING (G.Offx + (col - 1) * G.CellWidth + 3 + (INT(G.CellWidth \ 2) - 8), G.Offy + row * G.CellHeight + 3 + (INT(G.CellHeight \ 2) - 8)), "50", Layer(2)
 COLOR OffWhite
 _DEST Layer(0)
END SUB
 
SUB Change_Level
 G.Level = G.Level + 1
 ClearLayerTrans Layer(2)
 ClearLayer Layer(5)
 ClearLayer Layer(6)
 '_CLEARCOLOR _RGB32(0, 0, 0), Layer(2)
 DrawBoard
 FOR i%% = 0 TO 72
  FinishedBox(i%%) = FALSE
 NEXT i%%
END SUB

bplus · « **Reply #1 on:** November 15, 2021, 12:01:43 am »

Quote

@bplus any idea why BoxSurrounded stops working on that level?

The first set of code I posted in the other thread was flawed, not just the typo but several things needed fixing that the typo covered up. So if you are using that,... well should have problems on all levels.

My codes calculated cellWidth and CellHeight from cellsAcross and cellsDown not merely assigned as you have it here. And from those numbers the grid was based and drawn. I didn't worry about x margin and y margins because grids of different sizes fitting in same space left different margins after rounding to integer values and then multiplying by cellsAcross or cellsDown. I took the CellWidth = int(_Width/cellsAcross) -1 to be sure all the bars of grid were visible on screen, likewise similar calc for CellHeight.

So perhaps you miscalc'd on the level with a problem.

You could save allot of lines of code:

Code: QB64: [Select]

 
SUB Level_1_Board
 FOR I%% = 0 TO 3
  LINE (4, 10 + I%% * 60)-STEP(311, 0), Cyan 'horizontal lines
  LINE (4 + I%% * 104, 10)-STEP(0, 180), Cyan 'vertical lines
 NEXT I%%
 G.SS = 2 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 1 Start Pos.------
 G.GX = 0: G.GY = 14 'Gapper
 G.SX = 626: G.SY = 374 'Seeker
 'Level 1 board info------
 G.CellWidth = 104
 G.CellHeight = 60
 G.Rows = 3
 G.Columns = 3
 G.Offx = 4
 G.Offy = 10
 G.Needed = 9
 G.Finished = 0
 '------------------------
 
END SUB
 
SUB Level_2_Board
 FOR I%% = 0 TO 4
  LINE (8, 12 + I%% * 44)-STEP(304, 0), Cyan 'horizontal lines
  LINE (8 + I%% * 76, 12)-STEP(0, 176), Cyan 'vertical lines
 NEXT I%%
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 2 Start Pos.------
 G.GX = 8: G.GY = 18 'Gapper
 G.SX = 616: G.SY = 370 'Seeker
 '------------------------
 'Level 2 board info------
 G.CellWidth = 76
 G.CellHeight = 44
 G.Rows = 4
 G.Columns = 4
 G.Offx = 8
 G.Offy = 12
 G.Needed = 16
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_3_Board
 FOR I%% = 0 TO 5
  LINE (10, 10 + I%% * 36)-STEP(300, 0), Cyan 'horizontal lines
  LINE (10 + I%% * 60, 10)-STEP(0, 180), Cyan 'vertical lines
 NEXT I%%
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 3 Start Pos.------
 G.GX = 12: G.GY = 14 'Gapper
 G.SX = 612: G.SY = 374 'Seeker
 '------------------------
 'Level 3 board info------
 G.CellWidth = 60
 G.CellHeight = 36
 G.Rows = 5
 G.Columns = 5
 G.Offx = 10
 G.Offy = 10
 G.Needed = 25
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_4_Board
 FOR I%% = 0 TO 6
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 48, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
 G.SS = 1 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 4 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 4 board info------
 G.CellWidth = 48
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 6
 G.Offx = 16
 G.Offy = 16
 G.Needed = 42
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_5_Board
 FOR I%% = 0 TO 4
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 FOR I%% = 0 TO 2
  LINE (88, 136 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
  LINE (268 + I%% * 36, 16)-STEP(0, 96), Cyan 'vertical lines
 NEXT I%%
 
 G.SS = 1 'set seeker speed = player speed
 G.Start = FALSE
 'Level 5 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 458: G.SY = 362 'Seeker
 '------------------------
 'Level 5 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 44
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_6_Board
 FOR I%% = 0 TO 3
  LINE (16, 64 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 
 FOR I%% = 0 TO 1
  LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (88, 160 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
  LINE (268 + I%% * 36, 64)-STEP(0, 72), Cyan 'vertical lines
 NEXT I%%
 
 G.SS = 1 'set seeker speed = player speed
 G.Start = FALSE
 'Level 6 Start Pos.------
 G.GX = 168: G.GY = 26 'Gapper
 G.SX = 458: G.SY = 362 'Seeker
 '------------------------
 'Level 6 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 40
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_7_Board
 FOR I%% = 0 TO 4
  LINE (16, 88 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (88 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 FOR I%% = 0 TO 1
  LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
  LINE (268 + I%% * 36, 88)-STEP(0, 96), Cyan 'vertical lines
 NEXT I%%
 LINE (88, 16 + I%% * 24)-STEP(144, 0), Cyan 'horizontal lines
 
 G.SS = 0 'set seeker speed = player speed
 G.Start = FALSE
 'Level 7 Start Pos.------
 G.GX = 168: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 7 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 7
 G.Columns = 8
 G.Offx = 16
 G.Offy = 16
 G.Needed = 44
 G.Finished = 0
 '------------------------
END SUB
 
SUB Level_8_Board
 FOR I%% = 0 TO 7
  LINE (16, 16 + I%% * 24)-STEP(288, 0), Cyan 'horizontal lines
  LINE (16 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 NEXT I%%
 LINE (16 + I%% * 36, 16)-STEP(0, 168), Cyan 'vertical lines
 G.SS = 0 'set seeker speed 1\4th player speed
 G.Start = FALSE
 'Level 8 Start Pos.------
 G.GX = 24: G.GY = 26 'Gapper
 G.SX = 600: G.SY = 362 'Seeker
 '------------------------
 'Level 1 board info------
 G.CellWidth = 36
 G.CellHeight = 24
 G.Rows = 8
 G.Columns = 7
 G.Offx = 16
 G.Offy = 16
 G.Needed = 56
 G.Finished = 0
 '------------------------
END SUB
 

With one sub that also draws the grid

Code: QB64: [Select]

Sub Level(cellsAcross, cellsDown)  
    nCells = cellsAcross * cellsDown
    cellWidth = Int(_Width / cellsAcross - 1) 'subtract 1 to get borders around all cells on screen
    cellHeight = Int(_Height / cellsDown - 1)
    ' surroundColor = _RGB32(255, 0, 255) ' purple as I recall
    ReDim Shared BoxesSurrounded(1 To nCells) As Integer
    '_Title "Box Surrounded Test: To demo, we need to start with a grid... zzz = Sleep, press any to continue."
    'Sleep
    'drawGrid
    For I = 0 To _Width Step cellWidth
        Line (I, 0)-(I, cellsDown * cellHeight)
    Next
    For I = 0 To _Height Step cellHeight
        Line (0, I)-(cellsAcross * cellWidth, I)
    Next
    'label cells (boxes) with id number
    'I = 1
    'For r = 1 To cellsDown
    '    For c = 1 To cellsAcross
    '        _PrintString ((c - 1) * cellWidth + 2, (r - 1) * cellHeight + 2), _Trim$(Str$(I))
    '        I = I + 1
    '    Next
    'Next
end sub

Your mod of my code isn't even using the part that saves you all that redundant box checking by using an array to store boxes already checked! the BoxesSurrounded array:

Code: QB64: [Select]

Function BoxSurrounded% (boxNumber As Integer) 'save already tested boxes in shared array BoxesSurrounded()
    If BoxesSurrounded(boxNumber) = 0 Then  ' <<<<<  Save time don't check any box twice!!!!!!!!!!!!!!
        row = Int((boxNumber - 1) / cellsAcross)
        col = (boxNumber - 1) Mod cellsAcross + 1
        For i = row * cellHeight To row * cellHeight + row
            If Point((col - 1) * cellWidth, i) <> surroundColor Then Exit Function ' False Box not surrounded
            If Point(col * cellWidth, i) <> surroundColor Then Exit Function
        Next
        For i = (col - 1) * cellWidth To col * cellWidth
            If Point(i, row * cellHeight) <> surroundColor Then Exit Function ' False Box not surrounded
            If Point(i, row * cellHeight + row) <> surroundColor Then Exit Function
        Next
 BoxesSurrounded(boxNumber) = -1  '<<<< set this too while we're here
        BoxSurrounded% = -1 'all OK
    Else
        BoxSurrounded = -1
    End If
End Function
 
 

Cobalt · « **Reply #2 on:** November 15, 2021, 12:10:10 pm »

Quote from: bplus on November 15, 2021, 12:01:43 am

The first set of code I posted in the other thread was flawed, not just the typo but several things needed fixing that the typo covered up. So if you are using that,... well should have problems on all levels.

I made the adjustment to the code when you posted that. But I will go over it again and make sure I didn't miss something (not that that would ever happen[heavy sarcasm!])

Quote from: bplus on November 15, 2021, 12:01:43 am

My codes calculated cellWidth and CellHeight from cellsAcross and cellsDown not merely assigned as you have it here. And from those numbers the grid was based and drawn. I didn't worry about x margin and y margins because grids of different sizes fitting in same space left different margins after rounding to integer values and then multiplying by cellsAcross or cellsDown. I took the CellWidth = int(_Width/cellsAcross) -1 to be sure all the bars of grid were visible on screen, likewise similar calc for CellHeight.

So perhaps you miscalc'd on the level with a problem.

Its all pretty straight forward in terms of numbers. the Columns and Rows max out at 8x7 at level 5 and keep that till level 8. Its just the shape that changes with levels 5,6, and 7.

Quote from: bplus on November 15, 2021, 12:01:43 am

You could save allot of lines of code:

True, that was just a quick and dirty way to get them all roughed out, and a single sub for levels 1 to 4 +8 would be best. however Levels 5,6 and 7 are not "square". the layout is shaped differently, as a "T", "+", and upside down "T" (attachment below)

Quote from: bplus on November 15, 2021, 12:01:43 am

Your mod of my code isn't even using the part that saves you all that redundant box checking by using an array to store boxes already checked! the BoxesSurrounded array:

Actually it does, but I already had an array I was trying to use so I just popped in my array name. which was "FinishedBox". So it still makes sure the box isn't done just with a different name. And only because I already had an array for it. (as the second comment down notes)

Code: QB64: [Select]

FUNCTION BoxSurrounded%% (boxNumber AS INTEGER) 'save already tested boxes in shared array BoxesSurrounded()
 'Bplus contributed code. 11\12\2021
 'some variables changed to use existing, `**` comments are added
 _SOURCE Layer(2)
 IF FinishedBox(boxNumber) = 0 THEN '**Is the box completed already? <------------- originally BoxesSurrounded
  row = INT((boxNumber - 1) / G.Columns) '[cellsPerCpl)] '**which row
  col = (boxNumber - 1) MOD G.Columns + 1 '[cellsAcross + 1] '**which column
 
  Good%% = TRUE
  FOR I% = row * G.CellHeight TO (row + 1) * G.CellHeight STEP 4 '**No need to check every pixel
   IF POINT(G.Offx + (col - 1) * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
   IF POINT(G.Offx + col * G.CellWidth, G.Offy + I%) <> Magenta THEN I% = 9999: Good%% = FALSE
  NEXT I%
 
  IF Good%% THEN '**only check other lines if it hasn't failed yet
   FOR I% = (col - 1) * G.CellWidth TO col * G.CellWidth STEP 4 '**No need to check every pixel
    IF POINT(G.Offx + I%, G.Offy + row * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE ' False Baox not surrounded
    IF POINT(G.Offx + I%, G.Offy + (row + 1) * G.CellHeight) <> Magenta THEN I% = 9999: Good%% = FALSE
   NEXT I%
  END IF
  IF Good%% THEN BoxSurrounded = -1: G.Finished = G.Finished + 1: G.Score = G.Score + 50 'all OK
 ELSE
  BoxSurrounded = -1
 END IF
 _SOURCE Layer(6)
END FUNCTION
 

Though with the problem on level 5, I attached what it is doing. it simply stops acknowledging surrounded boxes near the bottom of the board. Now this board is "T" shaped, but I just assumed the function would treat it as if all the board was there. Thats why G.Needed(which denotes the number of boxes on screen to finish a board) is set to 44 and not 56(8*7). But it stops filling boxes at 38.

bplus · « **Reply #3 on:** November 15, 2021, 12:27:08 pm »

Ah different shaped grids!! I missed that.

So the box number system would need to pretend the missing boxes (from a fully gridded rectangle) are there as the row and column the box is in is determined by numbers.

Wow tracking where you are able to go with hero and chaser would get hairy. For boxes enclosed you can't mark the pretend boxes as enclosed and you better not try and check them from boxes enclosed array that tracks boxes checked.

Well different shaped grids with missing chunks from full rectangle was not a mod I anticipated with my code.

Cobalt · « **Reply #4 on:** November 15, 2021, 12:32:31 pm »

I think I've figured out what I did.

Code: QB64: [Select]

 FOR i%% = 1 TO G.Needed
  IF BoxSurrounded(i%%) THEN FinishedBox(i%%) = TRUE
  IF FinishedBox(i%%) THEN FillBox i%%
 NEXT i%%
 

I'm pretty sure that was telling it to stop checking for boxes after what was needed for the level, where as BoxSurrounded was looking at all 56 possible boxes. I forgot about the "invisible" boxes counting. and if you add the boxes on the sides of the level 5 board that you cant see into the 38 you come up with 44. upon which the FOR:NEXT stopped checking.

Code: QB64: [Select]

 FOR i%% = 1 TO G.Columns * G.Rows
  IF BoxSurrounded(i%%) THEN FinishedBox(i%%) = TRUE
  IF FinishedBox(i%%) THEN FillBox i%%
 NEXT i%%
 

This seems to have fixed it. So now its checking the entire grid space. even though it will not all be used.
Wonder what it would take to do diagonal lines? Not that the original game had those, but might make an interesting addition.

well now to clean the code up some.

bplus · « **Reply #5 on:** November 15, 2021, 12:47:15 pm »

Glad you have it figured out, your mods are extending beyond the original assumptions I had for BoxEnclosed function. Not sure if those boxes not being used should be premarked as enclosed or not? Maybe so or definitely not. If you want to avoid even more pixel checking you could check if adjacent boxes are enclosed ie a box has boxes enclosed on all of it's 4 sides would itself have to be enclosed without checking a single pixel.

Diagonals, ha! how about every pixel? ;-))

News:

Author Topic: Gapper Playable to level 5 (Read 2392 times)

Cobalt

Gapper Playable to level 5

bplus

Re: Gapper Playable to level 5

Cobalt

Re: Gapper Playable to level 5

bplus

Re: Gapper Playable to level 5

Cobalt

Re: Gapper Playable to level 5

bplus

Re: Gapper Playable to level 5