Labyrinth Tiles

[bplus]

@bplus
hey my nice DIMs are gone waaaa

I like the small circles to mark the x, y positions. can't see blue ones though so they are all the same now
maybe there was a reason for the way it was?

The small circles are only for testing of navigation etc  but they do look nice.

mouse clicks toggle the color from black to color to black etc

Im trying some crude navigation code.  How do you erase a previous CIRCLE from the screen?

As far as "cell centers" go, there are cell centers generated directly from the FOR NEXT  outputs.  The other centers are  "offset" (both in x and y) from the FOR NEXT outputs.  These "offsets"  were the tricky part.  It look like you had the "offset" centers in blue.  That could be useful, will see.

Code: QB64: [Select]

1. ' b+ mod NOVARSEG code for 2 tiler 2021-01-25
2. s = 10
3. h = 700
4. w = 1024
5. SCREEN _NEWIMAGE(w, h, 32)
6. _DELAY .25
7. _SCREENMOVE _MIDDLE
8. '_FULLSCREEN
9. t = .5
10.  
11. _TITLE "Press z increase over/under,  x increase left/right, c makes smaller cells, v bigger, esc to quit, left mouse paints red, right blue"
12.  
13. DO
14.  
15.     CLS
16.  
17.     FOR y = 0 TO h STEP s * 4
18.  
19.         FOR x = 0 TO w STEP s * 4
20.  
21.             r = RND
22.             CIRCLE (x, y), 2, &HFFFFFF00
23.             IF r <= t THEN
24.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
25.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
26.             END IF
27.             IF r > t THEN
28.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
29.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
30.             END IF
31.  
32.             x = x + s * 2
33.             y = y + s * 2
34.             CIRCLE (x, y), 2, &HFFFFFF00 ' &HFF0000FF
35.             r = RND
36.  
37.             IF r <= t THEN
38.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
39.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
40.             END IF
41.             IF r > t THEN
42.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
43.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
44.             END IF
45.  
46.             x = x - s * 2
47.             y = y - s * 2
48.  
49.         NEXT
50.  
51.     NEXT
52.     DO
53.         IF _MOUSEINPUT = -1 THEN
54.  
55.  
56.             IF _MOUSEBUTTON(1) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 0) THEN
57.                 PAINT (_MOUSEX, _MOUSEY), _RGB(255, 0, 0), &HFFFFFFFF
58.                 GOTO L1
59.             END IF
60.             IF _MOUSEBUTTON(1) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(255, 0, 0) THEN
61.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 0), &HFFFFFFFF
62.             END IF
63.  
64.             L1:
65.  
66.             IF _MOUSEBUTTON(2) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 0) THEN
67.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 255), &HFFFFFFFF
68.                 GOTO L2
69.             END IF
70.             IF _MOUSEBUTTON(2) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 255) THEN
71.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 0), &HFFFFFFFF
72.             END IF
73.  
74.             L2:
75.  
76.  
77.         END IF
78.  
79.  
80.         i$ = INKEY$
81.         IF i$ = "z" AND t < 1 THEN t = t + .005: EXIT DO
82.         IF i$ = "x" AND t > 0 THEN t = t - .005: EXIT DO
83.         IF i$ = "c" AND s > 1 THEN s = s - 1: EXIT DO
84.         IF i$ = "v" AND s < 41 THEN s = s + 1: EXIT DO
85.         IF i$ = CHR$(27) THEN END
86.         IF i$ = CHR$(32) THEN EXIT DO
87.     LOOP
88. LOOP
89.  

I like the small circles to mark the x, y positions. can't see blue ones though so they are all the same now
maybe there was a reason for the way it was?

Yes, it was to distinguish the first set of x, y positions and the second set.

Im trying some crude navigation code.  How do you erase a previous CIRCLE from the screen?

After I make the map, I'd save the image, then in main loop, I _PUTIMAGE that image back in as background and then draw in the present location of the hero position then I poll for arrow keypresses and update hero position if he doesn't have to run through a wall, and loop... background image, hero drawn, update next position, loop...

The other centers are  "offset" (both in x and y) from the FOR NEXT outputs.  These "offsets"  were the tricky part.  It look like you had the "offset" centers in blue.  That could be useful, will see.

And we are back to first comment :) that's why one set blue and the other yellow.

[NOVARSEG]

