A do-nothing zen garden

[STxAxTIC]

Click the mouse to create heat, life, and waves. Right click to destroy.

Code: QB64: [Select]

1. OPTION _EXPLICIT
2. SCREEN _NEWIMAGE(800, 800, 32)
3.  
4. DIM SHARED GridWidth
5. DIM SHARED GridHeight
6. DIM SHARED CellWidth
7. DIM SHARED CellHeight
8. GridWidth = _WIDTH / 8
9. GridHeight = _HEIGHT / 8
10. CellWidth = _WIDTH / GridWidth
11. CellHeight = _HEIGHT / GridHeight
12.  
13. TYPE Vector
14.     x AS DOUBLE
15.     y AS DOUBLE
16.     z AS DOUBLE
17. END TYPE
18.  
19. DIM SHARED MainGrid(GridWidth, GridHeight) AS Vector
20. DIM SHARED AuxiGrid(GridWidth, GridHeight) AS Vector
21. DIM SHARED GridVel(GridWidth, GridHeight) AS DOUBLE
22.  
23. DIM SelectedCelli
24. DIM SelectedCellj
25. DO
26.  
27.     DO WHILE _MOUSEINPUT
28.         SelectedCelli = INT(_MOUSEX / CellWidth)
29.         SelectedCellj = INT(_MOUSEY / CellHeight)
30.         IF _MOUSEBUTTON(1) THEN
31.             MainGrid(SelectedCelli, SelectedCellj).x = 8
32.             MainGrid(SelectedCelli, SelectedCellj).y = 1
33.             MainGrid(SelectedCelli, SelectedCellj).z = 6
34.             GridVel(SelectedCelli, SelectedCellj) = 0
35.         END IF
36.         IF _MOUSEBUTTON(2) THEN
37.             MainGrid(SelectedCelli, SelectedCellj).x = 0
38.             MainGrid(SelectedCelli, SelectedCellj).y = 0
39.             MainGrid(SelectedCelli, SelectedCellj).z = 0
40.             GridVel(SelectedCelli, SelectedCellj) = 0
41.         END IF
42.     LOOP
43.  
44.     CALL UpdateGrid
45.     CLS
46.     CALL PlotGrid
47.     _DISPLAY
48.     _LIMIT 30
49. LOOP
50.  
51. END
52.  
53. SUB UpdateGrid
54.     DIM i AS INTEGER
55.     DIM j AS INTEGER
56.     DIM t AS DOUBLE
57.     DIM AS Vector a1, a2, a3, a4, a5, a6, a7, a8, a9
58.     FOR i = 1 TO GridWidth
59.         FOR j = 1 TO GridHeight
60.             AuxiGrid(i, j).x = MainGrid(i, j).x
61.             AuxiGrid(i, j).y = MainGrid(i, j).y
62.             AuxiGrid(i, j).z = MainGrid(i, j).z
63.         NEXT
64.     NEXT
65.     FOR i = 1 TO GridWidth - 2
66.         FOR j = 1 TO GridHeight - 2
67.             a1 = AuxiGrid(i - 1, j + 1)
68.             a2 = AuxiGrid(i, j + 1)
69.             a3 = AuxiGrid(i + 1, j + 1)
70.             a4 = AuxiGrid(i - 1, j)
71.             a5 = AuxiGrid(i, j)
72.             a6 = AuxiGrid(i + 1, j)
73.             a7 = AuxiGrid(i - 1, j - 1)
74.             a8 = AuxiGrid(i, j - 1)
75.             a9 = AuxiGrid(i + 1, j - 1)
76.  
77.  
78.             ' Diffusion
79.             MainGrid(i, j).x = (1 / 5) * (a2.x + a4.x + a6.x + a8.x + a5.x)
80.  
81.             ' Game of life
82.             t = a1.y + a2.y + a3.y + a4.y + a6.y + a7.y + a8.y + a9.y
83.             IF (a5.y = 1) THEN
84.                 SELECT CASE t
85.                     CASE IS < 2
86.                         MainGrid(i, j).y = 0
87.                     CASE 2
88.                         MainGrid(i, j).y = 1
89.                     CASE 3
90.                         MainGrid(i, j).y = 1
91.                     CASE IS > 3
92.                         MainGrid(i, j).y = 0
93.                 END SELECT
94.             ELSE
95.                 IF (t = 3) THEN
96.                     MainGrid(i, j).y = 1
97.                 END IF
98.             END IF
99.  
100.             ' Wave propagation
101.             DIM alpha
102.             DIM wp1, wp2
103.             alpha = .25
104.             wp1 = alpha * (a6.z + a4.z) + 2 * (1 - alpha) * a5.z - GridVel(i, j)
105.             wp2 = alpha * (a2.z + a8.z) + 2 * (1 - alpha) * a5.z - GridVel(i, j)
106.             MainGrid(i, j).z = (0.98) * (1 / 2) * (wp1 + wp2)
107.             GridVel(i, j) = AuxiGrid(i, j).z
108.         NEXT
109.     NEXT
110. END SUB
111.  
112. SUB PlotGrid
113.     DIM i AS INTEGER
114.     DIM j AS INTEGER
115.     FOR i = 0 TO GridWidth
116.         FOR j = 0 TO GridHeight
117.             LINE (i * CellWidth, j * CellHeight)-(i * CellWidth + CellWidth, j * CellHeight + CellHeight), _RGB32(255 * MainGrid(i, j).x, 25 + 230 * MainGrid(i, j).y, 255 * ABS(MainGrid(i, j).z)), BF
118.             LINE (i * CellWidth, j * CellHeight)-(i * CellWidth + CellWidth, j * CellHeight + CellHeight), _RGB32(100, 100, 100), B
119.         NEXT
120.     NEXT
121. END SUB

[bplus]

Wow, cool!
 

[FellippeHeitor]

Whoooooooooooooooooooooooooooooooooooooooooooooooa.

🤯

Running this feels... magical.

[191Brian]

Wow really cool reminds me of an android app simulating fluid mechanics.

[OldMoses]

Amazing effect on so few code lines. I particularly liked the wave canceling effect. Very cool.

[Aurel]

Yes it is really cool i like it STATIC....raster is great
maybe is good also for RETRO -GAME or something similar

[euklides]

Nice !
I had a problem with line 57    ( DIM AS Vector a1, a2, a3, a4, a5, a6, a7, a8, a9 )
and replaced it with:
    DIM a1 AS Vector:    DIM a2 AS Vector:    DIM a3 AS Vector
    DIM a4 AS Vector:    DIM a5 AS Vector:    DIM a6 AS Vector
    DIM a7 AS Vector:    DIM a8 AS Vector:    DIM a9 AS Vector

Reason ???  (V1.4 in use)

[bplus]

Nice !
I had a problem with line 57    ( DIM AS Vector a1, a2, a3, a4, a5, a6, a7, a8, a9 )
and replaced it with:
    DIM a1 AS Vector:    DIM a2 AS Vector:    DIM a3 AS Vector
    DIM a4 AS Vector:    DIM a5 AS Vector:    DIM a6 AS Vector
    DIM a7 AS Vector:    DIM a8 AS Vector:    DIM a9 AS Vector

Reason ???  (V1.4 in use)

Yes will work in v1.5 "that alone is worth the price of admission" as they say in USA!
Meaning get v1.5 because you can DIM or ReDim mass amounts of variables with only one "As Type" at the start of the line, eg the line you noted above.

[TempodiBasic]

@STxAxTIC
always impressive your works!
 

Great job bro!