Pushing circles around

[bplus]

I just found this in collisions folder, kind of interesting:

Code: QB64: [Select]

1. _TITLE "Ball Collision - use left mouse button to move red ball"
2. ' by ED12345 copied from [abandoned, outdated and now likely malicious qb64 dot net website - don’t go there] 2018-04-02
3. SCREEN _NEWIMAGE(800, 600, 32)
4.  
5. TYPE BALL
6.     x AS DOUBLE
7.     y AS DOUBLE
8.     radius AS DOUBLE
9. END TYPE
10.  
11. TYPE TARGET
12.     x AS DOUBLE
13.     y AS DOUBLE
14.     radius AS DOUBLE
15. END TYPE
16.  
17. CONST RED = _RGB32(255, 0, 0)
18. CONST BLUE = _RGB32(0, 0, 255)
19. CONST leftMouseButton = 1
20.  
21. DIM SHARED ball AS BALL
22. DIM SHARED target AS TARGET
23.  
24. ball.x = 200: ball.y = 200
25. target.x = 600: target.y = 400
26. ball.radius = 50
27. target.radius = 50
28.  
29.  
30. DO
31.     mouse = _MOUSEINPUT
32.  
33.     IF _MOUSEBUTTON(leftMouseButton) THEN
34.         ball.x = _MOUSEX
35.         ball.y = _MOUSEY
36.  
37.         CALL Collision
38.     END IF
39.  
40.     PCOPY _DISPLAY, 1
41.     CIRCLE (ball.x, ball.y), ball.radius, RED
42.     CIRCLE (target.x, target.y), target.radius, BLUE
43.     _DISPLAY
44.     PCOPY 1, _DISPLAY
45. LOOP
46.  
47.  
48. SUB Collision
49.  
50.     distance! = _HYPOT((ball.x - target.x), (ball.y - target.y))
51.  
52.     IF distance! <= ball.radius + target.radius THEN
53.  
54.         overlap! = (distance - (ball.radius + target.radius)) * 0.5
55.  
56.         ball.x = ball.x - overlap! * (ball.x - target.x) / distance!
57.         ball.y = ball.y - overlap! * (ball.y - target.y) / distance!
58.  
59.         target.x = target.x - overlap! * (target.x - ball.x) / distance!
60.         target.y = target.y - overlap! * (target.y - ball.y) / distance!
61.  
62.     END IF
63.  
64. END SUB
65.  
66.  

Works great!

[OldMoses]

When I pushed the target ball too far off the screen, I felt like the kid who tossed his favorite toy out of the car window. :D

[bplus]

Yeah, STxAxTIC ahead of us in wonderland shooting rocks with his catapult.

I wonder when he'll get to bow and arrow? ;)

[Ashish]

This is nice! I would like to know math behind this... I thought for trigonometry, but you are using different approach I think so..

[STxAxTIC]

This one has pretty simple math in that this demo ignores momentum exchange - that is, speed is not defined at all here. The screenshots below show the derivation for when speed *is* involved, so to make my math match this demo, you have to limit u1 = u2 = 0.

Edit: This derivation of mine sucks. It's impenetrable.  Just use the "q" equation at the bottom of ss1 and call it done.

[bplus]

This is nice! I would like to know math behind this... I thought for trigonometry, but you are using different approach I think so..

Yeah, it's simpler than trig! I will comment.

Code: QB64: [Select]

1. SUB Collision
2.  
3.     distance! = _HYPOT((ball.x - target.x), (ball.y - target.y)) ' <<<< the distance between the 2 circles as the crow flies,
4. ' this distance has an x component and a y component that we deal with individually below for readjusting ball and target
5.  
6.     IF distance! <= ball.radius + target.radius THEN ' <<<< if distance < the sum of the 2 radii of the 2 circles then they must be overlapping
7.         overlap! = (distance - (ball.radius + target.radius)) * 0.5  '<<< split the difference of overlap this should be labeled 1/2 the overlap!
8.  
9.         ball.x = ball.x - overlap! * (ball.x - target.x) / distance!  ' position ball.x according to difference in target.x  and ball.x as a fraction of their distance away
10.         ball.y = ball.y - overlap! * (ball.y - target.y) / distance!  'like wise for ball.y
11.  
12.         target.x = target.x - overlap! * (target.x - ball.x) / distance! '  likewise and in reverse for target.x and y
13.         target.y = target.y - overlap! * (target.y - ball.y) / distance!
14.  
15.     END IF
16.  
17. END SUB
18.  
19.  

While the mouse is down and it's circle is being constantly updated by mouse polling and relocating to that, we don't see the target pushing back on the mouse circle.