Spriggsy's API Collection

[SpriggsySpriggs]

Upated 12/22/2020 @ 6:24 PM

Added preproc, a header file that gives QB64 access to C++ preprocessor macros for getting things like when the executable had been compiled (__COMPILE_DATE, __COMPILE_TIME), which file was compiled (__SRC_FILE, __BASE_FILE), static counters (__STATIC_COUNT), when the source file had last been edited (__SRC_LAST_EDIT), the C++ names of variables and functions (__VARIABLE_NAME, __FUNCTION_NAME, __FUNCTION_NAME_FULL), etc.

 

[SpriggsySpriggs]

Made a GitHub repository to host this collection so changes and other things can be tracked/managed there with greater ease. The zip folder won't be hosted here anymore. It will only be on GitHub and the code will be downloaded from that repository. However, changes made to the repository will be reflected here as updates to the thread.

https://github.com/SpriggsySpriggs/Spriggsys-API-Collection

[SpriggsySpriggs]

Updated 11:01 PM on 02/06/2021

Added SHOpenWithDialog from Shell32. This function invokes the "Open With" dialog many of you are familiar with.
The source also contains usage for WideCharToMultiByte (Unicode/wchar to ANSI) and MultiByteToWideChar (ANSI to Unicode/wchar) but those are small and don't deserve their own file/post. They are needed for this function since it only has a W (wchar/Unicode) variant and not an A (ANSI/cp437).

 

[SpriggsySpriggs]

Updated on 02/12/2021 @ 08:56 AM

As many of you already saw in the dedicated forum post, I've updated pipecom and converted it into a QB64 $INCLUDE. This post is just to serve as the official update to my API collection. Below is the code:

Code: QB64: [Select]

