Genius

[FellippeHeitor]

Genius (you may call it Simon... we call it Genius in Brazil ;-) has already been implemented in QB64, brilliantly written by Terry Ritchie (see it at https://www.qb64.org/forum/index.php?topic=2263.msg114988#msg114988) and also by Cobalt (see it at https://www.qb64.org/forum/index.php?topic=984.msg101822#msg101822)

But this is a minimalist (minimalistic?) version. There's no awesome technique I wanna showcase or point I want to make with this: it's just a weekend free time bonus project.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST true = -1, false = 0
4.  
5. DIM SHARED AS LONG boardX, boardY
6. boardX = 0
7. boardY = _FONTHEIGHT
8.  
9. RANDOMIZE TIMER
10.  
11. TYPE blocks
12.     AS INTEGER x, y, w, h
13.     AS _UNSIGNED LONG low, high
14.     AS STRING note
15. END TYPE
16.  
17. DIM SHARED AS blocks block(1 TO 4)
18. DIM SHARED AS LONG canvas, gameScreen
19.  
20. DIM i AS LONG
21.  
22. gameScreen = _NEWIMAGE(400, 400 + _FONTHEIGHT, 32)
23. canvas = _NEWIMAGE(400, 400, 32)
24.  
25. SCREEN gameScreen
26. DO UNTIL _SCREENEXISTS: LOOP
27. _TITLE "Genius"
28.  
29. FOR i = 1 TO 4
30.     block(i).w = _WIDTH(canvas) \ 2
31.     block(i).h = _HEIGHT(canvas) \ 2
32. NEXT
33.  
34. i = 0
35. i = i + 1: block(i).x = 0: block(i).y = 0
36. block(i).note = "o3c" 'green
37. block(i).high = _RGB32(0, 155, 0)
38. block(i).low = _RGB32(0, 78, 0)
39.  
40. i = i + 1: block(i).x = 0: block(i).y = _HEIGHT(canvas) \ 2
41. block(i).note = "o2e" 'red
42. block(i).high = _RGB32(227, 0, 0)
43. block(i).low = _RGB32(78, 0, 0)
44.  
45. i = i + 1: block(i).x = _WIDTH(canvas) \ 2: block(i).y = 0
46. block(i).note = "o2g" 'yellow
47. block(i).high = _RGB32(194, 194, 0)
48. block(i).low = _RGB32(161, 116, 0)
49.  
50. i = i + 1: block(i).x = _WIDTH(canvas) \ 2: block(i).y = _HEIGHT(canvas) \ 2
51. block(i).note = "o2b" 'blue
52. block(i).high = _RGB32(0, 105, 233)
53. block(i).low = _RGB32(0, 0, 78)
54.  
55.  
56. DIM SHARED AS _BYTE gameOver, inGame
57. DIM SHARED sequence$, goal AS INTEGER
58. CONST initialGoal = 3
59. goal = initialGoal
60.  
61. DO
62.     IF gameOver THEN
63.         gameOver = false
64.         inGame = false
65.         goal = initialGoal
66.     END IF
67.  
68.     IF inGame THEN
69.         resetSequence
70.         DO 'main game
71.             DIM AS INTEGER x, y
72.  
73.             IF LEN(sequence$) \ 2 = goal THEN
74.                 COLOR _RGB32(0, 222, 0)
75.                 _PRINTSTRING (x, y), STRING$(goal, 1)
76.                 _DISPLAY
77.                 goal = goal + 2
78.                 EXIT DO
79.             END IF
80.  
81.             CLS
82.             addNote
83.             y = boardY - _FONTHEIGHT
84.             x = (_WIDTH - _PRINTWIDTH(STRING$(goal, 254))) \ 2
85.             COLOR _RGB32(78)
86.             _PRINTSTRING (x, y), STRING$(goal, 254)
87.             COLOR _RGB32(255)
88.             _PRINTSTRING (x, y), STRING$(LEN(sequence$) \ 2, 254)
89.             playSequence
90.             getSequence
91.         LOOP UNTIL gameOver
92.         IF gameOver THEN resetSequence
93.     ELSE
94.         showMenu
95.     END IF
96. LOOP
97.  
98. SUB showMenu
99.     DIM m$
100.     DIM AS LONG x, y, mx, my
101.     DIM AS _BYTE mouseIsDown, mouseDownOnStart, startButtonHovered
102.  
103.     m$ = "< Start >"
104.     y = boardY - _FONTHEIGHT
105.     x = (_WIDTH - _PRINTWIDTH(m$)) \ 2
106.     DO
107.         CLS
108.         drawBoard
109.  
110.         WHILE _MOUSEINPUT: WEND
111.         mx = _MOUSEX: my = _MOUSEY
112.  
113.         startButtonHovered = (mx >= x AND mx <= x + _PRINTWIDTH(m$) AND my >= y AND my <= y + _FONTHEIGHT)
114.  
115.         IF startButtonHovered THEN
116.             COLOR _RGB32(0), _RGB32(255)
117.         ELSE
118.             COLOR _RGB32(255), _RGB32(0)
119.         END IF
120.  
121.         _PRINTSTRING (x, y), m$
122.         COLOR , _RGB32(0)
123.  
124.         IF _MOUSEBUTTON(1) THEN
125.             IF mouseIsDown = false THEN
126.                 mouseIsDown = true
127.                 mouseDownOnStart = false
128.                 IF startButtonHovered THEN mouseDownOnStart = true
129.             ELSE
130.             END IF
131.         ELSE
132.             IF mouseIsDown THEN
133.                 IF mouseDownOnStart AND startButtonHovered THEN
134.                     inGame = true
135.                     CLS
136.                     EXIT SUB
137.                 END IF
138.             END IF
139.             mouseIsDown = false
140.         END IF
141.         _DISPLAY
142.         _LIMIT 30
143.     LOOP UNTIL _KEYHIT
144. END SUB
145.  
146. SUB getSequence STATIC
147.     DIM AS LONG i, index, mouseDownOn, mx, my, check
148.     DIM AS INTEGER x, y
149.     DIM AS _BYTE mouseIsDown
150.     DIM start!
151.  
152.     x = (_WIDTH - _PRINTWIDTH(STRING$(goal, 254))) \ 2
153.     y = boardY - _FONTHEIGHT
154.     index = 0
155.     mouseIsDown = false
156.     mouseDownOn = 0
157.     start! = TIMER
158.     DO
159.         IF timeElapsedSince(start!) > 3 THEN
160.             gameOver = true
161.             COLOR _RGB32(127, 0, 0)
162.             _PRINTSTRING (x, y), STRING$(goal, 254)
163.             EXIT DO
164.         END IF
165.  
166.         drawBoard
167.         WHILE _MOUSEINPUT: WEND
168.         mx = _MOUSEX - boardX: my = _MOUSEY - boardY
169.         IF _MOUSEBUTTON(1) THEN
170.             start! = TIMER
171.             IF mouseIsDown = false THEN
172.                 mouseIsDown = true
173.                 FOR i = 1 TO 4
174.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
175.                         mouseDownOn = i
176.                         EXIT FOR
177.                     END IF
178.                 NEXT
179.             ELSE
180.                 FOR i = 1 TO 4
181.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
182.                         IF mouseDownOn = i THEN drawSquare mouseDownOn, 2
183.                         EXIT FOR
184.                     END IF
185.                 NEXT
186.             END IF
187.         ELSE
188.             IF mouseIsDown = true THEN
189.                 FOR i = 1 TO 4
190.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
191.                         IF i = mouseDownOn THEN
192.                             'click
193.                             index = index + 1
194.                             IF index < LEN(sequence$) \ 2 THEN
195.                                 COLOR _RGB32(238, 166, 0)
196.                             ELSE
197.                                 COLOR _RGB32(0, 166, 238)
198.                             END IF
199.                             _PRINTSTRING (x, y), STRING$(index, 254)
200.  
201.                             check = CVI(MID$(sequence$, index * 2 - 1, 2))
202.                             drawBoard
203.                             drawSquare i, 2
204.                             PLAY "l16" + block(i).note + "l4"
205.                             _DISPLAY
206.                             IF i = check THEN
207.                                 IF index = LEN(sequence$) \ 2 THEN
208.                                     drawBoard
209.                                     _DISPLAY
210.                                     _DELAY .5
211.                                     EXIT DO
212.                                 END IF
213.                             ELSE
214.                                 'error - restart
215.                                 gameOver = true
216.                                 COLOR _RGB32(127, 0, 0)
217.                                 _PRINTSTRING (x, y), STRING$(goal, 254)
218.                                 EXIT DO
219.                             END IF
220.                         END IF
221.                         EXIT FOR
222.                     END IF
223.                 NEXT
224.             ELSE
225.                 'hover
226.                 'FOR i = 1 TO 4
227.                 '    IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
228.                 '        LINE (boardX + block(i).x, boardY + block(i).y)-STEP(block(i).w - 1, block(i).h - 1), _RGB32(255, 50), BF
229.                 '        EXIT FOR
230.                 '    END IF
231.                 'NEXT
232.             END IF
233.             mouseIsDown = false
234.         END IF
235.         _DISPLAY
236.     LOOP
237. END SUB
238.  
239. SUB addNote
240.     DIM i AS LONG
241.     i = _CEIL(RND * 4)
242.     sequence$ = sequence$ + MKI$(i)
243. END SUB
244.  
245. SUB playSequence
246.     DIM AS LONG j, i
247.     FOR j = 1 TO LEN(sequence$) \ 2
248.         drawBoard
249.         _DISPLAY
250.         _DELAY .05
251.         i = CVI(MID$(sequence$, j * 2 - 1, 2))
252.         drawSquare i, 2
253.         _DISPLAY
254.         _DELAY .2
255.         PLAY block(i).note
256.     NEXT
257. END SUB
258.  
259. SUB resetSequence
260.     DIM AS LONG j, i
261.     sequence$ = ""
262.  
263.     IF NOT gameOver THEN
264.         PLAY "mbT240l16aebcbedfcaebl4"
265.         'animation
266.         FOR j = 1 TO 12
267.             i = i + 1
268.             IF i = 5 THEN i = 1
269.             drawBoard
270.             drawSquare i, 2
271.             _DISPLAY
272.             _LIMIT 20
273.         NEXT
274.         PLAY "T120mf"
275.     ELSE
276.         FOR i = 1 TO 4
277.             drawSquare i, 2
278.         NEXT
279.         _DISPLAY
280.         PLAY "t120mfl2o1cl4"
281.     END IF
282.     drawBoard
283.     _DISPLAY
284.     _DELAY .5
285. END SUB
286.  
287. SUB drawBoard
288.     STATIC board AS LONG
289.     DIM AS LONG i
290.  
291.     IF board = 0 THEN
292.         board = _NEWIMAGE(_WIDTH(canvas), _HEIGHT(canvas), 32)
293.         FOR i = 1 TO 4
294.             drawSquare i, 1
295.         NEXT
296.         _PUTIMAGE (0, 0), , board, (boardX, boardY)-STEP(_WIDTH(canvas) - 1, _HEIGHT(canvas) - 1)
297.     ELSE
298.         _PUTIMAGE (boardX, boardY), board
299.     END IF
300.  
301. END SUB
302.  
303. SUB drawSquare (this AS INTEGER, c AS INTEGER)
304.     DIM thisColor AS _UNSIGNED LONG
305.     IF c = 1 THEN thisColor = block(this).low ELSE thisColor = block(this).high
306.     LINE (boardX + block(this).x, boardY + block(this).y)-STEP(block(this).w - 1, block(this).h - 1), thisColor, BF
307. END SUB
308.  
309. FUNCTION timeElapsedSince! (startTime!)
310.     IF startTime! > TIMER THEN startTime! = startTime! - 86400
311.     timeElapsedSince! = TIMER - startTime!
312. END FUNCTION
313.  

 

[Cobalt]

Wow, pretty good!

As things seem to be Tiny or Minimalistic(spelled right but still flagged??) around here lately, perhaps you should make the touch areas 1 pixel!

[FellippeHeitor]

Hahahha, it's a thought :-D

[bplus]

Genius (you may call it Simon... we call it Genius in Brazil ;-) has already been implemented in QB64, brilliantly written by Terry Ritchie (see it at https://www.qb64.org/forum/index.php?topic=2263.msg114988#msg114988) and also by Cobalt (see it at https://www.qb64.org/forum/index.php?topic=984.msg101822#msg101822)

But this is a minimalist (minimalistic?) version. There's no awesome technique I wanna showcase or point I want to make with this: it's just a weekend free time bonus project.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2.  
3. CONST true = -1, false = 0
4.  
5. DIM SHARED AS LONG boardX, boardY
6. boardX = 0
7. boardY = _FONTHEIGHT
8.  
9. RANDOMIZE TIMER
10.  
11. TYPE blocks
12.     AS INTEGER x, y, w, h
13.     AS _UNSIGNED LONG low, high
14.     AS STRING note
15. END TYPE
16.  
17. DIM SHARED AS blocks block(1 TO 4)
18. DIM SHARED AS LONG canvas, gameScreen
19.  
20. DIM i AS LONG
21.  
22. gameScreen = _NEWIMAGE(400, 400 + _FONTHEIGHT, 32)
23. canvas = _NEWIMAGE(400, 400, 32)
24.  
25. SCREEN gameScreen
26. DO UNTIL _SCREENEXISTS: LOOP
27. _TITLE "Genius"
28.  
29. FOR i = 1 TO 4
30.     block(i).w = _WIDTH(canvas) \ 2
31.     block(i).h = _HEIGHT(canvas) \ 2
32. NEXT
33.  
34. i = 0
35. i = i + 1: block(i).x = 0: block(i).y = 0
36. block(i).note = "o3c" 'green
37. block(i).high = _RGB32(0, 155, 0)
38. block(i).low = _RGB32(0, 78, 0)
39.  
40. i = i + 1: block(i).x = 0: block(i).y = _HEIGHT(canvas) \ 2
41. block(i).note = "o2e" 'red
42. block(i).high = _RGB32(227, 0, 0)
43. block(i).low = _RGB32(78, 0, 0)
44.  
45. i = i + 1: block(i).x = _WIDTH(canvas) \ 2: block(i).y = 0
46. block(i).note = "o2g" 'yellow
47. block(i).high = _RGB32(194, 194, 0)
48. block(i).low = _RGB32(161, 116, 0)
49.  
50. i = i + 1: block(i).x = _WIDTH(canvas) \ 2: block(i).y = _HEIGHT(canvas) \ 2
51. block(i).note = "o2b" 'blue
52. block(i).high = _RGB32(0, 105, 233)
53. block(i).low = _RGB32(0, 0, 78)
54.  
55.  
56. DIM SHARED AS _BYTE gameOver, inGame
57. DIM SHARED sequence$, goal AS INTEGER
58. CONST initialGoal = 3
59. goal = initialGoal
60.  
61. DO
62.     IF gameOver THEN
63.         gameOver = false
64.         inGame = false
65.         goal = initialGoal
66.     END IF
67.  
68.     IF inGame THEN
69.         resetSequence
70.         DO 'main game
71.             DIM AS INTEGER x, y
72.  
73.             IF LEN(sequence$) \ 2 = goal THEN
74.                 COLOR _RGB32(0, 222, 0)
75.                 _PRINTSTRING (x, y), STRING$(goal, 1)
76.                 _DISPLAY
77.                 goal = goal + 2
78.                 EXIT DO
79.             END IF
80.  
81.             CLS
82.             addNote
83.             y = boardY - _FONTHEIGHT
84.             x = (_WIDTH - _PRINTWIDTH(STRING$(goal, 254))) \ 2
85.             COLOR _RGB32(78)
86.             _PRINTSTRING (x, y), STRING$(goal, 254)
87.             COLOR _RGB32(255)
88.             _PRINTSTRING (x, y), STRING$(LEN(sequence$) \ 2, 254)
89.             playSequence
90.             getSequence
91.         LOOP UNTIL gameOver
92.         IF gameOver THEN resetSequence
93.     ELSE
94.         showMenu
95.     END IF
96. LOOP
97.  
98. SUB showMenu
99.     DIM m$
100.     DIM AS LONG x, y, mx, my
101.     DIM AS _BYTE mouseIsDown, mouseDownOnStart, startButtonHovered
102.  
103.     m$ = "< Start >"
104.     y = boardY - _FONTHEIGHT
105.     x = (_WIDTH - _PRINTWIDTH(m$)) \ 2
106.     DO
107.         CLS
108.         drawBoard
109.  
110.         WHILE _MOUSEINPUT: WEND
111.         mx = _MOUSEX: my = _MOUSEY
112.  
113.         startButtonHovered = (mx >= x AND mx <= x + _PRINTWIDTH(m$) AND my >= y AND my <= y + _FONTHEIGHT)
114.  
115.         IF startButtonHovered THEN
116.             COLOR _RGB32(0), _RGB32(255)
117.         ELSE
118.             COLOR _RGB32(255), _RGB32(0)
119.         END IF
120.  
121.         _PRINTSTRING (x, y), m$
122.         COLOR , _RGB32(0)
123.  
124.         IF _MOUSEBUTTON(1) THEN
125.             IF mouseIsDown = false THEN
126.                 mouseIsDown = true
127.                 mouseDownOnStart = false
128.                 IF startButtonHovered THEN mouseDownOnStart = true
129.             ELSE
130.             END IF
131.         ELSE
132.             IF mouseIsDown THEN
133.                 IF mouseDownOnStart AND startButtonHovered THEN
134.                     inGame = true
135.                     CLS
136.                     EXIT SUB
137.                 END IF
138.             END IF
139.             mouseIsDown = false
140.         END IF
141.         _DISPLAY
142.         _LIMIT 30
143.     LOOP UNTIL _KEYHIT
144. END SUB
145.  
146. SUB getSequence STATIC
147.     DIM AS LONG i, index, mouseDownOn, mx, my, check
148.     DIM AS INTEGER x, y
149.     DIM AS _BYTE mouseIsDown
150.     DIM start!
151.  
152.     x = (_WIDTH - _PRINTWIDTH(STRING$(goal, 254))) \ 2
153.     y = boardY - _FONTHEIGHT
154.     index = 0
155.     mouseIsDown = false
156.     mouseDownOn = 0
157.     start! = TIMER
158.     DO
159.         IF timeElapsedSince(start!) > 3 THEN
160.             gameOver = true
161.             COLOR _RGB32(127, 0, 0)
162.             _PRINTSTRING (x, y), STRING$(goal, 254)
163.             EXIT DO
164.         END IF
165.  
166.         drawBoard
167.         WHILE _MOUSEINPUT: WEND
168.         mx = _MOUSEX - boardX: my = _MOUSEY - boardY
169.         IF _MOUSEBUTTON(1) THEN
170.             start! = TIMER
171.             IF mouseIsDown = false THEN
172.                 mouseIsDown = true
173.                 FOR i = 1 TO 4
174.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
175.                         mouseDownOn = i
176.                         EXIT FOR
177.                     END IF
178.                 NEXT
179.             ELSE
180.                 FOR i = 1 TO 4
181.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
182.                         IF mouseDownOn = i THEN drawSquare mouseDownOn, 2
183.                         EXIT FOR
184.                     END IF
185.                 NEXT
186.             END IF
187.         ELSE
188.             IF mouseIsDown = true THEN
189.                 FOR i = 1 TO 4
190.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
191.                         IF i = mouseDownOn THEN
192.                             'click
193.                             index = index + 1
194.                             IF index < LEN(sequence$) \ 2 THEN
195.                                 COLOR _RGB32(238, 166, 0)
196.                             ELSE
197.                                 COLOR _RGB32(0, 166, 238)
198.                             END IF
199.                             _PRINTSTRING (x, y), STRING$(index, 254)
200.  
201.                             check = CVI(MID$(sequence$, index * 2 - 1, 2))
202.                             drawBoard
203.                             drawSquare i, 2
204.                             PLAY "l16" + block(i).note + "l4"
205.                             _DISPLAY
206.                             IF i = check THEN
207.                                 IF index = LEN(sequence$) \ 2 THEN
208.                                     drawBoard
209.                                     _DISPLAY
210.                                     _DELAY .5
211.                                     EXIT DO
212.                                 END IF
213.                             ELSE
214.                                 'error - restart
215.                                 gameOver = true
216.                                 COLOR _RGB32(127, 0, 0)
217.                                 _PRINTSTRING (x, y), STRING$(goal, 254)
218.                                 EXIT DO
219.                             END IF
220.                         END IF
221.                         EXIT FOR
222.                     END IF
223.                 NEXT
224.             ELSE
225.                 'hover
226.                 FOR i = 1 TO 4
227.                     IF mx >= block(i).x AND mx <= block(i).x + block(i).w AND my >= block(i).y AND my <= block(i).y + block(i).h THEN
228.                         LINE (boardX + block(i).x, boardY + block(i).y)-STEP(block(i).w - 1, block(i).h - 1), _RGB32(255, 50), BF
229.                         EXIT FOR
230.                     END IF
231.                 NEXT
232.             END IF
233.             mouseIsDown = false
234.         END IF
235.         _DISPLAY
236.     LOOP
237. END SUB
238.  
239. SUB addNote
240.     DIM i AS LONG
241.     i = _CEIL(RND * 4)
242.     sequence$ = sequence$ + MKI$(i)
243. END SUB
244.  
245. SUB playSequence
246.     DIM AS LONG j, i
247.     FOR j = 1 TO LEN(sequence$) \ 2
248.         drawBoard
249.         _DISPLAY
250.         _DELAY .05
251.         i = CVI(MID$(sequence$, j * 2 - 1, 2))
252.         drawSquare i, 2
253.         _DISPLAY
254.         _DELAY .2
255.         PLAY block(i).note
256.     NEXT
257. END SUB
258.  
259. SUB resetSequence
260.     DIM AS LONG j, i
261.     sequence$ = ""
262.  
263.     IF NOT gameOver THEN
264.         PLAY "mbT240l16aebcbedfcaebl4"
265.         'animation
266.         FOR j = 1 TO 12
267.             i = i + 1
268.             IF i = 5 THEN i = 1
269.             drawBoard
270.             drawSquare i, 2
271.             _DISPLAY
272.             _LIMIT 20
273.         NEXT
274.         PLAY "T120mf"
275.     ELSE
276.         FOR i = 1 TO 4
277.             drawSquare i, 2
278.         NEXT
279.         _DISPLAY
280.         PLAY "t120mfl2o1cl4"
281.     END IF
282.     drawBoard
283.     _DISPLAY
284.     _DELAY .5
285. END SUB
286.  
287. SUB drawBoard
288.     STATIC board AS LONG
289.     DIM AS LONG i
290.  
291.     IF board = 0 THEN
292.         board = _NEWIMAGE(_WIDTH(canvas), _HEIGHT(canvas), 32)
293.         FOR i = 1 TO 4
294.             drawSquare i, 1
295.         NEXT
296.         _PUTIMAGE (0, 0), , board, (boardX, boardY)-STEP(_WIDTH(canvas) - 1, _HEIGHT(canvas) - 1)
297.     ELSE
298.         _PUTIMAGE (boardX, boardY), board
299.     END IF
300.  
301. END SUB
302.  
303. SUB drawSquare (this AS INTEGER, c AS INTEGER)
304.     DIM thisColor AS _UNSIGNED LONG
305.     IF c = 1 THEN thisColor = block(this).low ELSE thisColor = block(this).high
306.     LINE (boardX + block(this).x, boardY + block(this).y)-STEP(block(this).w - 1, block(this).h - 1), thisColor, BF
307. END SUB
308.  
309. FUNCTION timeElapsedSince! (startTime!)
310.     IF startTime! > TIMER THEN startTime! = startTime! - 86400
311.     timeElapsedSince! = TIMER - startTime!
312. END FUNCTION
313.  

 

But this is a minimalist (minimalistic?) version.

Certainly not minimalest, can't be at 312 LOC. ;-)

[FellippeHeitor]

Minimalistic in visuals... I could never compete is those competitions of who does more with less code.

[Pete]

So let me get this straight... In Brazil, they would call me Simon?

Pete

[FellippeHeitor]

So let me get this straight... In Brazil, they would call me Simon?

Pete

Precisely 😉

[FellippeHeitor]

[Dav]

Nice, @FellippeHeitor!  You beat me to it!  I was just this weekend working on the exact same thing, converting THIS smartbasic version to QB64.  I will abandon it now and just play yours.:)

-Dav

[FellippeHeitor]

That's a big coincidence! I sure wish you wouldn't give up converting yours, though. It must be an interesting comparison exercise!

[FellippeHeitor]

Updated the code box above, but I will keep it fresh from now on at the repository: https://github.com/FellippeHeitor/genius

[Dav]

That's a big coincidence! I sure wish you wouldn't give up converting yours, though. It must be an interesting comparison exercise!

I'll try to finish it then.  I'm finding less and less time to code these days though - my gigs are roaring back this month.  Yay.  And getting more piano tuning calls. Feels so good to work again!

I like how you show the progress at the top.  To me Genius (Simon) is easier with sounds - without note patterns I don't seem to do as good. 

- Dav