Trick or Treat simulator(One key only)

[Cobalt]

well for shints and giggles I thought I would throw something together for this one key only Halloween game thingy, not sure just what it is actually about or if this would even count, but hell why not.

The values will need some tweaking but they'll work for now. Perhaps I should add some random events too?

still pickin' the bugs out of my teeth but it mostly works. some weird inconsistency in some numbers I need to address but what do you guys think of the idea so far?

only key used is Space bar

Code: QB64: [Select]

1. 'Trick or Treat  candy collection simulator
2. 'One key only input
3. '2021-12-Oct
4. 'Author - Cobalt
5.  
6. '-----------------Lets do our setup---------------------
7. TYPE Trick_or_Treatr_Data
8.  Bag_Size AS _BYTE 'Size of player's colletion bag; Small, Med, Large, and back of Dad's pickup!
9.  Houses_hit AS INTEGER 'How many houses has player approched?
10.  Treats AS SINGLE 'How many OZs of treats has player recieved
11.  Tricks AS INTEGER 'How many Tricks have been played on player
12.  Energy AS SINGLE 'How much energy\drive does player have to walk up to houses?
13.  Distance AS SINGLE 'How far has player traveled collecting candy?
14. END TYPE
15.  
16. TYPE Game_Data
17.  N_Houses AS _BYTE 'How many houses are lit on street
18.  E_Houses AS _BYTE
19.  W_Houses AS _BYTE
20.  S_Houses AS _BYTE
21.  N_Feet AS INTEGER 'how long is the street(This is used to calculate remaining energy)
22.  E_Feet AS INTEGER
23.  W_Feet AS INTEGER
24.  S_Feet AS INTEGER
25.  Egain AS INTEGER 'slight random chance of regaining energy
26.  Eloss AS INTEGER 'energy loss from tricks
27.  Street AS _BYTE
28.  Treats AS _BYTE 'how much candy did player get from that street?
29. END TYPE
30.  
31. CONST True = -1, False = NOT True
32. CONST North = 0, East = 2, West = 3, South = 1
33.  
34. SCREEN 0: CLS: RANDOMIZE TIMER 'havent used this main line setup in YEARS!
35. DIM SHARED Player AS Trick_or_Treatr_Data
36. DIM SHARED Game AS Game_Data
37. DIM SHARED Directions(3) AS STRING
38. DIM SHARED Layer(4) AS LONG
39. Layer(1) = _NEWIMAGE(80, 25, 0) 'our temp layer
40. Layer(2) = _NEWIMAGE(80, 25, 0) 'Menu Master layer
41. '------------------------------------------------------
42. Directions(0) = "North"
43. Directions(1) = "South"
44. Directions(2) = "East"
45. Directions(3) = "West"
46.  
47. Player.Energy = 5280 'players starting energy
48. Player.Distance = 0
49. '------------------------------------------------------
50.  
51. Title_Screen
52. _TITLE "Trick Or Treat Sim Ver 1.0"
53. DO: _LIMIT 60: LOOP UNTIL _KEYHIT = 32
54. DO: LOOP WHILE _KEYDOWN(32) 'wait for player to release spacebar
55. _KEYCLEAR
56. Select_Collection_Bag_Size
57.  
58. DO
59.  Create_Street_Options 'pick new streets
60.  Select_Street
61.  IF Game.Street < 4 THEN
62.   IF Player.Energy > 0 THEN
63.    IF VAL(Bag_Load) < 100 THEN
64.     Generate_Results Game.Street
65.     Display_Stats
66.     Display_Results
67.     PCOPY Layer(1), _DISPLAY
68.     DO: _LIMIT 60: LOOP UNTIL _KEYHIT = 32
69.     DO: LOOP WHILE _KEYDOWN(32) 'wait for player to release spacebar
70.     _KEYCLEAR
71.    ELSE
72.     Display_Stats
73.     PRINT "Bag Too Full"
74.     PRINT: PRINT: PRINT: PRINT: PRINT "press space bar to continue"
75.     PCOPY Layer(1), _DISPLAY
76.     DO: _LIMIT 60: LOOP UNTIL _KEYHIT = 32
77.     DO: LOOP WHILE _KEYDOWN(32) 'wait for player to release spacebar
78.     _KEYCLEAR
79.    END IF
80.   ELSE
81.    Display_Stats
82.    PRINT "Too Tired."
83.    PRINT: PRINT: PRINT: PRINT: PRINT "press space bar to continue"
84.    PCOPY Layer(1), _DISPLAY
85.    DO: _LIMIT 60: LOOP UNTIL _KEYHIT = 32
86.    DO: LOOP WHILE _KEYDOWN(32) 'wait for player to release spacebar
87.    _KEYCLEAR
88.   END IF
89.  ELSE
90.   _DEST _DISPLAY
91.   CLS
92.   'Player quit so display final stats
93.   PRINT "You visited"; Player.Houses_hit; "houses and collected"; Player.Treats; "oz of candy!"
94.   PRINT "You traveled"; Generate_Distance(5); "miles in your search for candy."
95.   PRINT "You were tricked"; Player.Tricks; "times."
96.   PRINT
97.   PRINT "your bag was"; Bag_Load; " full,"
98.   SELECT CASE VAL(Bag_Load)
99.    CASE IS > 100
100.     PRINT "Amazing job! Just don't forget to brush your teeth!"
101.    CASE 80 TO 100
102.     PRINT "Not Bad, enough candy for a super sugar high!"
103.    CASE 50 TO 79
104.     PRINT "A good practice year, you'll get even more next year for sure!"
105.    CASE 30 TO 49
106.     PRINT "What happened!? Too many tricks and not enough treats?"
107.    CASE IS < 29
108.     PRINT "Pathetic... really pathetic! You call your self a Trick or Treatr'?"
109.   END SELECT
110.   Exitflag%% = True
111.  END IF
112. LOOP UNTIL Exitflag%%
113.  
114.  
115. SUB Display_Results
116.  _DEST Layer(1)
117.  LOCATE 4, 1
118.  PRINT "After walking"; Generate_Distance(Game.Street); " miles and visiting";
119.  
120.  SELECT CASE Game.Street
121.   CASE North
122.    PRINT Game.N_Houses; "houses;"
123.   CASE South
124.    PRINT Game.S_Houses; "houses;"
125.   CASE East
126.    PRINT Game.E_Houses; "houses;"
127.   CASE West
128.    PRINT Game.W_Houses; "houses;"
129.  END SELECT
130.  PRINT "You gained"; Game.Treats; "oz candy."
131.  PRINT "You lost an extra"; Game.Eloss; "points of energy from tricks."
132.  IF Game.Egain THEN
133.   PRINT "You gained"; Game.Egain; "energy from a punch bowl at one house!"
134.   Game.Egain = 0
135.  END IF
136.  PRINT: PRINT: PRINT: PRINT
137.  PRINT "press any space bar to continue"
138. END SUB
139.  
140.  
141. SUB Generate_Results (Which%%)
142.  SELECT CASE Which%%
143.   CASE North
144.    Player.Distance = Player.Distance + Game.N_Feet
145.    Player.Energy = Player.Energy - Game.N_Feet 'Remove the distance traveled from players energy
146.    H%% = Game.W_Houses 'temp variable for number of houses
147.   CASE South
148.    Player.Distance = Player.Distance + Game.S_Feet
149.    Player.Energy = Player.Energy - Game.S_Feet
150.    H%% = Game.S_Houses 'temp variable for number of houses
151.   CASE East
152.    Player.Distance = Player.Distance + Game.E_Feet
153.    Player.Energy = Player.Energy - Game.E_Feet
154.    H%% = Game.E_Houses 'temp variable for number of houses
155.   CASE West
156.    Player.Distance = Player.Distance + Game.W_Feet
157.    Player.Energy = Player.Energy - Game.W_Feet
158.    H%% = Game.W_Houses 'temp variable for number of houses
159.  END SELECT
160.  'how many houses treated and how many tricked
161.  Player.Houses_hit = Player.Houses_hit + H%%
162.  Game.Treats = INT(H%% * (RND + .05)) 'treats add weight
163.  Tricks = H%% - Game.Treats 'tricks take energy
164.  Player.Treats = Player.Treats + INT(RND * Game.Treats) * 2 'add to weight up to 2x the treat houses
165.  Game.Eloss = Tricks * 2 'stored here for the results messages
166.  Player.Energy = Player.Energy - Tricks * 2 'energy cost
167.  Player.Tricks = Player.Tricks + Tricks
168.  IF INT(RND * 128) = 44 THEN 'get an energy bonus
169.   'slight chance that player will gain some energy
170.   Game.Egain = INT(RND * 263) + 263
171.   Player.Energy = Player.Energy + Game.Egain
172.  END IF
173. END SUB
174.  
175. SUB Select_Street
176.  '---------------create menu for bag selection----------------
177.  Make_Menu 2
178.  '------------------------------------------------------------
179.  _DEST Layer(1)
180.  'main loop
181.  Selection_Timer = 0
182.  DO
183.  
184.   IF _KEYDOWN(32) THEN
185.    'Move the selection while spacebar is down at 1\2 second intervals
186.    Selection_Timer%% = Selection_Timer%% + 1
187.    Key_Down%% = True
188.   ELSE
189.    Key_Down%% = False
190.   END IF
191.  
192.   IF Key_Down%% THEN 'while key is down increment selection every 30 cycles
193.    IF Selection_Timer%% = 30 THEN Selection%% = Selection%% + 1: Selection_Timer%% = 0
194.    IF Selection%% = 6 THEN Selection%% = 1
195.   ELSEIF Selection%% > 0 THEN 'only make choice if a selection was made
196.    Game.Street = Selection%% - 1
197.    ExitFlag%% = True
198.   ELSE
199.    Selection_Timer%% = 0 'if player just tapped space bar reset timer
200.   END IF
201.  
202.   PCOPY Layer(2), Layer(1)
203.   COLOR 14
204.   SELECT CASE Selection%%
205.    CASE 1
206.     LOCATE 12, 12: Describe_Street Game.N_Houses, Generate_Distance(North), North
207.    CASE 2
208.     LOCATE 14, 12: Describe_Street Game.S_Houses, Generate_Distance(South), South
209.    CASE 3
210.     LOCATE 16, 12: Describe_Street Game.E_Houses, Generate_Distance(East), East
211.    CASE 4
212.     LOCATE 18, 12: Describe_Street Game.W_Houses, Generate_Distance(West), West
213.    CASE 5
214.     LOCATE 20, 12: PRINT "All done, head home."
215.   END SELECT
216.   Display_Stats
217.   PCOPY Layer(1), _DISPLAY
218.   CLS
219.   _LIMIT 60
220.  LOOP UNTIL ExitFlag%%
221.  COLOR 7
222.  _KEYCLEAR
223. END SUB
224.  
225. SUB Create_Street_Options
226.  'generate the street info at this intersection
227.  'Houses giving candy
228.  Game.N_Houses = INT(RND * 100) + 1
229.  Game.S_Houses = INT(RND * 100) + 1
230.  Game.E_Houses = INT(RND * 100) + 1
231.  Game.W_Houses = INT(RND * 100) + 1
232.  'length of street(energy used to visit houses)
233.  Game.N_Feet = INT(RND * 1056) + 528 + Game.N_Houses * 10
234.  Game.S_Feet = INT(RND * 1056) + 528 + Game.S_Houses * 10
235.  Game.E_Feet = INT(RND * 1056) + 528 + Game.E_Houses * 10
236.  Game.W_Feet = INT(RND * 1056) + 528 + Game.W_Houses * 10
237. END SUB
238.  
239. SUB Select_Collection_Bag_Size
240.  '---------------create menu for bag selection----------------
241.  Make_Menu 1
242.  '------------------------------------------------------------
243.  _DEST Layer(1)
244.  'main loop
245.  Selection_Timer = 0
246.  DO
247.  
248.   IF _KEYDOWN(32) THEN
249.    'Move the selection while spacebar is down at 1\2 second intervals
250.    Selection_Timer%% = Selection_Timer%% + 1
251.    Key_Down%% = True
252.   ELSE
253.    Key_Down%% = False
254.   END IF
255.  
256.   IF Key_Down%% THEN 'while key is down increment selection every 30 cycles
257.    IF Selection_Timer%% = 30 THEN Selection%% = Selection%% + 1: Selection_Timer%% = 0
258.    IF Selection%% = 5 THEN Selection%% = 1
259.   ELSEIF Selection%% > 0 THEN 'only make choice if a selection was made
260.    Player.Bag_Size = Selection%%
261.    ExitFlag%% = True
262.   ELSE
263.    Selection_Timer%% = 0 'if player just tapped space bar reset timer
264.   END IF
265.  
266.   PCOPY Layer(2), Layer(1)
267.   COLOR 14
268.   SELECT CASE Selection%%
269.    CASE 1
270.     LOCATE 12, 12: PRINT "Small bag(can hold ~160oz)"
271.    CASE 2
272.     LOCATE 14, 12: PRINT "Medium bag(can hold ~240oz)"
273.    CASE 3
274.     LOCATE 16, 12: PRINT "Large bag(can hold ~400oz)"
275.    CASE 4
276.     LOCATE 18, 12: PRINT "Dad's Pickup Truck(can hold ~32000oz)"
277.   END SELECT
278.   Display_Stats
279.   PCOPY Layer(1), _DISPLAY
280.   CLS
281.   _LIMIT 60
282.  LOOP UNTIL ExitFlag%%
283.  COLOR 7
284. END SUB
285.  
286. SUB Make_Menu (Which%%)
287.  _DEST Layer(2)
288.  CLS
289.  LOCATE 3, 1: PRINT "Instructions: Hold the space bar down until your option is selected then release "
290.  LOCATE 4, 1: PRINT "              the space bar. Selected option will display in";: COLOR 14: PRINT " Yellow": COLOR 7
291.  SELECT CASE Which%%
292.   CASE 1 'bag selection menu"
293.    Display_Option_Box 10, 10, 60, 9
294.    LOCATE 10, 28: PRINT "Select your candy Bag size"
295.    LOCATE 12, 12: PRINT "Small bag(can hold ~160oz)"
296.    LOCATE 14, 12: PRINT "Medium bag(can hold ~240oz)"
297.    LOCATE 16, 12: PRINT "Large bag(can hold ~400oz)"
298.    LOCATE 18, 12: PRINT "Dad's Pickup Truck(can hold ~32000oz)"
299.   CASE 2 'Street Selection Menu"
300.    Display_Option_Box 5, 10, 70, 11
301.    LOCATE 10, 28: PRINT "Select Street to collect from"
302.    LOCATE 12, 12: Describe_Street Game.N_Houses, Generate_Distance(North), North
303.    LOCATE 14, 12: Describe_Street Game.S_Houses, Generate_Distance(South), South
304.    LOCATE 16, 12: Describe_Street Game.E_Houses, Generate_Distance(East), East
305.    LOCATE 18, 12: Describe_Street Game.W_Houses, Generate_Distance(West), West
306.    LOCATE 20, 12: PRINT "All done, head home."
307.  END SELECT
308.  _DEST Layer(1)
309. END SUB
310.  
311. SUB Display_Option_Box (X1, Y1, Xsize, Ysize)
312.  'Ä¿À³ÙÚ
313.  '----------top and bottom line----------------
314.  FOR x% = 0 TO Xsize
315.   LOCATE Y1, X1 + x%: PRINT "Ä"
316.   LOCATE Y1 + Ysize, X1 + x%: PRINT "Ä"
317.  NEXT x%
318.  '---------------------------------------------
319.  '---------Left and Right lines----------------
320.  FOR y% = 0 TO Ysize
321.   LOCATE Y1 + y%, X1: PRINT "³"
322.   LOCATE Y1 + y%, X1 + Xsize: PRINT "³"
323.  NEXT y%
324.  '---------------------------------------------
325.  '----------Four corners-----------------------
326.  LOCATE Y1, X1: PRINT "Ú"
327.  LOCATE Y1 + Ysize, X1: PRINT "À"
328.  LOCATE Y1, X1 + Xsize: PRINT "¿"
329.  LOCATE Y1 + Ysize, X1 + Xsize: PRINT "Ù"
330.  '---------------------------------------------
331. END SUB
332.  
333. SUB Display_Stats
334.  _DEST Layer(1)
335.  LOCATE 1, 1: PRINT "Bag Status:"; Bag_Load$; " full"; TAB(25); "Energy Left:"; Player.Energy; TAB(50); "Candy Collected:"; Player.Treats; "oz"
336. END SUB
337.  
338. SUB Describe_Street (Count%, Length!, Direction%)
339.  PRINT "To the "; Directions(Direction%); " has"; Count%; "lights on, and is"; Length!; "miles long"
340. END SUB
341.  
342. FUNCTION Generate_Distance! (which%%)
343.  SELECT CASE which%%
344.   CASE 0
345.    Result! = Game.N_Feet / 5280
346.   CASE 1
347.    Result! = Game.S_Feet / 5280
348.   CASE 2
349.    Result! = Game.E_Feet / 5280
350.   CASE 3
351.    Result! = Game.W_Feet / 5280
352.   CASE 5 'player final distance
353.    Result! = Player.Distance / 5280
354.  END SELECT
355.  Result! = INT(Result! * 100) / 100
356.  Generate_Distance = Result!
357. END FUNCTION
358.  
359. FUNCTION Bag_Load$
360.  Result$ = "0%"
361.  SELECT CASE Player.Bag_Size
362.   CASE 1 'Small bag
363.    Result$ = STR$(INT(Player.Treats / 160 * 100)) + "%"
364.   CASE 2 'Medium bag
365.    Result$ = STR$(INT(Player.Treats / 240 * 100)) + "%"
366.   CASE 3 'Large bag
367.    Result$ = STR$(INT(Player.Treats / 400 * 100)) + "%"
368.   CASE 4 'truck
369.    Result$ = STR$(INT(Player.Treats / 32000 * 100)) + "%"
370.  END SELECT
371.  Bag_Load = Result$
372. END FUNCTION
373.  
374. SUB Title_Screen
375.  COLOR 6
376.  PRINT "   TTTTTT  RRRR    IIIIII   CCCC   KK  KK                                      "
377.  PRINT "     TT    RR  RR    II    CC  CC  KK KK                                       "
378.  PRINT "     TT    RR  RR    II    CC      KKKK                                        "
379.  PRINT "     TT    RR RR     II    CC  CC  KK KK                                       "
380.  PRINT "     TT    RR  RR  IIIIII   CCCC   KK  KK                                      "
381.  PRINT "                                                                               "
382.  PRINT "                                OOOO   RRRR                                    "
383.  PRINT "                               OO  OO  RR  RR                                  "
384.  PRINT "                               OO  OO  RR  RR                                  "
385.  PRINT "             /\                OO  OO  RR RR                                   "
386.  PRINT "          __(_(__               OOOO   RR  RR                                  "
387.  PRINT "       .-'._'-'_.'-                                                            "
388.  PRINT "     .'.' (•\'/¢) '.'.            TTTTTT  RRRR    EEEEEE    AA   TTTTTT        "
389.  PRINT "    / :_/_:  ê  :_\_: \             TT    RR  RR  EE       AAAA    TT          "
390.  PRINT "   | :   \'=...='/   : |            TT    RR  RR  EEEE    AA  AA   TT          "
391.  PRINT "    \ :  :'.___.':  : /             TT    RR RR   EE      AAAAAA   TT          "
392.  PRINT "     '-:__:__:__:__:-'              TT    RR  RR  EEEEEE  AA  AA   TT          "
393.  COLOR 8
394.  LOCATE 23, 1: PRINT "Powered by QB64      (press space bar to continue)"
395.  COLOR 7
396. END SUB
397.  
398. SUB Pumpkin_Screen
399.  '
400.  '                             @@@
401.  '                             @@@
402.  '                              @@@                       H A P P Y
403.  '                              @@@
404.  '                      @@@@@@@@@@@@@@@@@@@@@@         H A L L O W E E N
405.  '                    @@@@@@@@@@@@@@@@@@@@@@@@@@
406.  '                  @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
407.  '                @@@@@@@@ @@@@@@@@@@@@@@@@ @@@@@@@@
408.  '              @@@@@@@@@   @@@@@@@@@@@@@@   @@@@@@@@@
409.  '            @@@@@@@@@@     @@@@@@@@@@@@     @@@@@@@@@@
410.  '           @@@@@@@@@@       @@@@  @@@@       @@@@@@@@@@
411.  '           @@@@@@@@@@@@@@@@@@@@    @@@@@@@@@@@@@@@@@@@@
412.  '           @@@@@@@@@@@@@@@@@@        @@@@@@@@@@@@@@@@@@
413.  '           @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
414.  '           @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
415.  '           @@@@@@@@@ @@@@@@@@@@@@@@@@@@@@@@@@ @@@@@@@@@
416.  '            @@@@@@@@  @@ @@ @@ @@ @@ @@ @@ @  @@@@@@@@
417.  '              @@@@@@@                        @@@@@@@
418.  '                @@@@@@  @@ @@ @@ @@ @@ @@ @ @@@@@@
419.  '                  @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
420.  '                    @@@@@@@@@@@@@@@@@@@@@@@@@@
421.  '                      @@@@@@@@@@@@@@@@@@@@@@
422.  '
423.  '------------------------------------------------
424.  'Thank you for visiting https://asciiart.website/
425.  'This ASCII pic can be found at
426.  'https://asciiart.website/index.php?art=holiday/halloween
427. END SUB

