Address Validation using API

[SpriggsySpriggs]

In case anyone needs to validate addresses for any reason, here is a way that you can do it! Go to smartystreets.com and make a free account! You are limited to 250 API requests per month and you can validate any address! I've created a simple program to show how it can be done.:

Code: QB64: [Select]

1. $CONSOLE:ONLY
2. _DEST _CONSOLE
3. TYPE USaddress
4.     Street AS STRING
5.     City AS STRING
6.     State AS STRING
7. END TYPE
8.  
9. DIM Address AS USaddress
10.  
11. Address.Street = "1600 Pennsylvania Avenue NW"
12. Address.City = "Washington"
13. Address.State = "DC"
14.  
15. PRINT ValidateAddress(Address)
16. SLEEP
17.  
18. FUNCTION ValidateAddress$ (Address AS USaddress)
19.     DIM URL AS STRING
20.     DIM URLFile AS STRING
21.     URL = "https://us-street.api.smartystreets.com/street-address?auth-id=YOURAUTHIDHERE&auth-token=YOURAUTHTOKENHERE&"
22.     URL = URL + "street=" + FormatAsHTTP(Address.Street) + "&"
23.     URL = URL + "city=" + FormatAsHTTP(Address.City) + "&"
24.     URL = URL + "state=" + Address.State + "&"
25.     URL = URL + "candidates=1"
26.     URLFile = "addressvalidation.json"
27.     a% = FileDownload(URL, URLFile)
28.     DIM U AS INTEGER
29.     U = FREEFILE
30.     OPEN URLFile FOR BINARY AS #U
31.     IF LOF(U) <> 0 THEN
32.         LINE INPUT #U, result$
33.     ELSE
34.         CLOSE #U
35.         KILL URLFile
36.         ValidateAddress = "Could not validate"
37.         EXIT FUNCTION
38.     END IF
39.     CLOSE #U
40.     KILL URLFile
41.     validation$ = MID$(result$, INSTR(result$, "dpv_match_code") + 17, 1)
42.     IF validation$ = "Y" THEN
43.         ValidateAddress = "Address exists and is correct"
44.     ELSE
45.         ValidateAddress = "Address either doesn't exist or is invalid"
46.     END IF
47. END FUNCTION
48.  
49. FUNCTION FormatAsHTTP$ (Request AS STRING)
50.     start% = 1
51.     DO
52.         position% = INSTR(start%, Request, " ")
53.         IF position% THEN
54.             MID$(Request, position%, 1) = "+"
55.             start% = position% + 1
56.         END IF
57.     LOOP UNTIL position% = 0
58.     FormatAsHTTP = LCASE$(Request)
59. END FUNCTION
60.  
61. DECLARE DYNAMIC LIBRARY "urlmon"
62.     FUNCTION URLDownloadToFileA (BYVAL pCaller AS LONG, szURL AS STRING, szFileName AS STRING, BYVAL dwReserved AS LONG, BYVAL lpfnCB AS LONG)
63. END DECLARE
64.  
65. FUNCTION FileDownload (URL AS STRING, File AS STRING)
66.     FileDownload = URLDownloadToFileA(0, URL + CHR$(0), File + CHR$(0), 0, 0)
67. END FUNCTION

For obvious reasons I'm not posting my API keys here in the forum. I don't want everyone burning up my allotment. Check it out for yourself and see if you like it! It could be great for an InForm project with an address form where you might need to make sure that someone is entering a valid address. Definitely give this a try!

[loudar]

Ohhhh this is really cool! Might try that out :D

[SpriggsySpriggs]

And if you desired more candidates for your validation you could increase the number in the candidates part of the query string but then you would need to make sure that you parse the return file and handle multiple address returns.