@bplus

working on navigation.


With the arrow keys,  i'm trying to navigate from center to any other center.  Any turn must be made from yet another center which is in between the centers shown on the screen.  The moving object is another circle or similar which is somewhat larger (maybe a solid) .  The object moves in S * 2 steps left, right, up or down.

To make it more complex the moving object must stay centered for any cell size.

The action of the moving object is s * 2 pixels at a time for any arrow key pressed.  For a game, a smoothly moving object is wanted, but I have not yet figure that out.

[bplus]

Re: Navigation
Looking over the blue and yellow little circles, I notice every place open to turn, you have to be exactly between the colored circles, can't turn when on a colored circle. So I think the arrow keys should move us an s amount not 2 * s and it will certainly be easier to tell in code where walls are by using POINT to check down the line you want to head.

As for reversing walls you have to be standing on a colored circle and you have to work in offsets depending on if you are standing on a blue circle or a yellow.

The blue circles were the offset group:

Code: QB64: [Select]

1.             x = x + s * 2
2.             y = y + s * 2
3.             CIRCLE (x, y), 2, &HFF0000FF
4.  

yellow set 0 4 8 12  *s    both x and y
   blue set 2, 6, 10   *s

so all the places you can turn are odd numbers *s

[NOVARSEG]

@bplus

Looking over the blue and yellow little circles, I notice every place open to turn, you have to be exactly between the colored circles, can't turn when on a colored circle.

correct.

 

FOR y = 0 TO h STEP s * 4

        FOR x = 0 TO w STEP s * 4

The step size is S * 4 from color center to color center (no diagonal moves), so S * 2 should land half way between any color center. 

[bplus]

so S * 2 should land half way between any color center.

@NOVARSEG confirmed! I just got the up arrow working. The walls to watch out for are only 1 s away +- 1 pixel, so I am using POINT for wall detection. But when you do move it is 2*S.

[NOVARSEG]

@bplus

Got some crude navigation code working.  Press space bar to obtain a maze that'll work.

The moving circle stays within the grid lines (walls).  use arrow keys to move around.

c and v keys are disabled for this test.

Code: QB64: [Select]