[bplus]

Ah, you have a sort of text adventure game going all in text and with Halloween Theme one key spacebar.

Is there like dice rolling taking place so user can see how his fate went with his choice? Could be illustrated in ASCII.

All good! are there any candy bag skeletal thieves in the future? (Kkeletal because they are dying or died of hunger).

Ha! I've been raiding the on-line ASCII files too!
 

[bplus]

Credits:

From Christopher Johnson's ASCII Art Collection:
https://asciiart.website/index.php

Splash Screen comic:
Thank you for visiting https://asciiart.website/
This ASCII pic can be found at
https://asciiart.website/index.php?art=holiday/halloween

10 Halloweens.txt (supposed to be 13 I think):
Thank you for visiting https://asciiart.website/
This ASCII pic can be found at
https://asciiart.website/index.php?art=holiday/halloween

[Pete]

My sister-in-law and will be citing you with a copyright violation. Not the code, the artwork.

Pete

[Cobalt]

My sister-in-law and will be citing you with a copyright violation. Not the code, the artwork.

Pete

Why? Illegal use of a self portrait ?

[Cobalt]

Ah, you have a sort of text adventure game going all in text and with Halloween Theme one key spacebar.

Is there like dice rolling taking place so user can see how his fate went with his choice? Could be illustrated in ASCII.

All good! are there any candy bag skeletal thieves in the future? (Kkeletal because they are dying or died of hunger).

Ha! I've been raiding the on-line ASCII files too!

I was wondering about some kind of random chance events, and thats not a bad one.
might find some ASCII art to make a kind of splash screen when they happen.

yep those are the sites I ran by, added my own little tweaks to the pumpkin though, so not totally leaching.

[Pete]

Yeah, the ASCII witch is spot on. She's old fashioned, too. Still rides around on a broomstick, when most have upgraded to automatics.

Pete

[bplus]

Here's maybe a funny story, I cut that image out of a group of 3.75 a coven in a cloud. It was the only one whole after clearing overlap of others in row X col frame.

I WAS thinking I could do a mirror image of it be reversing the order of the letters, ha, ha, ha!
Not a blunder, not a blonder, not a blender or a blinder, an out and out boner, skeletal speaking of course.