1. Option _Explicit
2. $Console:Only
3. _Dest _Console
4.  
5. Print pipecom("dir /b")
6. If _Dest = _Console Then
7.     Sleep
8. End If
9.  
10. Function pipecom$ (cmd As String)
11.     $If WIN Then
12.         Type SECURITY_ATTRIBUTES
13.             nLength As Long
14.             $If 64BIT Then
15.                 padding As Long
16.             $End If
17.             lpSecurityDescriptor As _Offset
18.             bInheritHandle As Long
19.             $If 64BIT Then
20.                 padding2 As Long
21.             $End If
22.         End Type
23.  
24.         Type STARTUPINFO
25.             cb As Long
26.             $If 64BIT Then
27.                 padding As Long
28.             $End If
29.             lpReserved As _Offset
30.             lpDesktop As _Offset
31.             lpTitle As _Offset
32.             dwX As Long
33.             dwY As Long
34.             dwXSize As Long
35.             dwYSize As Long
36.             dwXCountChars As Long
37.             dwYCountChars As Long
38.             dwFillAttribute As Long
39.             dwFlags As Long
40.             wShowWindow As Integer
41.             cbReserved2 As Integer
42.             $If 64BIT Then
43.                 padding2 As Long
44.             $End If
45.             lpReserved2 As _Offset
46.             hStdInput As _Offset
47.             hStdOutput As _Offset
48.             hStdError As _Offset
49.         End Type
50.  
51.         Type PROCESS_INFORMATION
52.             hProcess As _Offset
53.             hThread As _Offset
54.             dwProcessId As Long
55.             $If 64BIT Then
56.                 padding2 As Long
57.             $End If
58.         End Type
59.  
60.         Const STARTF_USESTDHANDLES = &H00000100
61.         Const CREATE_NO_WINDOW = &H8000000
62.  
63.         Declare Dynamic Library "Kernel32"
64.             Function CreatePipe% (ByVal hReadPipe As _Offset, Byval hWritePipe As _Offset, Byval lpPipeAttributes As _Offset, Byval nSize As Long)
65.             Function CreateProcess% Alias CreateProcessA (ByVal lpApplicationName As _Offset, Byval lpCommandLine As _Offset, Byval lpProcessAttributes As _Offset, Byval lpThreadAttributes As _Offset, Byval bInheritHandles As Integer, Byval dwCreationFlags As Long, Byval lpEnvironment As _Offset, Byval lpCurrentDirectory As _Offset, Byval lpStartupInfor As _Offset, Byval lpProcessInformation As _Offset)
66.             Function CloseHandle% (ByVal hObject As Long)
67.             Function ReadFile% (ByVal hFile As Long, Byval lpBuffer As _Offset, Byval nNumberOfBytesToRead As Long, Byval lpNumberOfBytesRead As _Offset, Byval lpOverlapped As _Offset)
68.         End Declare
69.  
70.         Dim As String pipecom_buffer
71.         Dim As Integer ok: ok = 1
72.         Dim As Long hStdOutPipeRead
73.         Dim As Long hStdOutPipeWrite
74.         Dim As SECURITY_ATTRIBUTES sa: sa.nLength = Len(sa): sa.lpSecurityDescriptor = 0: sa.bInheritHandle = 1
75.  
76.         If CreatePipe(_Offset(hStdOutPipeRead), _Offset(hStdOutPipeWrite), _Offset(sa), 0) = 0 Then
77.             pipecom = ""
78.             Exit Function
79.         End If
80.  
81.         Dim As STARTUPINFO si
82.         si.cb = Len(si)
83.         si.dwFlags = STARTF_USESTDHANDLES
84.         si.hStdError = 0
85.         si.hStdOutput = hStdOutPipeWrite
86.         si.hStdInput = 0
87.         Dim As PROCESS_INFORMATION pi
88.         Dim As _Offset lpApplicationName
89.         Dim As String fullcmd: fullcmd = "cmd /c " + cmd + " 2>&1" + Chr$(0)
90.         Dim As String lpCommandLine: lpCommandLine = fullcmd
91.         Dim As Long lpProcessAttributes
92.         Dim As Long lpThreadAttributes
93.         Dim As Integer bInheritHandles: bInheritHandles = 1
94.         Dim As Long dwCreationFlags: dwCreationFlags = CREATE_NO_WINDOW
95.         Dim As _Offset lpEnvironment
96.         Dim As _Offset lpCurrentDirectory
97.         ok = CreateProcess(lpApplicationName,_
98.                            _Offset(lpCommandLine),_
99.                            lpProcessAttributes,_
100.                            lpThreadAttributes,_
101.                            bInheritHandles,_
102.                            dwCreationFlags,_
103.                            lpEnvironment,_
104.                            lpCurrentDirectory,_
105.                            _Offset(si),_
106.                            _Offset(pi))
107.         If ok = 0 Then
108.             pipecom = ""
109.             Exit Function
110.         End If
111.  
112.         ok = CloseHandle(hStdOutPipeWrite)
113.  
114.         Dim As String buf: buf = Space$(4096 + 1)
115.         Dim As Long dwRead
116.         While ReadFile(hStdOutPipeRead, _Offset(buf), 4096, _Offset(dwRead), 0) <> 0 And dwRead > 0
117.             buf = Mid$(buf, 1, dwRead)
118.             buf = String.Remove(buf, Chr$(13))
119.             pipecom_buffer = pipecom_buffer + buf
120.             buf = Space$(4096 + 1)
121.         Wend
122.         ok = CloseHandle(hStdOutPipeRead)
123.         pipecom = pipecom_buffer
124.     $Else
125.         Declare CustomType Library
126.         Function popen%& (cmd As String, readtype As String)
127.         Function feof& (ByVal stream As _Offset)
128.         Function fgets$ (str As String, Byval n As Long, Byval stream As _Offset)
129.         Function pclose& (ByVal stream As _Offset)
130.         End Declare
131.  
132.         Dim As String pipecom_buffer
133.         Dim As _Offset stream
134.  
135.         Dim buffer As String * 4096
136.         stream = popen(cmd+ " 2>&1", "r")
137.         If stream Then
138.         While feof(stream) = 0
139.         If fgets(buffer, 4096, stream) <> "" And feof(stream) = 0 Then
140.         pipecom_buffer = pipecom_buffer + Mid$(buffer, 1, InStr(buffer, Chr$(0)) - 1)
141.         End If
142.         Wend
143.         Dim As Long a
144.         a = pclose(stream)
145.         End If
146.         pipecom = pipecom_buffer
147.     $End If
148. End Function
149.  
150. $If WIN Then
151.     Function String.Remove$ (a As String, b As String)
152.         Dim c As String
153.         Dim j
154.         Dim r$
155.         c = ""
156.         j = InStr(a, b)
157.         If j > 0 Then
158.             r$ = Left$(a, j - 1) + c + String.Remove(Right$(a, Len(a) - j + 1 - Len(b)), b)
159.         Else
160.             r$ = a
161.         End If
162.         String.Remove = r$
163.     End Function
164. $End If

[SpriggsySpriggs]

Removed header version of pipecom from library. The new bas version is far superior to the old header and it will be too difficult for me to maintain both versions. The QB64 version is far more interesting and easier to maintain/adapt at this point.

[SpriggsySpriggs]

Updated 02/17/21 @ 11:55 PM

Complete rewrite of PeepingTom library with dedicated post.
Post link:Rewrite of PeepingTom library (Peek/Poke replacement)

[zaadstra]

Hi @SpriggsySpriggs,

I am trying to have Windows do a time calculation for me.  And I was looking here for the API Collection to see if something will help me.

I want to use the call SystemTimeToTzSpecificLocalTime, to convert an UTC timesmap to local timezone stamp.   I just found out that your API collection is gone from Github (link throws a 404 error), did you know that?

Half a year ago I grabbed a zip from it,  I'll start digging from there.

[SpriggsySpriggs]

@zaadstra It's public now. I had it private for a while.

[zaadstra]

Thanks!