1. DIM r AS SINGLE
2. DIM h AS INTEGER
3. DIM w AS INTEGER
4. DIM s AS INTEGER
5. DIM x AS INTEGER
6. DIM y AS INTEGER
7. DIM t AS SINGLE
8. DIM xx AS INTEGER
9. DIM yy AS INTEGER
10.  
11. s = 20
12. h = 768
13. w = 1024
14. SCREEN _NEWIMAGE(w, h, 32)
15. _FULLSCREEN
16. t = .5
17.  
18. _TITLE "Press z increase over/under,  x increase left/right, c makes smaller cells, v bigger, esc to quit, left mouse paints red, right blue"
19.  
20. DO
21.  
22.     CLS
23.  
24.     FOR y = 0 TO h STEP s * 4
25.  
26.         FOR x = 0 TO w STEP s * 4
27.  
28.             r = RND
29.             CIRCLE (x, y), 2, _RGB(255, 255, 0)
30.             IF r <= t THEN
31.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
32.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
33.             END IF
34.             IF r > t THEN
35.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
36.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
37.             END IF
38.  
39.             x = x + s * 2
40.             y = y + s * 2
41.  
42.             CIRCLE (x, y), 2, _RGB(0, 255, 0)
43.             r = RND
44.  
45.             IF r <= t THEN
46.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
47.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
48.             END IF
49.             IF r > t THEN
50.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
51.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
52.             END IF
53.  
54.             x = x - s * 2
55.             y = y - s * 2
56.  
57.         NEXT
58.  
59.     NEXT
60.     'yy = 100
61.     DO
62.         IF _MOUSEINPUT = -1 THEN
63.  
64.  
65.             IF _MOUSEBUTTON(1) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 0) THEN
66.                 PAINT (_MOUSEX, _MOUSEY), _RGB(255, 0, 0), &HFFFFFFFF
67.                 GOTO L1
68.             END IF
69.             IF _MOUSEBUTTON(1) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(255, 0, 0) THEN
70.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 0), &HFFFFFFFF
71.             END IF
72.  
73.             L1:
74.  
75.             IF _MOUSEBUTTON(2) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 0) THEN
76.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 255), &HFFFFFFFF
77.                 GOTO L2
78.             END IF
79.             IF _MOUSEBUTTON(2) = -1 AND POINT(_MOUSEX, _MOUSEY) = _RGB(0, 0, 255) THEN
80.                 PAINT (_MOUSEX, _MOUSEY), _RGB(0, 0, 0), &HFFFFFFFF
81.             END IF
82.  
83.             L2:
84.  
85.  
86.         END IF
87.  
88.  
89.  
90.  
91.         KH& = _KEYHIT
92.         IF KH& = 18432 AND yy > s * 2 AND POINT(xx, yy - 20) <> _RGB(255, 255, 255) THEN 'up
93.             CIRCLE (xx, yy), 6, _RGB(0, 0, 0)
94.             yy = yy - s * 2
95.             CIRCLE (xx, yy), 6, &HFF00FF00
96.  
97.         END IF
98.  
99.         IF KH& = 19712 AND xx < 1024 AND POINT(xx + 20, yy) <> _RGB(255, 255, 255) THEN 'right
100.             CIRCLE (xx, yy), 6, _RGB(0, 0, 0)
101.             xx = xx + s * 2
102.             CIRCLE (xx, yy), 6, &HFF00FF00
103.             IF POINT(xx + 5, yy) = _RGB(255, 255, 255) THEN SOUND 300, 1
104.         END IF
105.  
106.         IF KH& = 20480 AND yy < 768 AND POINT(xx, yy + 20) <> _RGB(255, 255, 255) THEN 'down
107.             CIRCLE (xx, yy), 6, _RGB(0, 0, 0)
108.             yy = yy + s * 2
109.             CIRCLE (xx, yy), 6, &HFF00FF00
110.         END IF
111.  
112.         IF KH& = 19200 AND xx > s * 2 AND POINT(xx - 20, yy) <> _RGB(255, 255, 255) THEN 'left
113.             CIRCLE (xx, yy), 6, _RGB(0, 0, 0)
114.             xx = xx - s * 2
115.             CIRCLE (xx, yy), 6, &HFF00FF00
116.         END IF
117.  
118.         IF xx MOD s * 4 = 0 AND yy MOD s * 4 = 0 THEN LOCATE 20, 20: PRINT "Yellow circle"
119.         IF (xx + s * 2) MOD s * 4 = 0 AND (yy + s * 2) MOD s * 4 = 0 THEN LOCATE 20, 20: PRINT "green circle"
120.  
121.         IF (xx + s * 4) MOD s * 4 = 0 AND (yy + s * 2) MOD s * 4 = 0 THEN LOCATE 20, 20: PRINT "between      "
122.         IF (xx + s * 2) MOD s * 4 = 0 AND yy MOD s * 4 = 0 THEN LOCATE 20, 20: PRINT "between      "
123.  
124.  
125.         i$ = INKEY$
126.  
127.         IF i$ = "z" AND t < 1 THEN t = t + .005: EXIT DO
128.         IF i$ = "x" AND t > 0 THEN t = t - .005: EXIT DO
129.         ' IF i$ = "c" AND s > 1 THEN s = s - 1: xx = 0: yy = 0: EXIT DO
130.         'IF i$ = "v" AND s < 41 THEN s = s + 1: xx = 0: yy = 0: EXIT DO
131.         IF i$ = CHR$(27) THEN END
132.         IF i$ = CHR$(32) THEN EXIT DO
133.     LOOP
134. LOOP
135.  

[bplus]

Hey good work @NOVARSEG I know this was hard!

I got everything working good including toggling the PAINT jobs that you suggested then went to clean up code a bit and suddenly my guy is walking through walls! Dang WTH happened? After much hair pulling I discovered my White Constant was saying it was -1???
So I had to make White a normal variable and remember to dimension it _UNSIGNED LONG first and everything was working again, yeah! You should be able to resize s now too.

Code: QB64: [Select]

