Function to convert UTC to local time?

[SpriggsySpriggs]

Does anyone happen to have a function handy for converting UTC to local time? I've found several things online for C/C++ but they always fail to compile. I'd like to be able to take a UTC timestamp and just put it into whatever time zone is passed.

[Dav]

Is this something like you're looking for?
https://www.qb64.org/forum/index.php?topic=1638.30

- Dav

[moises1953]

Have you tested this?
https://docs.microsoft.com/es-es/windows/win32/api/timezoneapi/nf-timezoneapi-systemtimetotzspecificlocaltimeex

[SpriggsySpriggs]

Have you tested this?
https://docs.microsoft.com/es-es/windows/win32/api/timezoneapi/nf-timezoneapi-systemtimetotzspecificlocaltimeex

@moises1953
I've looked at it but I can't find good information on how to pass the timestamp I have to it.

[SpriggsySpriggs]

Is this something like you're looking for?
https://www.qb64.org/forum/index.php?topic=1638.30

@Dav I saw that but it look like it just converts a timestamp to Epoch/UNIX time which I already have. I'm just wanting to take a string of a UTC date and time and make it local time. Using SystemTimeToTzSpecificLocalTime as moises suggested would probably be it but I can't figure out how to go about using it.

[moises1953]

May be this code helps you

Code: QB64: [Select]

1. TYPE SystemTime
2.   wYear AS INTEGER
3.   wMonth AS INTEGER
4.   wDayOfWeek AS INTEGER
5.   wDay AS INTEGER
6.   wHour AS INTEGER
7.   wMinute AS INTEGER
8.   wSecond AS INTEGER
9.   wMilliseconds AS INTEGER
10. END TYPE
11.  
12. TYPE TDZoneInfo 'TIME_DYNAMIC_ZONE_INFORMATION
13.   Bias AS LONG
14.   StandardName AS STRING * 64 'wchar32
15.   StandardDate AS SystemTime
16.   StandardBias AS LONG
17.   DaylightName AS STRING * 64 'wchar32
18.   DaylightDate AS SystemTime
19.   DaylightBias AS LONG
20.   TimeZoneKeyName AS STRING * 256 ' WCHAR128
21.   DynamicDaylightTimeDisabled AS _BYTE 'BOOLEAN->BYTE
22. END TYPE
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.   FUNCTION SystemTimeToTzSpecificLocalTimeEx%% (BYVAL lpTimeZoneInformation AS _UNSIGNED _OFFSET,_
26.     BYVAL lpUniversalTime AS _UNSIGNED _OFFSET, byval lpLocalTime AS _UNSIGNED _OFFSET)
27.   FUNCTION GetDynamicTimeZoneInformation~& (BYVAL lpTimeZoneInformation AS _UNSIGNED _OFFSET)
28.   SUB GetSystemTime (BYVAL lpSystemTime AS _UNSIGNED _OFFSET)
29. END DECLARE
30.  
31. DIM UTCTime AS SystemTime, loctime AS SystemTime, ZoneInfo AS TDZoneInfo
32.  
33. CALL GetSystemTime(_OFFSET(UTCTime))
34.  
35. PRINT UTCTime.wYear; "/"; UTCTime.wMonth; "/"; UTCTime.wDay
36. PRINT UTCTime.wHour; ":"; UTCTime.wMinute; ":"; UTCTime.wSecond
37.  
38. e~& = GetDynamicTimeZoneInformation(_OFFSET(ZoneInfo))
39. PRINT ZoneInfo.StandardName
40.  
41. f%% = SystemTimeToTzSpecificLocalTimeEx(_OFFSET(ZoneInfo), _OFFSET(UTCTime), _OFFSET(loctime))
42.  
43. PRINT loctime.wYear; "/"; loctime.wMonth; "/"; loctime.wDay
44. PRINT loctime.wHour; ":"; loctime.wMinute; ":"; loctime.wSecond
45.  
46. END
47.  

[SpriggsySpriggs]

