Xor image pixels with a known value

[NOVARSEG]

Say, there is a 400 * 400 pixel image on the screen. It consists of white text and black background.  I want to XOR every pixel in the image with green (0,255,0).

The result should be magenta text  and green background. I've tried GET and PUT but these are way too much coding for such a simple task.  What is the easiest way to do this?

If XNOR was used, you'd get green text and a magenta background

[bplus]

Say, there is a 400 * 400 pixel image on the screen. It consists of white text and black background.  I want to XOR every pixel in the image with green (0,255,0).

The result should be magenta text  and green background. I've tried GET and PUT but these are way too much coding for such a simple task.  What is the easiest way to do this?

Looks like this works:

Code: QB64: [Select]

1. _Title "Xor Test with Green" 'b+ 2021-04-09
2. Screen _NewImage(400, 400, 32)
3. Color &HFFFFFFFF, &HFF000000
4. Dim As Single r, g, b, a
5. Cls
6. Print "Testing 1, 2, 3..."
7. Print
8. Print "ZZZ... press any to see Xor Green."
9. Sleep
10. For y = 0 To _Height
11.     For x = 0 To _Width
12.         c~& = Point(x, y)
13.         cAnalysis c~&, r, g, b, a
14.         PSet (x, y), _RGB32(r Xor 0, g Xor 255, b Xor 0)
15.     Next
16. Next
17.  
18. Sub cAnalysis (c As _Unsigned Long, outRed, outGrn, outBlu, outAlp)
19.     outRed = _Red32(c): outGrn = _Green32(c): outBlu = _Blue32(c): outAlp = _Alpha32(c)
20. End Sub
21.  

[NOVARSEG]

bplus
 how does cAnalysis  work

[bplus]

The _Red32, _Green32, _Blue32 functions take a full _RGB32 number and tell what the red, green and blue component values are _Alpha32 is transparency level like the others also returns a number 0-255.

So cAnalysis just does all 3 reports in one sub, pass it a color number (_unsigned Long) and the 4 Holder variables to pass results back to the main code calling then sub. You have to make sure the variables are the same Type (in the above demo, Single) so the main code can get the values from the variables back after the sub runs.

[NOVARSEG]

Thanks,    yep that makes sense.

I got XNOR to work but had to DIM variables as  _UNSIGNED _BYTE    to make it work.

The NOT would NOT work without the _UNSIGNED _BYTE  types

even had to DIM the SUB arguments as _UNSIGNED _BYTE

yep, green text and a magenta background with XNOR

Code: QB64: [Select]

1. _TITLE "Xor Test with Green" 'b+ 2021-04-09
2. SCREEN _NEWIMAGE(400, 400, 32)
3. COLOR &HFFFFFFFF, &HFF000000
4. DIM r AS _UNSIGNED _BYTE
5. DIM g AS _UNSIGNED _BYTE
6. DIM b AS _UNSIGNED _BYTE
7. DIM a AS _UNSIGNED _BYTE
8. CLS
9. PRINT "Testing 1, 2, 3..."
10. PRINT
11. PRINT "ZZZ... press any to see Xor Green."
12. SLEEP
13. FOR y = 0 TO _HEIGHT
14.     FOR x = 0 TO _WIDTH
15.         c~& = POINT(x, y)
16.         cAnalysis c~&, r, g, b, a
17.  
18.         r = r XOR 0: r = NOT r
19.         g = g XOR 255: g = NOT g
20.         b = b XOR 0: b = NOT b
21.  
22.         PSET (x, y), _RGB32(r, g, b, a)
23.     NEXT
24. NEXT
25.  
26. SUB cAnalysis (c AS _UNSIGNED LONG, outRed AS _UNSIGNED _BYTE, outGrn AS _UNSIGNED _BYTE, outBlu AS _UNSIGNED _BYTE, outAlp AS _UNSIGNED _BYTE)
27.     outRed = _RED32(c): outGrn = _GREEN32(c): outBlu = _BLUE32(c): outAlp = _ALPHA32(c)
28. END SUB
29.  

[bplus]

Hi @NOVARSEG

I don't understand the business with NOT.

It works fine without:

Oh! you reverse with NOT for magenta background and green text, OK? So XNOR is NOT a Typo LOL!
Oh you edited your original post!

[NOVARSEG]

XNOR <> XOR

[bplus]

XNOR <> XOR

Yeah and XNOR is not a built in bit manipulating function, so I thought it a type-o.

You changed your original post in between time I read it and time I posted my code for original question, confusing!!!

[NOVARSEG]

Example of logic NAND

Code: QB64: [Select]

1. _TITLE "Xor Test with Green" 'b+ 2021-04-09
2. SCREEN _NEWIMAGE(500, 400, 32)
3. COLOR &HFFFFFFFF, &HFF000000
4. DIM r AS _UNSIGNED _BYTE
5. DIM g AS _UNSIGNED _BYTE
6. DIM b AS _UNSIGNED _BYTE
7. DIM a AS _UNSIGNED _BYTE
8. DIM C AS _UNSIGNED LONG
9.  
10. CLS
11. PRINT "Testing 1, 2, 3..."
12. PRINT "original image is white font with black background"
13. PRINT "ZZZ... press any key to see pixels NANDed with yellow."
14.  
15. PRINT "press ESC to exit"
16. SLEEP
17. LL1:
18.  
19.  
20. FOR y = 0 TO _HEIGHT
21.     FOR x = 0 TO _WIDTH
22.         C = POINT(x, y)
23.  
24.         r = _RED32(C): g = _GREEN32(C): b = _BLUE32(C): a = _ALPHA32(C)
25.  
26.         r = r AND 255: r = NOT r
27.         g = g AND 255: g = NOT g
28.         b = b AND 0: b = NOT b
29.  
30.         PSET (x, y), _RGB32(r, g, b, a)
31.     NEXT
32. NEXT
33. DO
34.     i$ = INKEY$
35.     IF i$ = CHR$(27) THEN EXIT DO
36.     _DELAY .7: GOTO LL1
37. LOOP
38. END
39.