1. ' b+ mod NOVARSEG code for 2 tiler 2021-01-25
2. ' 2021-01-27  mod this for navigation and toggle paint jobs red and back or blue and black as per NOVARSEG
3. CONST W = 1024, H = 700 ' screen width and height and color for lines and border check
4. SCREEN _NEWIMAGE(W, H, 32)
5. _DELAY .25 'wait for screen to set
6. _SCREENMOVE _MIDDLE 'then center it in screen
7. REDIM white AS _UNSIGNED LONG
8. white = &HFFFFFFFF
9. s = 10 ' s is the unit for drawing and navigating screen each step is 2*s
10. t = .5 ' t is splitter between up/down walls and left/right walls
11. COLOR white
12. _TITLE "Press z increase over/under,  x increase left/right, c makes smaller cells, v bigger, esc to quit, left mouse paints red/black, right blue/black"
13. DO
14.     CLS
15.     FOR y = 0 TO H STEP s * 4
16.         FOR x = 0 TO W STEP s * 4
17.             r = RND
18.             'CIRCLE (x, y), 2, &HFFFFFF00
19.             IF r <= t THEN
20.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
21.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
22.             END IF
23.             IF r > t THEN
24.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
25.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
26.             END IF
27.             x = x + s * 2: y = y + s * 2 ' offset to do the other half of screen
28.             'CIRCLE (x, y), 2, &HFF0000FF
29.             r = RND
30.             IF r <= t THEN
31.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
32.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
33.             END IF
34.             IF r > t THEN
35.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
36.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
37.             END IF
38.             x = x - s * 2: y = y - s * 2 ' set back to first set
39.         NEXT
40.     NEXT
41.     IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
42.     REDIM back AS LONG
43.     back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
44.     _PUTIMAGE , 0, back 'store current maze into image
45.     xcells = INT(W / s) 'how many cells across
46.     ycells = INT(H / s) 'how many down
47.     hx = INT(xcells / 2) 'put our guy smack in middle of screen but he has to be on even number of cells!
48.     IF hx MOD 2 = 1 THEN hx = hx + 1
49.     hy = INT(ycells / 2)
50.     IF hy MOD 2 = 1 THEN hy = hy + 1
51.     's2 = 2 * s ' this is distance to move for each arrow press edit: did not need
52.     DO
53.         _PUTIMAGE , back, 0
54.         KH& = _KEYHIT
55.         SELECT CASE KH& '                                       which key was pressed?
56.             CASE 27 '                                           the ESC key
57.                 SYSTEM '
58.             CASE 18432 '  Up Arrow
59.                 IF hy - 2 > 0 THEN
60.                     'CIRCLE (hx * s, (hy - 1) * s), 5, &HFFFFFF00
61.                     '_DELAY .5
62.                     'PRINT POINT(hx * s, (hy - 1) * s), POINT(hx * s, (hy - 1) * s + 1), POINT(hx * s, (hy - 1) * s - 1), white
63.                     '_DISPLAY
64.                     'SLEEP
65.                     IF POINT(hx * s, (hy - 1) * s) <> white AND POINT(hx * s, (hy - 1) * s + 1) <> white AND POINT(hx * s, (hy - 1) * s - 1) <> white THEN hy = hy - 2
66.                 END IF
67.             CASE 19712 'the RIGHT ARROW key
68.                 IF hx + 2 < xcells THEN
69.                     'CIRCLE ((hx + 1) * s, hy * s), 5, &HFFFFFF00
70.                     '_DELAY .5
71.                     IF POINT((hx + 1) * s, hy * s) <> white AND POINT((hx + 1) * s + 1, hy * s) <> white AND POINT((hx + 1) * s - 1, hy * s) <> white THEN hx = hx + 2
72.                 END IF
73.             CASE 20480 ' the DOWN ARROW key
74.                 IF hy + 2 < ycells THEN
75.                     'CIRCLE (hx * s, (hy + 1) * s), 5, &HFFFFFF00
76.                     '_DELAY .5
77.                     IF POINT(hx * s, (hy + 1) * s) <> white AND POINT(hx * s, (hy + 1) * s + 1) <> white AND POINT(hx * s, (hy + 1) * s - 1) <> white THEN hy = hy + 2
78.                 END IF
79.             CASE 19200 'the LEFT ARROW key
80.                 IF hx - 2 > 0 THEN
81.                     'CIRCLE ((hx - 1) * s, hy * s), 5, &HFFFFFF00
82.                     '_DELAY .5
83.                     IF POINT((hx - 1) * s, hy * s) <> white AND POINT((hx - 1) * s + 1, hy * s) <> white AND POINT((hx - 1) * s - 1, hy * s) <> white THEN hx = hx - 2
84.                 END IF
85.         END SELECT
86.         FOR ra = 0 TO .5 * s STEP .25 ' make a solid filled circle
87.             CIRCLE (hx * s, hy * s), ra, &HFFFFFF00
88.         NEXT
89.         _DISPLAY
90.         _LIMIT 60
91.  
92.         ' the rest of this loop is input from user, the drawing part is over but might PAINT roadways
93.  
94.         WHILE _MOUSEINPUT: WEND
95.         IF _MOUSEBUTTON(1) THEN
96.             _DELAY .2
97.             _PUTIMAGE , back, 0 'get rid of hero
98.             IF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 0) THEN
99.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(255, 0, 0), &HFFFFFFFF
100.             ELSEIF POINT(_MOUSEX, _MOUSEY) = _RGB32(255, 0, 0) THEN
101.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 0), &HFFFFFFFF
102.             END IF
103.             _DISPLAY
104.             IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
105.             back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
106.             _PUTIMAGE , 0, back 'store current maze into image
107.         END IF
108.         IF _MOUSEBUTTON(2) THEN
109.             _DELAY .2
110.             _PUTIMAGE , back, 0 'get rid of hero
111.             IF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 255) THEN
112.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 0), &HFFFFFFFF
113.             ELSEIF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 0) THEN
114.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 255), &HFFFFFFFF
115.             END IF
116.             _DISPLAY
117.             IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
118.             back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
119.             _PUTIMAGE , 0, back 'store current maze into image
120.         END IF
121.         i$ = INKEY$
122.         IF i$ = "z" AND t < 1 THEN t = t + .005: EXIT DO
123.         IF i$ = "x" AND t > 0 THEN t = t - .005: EXIT DO
124.         IF i$ = "c" AND s > 1 THEN s = s - 1: EXIT DO
125.         IF i$ = "v" AND s < 41 THEN s = s + 1: EXIT DO
126.         IF i$ = CHR$(27) THEN END
127.         IF i$ = CHR$(32) THEN EXIT DO
128.     LOOP
129. LOOP
130.  
131.  
132.  