@moises1953 That is exactly what I need! Thank you so much!
In the meantime, I discovered how to implement Javascript in QB64 using NodeJS! I'll make a full post on how to do that soon. Here is what my solution was for getting the correct date:

Code: QB64: [Select]

1.     DIM JS AS INTEGER
2.     JS = FREEFILE
3.     OPEN "uuiddate.js" FOR OUTPUT AS #JS
4.     PRINT #JS, "const fs = require('fs');"
5.     PRINT #JS, "let writeStream = fs.createWriteStream('uuiddate.d');"
6.     PRINT #JS, "var d = new Date('" + uuiddate(timestamp) + " " + hour + ":" + minute + ":" + second + " UTC');"
7.     PRINT #JS, "writeStream.write(d.toLocaleString().replace(',',''),'ascii');"
8.     PRINT #JS, "writeStream.end();"
9.     CLOSE #JS
10.     SHELL _HIDE "node " + CHR$(34) + _STARTDIR$ + "\uuiddate.js" + CHR$(34)
11.     KILL "uuiddate.js"
12.     DIM d AS INTEGER
13.     d = FREEFILE
14.     DIM utctolocale AS STRING
15.     OPEN "uuiddate.d" FOR BINARY AS #d
16.     IF LOF(d) <> 0 THEN
17.         LINE INPUT #d, utctolocale
18.     END IF
19.     CLOSE #d
20.     KILL "uuiddate.d"
21.     ExtractTimestamp = utctolocale

[moises1953]

This is a more compact form

Code: QB64: [Select]

1. TYPE SystemTime
2.   wYear AS INTEGER
3.   wMonth AS INTEGER
4.   wDayOfWeek AS INTEGER
5.   wDay AS INTEGER
6.   wHour AS INTEGER
7.   wMinute AS INTEGER
8.   wSecond AS INTEGER
9.   wMilliseconds AS INTEGER
10. END TYPE
11.  
12. TYPE TDZoneInfo 'TIME_DYNAMIC_ZONE_INFORMATION
13.   Bias AS LONG
14.   StandardName AS STRING * 64 'wchar32
15.   StandardDate AS SystemTime
16.   StandardBias AS LONG
17.   DaylightName AS STRING * 64 'wchar32
18.   DaylightDate AS SystemTime
19.   DaylightBias AS LONG
20.   TimeZoneKeyName AS STRING * 256 ' WCHAR128
21.   DynamicDaylightTimeDisabled AS _BYTE 'BOOLEAN->BYTE
22. END TYPE
23.  
24. DECLARE DYNAMIC LIBRARY "kernel32"
25.   FUNCTION SystemTimeToTzSpecificLocalTimeEx%% (lpTimeZoneInformation AS tdzoneinfo,_
26.     lpUniversalTime AS systemTime, lpLocalTime AS systemTime)
27.   FUNCTION GetDynamicTimeZoneInformation~& (lpTimeZoneInformation AS TDZoneInfo)
28.   SUB GetSystemTime (lpSystemTime AS SystemTime)
29. END DECLARE
30.  
31. DIM UTCTime AS SystemTime, loctime AS SystemTime, ZoneInfo AS TDZoneInfo
32.  
33. CALL GetSystemTime(UTCTime)
34.  
35. PRINT UTCTime.wYear; "/"; UTCTime.wMonth; "/"; UTCTime.wDay
36. PRINT UTCTime.wHour; ":"; UTCTime.wMinute; ":"; UTCTime.wSecond
37.  
38. e~& = GetDynamicTimeZoneInformation(ZoneInfo)
39. PRINT ZoneInfo.StandardName
40.  
41. f%% = SystemTimeToTzSpecificLocalTimeEx(ZoneInfo, UTCTime, loctime)
42.  
43. PRINT loctime.wYear; "/"; loctime.wMonth; "/"; loctime.wDay
44. PRINT loctime.wHour; ":"; loctime.wMinute; ":"; loctime.wSecond
45.  
46. END
47.