3D : Sierpinski Cube by Ashish

[Qwerkey]

3D : Sierpinski Cube

Author: @Ashish
Source: qb64.org Forum
URL: https://www.qb64.org/forum/index.php?topic=2251.msg114913#msg114913
Version: 1
Tags: [3D], [Graphics], [Open_GL]

Description:
This fractal is popularly known as Menger Sponge. It looks beautiful.

Controls:
Move mouse for rotation.

Source Code:

Code: QB64: [Select]

1. '@Author:Ashish Kushwaha
2. '28 Feb, 2020s
3. _TITLE "Menger Sponge"
4. SCREEN _NEWIMAGE(600, 600, 32)
5.  
6. TYPE vec3
7.     x AS SINGLE
8.     y AS SINGLE
9.     z AS SINGLE
10. END TYPE
11.  
12. DECLARE LIBRARY
13.     SUB glutSolidCube (BYVAL dsize AS DOUBLE) 'use to draw a solid cube by taking the side length as its arguement
14. END DECLARE
15.  
16. 'Algorithm
17. '1. We take a cube.
18. '2. We divide it into 27 equal cubical parts.
19. '3. Out of this 27 cubes, 7 cubes are removed.
20. '4. In the remaining 20 cubes, Step-1 is repeated for each cube.
21. iteration = 3 'no. of iteration. At each iteration, 7 cubes are removed from parent cube.
22. size = 0.5 'the size of our first cube
23. n = (20 ^ iteration) - 1
24.  
25. DIM SHARED glAllow, cubeLoc(n) AS vec3, fundamentalCubeSize 'cubeLoc array store the location of cubes to be rendered. They are the smallest cube which are formed in the last iteration
26. fundamentalCubeSize = size / (3 ^ iteration) 'the size the smallest cube which is formed in the last iteration
27. initFractal 0, 0, 0, size, iteration 'this sub done all calculation for cube location & other stuff.
28.  
29. PRINT (n + 1); " Cubes will rendered with total of "; 8 * (n + 1); " vertices"
30. PRINT "Hit a Key"
31. SLEEP
32. glAllow = 1 'to start rendering in the SUB _GL
33. DO
34.     WHILE _MOUSEINPUT: WEND
35.     _LIMIT 40
36. LOOP
37.  
38. SUB _GL () STATIC
39.     DIM clr(3)
40.     IF glAllow = 0 THEN EXIT SUB 'So that rendering will start as soon as initialization is done.
41.     IF glInit = 0 THEN
42.         _glViewport 0, 0, _WIDTH, _HEIGHT 'this defines the area in the screen where GL rendering will occur
43.         aspect# = _WIDTH / _HEIGHT
44.  
45.         glInit = 1
46.     END IF
47.  
48.     _glEnable _GL_DEPTH_TEST 'this enable Z-buffer. So that we can do 3D things.
49.     _glClear _GL_DEPTH_BUFFER_BIT OR _GL_COLOR_BUFFER_BIT 'Not required unless we do softwre rendering as well.
50.  
51.     'LIGHTS CONFIG
52.     _glEnable _GL_LIGHTING 'this enable us to use light. There are max of 8 lights in GL
53.     _glEnable _GL_LIGHT0
54.     clr(0) = 0.2: clr(1) = 0.2: clr(2) = 0.2: clr(3) = 1
55.     _glLightfv _GL_LIGHT0, _GL_AMBIENT, _OFFSET(clr()) 'this define the color of the material where light can hardly reach.
56.     clr(0) = 0.8: clr(1) = 0.8: clr(2) = 0.8: clr(3) = 1
57.     _glLightfv _GL_LIGHT0, _GL_SPECULAR, _OFFSET(clr()) 'this define the color of the material where light is directly reflected & reach your eye.
58.     _glLightfv _GL_LIGHT0, _GL_DIFFUSE, _OFFSET(clr()) 'this define the default/usual color of the light on the material.
59.     clr(0) = 0: clr(1) = 0: clr(2) = 0: clr(3) = 1
60.     _glLightfv _GL_LIGHT0, _GL_POSITION, _OFFSET(clr()) 'use to define the direction of light when 4th component is 0. When 4th component is 1, it defines the position of light. In this case, the light looses its intensity as distance increases.
61.  
62.     _glMatrixMode _GL_PROJECTION 'usually used for setting up perspective etc.
63.     _gluPerspective 60, aspect#, 0.1, 10 'first arguement tell angle for FOV (Field of View, for human it is round 70degree for one eye.LOL) next one aspect ratio, next 2 are near & far distance. Objects which are not between these distance are clipped. (or are not rendered.)
64.  
65.     _glMatrixMode _GL_MODELVIEW 'rendering takes place here
66.     _glLoadIdentity
67.  
68.     _glTranslatef 0, 0, -1 'move the origin forward by 1 unit
69.     _glRotatef _MOUSEX, 0, 1, 0 'these are for rotation by the movement of mouse.
70.     _glRotatef _MOUSEY, 1, 0, 0
71.  
72.     drawFractal 'draws the fractal
73.     _glFlush 'force all the GL command to complete in finite amount of time
74. END SUB
75.  
76. SUB initFractal (x, y, z, s, N) 'x-position, y-position, z-position, size, N-> iteration
77.     STATIC i
78.     'As we divide the cube, value of N decreases.
79.     IF N = 0 THEN 'when the division is done N times (no. of iteration)
80.         cubeLoc(i).x = x 'store the coordinates of cube
81.         cubeLoc(i).y = y
82.         cubeLoc(i).z = z
83.         i = i + 1
84.         ' ? "Added #",i
85.         ' sleep
86.         EXIT SUB
87.     END IF
88.     'top section
89.     'front row, left to right
90.     initFractal (x - s / 3), (y + s / 3), (z + s / 3), s / 3, N - 1
91.     initFractal (x), (y + s / 3), (z + s / 3), s / 3, N - 1
92.     initFractal (x + s / 3), (y + s / 3), (z + s / 3), s / 3, N - 1
93.     'behind the previous row, left to right
94.     initFractal (x - s / 3), (y + s / 3), (z), s / 3, N - 1
95.     initFractal (x + s / 3), (y + s / 3), (z), s / 3, N - 1
96.     'behind the previous row, left to right
97.     initFractal (x - s / 3), (y + s / 3), (z - s / 3), s / 3, N - 1
98.     initFractal (x), (y + s / 3), (z - s / 3), s / 3, N - 1
99.     initFractal (x + s / 3), (y + s / 3), (z - s / 3), s / 3, N - 1
100.     'middle section
101.     'front row, left to right
102.     initFractal (x - s / 3), (y), (z + s / 3), s / 3, N - 1
103.     initFractal (x + s / 3), (y), (z + s / 3), s / 3, N - 1
104.     'behind the previous row (last one as middle one contain no cube ;) ), left to right
105.     initFractal (x - s / 3), (y), (z - s / 3), s / 3, N - 1
106.     initFractal (x + s / 3), (y), (z - s / 3), s / 3, N - 1
107.     'bottom section
108.     'front row, left to right
109.     initFractal (x - s / 3), (y - s / 3), (z + s / 3), s / 3, N - 1
110.     initFractal (x), (y - s / 3), (z + s / 3), s / 3, N - 1
111.     initFractal (x + s / 3), (y - s / 3), (z + s / 3), s / 3, N - 1
112.     'behind the previous row, left to right
113.     initFractal (x - s / 3), (y - s / 3), (z), s / 3, N - 1
114.     initFractal (x + s / 3), (y - s / 3), (z), s / 3, N - 1
115.     'behind the previous row, left to right
116.     initFractal (x - s / 3), (y - s / 3), (z - s / 3), s / 3, N - 1
117.     initFractal (x), (y - s / 3), (z - s / 3), s / 3, N - 1
118.     initFractal (x + s / 3), (y - s / 3), (z - s / 3), s / 3, N - 1 '20
119.  
120. END SUB
121.  
122. SUB drawFractal ()
123.     FOR i = 0 TO UBOUND(cubeLoc)
124.         _glPushMatrix 'save the previous transformation configuration
125.         _glTranslatef cubeLoc(i).x, cubeLoc(i).y, cubeLoc(i).z 'move at given location
126.         glutSolidCube fundamentalCubeSize 'draws the solid cube of smallest size which is formed in the last iteration
127.         _glPopMatrix 'restore the original transformation configuration
128.     NEXT
129. END SUB
130.