Re: Infinite loop situation?

[bplus]

Hi [banned user],

I modified some code I wrote for Secret Santa problem for you to code and decode with:

Code: QB64: [Select]

1. 'Secret Santa 3.bas for QB64 B+ 2018-05-01
2. ' based on versions of Secret Santa I did in JB  2016-12-03
3.  
4.  
5. ' the letters and digits want to give each other presents at Christmas
6. 'if A is Santa to B, then B can't also be Santa to A (or B)
7.  
8. 'To keep Code more secret randomize with a secret seed known only to you and intended reciever
9.  
10. secret## = 32547698.1000001 '< user and reciever should Enter this number
11. RANDOMIZE secret##
12.  
13. DIM SHARED Reform$, Code$
14.  
15. letters$ = "AaBbCcDdEeFfGgHhIiJjKkLlMmNnOoPpQqRrSsTtUuVvWwXxYyZz1234567890"
16. L = LEN(letters$)
17. DIM LS$(L)
18. 'laod array
19. FOR i = 1 TO L
20.     LS$(i) = MID$(letters$, i, 1)
21. NEXT
22. 'scramble array   Knuth Shuffle method
23. FOR i = L TO 2 STEP -1
24.     R = INT(i * RND) + 1
25.     SWAP LS$(i), LS$(R)
26. NEXT
27. 'now reform the Letters
28. Reform$ = ""
29. FOR i = 1 TO L
30.     Reform$ = Reform$ + LS$(i)
31. NEXT
32.  
33. ' Here is simple trick to non repetition > pair the letter with the next one up!!!
34. Code$ = ""
35. FOR i = 1 TO L - 1
36.     Code$ = Code$ + MID$(Reform$, i + 1, 1)
37. NEXT
38. 'catch last letter pair to first
39. Code$ = Code$ + MID$(Reform$, 1, 1)
40.  
41. 'now compare alphabet with code
42. FOR i = 1 TO L
43.     LOCATE 1, i: PRINT MID$(letters$, i, 1)
44.     LOCATE 2, i: PRINT encrypt$(MID$(letters$, i, 1))
45.     'test decode too!
46.     LOCATE 3, i: PRINT decode$(encrypt$(MID$(letters$, i, 1)))
47. NEXT
48. PRINT
49. 'now try some words or phrases
50. WHILE 1
51.     INPUT "(nothing quits) Enter a word or phrase to code "; codeThis$
52.     IF codeThis$ = "" THEN END
53.     coded$ = ""
54.     FOR i = 1 TO LEN(codeThis$)
55.         c$ = MID$(codeThis$, i, 1)
56.         IF INSTR(letters$, c$) = 0 THEN coded$ = coded$ + c$ ELSE coded$ = coded$ + encrypt$(MID$(codeThis$, i, 1))
57.     NEXT
58.     decoded$ = ""
59.     FOR i = 1 TO LEN(coded$)
60.         c$ = MID$(codeThis$, i, 1)
61.         IF INSTR(letters$, c$) = 0 THEN decoded$ = decoded$ + c$ ELSE decoded$ = decoded$ + decode$(MID$(coded$, i, 1))
62.     NEXT
63.     PRINT "           Coded: "; coded$
64.     PRINT "Check Decode too: "; decoded$
65. WEND
66.  
67. FUNCTION encrypt$ (forLetter$)
68.     p = INSTR(Reform$, forLetter$)
69.     encrypt$ = MID$(Code$, p, 1)
70. END FUNCTION
71. FUNCTION decode$ (Letter$)
72.     p = INSTR(Code$, Letter$)
73.     decode$ = MID$(Reform$, p, 1)
74. END FUNCTION
75.  

EDIT: spaces and punctuation now preserved in main code but not in the functions.

[bplus]

Well dang!

Hi [banned user],

Do you want to code spaces too? So you really could code a phrase (code above skips spaces so "Mark missed spaces." becomes "Markmissedspaces", oops! Easy enough to fix of course.


Append:
OK fixed in code above! Still can't use comma with Enter for one variable$.

[bplus]

Hmm... trying different seeds for RANDOMIZE, I find I get same coding for 3254768 as 3254769 but not 3254760 (just changing the last digit).

So even if you can use any numeric type for RANDOMIZE seed, it doesn't guarantee a unique code if vary it in that type.

[bplus]

Such encoding, in my opinion is useless because that would be too simple to decode.

Which is why I scrambled the letters to the variable string I called reform$, before "shifting the letters by x locations".

Take the letters A, B, C... throw them in a hat, pull them out 1, 2, 3, ... and reform$ is a shuffle of the original letters$ string.

reform$ = "MOZSTVA... "

Now M codes to O, O codes to Z, Z codes to S.... you have a code.

To code, find the position in the reform$ string of the letter to code,

say A was in the 15th position of reform$ found by INSTR(reform$, "A")

then it's code is in 15th position of code$ is say "F"  Mid$(code$, 15, 1)

And vice versa to decode:

The letter position in code$ is the decode position in reform$.

There is no constant distance from one letter to it's code and no letter is coded to itself and NO reverse coding like if A codes to S then S codes to A.


See if this is too simple to decode: (see attachhment)