differences between LINUX and WINDOZE mouse routines?

[Colonel_Panic]

phase 1 --- I begin to make retro games in QB64-WINdoze...
                  mouse *fine* in windoze.
                 
phase 2 --- compile SAME code to LINUX?
                  mouse is... drunk?

phase 3 --- decide to make retro games next in LINUX
                 mouse fine in LINUX

phase 4 --- compile to WINDOWS?
                  mouse is "sloppy drunk".

========================

now, I *am* a programmer; I have *some* logic to me, at least a little...
best I can explain? its as if, one is working on mouse UP, and the other on mouse DOWN...
and i have to PICK.

what am i missing, what am i describing?

[SMcNeill]

what am i missing, what am i describing?

A bad program?  Two computers with different settings?  Who knows!

Code, or it didn't happen.  😘   

We can't even attempt to diagnose problems without some sort of code to work off from.

[Colonel_Panic]

okay... let me see...

Code: QB64: [Select]

1. Sub PollMouseClicks ()
2.   found_lc = 0
3.   MS$ = ""
4.   If _MouseInput Then
5.     If _MouseButton(1) Or _MouseButton(2) = -1 Then
6.       If _MouseButton(1) And _MouseButton(2) Then LR$ = "LR": GoTo around:
7.       If _MouseButton(1) Then LR$ = "L"
8.       If _MouseButton(2) Then LR$ = "R"
9.       around:
10.       For t = 1 To clix_cnt
11.         If _MouseX >= clix!(t, 1) And _MouseX <= clix!(t, 3) Then
12.           If _MouseY >= clix!(t, 2) And _MouseY <= clix!(t, 4) Then
13.             Mx = _MouseX: My = _MouseY
14.             found_lc = t 'we trapped our click, but first...
15.             'if item *or parent* is not .visible, clix! needs to ignore
16.             'note default is .visible ON, if the def'n file doesn't specify
17.             nothing$ = GetMakeProperty$(proj$ + "." + clix_name$(t) + ".visible", "1")
18.             nothing2$ = GetMakeProperty$(proj$ + "." + ExtractParent$(clix_name$(t)) + ".visible", "1")
19.             If Val(nothing$) = 0 Or Val(nothing2$) = 0 Then found_lc = 0: GoTo cl_mouse:
20.             'both control & parent must be .visible
21.             'TXT$ = String$(64, " "): _PrintString (10, 10), TXT$
22.             'TXT$ = "you clicked on: " + clix_name$(t)
23.             '_PrintString (10, 10), TXT$
24.             'clear the mouse
25.             cl_mouse:
26.             If _MouseInput Then GoTo cl_mouse: Else GoTo done_mouse:
27.           End If
28.         End If
29.       Next t
30.     End If
31.   End If
32.   done_mouse:
33.   If ide_sw = 1 Then
34.     If found_lc > 0 And LR$ = "L" Then AdjustProperties (clix_name$(t))
35.     If found_lc > 0 And LR$ = "R" Then MoveObject (clix_name$(t))
36.   End If
37. End Sub
38.  

if i did this right, the above "code" is the "mouse click trapping" routine for... my project.
fast and accurate in Linux Mint... compile the same exact program in Windows?
drunken mouse clicking, is the best way i can describe it.

I cant post the whole program that calls it... its 1,983 lines of QB64 code.
but... here's the "main program flow" that ends up calling it...

Code: QB64: [Select]

1. Do: Loop Until _ScreenExists
2. _Title "CodeName:Takky 0.0.7 - preBETA"
3. _Display
4.  
5.  
6. ide_sw = 0
7.  
8. _Display
9. proj$ = "demo"
10.  
11. OpenProject: _Font fhand&: SplashDemo
12. PaintAllForms
13. again1:
14. If ide_sw = 1 Then
15.   _PrintString (110, 10), "F1=SAVE; F2=MakeForm; F3=MakeObj; F4=KillForm; F5=KillObj"
16.   _PrintString (110, 25), "L-Click=.props; R-Click=MoveObj"
17.   _Display
18. End If
19. PollMouseClicks
20. If ide_sw = 0 Then
21.   If found_lc > 0 Then
22.     Shell _DontWait "pacat --fix-format --fix-rate start.wav"
23.     PerformMouseClicks
24.   End If
25.   _Display
26. End If
27.  
28. 'BEGIN - KEY CALLS
29. 'These are the ESC and F1-F5 calls. UNcomment for IDE, comment out for run time
30. 'TIP: ESC is a handy "end" key,
31. 'and F1-save + others can be handy at run time while                                                                                                                                                                                                                                                                                                                                                           working
32. 'If _KeyDown(15104) Then UpdateDefn 'F1
33. 'If _KeyDown(15360) Then MakeForm 'F2
34. 'If _KeyDown(15616) Then MakeControl 'F3
35. 'If _KeyDown(15872) Then KillForm 'F4
36. 'If _KeyDown(16128) Then KillObject 'F5
37. If _KeyDown(27) Then End 'OutputProjectBones 'ESC
38. 'END - KEY CALLS
39.  
40. GoTo again1:
41. End