Oh heck, I never used s2!

[NOVARSEG]

@bplus

Your code is working perfect. The circle moves fast.  I  can scale it way down and it still works . Almost pacman grade!

Works with _FULLSCREEN too. 

Also moving circle scales up or down with cell size.

[bplus]

Hey maybe some sort of Pacman variation that employs red and blue paths and some maze magic to shift the walls around you. I have to confess I never played Pacman.

[NOVARSEG]

yep pacman is an old game for sure.   

Other  features can be added.     I want to try wall pair reversal for sure.  Might be useful in a game . With wall reversal, the moving circle can make a custom path, so in a game it depends on whether that is allowed or not.

[bplus]

OK use spacebar to switch a cells walls and if the cell can be switched (you are not in a corner or intersection of walls and every other step on long straight path section), the cell will switch and the color you are standing on will be painted down the new pathway. If the cell is not one with switchable walls a low buzzer will sound, try one step over from where you are.

It's pretty cool!

Code: QB64: [Select]

1. ' b+ mod NOVARSEG code for 2 tiler 2021-01-25
2. ' 2021-01-27  mod this for navigation and toggle paint jobs red and back or blue and black as per NOVARSEG
3. ' 2021-01-27  add spacebar to reverse a cells walls a sound will buzz if not inside a cell with walls
4. '             The color your standing on will PAINT the new roadway if the walls switch.
5.  
6. CONST W = 1024, H = 700 ' screen width and height and color for lines and border check
7. SCREEN _NEWIMAGE(W, H, 32)
8. _DELAY .25 'wait for screen to set
9. _SCREENMOVE _MIDDLE 'then center it in screen
10. REDIM white AS _UNSIGNED LONG, hColr AS _UNSIGNED LONG
11. white = &HFFFFFFFF
12. s = 10 ' s is the unit for drawing and navigating screen each step is 2*s
13. t = .5 ' t is splitter between up/down walls and left/right walls
14. COLOR white
15. _TITLE "Press z increase over/under, x increase left/right, c makes smaller cells, v bigger, esc to quit, left mouse paints red/black, right blue/black, spacebar to reverse cells"
16. DO
17.     CLS
18.     xcells = INT(W / s) 'how many cells across
19.     ycells = INT(H / s) 'how many down
20.     REDIM maze(xcells + 2, ycells + 2) AS LONG ' save our wall settings in maze array for wall changing with spacebar
21.     FOR y = 0 TO H STEP s * 4
22.         FOR x = 0 TO W STEP s * 4
23.             r = RND
24.             'CIRCLE (x, y), 2, &HFFFFFF00
25.             IF r <= t THEN
26.                 maze(INT(x / s), INT(y / s)) = -1
27.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
28.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
29.             END IF
30.             IF r > t THEN
31.                 maze(INT(x / s), INT(y / s)) = 1
32.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
33.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
34.             END IF
35.             x = x + s * 2: y = y + s * 2 ' offset to do the other half of screen
36.             'CIRCLE (x, y), 2, &HFF0000FF
37.             r = RND
38.             IF r <= t THEN
39.                 maze(INT(x / s), INT(y / s)) = -1
40.                 LINE (x - s, y + s)-(x + s, y + s) 'bottom line
41.                 LINE (x - s, y - s)-(x + s, y - s) 'top line
42.             END IF
43.             IF r > t THEN
44.                 maze(INT(x / s), INT(y / s)) = 1
45.                 LINE (x - s, y - s)-(x - s, y + s) 'left line
46.                 LINE (x + s, y - s)-(x + s, y + s) 'right line
47.             END IF
48.             x = x - s * 2: y = y - s * 2 ' set back to first set
49.         NEXT
50.     NEXT
51.     IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
52.     REDIM back AS LONG
53.     back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
54.     _PUTIMAGE , 0, back 'store current maze into image
55.     xcells = INT(W / s) 'how many cells across
56.     ycells = INT(H / s) 'how many down
57.     hx = INT(xcells / 2) 'put our guy smack in middle of screen but he has to be on even number of cells!
58.     IF hx MOD 2 = 1 THEN hx = hx + 1
59.     hy = INT(ycells / 2)
60.     IF hy MOD 2 = 1 THEN hy = hy + 1
61.     DO
62.         _PUTIMAGE , back, 0
63.         KH& = _KEYHIT
64.         SELECT CASE KH& '                                       which key was pressed?
65.             CASE 27 '                                           the ESC key
66.                 SYSTEM '
67.             CASE 32
68.                 IF maze(hx, hy) THEN ' make sure on a cell that has walls
69.                     IF maze(hx, hy) = 1 THEN
70.                         maze(hx, hy) = -1
71.                     ELSEIF maze(hx, hy) = -1 THEN
72.                         maze(hx, hy) = 1
73.                     END IF
74.                     ' now redraw everything!!!!
75.                     hColr = POINT(hx * s - (s - 1), hy * s - (s - 1)) ' preserve color at hx, hy
76.                     CLS
77.                     FOR y = 0 TO ycells STEP 2 'redraw maze
78.                         FOR x = 0 TO xcells STEP 2
79.                             IF maze(x, y) = -1 THEN
80.                                 LINE (x * s - s, y * s + s)-(x * s + s, y * s + s) 'bottom line
81.                                 LINE (x * s - s, y * s - s)-(x * s + s, y * s - s) 'top line
82.                             ELSEIF maze(x, y) = 1 THEN
83.                                 LINE (x * s - s, y * s - s)-(x * s - s, y * s + s) 'left line
84.                                 LINE (x * s + s, y * s - s)-(x * s + s, y * s + s) 'right line
85.                             END IF
86.                         NEXT
87.                     NEXT
88.                     IF hColr <> white THEN PAINT (hx * s, hy * s), hColr, white ' paint the new roadway
89.                     'take a new picture
90.                     _DISPLAY
91.                     IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
92.                     back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
93.                     _PUTIMAGE , 0, back 'store current maze into image
94.                 ELSE
95.                     SOUND 100, 4
96.                 END IF
97.             CASE 18432 '  Up Arrow
98.                 IF hy - 2 > 0 THEN
99.                     'CIRCLE (hx * s, (hy - 1) * s), 5, &HFFFFFF00
100.                     '_DELAY .5
101.                     'PRINT POINT(hx * s, (hy - 1) * s), POINT(hx * s, (hy - 1) * s + 1), POINT(hx * s, (hy - 1) * s - 1), white
102.                     '_DISPLAY
103.                     'SLEEP
104.                     IF POINT(hx * s, (hy - 1) * s) <> white AND POINT(hx * s, (hy - 1) * s + 1) <> white AND POINT(hx * s, (hy - 1) * s - 1) <> white THEN hy = hy - 2
105.                 END IF
106.             CASE 19712 'the RIGHT ARROW key
107.                 IF hx + 2 < xcells THEN
108.                     'CIRCLE ((hx + 1) * s, hy * s), 5, &HFFFFFF00
109.                     '_DELAY .5
110.                     IF POINT((hx + 1) * s, hy * s) <> white AND POINT((hx + 1) * s + 1, hy * s) <> white AND POINT((hx + 1) * s - 1, hy * s) <> white THEN hx = hx + 2
111.                 END IF
112.             CASE 20480 ' the DOWN ARROW key
113.                 IF hy + 2 < ycells THEN
114.                     'CIRCLE (hx * s, (hy + 1) * s), 5, &HFFFFFF00
115.                     '_DELAY .5
116.                     IF POINT(hx * s, (hy + 1) * s) <> white AND POINT(hx * s, (hy + 1) * s + 1) <> white AND POINT(hx * s, (hy + 1) * s - 1) <> white THEN hy = hy + 2
117.                 END IF
118.             CASE 19200 'the LEFT ARROW key
119.                 IF hx - 2 > 0 THEN
120.                     'CIRCLE ((hx - 1) * s, hy * s), 5, &HFFFFFF00
121.                     '_DELAY .5
122.                     IF POINT((hx - 1) * s, hy * s) <> white AND POINT((hx - 1) * s + 1, hy * s) <> white AND POINT((hx - 1) * s - 1, hy * s) <> white THEN hx = hx - 2
123.                 END IF
124.         END SELECT
125.         FOR ra = 0 TO .5 * s STEP .25 ' make a solid filled circle
126.             CIRCLE (hx * s, hy * s), ra, &HFFFFFF00
127.         NEXT
128.         _DISPLAY
129.         _LIMIT 60
130.  
131.         ' the rest of this loop is input from user, the drawing part is over but might PAINT roadways
132.  
133.         WHILE _MOUSEINPUT: WEND
134.         IF _MOUSEBUTTON(1) THEN
135.             _DELAY .2
136.             _PUTIMAGE , back, 0 'get rid of hero
137.             IF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 0) THEN
138.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(255, 0, 0), &HFFFFFFFF
139.             ELSEIF POINT(_MOUSEX, _MOUSEY) = _RGB32(255, 0, 0) THEN
140.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 0), &HFFFFFFFF
141.             END IF
142.             _DISPLAY
143.             IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
144.             back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
145.             _PUTIMAGE , 0, back 'store current maze into image
146.         END IF
147.         IF _MOUSEBUTTON(2) THEN
148.             _DELAY .2
149.             _PUTIMAGE , back, 0 'get rid of hero
150.             IF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 255) THEN
151.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 0), &HFFFFFFFF
152.             ELSEIF POINT(_MOUSEX, _MOUSEY) = _RGB32(0, 0, 0) THEN
153.                 PAINT (_MOUSEX, _MOUSEY), _RGB32(0, 0, 255), &HFFFFFFFF
154.             END IF
155.             _DISPLAY
156.             IF back THEN _FREEIMAGE back ' be careful not to cause a memory leak
157.             back = _NEWIMAGE(_WIDTH, _HEIGHT, 32) ' this uses new memory regardless if back is same old name or not
158.             _PUTIMAGE , 0, back 'store current maze into image
159.         END IF
160.         i$ = INKEY$
161.         IF i$ = "z" AND t < 1 THEN t = t + .05: EXIT DO '  changed from .005 because too slow
162.         IF i$ = "x" AND t > 0 THEN t = t - .05: EXIT DO
163.         IF i$ = "c" AND s > 3 THEN s = s - 1: EXIT DO
164.         IF i$ = "v" AND s < 41 THEN s = s + 1: EXIT DO
165.         IF i$ = CHR$(27) THEN END
166.     LOOP
167. LOOP
168.  
169.  
170.  

Oh I also changed how fast the t ratio gets changed by z or x, 10 times faster, more like s changes, noticeable with each press.

[NOVARSEG]

Nice toggle effect with space bar. Looking at your code to see how the reversal works.


Ya the t ratio was too slow.