thats basically "the whole program"... the rest of the 1983 lines of code? is basically all the "support routines"

[Colonel_Panic]

in this particular case? the LINUX compiled 'demo.bas' runs perfect.
then the WIN compiled 'demo.bas', not one byte changed, compiles fine. slow but fine.
it executes on WIN fine, except for
"drunken mouse clicking"... other than that, everything is 100% accurate and technically runs fine.

in this case? the windows "drunken stupor" manifests itself with what I feel like are 'extra mouse clicks" after
the "real" mouse click has been picked up and acted upon. A couple extra clicks tend to get through.
the same "pixel" click, just one or two extra after the fact.

as I am not an expert in the matter, but it is a consistent ongoing issue (for me anyways) it would SEEM
to be as if the "clear the mouse" routine were not working under WIN, but running fine in LINUX.

PS - I deployed to MANJARO? and no extra clicks.

[Colonel_Panic]

@McNeill:
A bad program? (or a loose nut on the keyboard, lol) 

Two computers with different settings? (MINT is native install, WIN's are all VM land, but. so is MANJARO which was good)
seems to rule out VM as culprit?

  Who knows!
I figured someone else might have run across a same/similar mouse issue.

[bplus]

Code: QB64: [Select]

1. Sub PollMouseClicks ()
2.   found_lc = 0
3.   MS$ = ""
4.   If _MouseInput Then
5.     If _MouseButton(1) Or _MouseButton(2) = -1 Then
6.       If _MouseButton(1) And _MouseButton(2) Then LR$ = "LR": GoTo around:
7.       If _MouseButton(1) Then LR$ = "L"
8.       If _MouseButton(2) Then LR$ = "R"
9.  

Unless you need mousewheel, poll mouse like this:

Code: QB64: [Select]

1. While _MouseInput: Wend  ' update Mouse status

This will update your mouse x, y position and buttons. You don't need to get inside that loop unless you need mouse wheel updates.

Every noobie (including me) gets this wrong! because they think they should be getting mouse info from inside that loop.

[SMcNeill]

I'd suggest reading over the topic here for understanding: https://www.qb64.org/forum/index.php?topic=4312.0

The issue you're having is from reading more mouse events than your program is processing each loop.  As each OS is different on how often they poll the mouse drivers, that explains why you're getting different results on different systems.

My advice:

Instead of IF _MOUSEINPUT, go with a routine to clear that buffer at start:

WHILE _MOUSEINPUT: WEND
LB = _MOUSEBUTTON(1): RB = _MOUSEBUTTON(2)
IF LB AND RB THEN
    LR$ = "LR"
ELSEIF LB THEN
    LR$ = "L"
ELSEIF RB THEN
   LR$ = "R"
END IF

[Colonel_Panic]

awesome!

thanks mcneil, and everyone else who chimed in...
I just figured I wasn't alone. great.

FINAL ANALYSIS:
 loose nut on my keyboard.
 tightened up.
 
Yeah, I really dont know what goes on in the Mouse routines
I... "fiddle" with mouse code... it gets working... and i try not to TOUCH IT when its working.

I *suppose* its about time, I took a break and "played" with the mouse for something SMALL,
until I can get past "first base" with the MOUSE.

see how many OS's I can satisfy at once, for a tiny non-game.

[Colonel_Panic]

McNeill-----> kudos
Bplus-------> kudos

hopefully, I can help back or help forward over time.

its funny to me, when I was a "cool programmer" way back when?
honestly, someone else always did...

1) mouse
2) high end screen stuff
3) everyone's fun game "where the &^%$ is my FILE !!!" ("MAPped" network drive(s) ??)

I basically "unplugged" those 2 sections of code (mouse/screen), and "worked" with a very basic text list.
I sort of "plugged back in" the mouse and screen, so to speak, when i was done "working" for the day.

I am "circling around" and picking up graphics and mouse and stuff to go with "everything" I want to do now.